Заполнение документа Начисление зарплаты (ограничить список сотрудников и вывести сообщение пользователю)

Question

Добрый день! 

Вопрос к опытным коллегам, сама программирую недавно. 

Поставили задачу: в документе начисление ЗП при заполнении делать проверку на наличие табеля у человека в месяце расчета зарплаты, иначе выводить список сотрудников, но без расчета ЗП или вообще не выводить, а писать сообщение "нет табеля".

Как я вижу, при подготовке данных для заполнения можно отредактировать запрос сотрудников, исключив тех, у кого нет табеля. Но как сообщить пользователю, что что-то идет не так? Ведь мы находимся в "эфире, на сервере, вне контекста формы. Если же делать на форме, то как, чтобы это более-менее оптимально, а не в стиле "рассчитаем всю зп - вернемся на форму - сообщим пользователю, что пошло не так - нужно рассчитать еще раз" + запретим проведение...

Посоветуйте, каким способом лучше решить задачу =)

Accepted Answer

(2) Хотелось бы по минимуму, конечно. С расширениями в этом проекте не работаем.

Кстати, на данный момент решила вопрос так: написала функцию ЕстьСотрудникиБезТабеляВМесяцеРасчета() 

[CODE]
&НаСервере
Функция ЕстьСотрудникиБезТабеляВМесяцеРасчета()
	
	ЕстьСотрудникиБезТабеля = Истина;
	
	ПараметрыПолученияСотрудников = КадровыйУчет.ПараметрыПолученияСотрудниковОрганизацийПоСпискуФизическихЛиц();
	ПараметрыПолученияСотрудников.Организация = Объект.Организация;
	ПараметрыПолученияСотрудников.Подразделение = Объект.Подразделение;
	ПараметрыПолученияСотрудников.НачалоПериода = Объект.МесяцНачисления;
	ПараметрыПолученияСотрудников.ОкончаниеПериода = КонецМесяца(Объект.МесяцНачисления);
	ПараметрыПолученияСотрудников.ПодработкиРаботниковПоТрудовымДоговорам = ПолучитьФункциональнуюОпцию("ИспользоватьПодработки");
	ПараметрыПолученияСотрудников.РаботникиПоДоговорамГПХ = Ложь; // не проверяем табель для гпхшников
	
	МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;
	КадровыйУчет.СоздатьВТСотрудникиОрганизации(МенеджерВременныхТаблиц, Истина, ПараметрыПолученияСотрудников, "ВТВсеСотрудникиОрганизации");
	
	//получим сотрудников, у которых есть табель
	Запрос = Новый Запрос;
	Запрос.МенеджерВременныхТаблиц = МенеджерВременныхТаблиц;
	Запрос.Текст = 
	"ВЫБРАТЬ РАЗЛИЧНЫЕ
	|	ТабельУчетаРабочегоВремениДанныеОВремени.Сотрудник КАК Сотрудник
	|ПОМЕСТИТЬ ВТСотрудникиСТабелем
	|ИЗ
	|	Документ.ТабельУчетаРабочегоВремени.ДанныеОВремени КАК ТабельУчетаРабочегоВремениДанныеОВремени
	|		ЛЕВОЕ СОЕДИНЕНИЕ Документ.ТабельУчетаРабочегоВремени КАК ТабельУчетаРабочегоВремени
	|		ПО (ТабельУчетаРабочегоВремениДанныеОВремени.Ссылка = ТабельУчетаРабочегоВремени.Ссылка)
	|ГДЕ
	|	ТабельУчетаРабочегоВремени.ДатаНачалаПериода >= &ДатаНачалаПериода
	|	И ТабельУчетаРабочегоВремени.ДатаОкончанияПериода <= &ДатаОкончанияПериода
	|	И ТабельУчетаРабочегоВремени.Организация = &Организация";
	Запрос.УстановитьПараметр("ДатаНачалаПериода", Объект.МесяцНачисления);
	Запрос.УстановитьПараметр("ДатаОкончанияПериода", КонецМесяца(Объект.МесяцНачисления));
	Запрос.УстановитьПараметр("Организация", Объект.Организация);
	Запрос.Выполнить();
	
	//получим отработавших в периоде сотрудников, у которых нет табеля
	Запрос = Новый Запрос;
	Запрос.МенеджерВременныхТаблиц = МенеджерВременныхТаблиц;
	Запрос.Текст = 
	"ВЫБРАТЬ
	|	ВТВсеСотрудникиОрганизации.Сотрудник КАК Сотрудник
	|ИЗ
	|	ВТВсеСотрудникиОрганизации КАК ВТВсеСотрудникиОрганизации
	|		ЛЕВОЕ СОЕДИНЕНИЕ ВТСотрудникиСТабелем КАК ВТСотрудникиСТабелем
	|		ПО ВТВсеСотрудникиОрганизации.Сотрудник = ВТСотрудникиСТабелем.Сотрудник
	|ГДЕ
	|	ВТСотрудникиСТабелем.Сотрудник ЕСТЬ NULL";
	РезультатЗапроса = Запрос.Выполнить();
	
	Если РезультатЗапроса.Пустой() Тогда
		ЕстьСотрудникиБезТабеля = Ложь;
	КонецЕсли;
		
	Возврат ЕстьСотрудникиБезТабеля;

КонецФункции [/CODE]

и в команды Заполнить и Подбор в модуле формы документа добавила: 

[CODE]
        Если ЕстьСотрудникиБезТабеляВМесяцеРасчета() = Истина Тогда
		ОбщегоНазначенияКлиентСервер.СообщитьПользователю("Документ не может быть рассчитан! У некоторых сотрудников отсутствует табель");
		Возврат;
	КонецЕсли; [/CODE]