Описание формата внутреннего представления данных 1С в контексте обмена данными

Процедура КоманднаяПанельРезультатСохратьТаблицуВФайлУниверсальная(Кнопка)
	
	ДиалогВыбораФайла = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Сохранение);
	ДиалогВыбораФайла.Фильтр = "Файл данных (*.txt)|*.txt";
	ДиалогВыбораФайла.Расширение = "txt";
	ДиалогВыбораФайла.ПредварительныйПросмотр = Ложь;
	ДиалогВыбораФайла.ИндексФильтра = 0;
	
	Если ДиалогВыбораФайла.Выбрать() Тогда
		
		СоответствиеЗамены = ПолучитьСоответствиеЗамены();
		Т = ЗначениеВСтрокуВнутр(РезультатТаблица);
		Для каждого стр Из СоответствиеЗамены Цикл
			Т = СтрЗаменить(Т,стр.Значение,стр.Имя);
			Т = СтрЗаменить(Т,Лев(стр.Значение,36),"_" + стр.Имя);    
		КонецЦикла; 
		
		 ТекстовыйФайл = Новый ТекстовыйДокумент;
		 ТекстовыйФайл.УстановитьТекст(Т);
		 ТекстовыйФайл.Записать(ДиалогВыбораФайла.ПолноеИмяФайла);
		 
	КонецЕсли;
КонецПроцедуры

Процедура КоманднаяПанельРезультатЗагрузитьТаблицуИЗФайлаУниверсальная­(Кнопка)
	
	ДиалогВыбораФайла = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Открытие);
	ДиалогВыбораФайла.Фильтр = "Файл данных (*.txt)|*.txt";
	ДиалогВыбораФайла.Расширение = "txt";
	ДиалогВыбораФайла.ПредварительныйПросмотр = Ложь;
	ДиалогВыбораФайла.ИндексФильтра = 0;
	
	Если ДиалогВыбораФайла.Выбрать() Тогда
		ТекстовыйФайл = Новый ТекстовыйДокумент;
		ТекстовыйФайл.Прочитать(ДиалогВыбораФайла.ПолноеИмяФайла);
		Т = ТекстовыйФайл.ПолучитьТекст();
		СоответствиеЗамены = ПолучитьСоответствиеЗамены();
		Для каждого стр Из СоответствиеЗамены Цикл
			Т = СтрЗаменить(Т,"_" + стр.Имя,Лев(стр.Значение,36));
			Т = СтрЗаменить(Т,стр.Имя,стр.Значение);
		КонецЦикла;
		
		РезультатТаблица = ЗначениеИзСтрокиВнутр(Т);
		
		ЭлементыФормы.ТаблицаРезультата.СоздатьКолонки();
		ЭлементыФормы.КоманднаяПанельРезультат.Кнопки.ВыполнитьАлгоритм.Доступность = Истина;
	КонецЕсли;  
	ЭлементыФормы.НадписьКолСтрокРезультата.Заголовок = СокрЛП(РезультатТаблица.Количество()) + " строк";

КонецПроцедуры

Функция ПолучитьСоответствиеЗамены()
	
	СоответствиеТипов = Новый ТаблицаЗначений;
	СоответствиеТипов.Колонки.Добавить("Имя");
	СоответствиеТипов.Колонки.Добавить("Значение");
	
	ЗапросТекстИтог = "";
	
	Для каждого стр Из Метаданные.Справочники Цикл
		ЗапросТекст = 
		"ВЫБРАТЬ ПЕРВЫЕ 1
		|	Ссылка,
		|	""<Имя>"" КАК Имя
		|ИЗ
		|	<Имя>
		|ОБЪЕДИНИТЬ ВСЕ
		|/////////////////////////////
		|";
		ЗапросТекст = СтрЗаменить(ЗапросТекст, "<Имя>", "Справочник." + стр.Имя);
		
		ЗапросТекстИтог = ЗапросТекстИтог + ЗапросТекст;
		
	КонецЦикла;
	
	//Для каждого стр Из Метаданные.Документы Цикл
	//	ЗапросТекст = 
	//	"ВЫБРАТЬ ПЕРВЫЕ 1
	//	|	Ссылка,
	//	|	""<Имя>"" КАК Имя
	//	|ИЗ
	//	|	<Имя>
	//	|ОБЪЕДИНИТЬ ВСЕ
	//	|/////////////////////////////
	//	|";
	//	ЗапросТекст = СтрЗаменить(ЗапросТекст, "<Имя>", "Документ." + стр.Имя);
	//	
	//	ЗапросТекстИтог = ЗапросТекстИтог + ЗапросТекст;
	//	
	//КонецЦикла;
	
	ЗапросТекстИтог = Лев(ЗапросТекстИтог,СтрДлина(ЗапросТекстИтог) - 45);
	
	Запрос = Новый Запрос;
	Запрос.Текст = ЗапросТекстИтог;
	ТЗ = Запрос.Выполнить().Выгрузить();   
	
	Для каждого стр Из ТЗ Цикл
		//"{"#",0b5f521e-459d-4962-86a6-f3a45fe61010,34:810100155d08eb1f11e7e01fe335f24f}"
		Значение = ЗначениеВСтрокуВнутр(стр.Ссылка);
		раз = Найти(Значение,":");
		НоваяСтрока = СоответствиеТипов.Добавить();
		ЗаполнитьЗначенияСвойств(НоваяСтрока,стр);
		НоваяСтрока.Значение = Сред(Значение,6,раз - 6);
	КонецЦикла; 
	
	Возврат СоответствиеТипов;
	
КонецФункции