Использование ПоказатьВопрос() в событии НачалоВыбора()

В качестве предисловия стоит написать, что в современных типовых конфигурациях настройка "Режим использования модальности" установлена в значение "Не использовать". 

В обычных формах было допустимо использование конструкции "Ответ = Вопрос()"... При вызове этой функции окно программы блокируется (т.е. работает в модальном режиме). Следовательно в пользовательском режиме будет выдана ошибка "Использование модальных окон в данном режиме запрещено".

Какую задачу решал я: 

Перед тем, как изменить одно из ключевых полей на форме, проверялась заполненность вспомогательных таблиц. И если вспомогательная таблица не пустая, необходимо от пользователя получить согласие на её автоматическую модификацию. Это необходимо, т.к. пользователь ранее потратил время на настройку. Возможно он случайно нажал на кнопку выбора из списка у реквизита.

Для этого мне необходимо такую проверку написать в событии "НачалоВыбора". 

Почему именно здесь? Потому как в этом событии есть параметр "СтандартнаяОбработка". 

&НаКлиенте
Процедура СпособОпределенияСпискаСотрудниковНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)

Если данный параметр установить в значение Ложь, и написать Возврат, то выбор даже не начнётся. Но, к сожалению здесь использовать конструкцию ПоказатьВопрос не получится по следующим причинам:

1. Если установить параметр СтандартнаяОбработка = Ложь сразу в процедуре, то не сработает стандартный механизм выбора, который нам нужен при положительном ответе пользователя. 

2. Передать это как параметр в Оповещение тоже нельзя, т.к. назад значение не вернётся. Связано это с тем, что ПоказатьВопрос должно быть последним выполняемым действием в процедуре/функции. 

3. Возможно пользователь ничего не поменял! Тогда и смысла нет ему лишний раз показывать вопрос. Понять произошли изменения или нет можно в событиях "ПриИзменении" либо "ОбработкаВыбора".

По этим причинам пришлось выдумать более сложную схему, состоящую из следующих шагов:

1. Создаем реквизит формы с постфиксом "Исходный".

2. Запоминаем его значение до изменения в событии "НачалоВыбора":

&НаКлиенте
Процедура СпособОпределенияСпискаСотрудниковНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)
	
	Если Не ТаблицаПоказателей.Количество() = 0 Тогда
		СпособОпределенияСпискаСотрудниковИсходный = Объект.СпособОпределенияСпискаСотрудников;
	КонецЕсли;
	
КонецПроцедуры

3. Обрабатываем выбор в событии "ОбработкаВыбора". Здесь мы проверяем, изменилось ли вообще значение. Может и смысла нет задавать пользователю лишний вопрос, ведь он ничего не поменял!

4. Если вспомогательная таблица пустая, то вызываем процедуру, которая является оповещением, как будто пользователь нажал на кнопку "Да". Таким образом ещё уменьшаем количество сценариев, где необходимо вмешательство пользователя.

5. Если вспомогательная таблица не пуста, и значение изменилось - задаем вопрос. 

6. В случае с обычными формами, мы бы обработали выбор в обработчике "При изменении". В данной ситуации код этого обработчика ушел в оповещение. Также в оповещение через параметр передаем СтандартнаяОбработка. Ниже по коду видно, что в одном из случаев, мы устанавливаем её в значение "Ложь". Делаем это ДО ВХОДА в оповещение.

&НаКлиенте
Процедура СпособОпределенияСпискаСотрудниковОбработкаВыбора(Элемент, ВыбранноеЗначение, СтандартнаяОбработка)
	
	Если Не ТаблицаПоказателей.Количество() = 0 И Не СпособОпределенияСпискаСотрудниковИсходный = Объект.СпособОпределенияСпискаСотрудников Тогда
		СтандартнаяОбработка = Ложь;
		СтруктураПараметров = Новый Структура("ВыбранноеЗначение, СтандартнаяОбработка", ВыбранноеЗначение, СтандартнаяОбработка);
		
		Оповещение = Новый ОписаниеОповещения("СпособОпределенияСпискаСотрудниковЗавершениеВыбора", ЭтотОбъект, СтруктураПараметров);
		ПоказатьВопрос(Оповещение, "Уже выбраны показатели. Некоторые могут пропасть при изменении способа определения списка сотрудников! Продолжить?", РежимДиалогаВопрос.ДаНет);
	Иначе
		СтруктураПараметров = Новый Структура("ВыбранноеЗначение, СтандартнаяОбработка", ВыбранноеЗначение, СтандартнаяОбработка);
		
		СпособОпределенияСпискаСотрудниковЗавершениеВыбора(КодВозвратаДиалога.Да, СтруктураПараметров);
	КонецЕсли;
	
КонецПроцедуры

7. Последняя задача - обработать выбор пользователя в оповещении. Если пользователь ответил "Нет", то возвращаем исходное значение реквизита из реквизита формы. 

8. Выполняем необходимые действия при изменении:

&НаКлиенте
Процедура СпособОпределенияСпискаСотрудниковЗавершениеВыбора(Результат, ПараметрыКоманды) Экспорт
	
	Если Результат = КодВозвратаДиалога.Нет Тогда
	    Объект.СпособОпределенияСпискаСотрудников = СпособОпределенияСпискаСотрудниковИсходный;
		
		Возврат;
	ИначеЕсли Результат = КодВозвратаДиалога.Да Тогда
		Если Не ПараметрыКоманды.СтандартнаяОбработка Тогда
		    Объект.СпособОпределенияСпискаСотрудников = ПараметрыКоманды.ВыбранноеЗначение;
		КонецЕсли; 
	КонецЕсли; 

 	ЗаполнитьДостуныеИИспользуемыеДанные(Объект.ТипВыгрузки, Объект.СпособОпределенияСпискаСотрудников);
	
	УстановитьВидимость();

КонецПроцедуры // СпособОпределенияСпискаСотрудниковЗавершениеВыбора()

Обратите внимание на то, что процедура СпособОпределенияСпискаСотрудниковЗавершениеВыбора экспортная. Не забывайте для оповещений ставить Экспорт.

Таким вот замысловатым способом удалось обойти ограничения по модальности окон, и решить мою задачу. Также данный подход снизил количество сценариев, при которых пользователь видит вопрос! Это немаловажно при разработке дружественных интерфейсов. Пользователя необходимо как можно реже отрывать от заполнения формы вопросами и сообщениями.

Собственно статью данную решил написать, т.к. ни на сайте 1С, ни на Инфостарте ничего подобного не нашел по событию "НачалоВыбора". Должна быть полезна... Возможно есть другие варианты решения данной задачи. Не претендую на то, что этот единственный. Предлагаемый мною способ - один из вариантов.