СКД: Вывод результата в ТЗ

Question

Добрый день!
Есть отчет на СКД,не получается вывести результат отчета в таблицу значений. Структура представляет собой 3 группировки, детальных записей нет.
Вывод в ТЗ делаю по кнопке, в дальнейшем хочу вывести в ТЧ.  В кнопке прописываю:

[1C-CODE]ОтчетОбъект = РеквизитФормыВЗначение("Отчет");
	СхемаКомпоновкиДанных = ОтчетОбъект.ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных");
	КомпоновщикНастроек = ОтчетОбъект.КомпоновщикНастроек;

	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;

	МакетКомпоновки   = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, КомпоновщикНастроек.Настройки ,,,Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));
		
	ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки);
	
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
	ТЗ = Новый ТаблицаЗначений;
	ПроцессорВывода.УстановитьОбъект(ТЗ);
	
	ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);
	
	[/1C-CODE]

ТЗ приходит с пустыми значениями,думаю, что дело в группировках, создаю новый вариант отчета Основной1, в котором вывожу только детальные записи без условного оформления , проверяю в предприятии - данные выводит. В кнопке делаю замену настроек (на настройки варианта Основной1):

[1C-CODE] ОтчетОбъект = РеквизитФормыВЗначение("Отчет");
	СхемаКомпоновкиДанных = ОтчетОбъект.ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных");
	КомпоновщикНастроек = ОтчетОбъект.КомпоновщикНастроек;

	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
	ВариантОтчета = СхемаКомпоновкиДанных.ВариантыНастроек.Основной1;
	КомпоновщикНастроек.ЗагрузитьНастройки(ВариантОтчета.Настройки);
	МакетКомпоновки   = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, КомпоновщикНастроек.Настройки ,,,Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));
		
	ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки);
	
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
	ТЗ = Новый ТаблицаЗначений;
	ПроцессорВывода.УстановитьОбъект(ТЗ);
	
	ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);
	

[/1C-CODE]
 
ТЗ приходит с одной пустой строчкой.
Пробовала также выгружать в дерево значений(без замены настроек):приходит дерево с пустыми значениями. 
Во вложении прикрепила как выглядит структура, по сути мне нужны данные по ДокументРеализации.
Подскажите, что я делаю не так.

Accepted Answer

(5)да, дело было в параметрах, не передавались пользовательские настройки

[CODE] ОтчетОбъект = РеквизитФормыВЗначение("Отчет");
	СхемаКомпоновкиДанных = ОтчетОбъект.ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных");
	КомпоновщикНастроек = ОтчетОбъект.КомпоновщикНастроек;
	
	ПользовательскиеНастройки = КомпоновщикНастроек.ПользовательскиеНастройки.Элементы;
	СтруктураПользовательскихНастроек = Новый Структура;
	Для Каждого Элем ИЗ ПользовательскиеНастройки Цикл
		СтруктураПользовательскихНастроек.Вставить(Строка(Элем.Параметр),Элем.Значение)
	КонецЦикла;	

	Настройки = КомпоновщикНастроек.Настройки;
	Для каждого Элемент ИЗ СтруктураПользовательскихНастроек Цикл
		ЭлементНастройки = Настройки.ПараметрыДанных.НайтиЗначениеПараметра(Новый ПараметрКомпоновкиДанных(Элемент.Ключ));
		ЭлементНастройки.Использование = Истина;      
		ЭлементНастройки.Значение = Элемент.Значение;
	КонецЦикла;
	
	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
	МакетКомпоновки   = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, КомпоновщикНастроек.Настройки ,,,Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));
		
	ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки);
	
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
	ТЗ = Новый ТаблицаЗначений;
	ПроцессорВывода.УстановитьОбъект(ТЗ);
	
	ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);
	ТЗ.Свернуть("ДокументРеализации");
	ТЧДокументы.Загрузить(ТЗ);

[/CODE]