Массив - структура - массив затирает массивы в цикле

Question

Столкнулся с такой проблемой
Есть процедура которая перебирает данные и формирует JSON строку но есть нюанс, он затирает массив который был в структуре уже и вставляет новые данные.
[1C-CODE]Процедура Команда1(Команда)
	//Параметры JSON
	ЗаписьJSON = Новый ЗаписьJSON;
	тПараметрыJSON = Новый ПараметрыЗаписиJSON(ПереносСтрокJSON.Авто, " ", Истина);  
	ЗаписьJSON.УстановитьСтроку(тПараметрыJSON); 
	
	МассивДанныхJSON = Новый Массив;
	СтруктураДанныхJSON = Новый Структура;
	
	СтруктураДанные = Новый Структура;
	
	СтруктураДанные.Вставить("token", "ТОКЕН");
	
	МассивStoks = Новый Массив;
	chrtid = 1;
	nmid = 1;
	ч=1;
	Для ч = 1 По 4 Цикл
		
		МассивStoks = Новый Массив;
		тДанные = Новый Структура;
		тДанные.Вставить("chrtId", chrtid);
		МассивStoks.Добавить(тДанные);
		СтруктураДанныхJSON.Вставить("stocks", МассивStoks);
		МассивДанныхJSON.Добавить(СтруктураДанныхJSON);
		ч=ч+1;	
		chrtid = chrtid+1;
		
	КонецЦикла; 
	
	Сообщить(МассивДанныхJSON);
	СтруктураДанные.Вставить("data", МассивДанныхJSON);
	ЗаписатьJSON(ЗаписьJSON, СтруктураДанные);
	СтрокаJS = ЗаписьJSON.Закрыть();
	х=1;
КонецПроцедуры
[/1C-CODE]


Получаю результат:
[IS-QUOTE]{
 "token": "ТОКЕН",
 "data": [
  {
   "stocks": [
    {
     "chrtId": 2
    }
   ]
  },
  {
   "stocks": [
    {
     "chrtId": 2
    }
   ]
  }
 ]
}[/IS-QUOTE]

а должен быть:

[1C-CODE]{
 "token": "ТОКЕН",
 "data": [
  {
   "stocks": [
    {
     "chrtId": 1
    }
   ]
  },
  {
   "stocks": [
    {
     "chrtId": 2
    }
   ]
  }
 ]
}[/1C-CODE]

Accepted Answer

(1) вот так должно быть:
[CODE]
	ЗаписьJSON = Новый ЗаписьJSON;
    тПараметрыJSON = Новый ПараметрыЗаписиJSON(ПереносСтрокJSON.Авто, " ", Истина);  
    ЗаписьJSON.УстановитьСтроку(тПараметрыJSON); 
    
    МассивДанныхJSON = Новый Массив;
    
    
    СтруктураДанные = Новый Структура;
    
    СтруктураДанные.Вставить("token", "ТОКЕН");
    
    chrtid = 1;
    Для ч = 1 По 4 Цикл
        
        МассивStoks = Новый Массив;
        тДанные = Новый Структура;
        тДанные.Вставить("chrtId", chrtid);
        МассивStoks.Добавить(тДанные);
		СтруктураДанныхJSON = Новый Структура;
        СтруктураДанныхJSON.Вставить("stocks", МассивStoks);
        МассивДанныхJSON.Добавить(СтруктураДанныхJSON);
        //ч=ч+1;  
        chrtid = chrtid+1;
        
    КонецЦикла; 
    
    Сообщить(МассивДанныхJSON);
    СтруктураДанные.Вставить("data", МассивДанныхJSON);
    ЗаписатьJSON(ЗаписьJSON, СтруктураДанные);
    СтрокаJS = ЗаписьJSON.Закрыть();[/CODE]