Создание документа "Заказ поставщику" на основании "Заказ на перемещение" (ЕРП )

Процедура ЗаполнитьДокументНаОснованииЗаказаНаПеремещение(Знач ЗаказНаПеремещение)
	
	Запрос = Новый Запрос(
	"ВЫБРАТЬ
	|	Заказ.Статус           КАК СтатусДокумента,
	|	Заказ.Проведен         КАК Проведен,
	|	Заказ.Организация      КАК Организация,
	|	Заказ.Сделка           КАК Сделка,
	|	Заказ.СТ_Автор.Подразделение    КАК Подразделение,
	|	ВЫБОР
	|		КОГДА Заказ.НаправлениеДеятельности.УчетЗатрат
	|			ТОГДА Заказ.НаправлениеДеятельности
	|		ИНАЧЕ ЗНАЧЕНИЕ(Справочник.НаправленияДеятельности.ПустаяСсылка)
	|	КОНЕЦ                  КАК НаправлениеДеятельности,
	|	Заказ.СкладОтправитель КАК СкладДокумента
	|ИЗ
	|	Документ.ЗаказНаПеремещение КАК Заказ
	|ГДЕ
	|	Заказ.Ссылка = &ЗаказНаПеремещение");
	
	Запрос.УстановитьПараметр("ЗаказНаПеремещение", ЗаказНаПеремещение);
	Реквизиты = Запрос.Выполнить().Выбрать();
	Реквизиты.Следующий();
	
	ОбщегоНазначенияУТ.ПроверитьВозможностьВводаНаОсновании(
		ЗаказНаПеремещение,
		Реквизиты.СтатусДокумента,
		НЕ Реквизиты.Проведен);
	
	// Заполнение шапки
	Организация             = Реквизиты.Организация;
	Сделка                  = Реквизиты.Сделка;
	ДокументОснование       = ЗаказНаПеремещение;
	Подразделение           = Реквизиты.Подразделение;
	НаправлениеДеятельности = Реквизиты.НаправлениеДеятельности;
	Склад                   = Реквизиты.СкладДокумента;
	
	// Заполнение табличной части.
	ПараметрыТаблицыТовары = ОбеспечениеСервер.ПараметрыТаблицыОстатковПоЗаказу();
	ТаблицаТовары          = ОбеспечениеСервер.ТаблицаОстатковКЗаказу(ЗаказНаПеремещение, ПараметрыТаблицыТовары);
	Товары.Загрузить(ТаблицаТовары);
	
	ПроверитьКорректностьНаправленияДеятельности();
	
КонецПроцедуры