Добрый день всем! Есть отчёт на скд. Вывожу суммуКТ по кварталам за год из регистра бухгалтерии (скрин1) по основным средствам. Необходимо вывести суммуКНалогу основногосредства так же по кварталам которая хранится в непереодическом регистре бухгалтерии. Встрял на моменте связи "Периода" у РС с периодом-кварталам регистра бух. (скрин2). Собственно как правильно связать периода РС с каждым квартлам РБ ?

Привязка периода к кварталам

Вознаграждение за ответ

Сумма: 0 $m

Добавили:
Intercititude (0.44 $m)

Получили:

v3n7 (0.44 $m)

Показать полностью

6. v3n7 15.03.21 13:22 Сейчас в теме +0.44 $m

ВЫБРАТЬ
	НАЧАЛОПЕРИОДА(РасчетНалогаНаИмущество.ПериодРасчета, КВАРТАЛ) КАК Квартал,
	РасчетНалогаНаИмущество.ОсновноеСредство КАК ОсновноеСредство,
	СУММА(РасчетНалогаНаИмущество.СуммаНалогаКУплате) КАК СуммаНалогаКУплате
ИЗ
	РегистрСведений.РасчетНалогаНаИмущество КАК РасчетНалогаНаИмущество

СГРУППИРОВАТЬ ПО
	НАЧАЛОПЕРИОДА(РасчетНалогаНаИмущество.ПериодРасчета, КВАРТАЛ),
	РасчетНалогаНаИмущество.ОсновноеСредство

Показать

Получилось что-то такое, а далее соединяйте по кварталу и основному средству.
Разные суммы в консоли и СКД могут быть из-за настройки измерений в макете компоновки и установленных отборов, т.к. СКД может оптимизировать отборы из-за чего бывает путаница. Да и не забудьте на РС РасчетНалогаНаИмущество наложить отбор по основному средству, чтобы не соединяться со всем регистром.

2. rovenskiy1C 15.03.21 12:36 Сейчас в теме

Мб стоит так поступить. Связать свои параметры со стандартным периодом

Прикрепленные файлы:

4. Intercititude 15.03.21 12:49 Сейчас в теме

(2) Выйдет так, что мне придётся добавить на форму ещё возможность выбирать дату начала и дата конца.
Но у меня сейчас выбирают только год. Мне надо ограничиться этим полем

3. v3n7 15.03.21 12:38 Сейчас в теме

Периодичность "Квартал" - это первое число месяца начала квартала. Для упрощения понимания в каждой временной таблице создайте отдельную колонку в которой будете хранить преобразованную дату, что-то типа:

ДАТАВРЕМЯ(ГОД(Период), МесяцКвартала, 1)

МесяцКвартала можно вычислить так:

ВЫБОР КВАРТАЛ(Период)
    КОГДА 1
        ТОГДА 1
   КОГДА 2
       ТОГДА 4
   КОГДА 3
       ТОГДА 7
   ИНАЧЕ 10
КОНЕЦ

Показать

5. Intercititude 15.03.21 12:51 Сейчас в теме

(3)

ВЫБРАТЬ
	ХозрасчетныйОбороты.Период КАК Квартал,
	ХозрасчетныйОбороты.Субконто1 КАК ОсновноеСредство,
	ХозрасчетныйОбороты.СуммаОборотКт КАК Сумма
ПОМЕСТИТЬ Хозрасчетный
ИЗ
	РегистрБухгалтерии.Хозрасчетный.Обороты(&НачПериода, &КонПериода, Квартал, , ЗНАЧЕНИЕ(ПланВидовХарактеристик.ВидыСубконтоХозрасчетные.ОсновныеСредства), , , ) КАК ХозрасчетныйОбороты

