Обычные формы и Список документов

Процедура ЭДО_ФормаСпискаДокумента_ПриПолученииДанных(Элемент, ОформленияСтрок, мИспользоватьОбменЭД, ЭтоСчетФактура = Ложь) Экспорт

	Если ЭтоСчетФактура Тогда
		ВидимостьКолонок = Элемент.Колонки.СостояниеЭД.Видимость
	  		ИЛИ Элемент.Колонки.ДействияСНашейСтороны.Видимость
	  		ИЛИ Элемент.Колонки.ДействияСоСтороныДругогоУчастника.Видимость;
	Иначе
		ВидимостьКолонок = Элемент.Колонки.СостояниеЭД.Видимость;
	КонецЕсли;
	
	Если Не мИспользоватьОбменЭД ИЛИ Не ВидимостьКолонок Тогда
		Возврат;
	КонецЕсли;
	
	// Сформируем массив документов для получения состояния 
	ДокументыДляПолученияСостояния = Новый Массив();
	Для Каждого ОформлениеСтроки Из ОформленияСтрок Цикл
		ДокументыДляПолученияСостояния.Добавить(ОформлениеСтроки.ДанныеСтроки.Ссылка);
	КонецЦикла;
	
	СостоянияЭД = ЭлектронныеДокументы.ПолучитьТекстСостоянияЭДПоВладельцам(ДокументыДляПолученияСостояния, ЭтоСчетФактура);
	
	Если ЭтоСчетФактура Тогда
		Для Каждого оформлениеСтроки Из ОформленияСтрок Цикл
			ОформлениеСтроки.Ячейки.СостояниеЭД.Видимость = Ложь;
			
			СостояниеЭД = СостоянияЭД[ОформлениеСтроки.ДанныеСтроки.Ссылка];
			ДействияСНашейСтороны 			  = ?(СостояниеЭД = Неопределено, "", СостояниеЭД.ДействияСНашейСтороны);
			ДействияСоСтороныДругогоУчастника = ?(СостояниеЭД = Неопределено, "", СостояниеЭД.ДействияСоСтороныДругогоУчастника);
			
			ОформлениеСтроки.Ячейки.ДействияСНашейСтороны.УстановитьТекст(ДействияСНашейСтороны);
			ОформлениеСтроки.Ячейки.ДействияСоСтороныДругогоУчастника.УстановитьТекст(ДействияСоСтороныДругогоУчастника);
			
		КонецЦикла
	Иначе
		Для Каждого ОформлениеСтроки Из ОформленияСтрок Цикл
			ОформлениеСтроки.Ячейки.СостояниеЭД.УстановитьТекст(СостоянияЭД[ОформлениеСтроки.ДанныеСтроки.Ссылка]);
		КонецЦикла;
	КонецЕсли;

КонецПроцедуры

Функция ПолучитьТекстСостоянияЭДПоВладельцам(МассивСсылокНаВладельцев, ПомещатьВСтруктуру = Ложь) Экспорт
		
	ТаблицаДанных = ЭлектронныеДокументыСлужебныйВызовСервера.ПолучитьДанныеЭДПоВладельцам(МассивСсылокНаВладельцев);
	Соответствие = Новый Соответствие;
	Для Каждого ТекСтрока Из ТаблицаДанных Цикл
		
		Если ПомещатьВСтруктуру Тогда
			СостояниеВерсииЭД = Новый Структура("СостояниеВерсииЭД, ДействияСНашейСтороны, ДействияСоСтороныДругогоУчастника");
			ЗаполнитьЗначенияСвойств(СостояниеВерсииЭД, ТекСтрока);
		Иначе
			СостояниеВерсииЭД = Строка(ТекСтрока.СостояниеВерсииЭД);
		КонецЕсли;
		Соответствие.Вставить(ТекСтрока.ВладелецЭД, СостояниеВерсииЭД);
	КонецЦикла;
	
	Возврат Соответствие;
	
КонецФункции

Функция ПолучитьДанныеЭДПоВладельцам(МассивСсылокНаВладельцев) Экспорт
	
	УстановитьПривилегированныйРежим(Истина);
	
	Запрос = Новый Запрос;
	Запрос.Текст =
	"ВЫБРАТЬ
	|	СостоянияЭД.СсылкаНаОбъект КАК ВладелецЭД,
	|	СостоянияЭД.СостояниеВерсииЭД КАК СостояниеВерсииЭД,
	|	СостоянияЭД.ДействияСНашейСтороны КАК ДействияСНашейСтороны,
	|	СостоянияЭД.ДействияСоСтороныДругогоУчастника КАК ДействияСоСтороныДругогоУчастника
	|ИЗ
	|	РегистрСведений.СостоянияЭД КАК СостоянияЭД
	|ГДЕ
	|	СостоянияЭД.СсылкаНаОбъект В(&МассивСсылокНаВладельцев)";
	
	Запрос.УстановитьПараметр("МассивСсылокНаВладельцев", МассивСсылокНаВладельцев);
	Результат = Запрос.Выполнить().Выгрузить();
	
	Возврат Результат;
	
КонецФункции