В запросе отбор по типу

Форум Программирование Общие вопросы программирования (Dev)

1. user1302499 26.10.20 09:25 Сейчас в теме

Выгружаю номенклатуру из ТЧ, в ТЧ в основном бывает только номенклатура с типом значения Номенклатурная группа, но иногда попадается и просто номенклатура, нужно учесть это в запросе. А то если я передаю только номенклатурные группы, и у какой-то номенклатурной группы не найден артикул, то мне возвращает пустую строку и при ЗагрузитьКолонку(Массив,"АртикулПоставщика"); оно четко загружает. А вот если передаю с типом значения Номенклатура, тогда ничего не возвращает и колонку в ТЧ заполняет не правильно.

Подскажите, как учесть что может быть и тип значения номенклатура помимо номенклатурнаяГруппа

Если ЗначениеЗаполнено(Элемент.ТекущаяСтрока) Тогда
		МассивНоменклатуры = ЭтотОбъект.ВыбраннаяГруппа.ВыгрузитьКолонку("НоменклатурнаяГруппа");
		

		Запрос = Новый Запрос;
		Запрос.Текст = 
		"ВЫБРАТЬ
		|	НоменклатураМТД_Поставщики.Артикул
		|ИЗ
		|	Справочник.Номенклатура.МТД_Поставщики КАК НоменклатураМТД_Поставщики
		|ГДЕ
		|	НоменклатураМТД_Поставщики.Ссылка.НоменклатурнаяГруппа В(&НоменклатурнаяГруппа)
		|	И НоменклатураМТД_Поставщики.Поставщики = &Поставщики
		|	И НоменклатураМТД_Поставщики.Ссылка.ОсновнаяНоменклатура = ИСТИНА";
		
		Запрос.УстановитьПараметр("НоменклатурнаяГруппа", МассивНоменклатуры);
		Запрос.УстановитьПараметр("Поставщики", Элемент.ТекущаяСтрока.Поставщик);
		
		РезультатЗапроса = Запрос.Выполнить().Выгрузить();
		Массив = РезультатЗапроса.ВыгрузитьКолонку("Артикул");
		Если ЗначениеЗаполнено(Массив) Тогда
			ЭтотОбъект.ВыбраннаяГруппа.ЗагрузитьКолонку(Массив,"АртикулПоставщика");
		Иначе
			ВыбраннаяГруппа[0].АртикулПоставщика = "";
		КонецЕсли;
	

	КонецЕсли;

Показать

По теме из базы знаний

Найденные решения

4. SlavaKron 26.10.20 09:34 Сейчас в теме

Если ЗначениеЗаполнено(Элемент.ТекущаяСтрока) Тогда
	
	МассивНоменклатуры = ЭтотОбъект.ВыбраннаяГруппа.ВыгрузитьКолонку("НоменклатурнаяГруппа");
	
	
	Запрос = Новый Запрос;
	Запрос.Текст = 
	"ВЫБРАТЬ
	|    НоменклатураМТД_Поставщики.Ссылка.НоменклатурнаяГруппа КАК НоменклатурнаяГруппа,
	|    НоменклатураМТД_Поставщики.Артикул
	|ИЗ
	|    Справочник.Номенклатура.МТД_Поставщики КАК НоменклатураМТД_Поставщики
	|ГДЕ
	|    НоменклатураМТД_Поставщики.Ссылка.НоменклатурнаяГруппа В(&НоменклатурнаяГруппа)
	|    И НоменклатураМТД_Поставщики.Поставщики = &Поставщики
	|    И НоменклатураМТД_Поставщики.Ссылка.ОсновнаяНоменклатура = ИСТИНА";
	
	Запрос.УстановитьПараметр("НоменклатурнаяГруппа", МассивНоменклатуры);
	Запрос.УстановитьПараметр("Поставщики", Элемент.ТекущаяСтрока.Поставщик);
	
	ТЗ = Запрос.Выполнить().Выгрузить();
	ТЗ.Индексы.Добавить("НоменклатурнаяГруппа");
	
	Для Каждого Стр Из ЭтотОбъект.ВыбраннаяГруппа Цикл
		МассивСтрок = ТЗ.НайтиСтроки(Новый Структура("НоменклатурнаяГруппа", Стр.НоменклатурнаяГруппа));
		Если МассивСтрок.Количество() > 0 Тогда
			Стр.АртикулПоставщика = МассивСтрок[0].Артикул;
		Иначе
			Стр.АртикулПоставщика = "";
		КонецЕсли;
	КонецЦикла;
	
