ВПФ УПД БП 3.0

Функция ПодготовитьДанныеДляПечатиСчетовФактур(ДокументОснование, ДанныеСчетаФактуры) Экспорт

	ДанныеДляПечати = Новый Структура;
	
	СчетФактураПолученныйИзСтранТаможенногоСоюза = 
		КонтрагентРезидентТаможенногоСоюза(ДанныеСчетаФактуры.Контрагент)
		И ТипЗнч(ДанныеСчетаФактуры.СчетФактура) = Тип("ДокументСсылка.СчетФактураПолученный");
	
	Если ТипЗнч(ДокументОснование) = Тип("ДокументСсылка.ПринятиеКУчетуОС")
		ИЛИ СчетФактураПолученныйИзСтранТаможенногоСоюза Тогда
		ДанныеДляПечати.Вставить("Реквизиты",			Неопределено);
		ДанныеДляПечати.Вставить("ТаблицаДокумента",	Неопределено);
		Возврат ДанныеДляПечати;
	КонецЕсли;
	
	ВалютаРеглУчета = ОбщегоНазначенияБПВызовСервераПовтИсп.ПолучитьВалютуРегламентированногоУчета();
	
	ДополнительнаяКолонкаПечатныхФормДокументов = Константы.ДополнительнаяКолонкаПечатныхФормДокументов.Получить();
	Если НЕ ЗначениеЗаполнено(ДополнительнаяКолонкаПечатныхФормДокументов) Тогда
		ДополнительнаяКолонкаПечатныхФормДокументов = Перечисления.ДополнительнаяКолонкаПечатныхФормДокументов.НеВыводить;
	КонецЕсли;
	
	Если НЕ ДанныеСчетаФактуры.Свойство("НеподтверждениеНулевойСтавки") Тогда
		ДанныеСчетаФактуры.Вставить("НеподтверждениеНулевойСтавки", Ложь);
	КонецЕсли;
	
	Если НЕ ДанныеСчетаФактуры.Свойство("СводныйКомиссионный") Тогда
		ДанныеСчетаФактуры.Вставить("СводныйКомиссионный", Ложь);
	КонецЕсли;
	
	Запрос = Новый Запрос;
	Запрос.УстановитьПараметр("ВалютаРеглУчета",					ВалютаРеглУчета);
	Запрос.УстановитьПараметр("ДокументОснование",					ДокументОснование);
	
	СводныйСФКомиссияПоЗакупке 	= Ложь;
	СводныйСФКомиссияПоПродаже	= Ложь;
	
	ПредставлениеПоставщика 	= "";
	АдресПоставщика 			= "";
	Грузоотправитель 			= "";
	ИННКПППоставщика 			= "";
	
	ПредставлениеПокупателя = "";
	АдресПокупателя 		= "";
	Грузополучатель			= "";
	ИННКПППокупателя 		= "";
	
	Если ДанныеСчетаФактуры.СводныйКомиссионный Тогда
		Если ТипЗнч(ДокументОснование) = Тип("ДокументСсылка.СчетФактураВыданный") Тогда
			//значит авансовый, нужно определить по закупке или по продаже
			Если ДанныеСчетаФактуры.ВидСчетаФактуры = Перечисления.ВидСчетаФактурыВыставленного.НаАвансКомитентаНаЗакупку Тогда
				//Значит авансовый выданный комиссионером (комиссия по закупке)
				СводныйСФКомиссияПоЗакупке = Истина;
				
				ПараметрыСводногоСФПоКомиссии = ПолучитьПараметрыСводногоСчетаФактурыКомиссияПоЗакупке(ДанныеСчетаФактуры.СчетФактура, ДанныеСчетаФактуры.ВидСчетаФактуры);
				
				ПредставлениеПоставщика = ПараметрыСводногоСФПоКомиссии.ПредставлениеПоставщика;
				АдресПоставщика 		= ПараметрыСводногоСФПоКомиссии.АдресПоставщика;
				Грузоотправитель 		= ПараметрыСводногоСФПоКомиссии.Грузоотправитель;
				ИННКПППоставщика 		= ПараметрыСводногоСФПоКомиссии.ИННКПППоставщика;	
			Иначе			
				//Значит авансовый выданный комитентом (комиссия по продаже)
				СводныйСФКомиссияПоПродаже	= Истина;
				
				ПараметрыСводногоСФПоКомиссии = ПолучитьПараметрыСводногоСчетаФактурыКомиссияПоПродаже(ДанныеСчетаФактуры.СчетФактура, ДанныеСчетаФактуры.ВидСчетаФактуры);
				
				ПредставлениеПокупателя = ПараметрыСводногоСФПоКомиссии.ПредставлениеПокупателя;
				АдресПокупателя 		= ПараметрыСводногоСФПоКомиссии.АдресПокупателя;
				Грузополучатель 		= ПараметрыСводногоСФПоКомиссии.Грузополучатель;
				ИННКПППокупателя 		= ПараметрыСводногоСФПоКомиссии.ИННКПППокупателя;
			КонецЕсли;
		ИначеЕсли ТипЗнч(ДокументОснование) = Тип("ДокументСсылка.ОтчетКомитентуОПродажах") 
			И ЗначениеЗаполнено(ДанныеСчетаФактуры.СчетФактура.Продавец) Тогда 
			//Значит комиссия по закупке СФ выданный комиссионером
			СводныйСФКомиссияПоЗакупке = Истина;
			
			ПараметрыСводногоСФПоКомиссии = ПолучитьПараметрыСводногоСчетаФактурыКомиссияПоЗакупке(ДанныеСчетаФактуры.СчетФактура, ДанныеСчетаФактуры.ВидСчетаФактуры);
			
			ПредставлениеПоставщика = ПараметрыСводногоСФПоКомиссии.ПредставлениеПоставщика;
			АдресПоставщика 		= ПараметрыСводногоСФПоКомиссии.АдресПоставщика;
			Грузоотправитель 		= ПараметрыСводногоСФПоКомиссии.Грузоотправитель;
			ИННКПППоставщика 		= ПараметрыСводногоСФПоКомиссии.ИННКПППоставщика;
			
		ИначеЕсли ТипЗнч(ДокументОснование) = Тип("ДокументСсылка.ОтчетКомиссионераОПродажах") Тогда
			//Значит комиссия по продаже СФ выданный комитентом
			СводныйСФКомиссияПоПродаже	= Истина;
			
			ПараметрыСводногоСФПоКомиссии = ПолучитьПараметрыСводногоСчетаФактурыКомиссияПоПродаже(ДанныеСчетаФактуры.СчетФактура, ДанныеСчетаФактуры.ВидСчетаФактуры);
			
			ПредставлениеПокупателя = ПараметрыСводногоСФПоКомиссии.ПредставлениеПокупателя;
			АдресПокупателя 		= ПараметрыСводногоСФПоКомиссии.АдресПокупателя;
			Грузополучатель 		= ПараметрыСводногоСФПоКомиссии.Грузополучатель;
			ИННКПППокупателя 		= ПараметрыСводногоСФПоКомиссии.ИННКПППокупателя;
		ИначеЕсли  ТипЗнч(ДокументОснование) = Тип("ДокументСсылка.ПоступлениеТоваровУслуг") Тогда
			//Значит комиссия по закупке СФ полученный от комиссионера
			СводныйСФКомиссияПоЗакупке = Истина;
			
			ПараметрыСводногоСФПоКомиссии = ПолучитьПараметрыСводногоСчетаФактурыКомиссияПоЗакупке(ДанныеСчетаФактуры.СчетФактура, ДанныеСчетаФактуры.ВидСчетаФактуры);
			
			ПредставлениеПоставщика = ПараметрыСводногоСФПоКомиссии.ПредставлениеПоставщика;
			АдресПоставщика 		= ПараметрыСводногоСФПоКомиссии.АдресПоставщика;
			Грузоотправитель 		= ПараметрыСводногоСФПоКомиссии.Грузоотправитель;
			ИННКПППоставщика 		= ПараметрыСводногоСФПоКомиссии.ИННКПППоставщика;
			
		КонецЕсли;
	КонецЕсли;
	
	Запрос.УстановитьПараметр("СводныйСФКомиссияПоЗакупке",			СводныйСФКомиссияПоЗакупке);
	Запрос.УстановитьПараметр("СводныйСФКомиссияПоПродаже",			СводныйСФКомиссияПоПродаже);
	Запрос.УстановитьПараметр("ПредставлениеПоставщика",			ПредставлениеПоставщика);
	Запрос.УстановитьПараметр("АдресПоставщика",					АдресПоставщика);
	Запрос.УстановитьПараметр("Грузоотправитель",					Грузоотправитель);
	Запрос.УстановитьПараметр("ИННКПППоставщика",					ИННКПППоставщика);
	Запрос.УстановитьПараметр("ПредставлениеПокупателя",			ПредставлениеПокупателя);
	Запрос.УстановитьПараметр("АдресПокупателя",					АдресПокупателя);
	Запрос.УстановитьПараметр("Грузополучатель",					Грузополучатель);
	Запрос.УстановитьПараметр("ИННКПППокупателя",					ИННКПППокупателя);
	Запрос.УстановитьПараметр("СчетФактура",						ДанныеСчетаФактуры.СчетФактура);
	Запрос.УстановитьПараметр("ВидСчетаФактуры",					ДанныеСчетаФактуры.ВидСчетаФактуры);
	Запрос.УстановитьПараметр("Контрагент",							ДанныеСчетаФактуры.Контрагент);
	Запрос.УстановитьПараметр("ДоговорКонтрагента",					ДанныеСчетаФактуры.ДоговорКонтрагента);
	Запрос.УстановитьПараметр("ИспользуетсяПостановлениеНДС1137",	ДанныеСчетаФактуры.ИспользуетсяПостановлениеНДС1137);
	Запрос.УстановитьПараметр("НеподтверждениеНулевойСтавки",		ДанныеСчетаФактуры.НеподтверждениеНулевойСтавки);
	Запрос.УстановитьПараметр("ПустоеПодразделение",				БухгалтерскийУчетПереопределяемый.ПустоеПодразделение());
	Запрос.УстановитьПараметр("ТекстБезАкциза",						?(ДанныеСчетаФактуры.ИспользуетсяПостановлениеНДС1137, НСтр("ru = 'без акциза'"), ""));
	Запрос.УстановитьПараметр("ТекстКомиссионноеВознаграждение",	НСтр("ru = 'Комиссионное вознаграждение'"));
	Запрос.УстановитьПараметр("ДополнительнаяКолонкаПечатныхФормДокументов",
		ДополнительнаяКолонкаПечатныхФормДокументов);
	Запрос.УстановитьПараметр("ЕдиницаИзмеренияШтука", Справочники.КлассификаторЕдиницИзмерения.ПолучитьЕдиницуИзмеренияПоУмолчанию());

	НомераТаблиц = Новый Структура;

	Запрос.Текст = Документы[ДокументОснование.Метаданные().Имя].ТекстЗапросаДанныеДляПечатиСчетовФактур(НомераТаблиц)
		+ ТекстЗапросаДанныеДляПечатиСчетовФактур(НомераТаблиц);
	
	Результат = Запрос.ВыполнитьПакет();
	
	Если Результат[НомераТаблиц.Реквизиты].Пустой()
		ИЛИ Результат[НомераТаблиц.ТаблицаДокумента].Пустой() Тогда
		
		ДанныеДляПечати.Вставить("Реквизиты",			Неопределено);
		ДанныеДляПечати.Вставить("ТаблицаДокумента",	Неопределено);

		Возврат ДанныеДляПечати;
		
	КонецЕсли;	
			
	ТаблицаРеквизиты = Результат[НомераТаблиц.Реквизиты].Выгрузить();
	ТаблицаДокумента = Результат[НомераТаблиц.ТаблицаДокумента].Выгрузить();
	
	Сообщить("/////////");
	
	Для Каждого Колонка Из ТаблицаДокумента.Колонки Цикл
	    Сообщить(Колонка.Имя);
	КонецЦикла;
	
	Реквизиты = ТаблицаРеквизиты[0];

	РасчетыВУсловныхЕдиницах = ?(ТипЗнч(Реквизиты.РасчетыВУсловныхЕдиницах) = Тип("Булево"), Реквизиты.РасчетыВУсловныхЕдиницах, Ложь);
	
	НуженПересчетВРубли = (РасчетыВУсловныхЕдиницах ИЛИ ДанныеСчетаФактуры.НеподтверждениеНулевойСтавки)
		И Реквизиты.Валюта <> ВалютаРеглУчета
		И (ДанныеСчетаФактуры.ИспользуетсяПостановлениеНДС1137 
		ИЛИ УчетнаяПолитика.ФормироватьСчетФактуруПоУЕвРублях(Реквизиты.Организация, Реквизиты.ДатаОснования));

	Если НуженПересчетВРубли Тогда
		ТаблицаРеквизиты.ЗаполнитьЗначения(ВалютаРеглУчета, "Валюта");	
	КонецЕсли;

	СчетФактураНаРеализацию = ДанныеСчетаФактуры.ВидСчетаФактуры = Перечисления.ВидСчетаФактурыВыставленного.НаРеализацию;
	
	Для каждого СтрокаДокумента Из ТаблицаДокумента Цикл
		
		Если НуженПересчетВРубли Тогда
			
			СтрокаДокумента.Всего	 = СтрокаДокумента.ВсегоРуб;
			СтрокаДокумента.СуммаНДС = СтрокаДокумента.НДСРуб;
			СтрокаДокумента.Цена	 = 0;
			
		КонецЕсли;	
		
		// Определяем окончательную сумму без НДС с учетом всех корректировок и цену
		СтрокаДокумента.СуммаБезНДС = СтрокаДокумента.Всего - СтрокаДокумента.СуммаНДС;
	
		Если СчетФактураНаРеализацию
			И (СтрокаДокумента.СтавкаНДС = Перечисления.СтавкиНДС.НДС20_120
			ИЛИ СтрокаДокумента.СтавкаНДС = Перечисления.СтавкиНДС.НДС18_118
			ИЛИ СтрокаДокумента.СтавкаНДС = Перечисления.СтавкиНДС.НДС10_110) Тогда
			
			// В счетах-фактурах, составляемых по товарам (работам, услугам),
			// реализуемым по государственным регулируемым ценам,
			// в графе 7 следует указывать ставку налога в размере 18 (10) процентов,
			// а в графе 5 – стоимость поставляемых по счету-фактуре товаров
			// (выполненных работ, оказанных услуг) без налога на добавленную стоимость
			
			Если СтрокаДокумента.Количество <> 0 Тогда
				СтрокаДокумента.Цена = Окр(СтрокаДокумента.Всего / СтрокаДокумента.Количество, 2);
			КонецЕсли;
			
		КонецЕсли;
		
		Если НЕ ЗначениеЗаполнено(СтрокаДокумента.ЕдиницаИзмерения) Тогда
			СтрокаДокумента.Количество = 0;
			СтрокаДокумента.Цена = 0;
		ИначеЕсли СтрокаДокумента.Количество = 0 Тогда
			СтрокаДокумента.ЕдиницаИзмерения = "";
			СтрокаДокумента.Цена = 0;
		ИначеЕсли СтрокаДокумента.Цена = 0 Тогда
			СтрокаДокумента.Цена = Окр(СтрокаДокумента.СуммаБезНДС / СтрокаДокумента.Количество, 2);
		КонецЕсли;
		
	КонецЦикла;
	
	ТаблицаРеквизиты.Колонки.Добавить("ДокументОснование", Документы.ТипВсеСсылки());
	ТаблицаРеквизиты.ЗаполнитьЗначения(ДокументОснование, "ДокументОснование");
	
	Если ТаблицаРеквизиты.Колонки.Найти("СводныйСФКомиссияПоЗакупке") = Неопределено Тогда
		ТаблицаРеквизиты.Колонки.Добавить("СводныйСФКомиссияПоЗакупке", Новый ОписаниеТипов("Булево"));
		ТаблицаРеквизиты.ЗаполнитьЗначения(Ложь, "СводныйСФКомиссияПоЗакупке");
	КонецЕсли;
	
	Если ТаблицаРеквизиты.Колонки.Найти("СводныйСФКомиссияПоПродаже") = Неопределено Тогда
		ТаблицаРеквизиты.Колонки.Добавить("СводныйСФКомиссияПоПродаже", Новый ОписаниеТипов("Булево"));
		ТаблицаРеквизиты.ЗаполнитьЗначения(Ложь, "СводныйСФКомиссияПоПродаже");
	КонецЕсли;
	
	ДанныеДляПечати.Вставить("Реквизиты",			ТаблицаРеквизиты);
	ДанныеДляПечати.Вставить("ТаблицаДокумента",	ТаблицаДокумента);

	Возврат ДанныеДляПечати;

КонецФункции