ИНДЕКСИРОВАТЬ ПО
	ОсновноеСредство
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
	ПервоначальныеСведенияОСБухгалтерскийУчетСрезПоследних.ОсновноеСредство КАК ОсновноеСредство,
	ПервоначальныеСведенияОСБухгалтерскийУчетСрезПоследних.ИнвентарныйНомер КАК ИнвентарныйНомер,
	ПервоначальныеСведенияОСБухгалтерскийУчетСрезПоследних.ПервоначальнаяСтоимость КАК ПервоначальнаяСтоимость,
	ПервоначальныеСведенияОСБухгалтерскийУчетСрезПоследних.ПорядокПогашенияСтоимости КАК ПорядокПогашенияСтоимости,
	ВЫБОР
		КОГДА ПервоначальныеСведенияОСБухгалтерскийУчетСрезПоследних.ПорядокПогашенияСтоимости = ЗНАЧЕНИЕ(Перечисление.ПорядокПогашенияСтоимостиОС.НачислениеАмортизации)
			ТОГДА ПервоначальныеСведенияОСБухгалтерскийУчетСрезПоследних.СпособНачисленияАмортизации
		ИНАЧЕ ПервоначальныеСведенияОСБухгалтерскийУчетСрезПоследних.ПорядокПогашенияСтоимости
	КОНЕЦ КАК СпособНачисленияАмортизации
ПОМЕСТИТЬ ПервоначальныеСведенияОСБухгалтерскийУчетКонПериода
ИЗ
	РегистрСведений.ПервоначальныеСведенияОСБухгалтерскийУчет.СрезПоследних(&КонПериода, ) КАК ПервоначальныеСведенияОСБухгалтерскийУчетСрезПоследних

ИНДЕКСИРОВАТЬ ПО
	ОсновноеСредство
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	Хозрасчетный.Квартал КАК Квартал,
	Хозрасчетный.ОсновноеСредство КАК ОсновноеСредство,
	ПервоначальныеСведенияОСБухгалтерскийУчетКонПериода.ИнвентарныйНомер КАК ИнвентарныйНомер,
	Хозрасчетный.Сумма КАК Сумма,
	РасчетНалогаНаИмущество.СуммаНалогаКУплате КАК СуммаНалогаКУплате
ИЗ
	Хозрасчетный КАК Хозрасчетный
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ПервоначальныеСведенияОСБухгалтерскийУчетКонПериода КАК ПервоначальныеСведенияОСБухгалтерскийУчетКонПериода
		ПО Хозрасчетный.ОсновноеСредство = ПервоначальныеСведенияОСБухгалтерскийУчетКонПериода.ОсновноеСредство
		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.РасчетНалогаНаИмущество КАК РасчетНалогаНаИмущество
		ПО Хозрасчетный.ОсновноеСредство = РасчетНалогаНаИмущество.ОсновноеСредство


УПОРЯДОЧИТЬ ПО
	Квартал

Показать

Собственно вот запрос.
Идею Вашу понял, но не пойму как в запросе это добавить корректно ?

6. v3n7 15.03.21 13:22 Сейчас в теме +0.44 $m

ВЫБРАТЬ
	НАЧАЛОПЕРИОДА(РасчетНалогаНаИмущество.ПериодРасчета, КВАРТАЛ) КАК Квартал,
	РасчетНалогаНаИмущество.ОсновноеСредство КАК ОсновноеСредство,
	СУММА(РасчетНалогаНаИмущество.СуммаНалогаКУплате) КАК СуммаНалогаКУплате
ИЗ
	РегистрСведений.РасчетНалогаНаИмущество КАК РасчетНалогаНаИмущество

СГРУППИРОВАТЬ ПО
	НАЧАЛОПЕРИОДА(РасчетНалогаНаИмущество.ПериодРасчета, КВАРТАЛ),
	РасчетНалогаНаИмущество.ОсновноеСредство

Показать

Получилось что-то такое, а далее соединяйте по кварталу и основному средству.
Разные суммы в консоли и СКД могут быть из-за настройки измерений в макете компоновки и установленных отборов, т.к. СКД может оптимизировать отборы из-за чего бывает путаница. Да и не забудьте на РС РасчетНалогаНаИмущество наложить отбор по основному средству, чтобы не соединяться со всем регистром.

7. Intercititude 15.03.21 13:29 Сейчас в теме

(6) Всё получилось! Спасибо,вы крутой!

По поводу отбору по основному средству не совсем понял правда. Имеете ввиду в ГДЕ наложить отбор на регистр ?
Но я подразумеваю что пользователь будет пользоваться типовым отбором от скд.Где уже сможет сам выбирать основные средства.