КонецЕсли;

Показать

5. vovan_victory 63 26.10.20 09:35 Сейчас в теме

"ВЫБРАТЬ
        |    НоменклатураМТД_Поставщики.Артикул
        |ИЗ
        |    Справочник.Номенклатура.МТД_Поставщики КАК НоменклатураМТД_Поставщики
        |ГДЕ
        |    НоменклатураМТД_Поставщики.Ссылка.НоменклатурнаяГруппа В(&НоменклатурнаяГруппа)
        |    И НоменклатураМТД_Поставщики.Поставщики = &Поставщики
        |    И НоменклатураМТД_Поставщики.Ссылка.ОсновнаяНоменклатура = ИСТИНА
		| Объединить все
		|ВЫБРАТЬ
        |    НоменклатураМТД_Поставщики.Артикул
        |ИЗ
        |    Справочник.Номенклатура.МТД_Поставщики КАК НоменклатураМТД_Поставщики
        |ГДЕ
        |    НоменклатураМТД_Поставщики.Ссылка В(&НоменклатурнаяГруппа)
        |    И НоменклатураМТД_Поставщики.Поставщики = &Поставщики
        |    И НоменклатураМТД_Поставщики.Ссылка.ОсновнаяНоменклатура = ИСТИНА"

Показать

Остальные ответы

Подписаться на ответы Инфостарт бот

Свернуть все

2. puzo50 26.10.20 09:31 Сейчас в теме

где НоменклатураМТД_Поставщики.Ссылка.Номенклатура ССЫЛКА Справочники.номенклатура
?

3. FatPanzer 26.10.20 09:33 Сейчас в теме

(2)

ССЫЛКА Справочники.номенклатура

Справочник. В данном случае употребляется в единственном числе. В остальном да.

8. user1302499 26.10.20 09:59 Сейчас в теме

(2) Но я так номенклатуру с типом НоменклатурнаяГруппа не вытащу

4. SlavaKron 26.10.20 09:34 Сейчас в теме

Если ЗначениеЗаполнено(Элемент.ТекущаяСтрока) Тогда
	
	МассивНоменклатуры = ЭтотОбъект.ВыбраннаяГруппа.ВыгрузитьКолонку("НоменклатурнаяГруппа");
	
	
	Запрос = Новый Запрос;
	Запрос.Текст = 
	"ВЫБРАТЬ
	|    НоменклатураМТД_Поставщики.Ссылка.НоменклатурнаяГруппа КАК НоменклатурнаяГруппа,
	|    НоменклатураМТД_Поставщики.Артикул
	|ИЗ
	|    Справочник.Номенклатура.МТД_Поставщики КАК НоменклатураМТД_Поставщики
	|ГДЕ
	|    НоменклатураМТД_Поставщики.Ссылка.НоменклатурнаяГруппа В(&НоменклатурнаяГруппа)
	|    И НоменклатураМТД_Поставщики.Поставщики = &Поставщики
	|    И НоменклатураМТД_Поставщики.Ссылка.ОсновнаяНоменклатура = ИСТИНА";
	
	Запрос.УстановитьПараметр("НоменклатурнаяГруппа", МассивНоменклатуры);
	Запрос.УстановитьПараметр("Поставщики", Элемент.ТекущаяСтрока.Поставщик);
	
	ТЗ = Запрос.Выполнить().Выгрузить();
	ТЗ.Индексы.Добавить("НоменклатурнаяГруппа");
	
	Для Каждого Стр Из ЭтотОбъект.ВыбраннаяГруппа Цикл
		МассивСтрок = ТЗ.НайтиСтроки(Новый Структура("НоменклатурнаяГруппа", Стр.НоменклатурнаяГруппа));
		Если МассивСтрок.Количество() > 0 Тогда
			Стр.АртикулПоставщика = МассивСтрок[0].Артикул;
		Иначе
			Стр.АртикулПоставщика = "";
		КонецЕсли;
	КонецЦикла;
	
КонецЕсли;

Показать

6. user1302499 26.10.20 09:48 Сейчас в теме

(4)

Если ЗначениеЗаполнено(Элемент.ТекущаяСтрока) Тогда

