1c розница 2.3 остатки товаров по поступлениям

ВЫБРАТЬ
	СебестоимостьТоваровОстатки.Номенклатура КАК Номенклатура,
	СУММА(СебестоимостьТоваровОстатки.КоличествоОстаток) КАК КоличествоОстаток
ПОМЕСТИТЬ врОстатки
ИЗ
	РегистрНакопления.ТоварыОрганизаций.Остатки(&ДатаОстатков, ) КАК СебестоимостьТоваровОстатки

СГРУППИРОВАТЬ ПО
	СебестоимостьТоваровОстатки.Номенклатура
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	СебестоимостьТоваровОбороты.Номенклатура КАК Номенклатура,
	СебестоимостьТоваровОбороты.Регистратор КАК Регистратор,
	СебестоимостьТоваровОбороты.Регистратор.МоментВремени КАК РегистраторМоментВремени,
	СебестоимостьТоваровОбороты.Период КАК Период,
	СУММА(СебестоимостьТоваровОбороты.КоличествоОборот) КАК КоличествоОборот
ПОМЕСТИТЬ врОборотРегистратор
ИЗ
	РегистрНакопления.ТоварыОрганизаций.Обороты(
			,
			&ДатаОстатков,
			Регистратор,
			Номенклатура В
				(ВЫБРАТЬ
					врОстатки.Номенклатура
				ИЗ
					врОстатки КАК врОстатки)) КАК СебестоимостьТоваровОбороты
ГДЕ
	(СебестоимостьТоваровОбороты.Регистратор ССЫЛКА Документ.ПоступлениеТоваров
			ИЛИ СебестоимостьТоваровОбороты.Регистратор ССЫЛКА Документ.ВводНачальныхОстатковУзла)

СГРУППИРОВАТЬ ПО
	СебестоимостьТоваровОбороты.Номенклатура,
	СебестоимостьТоваровОбороты.Регистратор,
	СебестоимостьТоваровОбороты.Регистратор.МоментВремени,
	СебестоимостьТоваровОбороты.Период
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	врОборотРегистратор.Номенклатура КАК Номенклатура,
	врОборотРегистратор.Регистратор КАК Регистратор,
	врОборотРегистратор.РегистраторМоментВремени КАК РегистраторМоментВремени,
	врОборотРегистратор.Период КАК Период,
	врОборотРегистратор.КоличествоОборот КАК КоличествоОборот
ПОМЕСТИТЬ врОборотРегистраторБезМинусов
ИЗ
	врОборотРегистратор КАК врОборотРегистратор
ГДЕ
	врОборотРегистратор.КоличествоОборот > 0
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	Документы.Номенклатура КАК Номенклатура,
	Документы.Регистратор КАК Регистратор,
	Документы.Период КАК Период,
	СУММА(ЕСТЬNULL(Движения.КоличествоОборот, 0)) КАК НарастающийИтог,
	МАКСИМУМ(Документы.КоличествоОборот) КАК КоличествоРегистратор
ПОМЕСТИТЬ врОстаткиНарастающийИтог
ИЗ
	врОборотРегистраторБезМинусов КАК Документы
		ЛЕВОЕ СОЕДИНЕНИЕ врОборотРегистраторБезМинусов КАК Движения
		ПО Документы.Номенклатура = Движения.Номенклатура
			И Документы.РегистраторМоментВремени < Движения.РегистраторМоментВремени

СГРУППИРОВАТЬ ПО
	Документы.Номенклатура,
	Документы.Регистратор,
	Документы.Период
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	врОстаткиНарастающийИтог.Номенклатура КАК Номенклатура,
	врОстаткиНарастающийИтог.Регистратор КАК Регистратор,
	врОстаткиНарастающийИтог.Период КАК Период,
	врОстаткиНарастающийИтог.НарастающийИтог КАК НарастающийИтог,
	врОстатки.КоличествоОстаток КАК ИтогоОстаток,
	ВЫБОР
		КОГДА врОстаткиНарастающийИтог.НарастающийИтог < врОстатки.КоличествоОстаток
			ТОГДА ВЫБОР
					КОГДА врОстаткиНарастающийИтог.КоличествоРегистратор > врОстатки.КоличествоОстаток - врОстаткиНарастающийИтог.НарастающийИтог
						ТОГДА врОстатки.КоличествоОстаток - врОстаткиНарастающийИтог.НарастающийИтог
					ИНАЧЕ врОстаткиНарастающийИтог.КоличествоРегистратор
				КОНЕЦ
		ИНАЧЕ 0
	КОНЕЦ КАК КоличествоОстатокПартии,
	НАЧАЛОПЕРИОДА(врОстаткиНарастающийИтог.Период, ПОЛУГОДИЕ) КАК ПериодПолугодие,
	врОстаткиНарастающийИтог.КоличествоРегистратор КАК КоличествоРегистратор
ПОМЕСТИТЬ врОстаткиПартий
ИЗ
	врОстаткиНарастающийИтог КАК врОстаткиНарастающийИтог
		ЛЕВОЕ СОЕДИНЕНИЕ врОстатки КАК врОстатки
		ПО (врОстатки.Номенклатура = врОстаткиНарастающийИтог.Номенклатура)
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	врОстаткиПартий.Номенклатура КАК Номенклатура,
	врОстаткиПартий.Регистратор КАК Регистратор,
	врОстаткиПартий.Период КАК Период,
	врОстаткиПартий.ПериодПолугодие КАК ПериодПолугодие,
	врОстаткиПартий.КоличествоОстатокПартии КАК КоличествоОстатокПартии,
	врОстаткиПартий.КоличествоРегистратор КАК КоличествоРегистратор,
	врОстаткиПартий.НарастающийИтог КАК НарастающийИтог,
	врОстаткиПартий.ИтогоОстаток КАК ИтогоОстаток	
	ИЗ
	врОстаткиПартий КАК врОстаткиПартий
ГДЕ
	врОстаткиПартий.КоличествоОстатокПартии > 0

УПОРЯДОЧИТЬ ПО
	Номенклатура,
	Период УБЫВ