Прикрепленные файлы:

8. v3n7 15.03.21 14:17 Сейчас в теме

(7) Спасибо)
Я имел ввиду, что вы сначала выбираете обороты по всем ОС за период, а потом соединяете эту таблицу с регистром сведений напрямую. Проблема здесь в том, что в оборотах у вас может быть 10 основных средств, а в РС - 1000 и это будет медленно.

ВЫБРАТЬ
	ХозрасчетныйОбороты.Период КАК Квартал,
	ХозрасчетныйОбороты.Субконто1 КАК ОсновноеСредство,
	ХозрасчетныйОбороты.СуммаОборотКт КАК Сумма
ПОМЕСТИТЬ Хозрасчетный
ИЗ
	РегистрБухгалтерии.Хозрасчетный.Обороты(&НачПериода, &КонПериода, Квартал, , ЗНАЧЕНИЕ(ПланВидовХарактеристик.ВидыСубконтоХозрасчетные.ОсновныеСредства), , , ) КАК ХозрасчетныйОбороты

ИНДЕКСИРОВАТЬ ПО
	ОсновноеСредство
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	НАЧАЛОПЕРИОДА(РасчетНалогаНаИмущество.ПериодРасчета, КВАРТАЛ) КАК Квартал,
	РасчетНалогаНаИмущество.ОсновноеСредство КАК ОсновноеСредство,
	СУММА(РасчетНалогаНаИмущество.СуммаНалогаКУплате) КАК СуммаНалогаКУплате
ИЗ
	РегистрСведений.РасчетНалогаНаИмущество КАК РасчетНалогаНаИмущество
ГДЕ
	РасчетНалогаНаИмущество.ПериодРасчета МЕЖДУ &НачПериода И &КонПериода
	И РасчетНалогаНаИмущество.ОсновноеСредство В
			(ВЫБРАТЬ
				Хозрасчетный.ОсновноеСредство КАК ОсновноеСредство
			ИЗ
				Хозрасчетный КАК Хозрасчетный)

СГРУППИРОВАТЬ ПО
	НАЧАЛОПЕРИОДА(РасчетНалогаНаИмущество.ПериодРасчета, КВАРТАЛ),
	РасчетНалогаНаИмущество.ОсновноеСредство

Показать

Также если у вас сложный запрос с большим количеством временных таблиц, где происходят какие-либо расчеты и в них всех есть поле одинаковым наименованием, то накладывая отбор СКД при преобразовании схемы в запрос, наложит этот отбор не только на результирующую таблицу запроса, но и на все временные, в есть поле отбора.

9. Intercititude 15.03.21 14:19 Сейчас в теме

(8) Сейчас обратил внимание, после соединения кварталов пропал 4 квартал при выводе очтета.почему так ?..

ВЫБРАТЬ
	ХозрасчетныйОбороты.Период КАК Квартал,
	ХозрасчетныйОбороты.Субконто1 КАК ОсновноеСредство,
	ХозрасчетныйОбороты.СуммаОборотКт КАК Сумма
ПОМЕСТИТЬ Хозрасчетный
ИЗ
	РегистрБухгалтерии.Хозрасчетный.Обороты(&НачПериода, &КонПериода, Квартал, , ЗНАЧЕНИЕ(ПланВидовХарактеристик.ВидыСубконтоХозрасчетные.ОсновныеСредства), , , ) КАК ХозрасчетныйОбороты

ИНДЕКСИРОВАТЬ ПО
	ОсновноеСредство
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
	ПервоначальныеСведенияОСБухгалтерскийУчетСрезПоследних.ОсновноеСредство КАК ОсновноеСредство,
	ПервоначальныеСведенияОСБухгалтерскийУчетСрезПоследних.ИнвентарныйНомер КАК ИнвентарныйНомер,
	ПервоначальныеСведенияОСБухгалтерскийУчетСрезПоследних.ПервоначальнаяСтоимость КАК ПервоначальнаяСтоимость,
	ПервоначальныеСведенияОСБухгалтерскийУчетСрезПоследних.ПорядокПогашенияСтоимости КАК ПорядокПогашенияСтоимости,
	ВЫБОР
		КОГДА ПервоначальныеСведенияОСБухгалтерскийУчетСрезПоследних.ПорядокПогашенияСтоимости = ЗНАЧЕНИЕ(Перечисление.ПорядокПогашенияСтоимостиОС.НачислениеАмортизации)
			ТОГДА ПервоначальныеСведенияОСБухгалтерскийУчетСрезПоследних.СпособНачисленияАмортизации
		ИНАЧЕ ПервоначальныеСведенияОСБухгалтерскийУчетСрезПоследних.ПорядокПогашенияСтоимости
	КОНЕЦ КАК СпособНачисленияАмортизации