МассивНоменклатуры = ЭтотОбъект.ВыбраннаяГруппа.ВыгрузитьКолонку("НоменклатурнаяГруппа");

Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ
| НоменклатураМТД_Поставщики.Ссылка.НоменклатурнаяГруппа КАК НоменклатурнаяГруппа,
| НоменклатураМТД_Поставщики.Артикул
|ИЗ
| Справочник.Номенклатура.МТД_Поставщики КАК НоменклатураМТД_Поставщики
|ГДЕ
| НоменклатураМТД_Поставщики.Ссылка.НоменклатурнаяГруппа В(&НоменклатурнаяГруппа)
| И НоменклатураМТД_Поставщики.Поставщики = &Поставщики
| И НоменклатураМТД_Поставщики.Ссылка.ОсновнаяНоменклатура = ИСТИНА";

Запрос.УстановитьПараметр("НоменклатурнаяГруппа", МассивНоменклатуры);
Запрос.УстановитьПараметр("Поставщики", Элемент.ТекущаяСтрока.Поставщик);

ТЗ = Запрос.Выполнить().Выгрузить();
ТЗ.Индексы.Добавить("НоменклатурнаяГруппа");

Для Каждого Стр Из ЭтотОбъект.ВыбраннаяГруппа Цикл
МассивСтрок = ТЗ.НайтиСтроки(Новый Структура("НоменклатурнаяГруппа", Стр.НоменклатурнаяГруппа));
Если МассивСтрок.Количество() > 0 Тогда
Стр.АртикулПоставщика = МассивСтрок[0].Артикул;
Иначе
Стр.АртикулПоставщика = "";
КонецЕсли;
КонецЦикла;

КонецЕсли;

Показать

Да, это помогло, но почему-то для номенклатуры с типом "Номенклатура" не выводит артикул (но он есть)

9. SlavaKron 26.10.20 10:07 Сейчас в теме

(6) Попробуйте адаптировать запрос из (5) под код в (4).

28. user1302499 28.10.20 12:34 Сейчас в теме

(4) Спасибо, понял как использовать индексы, полезно, тоже помогло!

5. vovan_victory 63 26.10.20 09:35 Сейчас в теме

"ВЫБРАТЬ
        |    НоменклатураМТД_Поставщики.Артикул
        |ИЗ
        |    Справочник.Номенклатура.МТД_Поставщики КАК НоменклатураМТД_Поставщики
        |ГДЕ
        |    НоменклатураМТД_Поставщики.Ссылка.НоменклатурнаяГруппа В(&НоменклатурнаяГруппа)
        |    И НоменклатураМТД_Поставщики.Поставщики = &Поставщики
        |    И НоменклатураМТД_Поставщики.Ссылка.ОсновнаяНоменклатура = ИСТИНА
		| Объединить все
		|ВЫБРАТЬ
        |    НоменклатураМТД_Поставщики.Артикул
        |ИЗ
        |    Справочник.Номенклатура.МТД_Поставщики КАК НоменклатураМТД_Поставщики
        |ГДЕ
        |    НоменклатураМТД_Поставщики.Ссылка В(&НоменклатурнаяГруппа)
        |    И НоменклатураМТД_Поставщики.Поставщики = &Поставщики
        |    И НоменклатураМТД_Поставщики.Ссылка.ОсновнаяНоменклатура = ИСТИНА"

Показать

7. user1302499 26.10.20 09:52 Сейчас в теме

(5)

Показать

Вообще ничего не вывело)

27. user1302499 28.10.20 12:33 Сейчас в теме

(5) Спасибо, этот запрос помог, но чуть поправил
(5)

Показать

10. vovan_victory 63 26.10.20 10:30 Сейчас в теме

В &НоменклатурнаяГруппа что содержится?

Эти условия валидны в обоих случаях(и когда номенклатура и когда номенклатурная группа) 
| И НоменклатураМТД_Поставщики.Поставщики = &Поставщики
| И НоменклатураМТД_Поставщики.Ссылка.ОсновнаяНоменклатура = ИСТИНА

Если подозрение, что "И НоменклатураМТД_Поставщики.Ссылка.ОсновнаяНоменклатура = ИСТИНА" не нужно

11. SlavaKron 26.10.20 10:42 Сейчас в теме

(10) Есть подозрение, что в случае с номенклатурой, достаточно просто выводить ее реквизит "Артикул".

12. user1302499 26.10.20 10:48 Сейчас в теме

(10) В номенклатурной группе есть несколько номенклатур, одна из этих номенклатур основная. Когда нужно вытащить артикул по номенклатурной группе, беру из основной

13. FatPanzer 26.10.20 10:50 Сейчас в теме

