Расширения 1с имена кнопок

//Создает на форме команду и кнопку для этой команды
//Параметры:
// Команды 		- КомандыФормы - Коллекция команд формы.
// Элементы 	- ВсеЭлементыФормы - Все элементы формы.
// ИмяКоманды  	- Строка - Имя команды. Уникальность не проверяется. Может возникнуть ошибка. 
//						для элемента формы к имени в начале добавляется "Кнопка".
// Заголовок	- Строка - Отображаемый текст команды.
// Подсказка	- Строка - Подсказка команды.
// Действие		- Строка - Имя процедуры обработчика команды.
// Родитель		- ГруппаФормы, ФормаКлиентскогоПриложения - Ссылка на родительский элемент.
// ВидКнопки	- ВидКнопкиФормы - Вид кнопки. Если не указан, то равно "КнопкаКоманднойПанели" - Необязателный.
//Возвращаемое значение:
//	Структура:
//		*Команда - КомандаФормы - Созданная команда
//		*Кнопка  - КнопкаФормы - Созданная кнопка
Функция СоздатьКоммандуИКнопку(Команды, Элементы, ИмяКоманды, Заголовок, Подсказка, Действие, Родитель, ВидКнопки = НЕОПРЕДЕЛЕНО) Экспорт
	//Создаем команду
	НоваяКоманда 				= Команды.Добавить(ИмяКоманды);
	НоваяКоманда.Заголовок 		= Заголовок;
	НоваяКоманда.Подсказка		= ?(ЗначениеЗаполнено(Подсказка), Подсказка, Заголовок);
	НоваяКоманда.Действие		= Действие;
	//Создаем кнопку на форме
	НовыйЭлемент 				= Элементы.Добавить("Кнопка" + ИмяКоманды, Тип("КнопкаФормы"), Родитель);
	НовыйЭлемент.Вид			= ?(ВидКнопки = НЕОПРЕДЕЛЕНО, ВидКнопкиФормы.КнопкаКоманднойПанели, ВидКнопки);
	НовыйЭлемент.ИмяКоманды		= ИмяКоманды;

	Возврат Новый Структура("Команда, Кнопка", НоваяКоманда, НовыйЭлемент);
КонецФункции

//Создает на форме группу
//Параметры:
// Элементы 	- ВсеЭлементыФормы - все элементы формы.
// ИмяГруппы  	- Строка - Имя группы. Уникальность не проверяется. Может возникнуть ошибка. 
// ВидГруппы  	- ВидГруппыФормы - Определяет способ представления группы в форме. 
// Заголовок	- Строка - Заголовок группы. Пустая строка означает автоматическое формирование - Необязателный.
// Родитель		- ГруппаФормы, ФормаКлиентскогоПриложения, ТаблицаФормы - Ссылка на родительский элемент - Необязателный.
// Подсказка	- Строка - Текст подсказки к группе - Необязателный.
//Возвращаемое значение:
//	ГруппаФормы - созданная группа указаного вида
Функция ДобавитьГруппу(Элементы, ИмяГруппы, ВидГруппы, Заголовок = "", Родитель = НЕОПРЕДЕЛЕНО, Подсказка = "") Экспорт
	НоваяГруппа 			= Элементы.Добавить(ИмяГруппы, Тип("ГруппаФормы"), Родитель);
	НоваяГруппа.Вид			= ВидГруппы;
	НоваяГруппа.Заголовок 	= Заголовок;
	НоваяГруппа.Подсказка 	= Подсказка;
	
	Возврат НоваяГруппа;
КонецФункции

//Создает на форме поле
//Параметры:
// Элементы 	- ВсеЭлементыФормы - все элементы формы.
// ИмяПоля  	- Строка - Имя поля. Уникальность не проверяется. Может возникнуть ошибка. 
// ВидПоля  	- ВидПоляФормы - Определяет способ представления данных реквизита в форме.
// ПутьКДанным	- Строка - Путь к реквизиту, с которым связан объект.
// Заголовок	- Строка - Заголовок к полю. Пустая строка означает автоматическое определение - Необязателный.
// Родитель		- ГруппаФормы, ФормаКлиентскогоПриложения, ТаблицаФормы - Ссылка на родительский элемент - Необязателный.
// Подсказка	- Строка - Текст всплывающей подсказки, которая появляется при наведении курсора к полю - Необязателный.
//Возвращаемое значение:
//	ГруппаФормы - созданная группа указаного вида
Функция ДобавитьПоле(Элементы, ИмяПоля, ВидПоля, ПутьКДанным, Заголовок = "", Родитель = НЕОПРЕДЕЛЕНО, Подсказка = "") Экспорт
	НовыйЭлемент 				= Элементы.Добавить(ИмяПоля, Тип("ПолеФормы"), Родитель);
	НовыйЭлемент.Вид			= ВидПоля;
	НовыйЭлемент.Заголовок		= Заголовок;
	НовыйЭлемент.Подсказка		= Подсказка;
	НовыйЭлемент.ПутьКДанным	= ПутьКДанным;

	Возврат НовыйЭлемент;
КонецФункции