ПОМЕСТИТЬ ПервоначальныеСведенияОСБухгалтерскийУчетКонПериода
ИЗ
	РегистрСведений.ПервоначальныеСведенияОСБухгалтерскийУчет.СрезПоследних(&КонПериода, {(Организация).*, (ОсновноеСредство).*}) КАК ПервоначальныеСведенияОСБухгалтерскийУчетСрезПоследних

ИНДЕКСИРОВАТЬ ПО
	ОсновноеСредство
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	НАЧАЛОПЕРИОДА(РасчетНалогаНаИмущество.ПериодРасчета, КВАРТАЛ) КАК Квартал,
	РасчетНалогаНаИмущество.ОсновноеСредство КАК ОсновноеСредство,
	СУММА(РасчетНалогаНаИмущество.СуммаНалогаКУплате) КАК СуммаНалогаКУплате
ПОМЕСТИТЬ Налог
ИЗ
	РегистрСведений.РасчетНалогаНаИмущество КАК РасчетНалогаНаИмущество
ГДЕ
	РасчетНалогаНаИмущество.ПериодРасчета МЕЖДУ &НачПериода И &КонПериода
	И РасчетНалогаНаИмущество.ОсновноеСредство В
			(ВЫБРАТЬ
				Хозрасчетный.ОсновноеСредство КАК ОсновноеСредство
			ИЗ
				Хозрасчетный КАК Хозрасчетный)

СГРУППИРОВАТЬ ПО
	РасчетНалогаНаИмущество.ОсновноеСредство,
	НАЧАЛОПЕРИОДА(РасчетНалогаНаИмущество.ПериодРасчета, КВАРТАЛ)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	Хозрасчетный.Квартал КАК Квартал,
	Хозрасчетный.ОсновноеСредство КАК ОсновноеСредство,
	ПервоначальныеСведенияОСБухгалтерскийУчетКонПериода.ИнвентарныйНомер КАК ИнвентарныйНомер,
	Хозрасчетный.Сумма КАК Сумма,
	Налог.СуммаНалогаКУплате КАК СуммаНалогаКУплате
ИЗ
	Хозрасчетный КАК Хозрасчетный
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ПервоначальныеСведенияОСБухгалтерскийУчетКонПериода КАК ПервоначальныеСведенияОСБухгалтерскийУчетКонПериода
		ПО Хозрасчетный.ОсновноеСредство = ПервоначальныеСведенияОСБухгалтерскийУчетКонПериода.ОсновноеСредство
		ЛЕВОЕ СОЕДИНЕНИЕ Налог КАК Налог
		ПО Хозрасчетный.Квартал = Налог.Квартал
			И Хозрасчетный.ОсновноеСредство = Налог.ОсновноеСредство

УПОРЯДОЧИТЬ ПО
	Квартал

Показать

10. v3n7 15.03.21 14:29 Сейчас в теме

(9) У вас во временной таблице "Хозрасчетный" есть данные по 4 кварталу?
Если них нет, то из временной таблицы "Налог" они тоже не попадут, т.к. соединение ЛЕВОЕ.

11. Intercititude 15.03.21 14:32 Сейчас в теме

(10)В том то и дело есть. Пока не соединил они отображались.. странно

Upd: стоп, они были, но вдруг пропали из регистра.хм пока вопрос отпал тогда.

То есть ли данные либо в хозрасчетном за 4 квартал появятся, либо основное средство попадет в периодрасчета в РС "РасчетНалогаНаИмущество" то 4 квартал отобразится ?

12. v3n7 15.03.21 15:04 Сейчас в теме

(11)Тут нужно смотреть данные.