(12) Интересный разворот, можете удалять свой запрос, забыть про него как про страшный сон и обдумывать логику с самого начала...

14. user1302499 26.10.20 10:50 Сейчас в теме

(13) почему?

15. FatPanzer 26.10.20 11:22 Сейчас в теме

(14) Потому что если у номенклатурной группы есть только одна основная номенклатура. А у вас есть еще и поставщик...
Может даже я не так выразился. Обдумать не логику запроса, а логику поиска и подбора данных. А потом уже претворять эту логику в запрос.

16. user1302499 26.10.20 12:58 Сейчас в теме

(15) Номенклатурная группа это несколько номенклатур в одной номенклатурной группе, у каждой есть основная номенклатура.
У каждой номенклатуры есть ТЧ где указаны АртикулПоставщика - Поставщик.

Моя задача:

Есть обработка "прайсы поставщиков". На ней есть 2 ТЧ в одну загружается номенклатурные группы/номенклатура, в другую все поставщики которые есть у номенклатуры. И когда я нажимаю на поставщика, в ТЧ с номенклатурой в колонку должны появится артикулы по этим поставщикам. Если у номенклатуры есть артикул по поставщику то он выводится, если нет, пустая ячейка остается.

17. user1302499 26.10.20 12:59 Сейчас в теме

(15) Мне кажется что запрос правильный, просто нужно доработать

18. vovan_victory 63 26.10.20 13:13 Сейчас в теме

Ну так совсем не понятно, что содержит &НоменклатурнаяГруппа? Это массив номенклатурных групп + номенклатура или все отдельно?

20. user1302499 26.10.20 13:21 Сейчас в теме

(18) Может быть массив номенклатурных групп, может быть номенклатур и может быть номенклатурных групп + номенклатура

19. vovan_victory 63 26.10.20 13:20 Сейчас в теме

"А вот если передаю с типом значения Номенклатура, тогда ничего не возвращает и колонку в ТЧ заполняет не правильно."

Я как что то должен вернуть запрос, если
|ГДЕ
| НоменклатураМТД_Поставщики.Ссылка.НоменклатурнаяГруппа В(&НоменклатурнаяГруппа)

ТипЗнч(НоменклатураМТД_Поставщики.Ссылка.НоменклатурнаяГруппа) = Тип("СправочникСсылка.НоменклатурныеГруппы")

По этому запрос и работает при условии ,что на &НоменклатурнаяГруппа содержит номенклатурные группы

21. user1302499 26.10.20 13:23 Сейчас в теме

(19) Я это понимаю, но как сделать так, чтобы он работал и Номенклатурная Группа + Номенклатура в &НоменклатурнаяГруппа

22. vovan_victory 63 26.10.20 14:01 Сейчас в теме

(21)Т. е в таб части "ВыбраннаяГруппа" колонка "НоменклатурнаяГруппа" имеет составной тип?

24. user1302499 26.10.20 16:56 Сейчас в теме

(22) Верно!

23. vovan_victory 63 26.10.20 14:46 Сейчас в теме

"ВЫБРАТЬ
        |	НоменклатураМТД_Поставщики.Артикул КАК Артикул
        |ИЗ
        |	Справочник.Номенклатура.МТД_Поставщики КАК НоменклатураМТД_Поставщики
        |ГДЕ
        |	НоменклатураМТД_Поставщики.Ссылка.НоменклатурнаяГруппа В(&НоменклатурнаяГруппа)
        |	И НоменклатураМТД_Поставщики.Ссылка.ОсновнаяНоменклатура
        |       И НоменклатураМТД_Поставщики.Поставщики = &Поставщики
        |
        |ОБЪЕДИНИТЬ ВСЕ
        |//Во вложенном запросе отбираем номенклатуру, получаем из нее номенклатурную группу,
        |//Потом соединяем с табличными частями 
        |//по номенклатурным группам.
        |// 
        |ВЫБРАТЬ
        |	НоменклатураМТД_Поставщики.Артикул
        |ИЗ
        |	(ВЫБРАТЬ
        |		Номенклатура.НоменклатурнаяГруппа КАК НоменклатурнаяГруппа
        |	ИЗ
        |		Справочник.Номенклатура КАК Номенклатура
        |	ГДЕ
        |		Номенклатура.Ссылка В(&НоменклатурнаяГруппа)) КАК ВложенныйЗапрос
        |		ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Номенклатура.МТД_Поставщики КАК НоменклатураМТД_Поставщики
        |		ПО ВложенныйЗапрос.НоменклатурнаяГруппа = НоменклатураМТД_Поставщики.Ссылка.НоменклатурнаяГруппа
        |ГДЕ
        |	НоменклатураМТД_Поставщики.Ссылка.ОсновнаяНоменклатура
        |       И НоменклатураМТД_Поставщики.Поставщики = &Поставщики"

Показать

25. user1302499 28.10.20 10:58 Сейчас в теме

(23)

Показать

Не, вообще что-то не то выдает)) Это прям вообще мимо)

26. vovan_victory 63 28.10.20 11:26 Сейчас в теме

Я подбросил Вам идею как можно реализовать, а Вы ее сами развивайте. Или ждете что кто то напишет для Вам на 100% рабочий код?

P/S
Еще несколько идей..

МассивНоменклатуры = ЭтотОбъект.ВыбраннаяГруппа.Выгрузить( , "НоменклатурнаяГруппа");//В итоге получите ТаблицуЗначений.

Загружаете эту ТЗ в запрос. Далее используете ее как источник данных(вместо массива) с проверкой типов

Для отладки разбейте запрос на 2 отдельных

29. user1302499 28.10.20 12:36 Сейчас в теме

(26)
(26)

Или ждете что кто то напишет для Вам на 100% рабочий код?

Нет, я использовал Ваш запрос в (5) немного переделал и заполение ТЧ использовал из (4)

30. user1302499 28.10.20 12:37 Сейчас в теме

(26)

МассивНоменклатуры = ЭтотОбъект.ВыбраннаяГруппа.ВыгрузитьКолонку("НоменклатурнаяГруппа");
	
	
	Запрос = Новый Запрос;
	Запрос.Текст = 	
	
	"ВЫБРАТЬ
	|	НоменклатураМТД_Поставщики.Артикул,
	|	НоменклатураМТД_Поставщики.Ссылка.НоменклатурнаяГруппа,
	|	NULL КАК Номенклатура
	|ИЗ
	|	Справочник.Номенклатура.МТД_Поставщики КАК НоменклатураМТД_Поставщики
	|ГДЕ
	|	НоменклатураМТД_Поставщики.Ссылка.НоменклатурнаяГруппа В(&НоменклатурнаяГруппа)
	|	И НоменклатураМТД_Поставщики.Поставщики = &Поставщики
	|	И НоменклатураМТД_Поставщики.Ссылка.ОсновнаяНоменклатура = ИСТИНА
	|
	|ОБЪЕДИНИТЬ ВСЕ
	|
	|ВЫБРАТЬ
	|	НоменклатураМТД_Поставщики.Артикул,
	|	NULL,
	|	НоменклатураМТД_Поставщики.Ссылка
	|ИЗ
	|	Справочник.Номенклатура.МТД_Поставщики КАК НоменклатураМТД_Поставщики
	|ГДЕ
	|	НоменклатураМТД_Поставщики.Ссылка В(&НоменклатурнаяГруппа)
	|	И НоменклатураМТД_Поставщики.Поставщики = &Поставщики";
	
		
	Запрос.УстановитьПараметр("НоменклатурнаяГруппа", МассивНоменклатуры);
	Запрос.УстановитьПараметр("Поставщики", Элемент.ТекущаяСтрока.Поставщик);
			
	ТЗ = Запрос.Выполнить().Выгрузить();
    ТЗ.Индексы.Добавить("НоменклатурнаяГруппа");
	ТЗ.Индексы.Добавить("Номенклатура");
    
	Для Каждого Стр Из ЭтотОбъект.ВыбраннаяГруппа Цикл
		Если ТипЗнч(Стр.НоменклатурнаяГруппа) = Тип("СправочникСсылка.НоменклатурныеГруппы") Тогда
			МассивСтрок = ТЗ.НайтиСтроки(Новый Структура("НоменклатурнаяГруппа", Стр.НоменклатурнаяГруппа));
		Иначе
			МассивСтрок = ТЗ.НайтиСтроки(Новый Структура("Номенклатура", Стр.НоменклатурнаяГруппа));
		КонецЕсли;
        Если МассивСтрок.Количество() > 0 Тогда
            Стр.АртикулПоставщика = МассивСтрок[0].Артикул;
        Иначе
            Стр.АртикулПоставщика = "";
        КонецЕсли;
    КонецЦикла;

Показать

Вот так вот получилось!

Оставьте свое сообщение

E-mail: