"Меньше копипаста!", или как Вася универсальную процедуру писал

29.06.21

Разработка - СКД

Программист Вася разбирает подход создания универсальных методов на примере программного вывода СКД.

Есть множество кусков кода, которые мы повторяем вновь и вновь. Одно и тоже. Однотипные кусочки, которые уже выучили наизусть. Однако, юный программист Василий считает, что копипасты - это зло. И что можно выделить универсальный метод, который позволит выполнить тоже самое, но с меньшим количеством строк кода и усилий разработчика.

 

1. Постановка цели

 

У программиста Васи простая задача - вывести программно СКД. Что делает среднестатистический разработчик? Копипастит в код заготовленный шаблон программного вывода. Когда нужно сделать таких выводов несколько штук с разными условиями? Делает несколько кусков однотипного кода, где меняется буквально пара параметров.


Но Вася не такой. Он ещё юн и свеж и полон решимости улучшать всё вокруг.

"Я делаю это, потому что копипасты - Зло!"

И для начала он копипастит пишет этот самый стандартный кусок кода.

//Формируем макет, с помощью компоновщика макета
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;

//Передаем в макет компоновки схему, настройки и данные расшифровки
МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, Настройки, ДанныеРасшифровки);

//Выполним компоновку с помощью процессора компоновки
ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки, , ДанныеРасшифровки);

//Выводим результат в табличный документ
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
ПроцессорВывода.УстановитьДокумент(Результат);

ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);

"Ну всё" - думает Вася. 

И действительно, если обернуть данный код в процедуру, то её использование уже поможет убрать из конфигурации несколько кучек стандартного вывода СКД. 

Процедура СкомпоноватьРезультатОтчета(Результат, СхемаКомпоновкиДанных, НастройкиКомпоновки, ДанныеРасшифровки = Неопределено) Экспорт
	
	//Формируем макет, с помощью компоновщика макета
	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
	
	//Передаем в макет компоновки схему, настройки и данные расшифровки
	МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, НастройкиКомпоновки, ДанныеРасшифровки);
	
	//Выполним компоновку с помощью процессора компоновки
	ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки, , ДанныеРасшифровки);
	
	//Выводим результат в табличный документ
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
	ПроцессорВывода.УстановитьДокумент(Результат);
	
	ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);

КонецПроцедуры

Этот код достаточно распространён и ещё не раз потребуется в разработке.

Однако, Вася идёт дальше... 

 

 

2. Варианты применения

 

"А что, если потребуется вывести результат в таблицу значений?"

Для этого используется немного другой кусок кода.

Вася нашёл его в гугле памяти и выделил для себя те участки, которые отличаются от предыдущего.

//Формируем макет, с помощью компоновщика макета
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
	
//Передаем в макет компоновки схему, настройки и данные расшифровки
МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, Настройки, ДанныеРасшифровки,,
Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));
	
//Выполним компоновку с помощью процессора компоновки
ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки, , ДанныеРасшифровки);
	
//Выводим результат в табличный документ
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
ПроцессорВывода.УстановитьОбъект(Результат);
	
ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);

Отличия минимальные и юный разработчик берётся за доработку своего метода.

"Я делаю это, потому что нужен умный метод!"

Для этого Вася сначала решает, как метод будет определять необходимость вывода в табличный документ или в коллекцию.

Можно, конечно, сделать просто - добавить параметр в процедуру. Однако, Васин метод должен быть максимально "умным"!

Решено. Будем смотреть на тип параметра "Результат".

//Определяем тип генератора
Если ТипЗнч(Результат) = Тип("ТаблицаЗначений") ИЛИ ТипЗнч(Результат) = Тип("ДеревоЗначений") Тогда
    ВыводВКоллекциюЗначений = Истина;
    ТипГенератораВывода     = Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений");
Иначе
    ВыводВКоллекциюЗначений = Ложь;
    ТипГенератораВывода	    = Тип("ГенераторМакетаКомпоновкиДанных");
КонецЕсли;

А далее, в зависимости от значения переменной ВыводВКоллекциюЗначений, используем тот или иной код. Вася оглядывает получившийся метод:

Процедура СкомпоноватьРезультатОтчета(Результат, СхемаКомпоновкиДанных, НастройкиКомпоновки, ДанныеРасшифровки) Экспорт
    
    //Определяем тип генератора
    Если ТипЗнч(Результат) = Тип("ТаблицаЗначений") ИЛИ ТипЗнч(Результат) = Тип("ДеревоЗначений") Тогда
        ВыводВКоллекциюЗначений = Истина;
        ТипГенератораВывода     = Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений");
    Иначе
        ВыводВКоллекциюЗначений = Ложь;
        ТипГенератораВывода     = Тип("ГенераторМакетаКомпоновкиДанных");
    КонецЕсли;
    
    //Формируем макет, с помощью компоновщика макета
    КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
    
    //Передаем в макет компоновки схему, настройки и данные расшифровки
    МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, НастройкиКомпоновки, ДанныеРасшифровки,,ТипГенератораВывода);
    
    //Выполним компоновку с помощью процессора компоновки
    ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
    ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки, , ДанныеРасшифровки);
    
    //Выводим результат
    Если ВыводВКоллекциюЗначений Тогда
        ПроцессорВывода    = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
        ПроцессорВывода.УстановитьОбъект(Результат);
    Иначе
        ПроцессорВывода    = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
        ПроцессорВывода.УстановитьДокумент(Результат);
    КонецЕсли;
    
    ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);

КонецПроцедуры

Ну вот, теперь наша процедура пригодится ещё в большей части случаев. Василий, откладывает подальше кисть мышку, но вдруг вспоминает, что в его задаче в СКД есть "набор данных объект"...

 

3. Распространенные параметры


Что мы делаем, когда нужно выполнить СКД с внешним набором данных? Формируем программно точно так же, но с передачей ещё одного параметра:

ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновки.Инициализировать(МакетКомпоновки, ВнешниеНаборыДанных, ДанныеРасшифровки);

Вот и Василий вспомнил об этом. И решил доработать свою процедуру.

"Я делаю это, потому что никто другой делать не захочет"

Он просто так не сдастся! Тем более, что тут всего лишь пара штрихов.

Процедура СкомпоноватьРезультатОтчета(Результат, СхемаКомпоновкиДанных, 
    НастройкиКомпоновки, ДанныеРасшифровки = Неопределено, ВнешниеНаборыДанных = Неопределено) Экспорт
    
    //Определяем тип генератора
    Если ТипЗнч(Результат) = Тип("ТаблицаЗначений") ИЛИ ТипЗнч(Результат) = Тип("ДеревоЗначений") Тогда
        ВыводВКоллекциюЗначений = Истина;
        ТипГенератораВывода     = Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений");
    Иначе
        ВыводВКоллекциюЗначений = Ложь;
        ТипГенератораВывода     = Тип("ГенераторМакетаКомпоновкиДанных");
    КонецЕсли;
    
    //Формируем макет, с помощью компоновщика макета
    КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
    
    //Передаем в макет компоновки схему, настройки и данные расшифровки
    МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, НастройкиКомпоновки, ДанныеРасшифровки,,ТипГенератораВывода);
    
    //Выполним компоновку с помощью процессора компоновки
    ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
    ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки, ВнешниеНаборыДанных, ДанныеРасшифровки);
    
    //Выводим результат
    Если ВыводВКоллекциюЗначений Тогда
        ПроцессорВывода    = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
        ПроцессорВывода.УстановитьОбъект(Результат);
    Иначе
        ПроцессорВывода    = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
        ПроцессорВывода.УстановитьДокумент(Результат);
    КонецЕсли;
    
    ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);

КонецПроцедуры

Красота! Всё, этот метод уже покроет большую часть необходимых программных выводов СКД.

Но почему-то Василий недоволен. Ему кажется, что что-то можно улучшить. Но что?

 

4. Дополнительные параметры


Какая-то неведанная сила толкнула юного разработчика открыть Синтаксис-Помощник...

Взгляните сами

<МакетОформления> (необязательный)

Тип: МакетОформленияКомпоновкиДанных. 
Макет оформления, в соответствии с которым необходимо оформлять макет компоновки данных. Если не указан, будет использоваться макет оформления по умолчанию.

<ПроверятьДоступностьПолей> (необязательный)

Тип: Булево. 
Определяет, выполнять ли проверку прав на просмотр полей и проверку доступности поля во включенных функциональных возможностях.
Значение по умолчанию: Истина.

<ПараметрыФункциональныхОпций> (необязательный)

Тип: Структура. 
Содержит параметры функциональных опций, используемые при исполнении отчета.

<ВозможностьИспользованияВнешнихФункций> (необязательный)

Тип: Булево. 
Указывает возможность использования функции общих модулей конфигурации в выражениях компоновки данных.
Значение по умолчанию: Ложь.

<ОграничиватьПолучениеПолейПоСсылкамПоПравуПросмотр> (необязательный)

Тип: Булево. 
Если значение параметра равно Истина, то при отображении результата запроса учитывается право пользователя "Просмотр" на таблицы и поля, участвующие в запросе. Если в отчете или динамическом списке присутствует значение поля недоступного по праву "Просмотр", то выводится пустая ячейка.
Если значение параметра равно Ложь и параметр ПроверятьДоступностьПолей установлен в Истина, то значение выводится, даже если у пользователя нет права "Просмотр".
Значение по умолчанию: Истина.
 

 

Василий узнал много нового. И теперь он жаждет открыть это для других. 

"Я это делаю, чтобы нести знания!".

Для начала он вставил все найденные параметры в методы.

//Передаем в макет компоновки схему, настройки и данные расшифровки
МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, НастройкиКомпоновки, 
ДанныеРасшифровки, МакетОформления, ТипГенератораВывода, ПроверятьДоступностьПолей, ПараметрыФункциональныхОпций);

//Выполним компоновку с помощью процессора компоновки
ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки, ВнешниеНаборыДанных, ДанныеРасшифровки, ВозможностьИспользованияВнешнихФункций);

На входе в процедуру он решил выделить для всех новых параметров одну структуру "ДополнительныеПараметры".

Процедура СкомпоноватьРезультатОтчета(Результат, СхемаКомпоновкиДанных, НастройкиКомпоновки, 
	ДанныеРасшифровки = Неопределено, ВнешниеНаборыДанных = Неопределено, ДополнительныеПараметры = Неопределено) Экспорт
    

Василий вообще любит структуры. Он сделал отдельную "ПараметрыВывода", где прописал все используемые дополнительные параметры с их стандартными значениями. А потом просто дозаполняет эту структуру.

//Инициализируем дополнительные параметры вывода
ПараметрыВывода    = Новый Структура;
ПараметрыВывода.Вставить("МакетОформления"                        , Неопределено);
ПараметрыВывода.Вставить("ПроверятьДоступностьПолей"              , Истина);
ПараметрыВывода.Вставить("ПараметрыФункциональныхОпций"           , Новый Структура);
ПараметрыВывода.Вставить("ВозможностьИспользованияВнешнихФункций" , Ложь);

Если НЕ ДополнительныеПараметры = Неопределено Тогда
    ЗаполнитьЗначенияСвойств(ПараметрыВывода, ДополнительныеПараметры);
КонецЕсли;

Вася доволен тем, что получилось:

Процедура СкомпоноватьРезультатОтчета(Результат, СхемаКомпоновкиДанных, НастройкиКомпоновки, 
    ДанныеРасшифровки = Неопределено, ВнешниеНаборыДанных = Неопределено, ДополнительныеПараметры = Неопределено) Экспорт
    
    
    //Инициализируем дополнительные параметры вывода
    ПараметрыВывода    = Новый Структура;
    ПараметрыВывода.Вставить("МакетОформления"                        , Неопределено);
    ПараметрыВывода.Вставить("ПроверятьДоступностьПолей"              , Истина);
    ПараметрыВывода.Вставить("ПараметрыФункциональныхОпций"           , Новый Структура);
    ПараметрыВывода.Вставить("ВозможностьИспользованияВнешнихФункций" , Ложь);
    
    Если НЕ ДополнительныеПараметры = Неопределено Тогда
        ЗаполнитьЗначенияСвойств(ПараметрыВывода, ДополнительныеПараметры);
    КонецЕсли;
    
    //Определяем тип генератора
    Если ТипЗнч(Результат) = Тип("ТаблицаЗначений") ИЛИ ТипЗнч(Результат) = Тип("ДеревоЗначений") Тогда
        ВыводВКоллекциюЗначений = Истина;
        ТипГенератораВывода     = Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений");
    Иначе
        ВыводВКоллекциюЗначений = Ложь;
        ТипГенератораВывода     = Тип("ГенераторМакетаКомпоновкиДанных");
    КонецЕсли;
    
    //Формируем макет, с помощью компоновщика макета
    КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
    
    //Передаем в макет компоновки схему, настройки и данные расшифровки
    МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, НастройкиКомпоновки, 
    ДанныеРасшифровки, ПараметрыВывода.МакетОформления, ТипГенератораВывода, 
    ПараметрыВывода.ПроверятьДоступностьПолей, ПараметрыВывода.ПараметрыФункциональныхОпций);
    
    //Выполним компоновку с помощью процессора компоновки
    ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
    ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки, ВнешниеНаборыДанных, 
    ДанныеРасшифровки, ПараметрыВывода.ВозможностьИспользованияВнешнихФункций);
    
    //Выводим результат
    Если ВыводВКоллекциюЗначений Тогда
        ПроцессорВывода    = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
        ПроцессорВывода.УстановитьОбъект(Результат);
    Иначе
        ПроцессорВывода    = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
        ПроцессорВывода.УстановитьДокумент(Результат);
    КонецЕсли;
    
    ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);

КонецПроцедуры

Метод, который полностью повторяет возможности платформенных, но при этом удобно обёрнут в универсальную процедуру.

"Ну теперь точно всё!".

И решил добавить ещё хотелочку...

 

5. Прихоть в мелочах

 

Метод готов. Но Васе хочется, чтобы он был ещё чуть по-умнее.

"Я делаю это, потому что хочу!"

И юный разработчик добавляет в начало процедуры обработку параметра с настройками.

//Инициализируем настройки
Если ТипЗнч(НастройкиКомпоновки) = Тип("КомпоновщикНастроекКомпоновкиДанных") Тогда
    ВыполняемыеНастройки    = НастройкиКомпоновки.ПолучитьНастройки();
ИначеЕсли ТипЗнч(НастройкиКомпоновки) = Тип("Строка") И ЭтоАдресВременногоХранилища(НастройкиКомпоновки) Тогда
    ВыполняемыеНастройки    = ПолучитьИзВременногоХранилища(НастройкиКомпоновки);
Иначе
    ВыполняемыеНастройки    = НастройкиКомпоновки;
КонецЕсли;

Если НЕ ТипЗнч(ВыполняемыеНастройки) = Тип("НастройкиКомпоновкиДанных") Тогда
    Возврат;
КонецЕсли;

Это позволит в метод передавать не только сами настройки, но и, к примеру, компоновщик настроек. Или же адрес хранилища, где настройки хранятся. Дополнительный штрих, который добавляет небольшую возможность.

Теперь, например, когда Васе потребуется вызывать методы из модуля отчёта, то он просто передаст КомпоновщикНастроек, а процедура сама уже возьмёт из него настройки. В результате код вызова этой процедуры немного, но уменьшится.

Процедура СкомпоноватьРезультатОтчета(Результат, СхемаКомпоновкиДанных, НастройкиКомпоновки, 
    ДанныеРасшифровки = Неопределено, ВнешниеНаборыДанных = Неопределено, ДополнительныеПараметры = Неопределено) Экспорт
    
    
    //Инициализируем настройки
    Если ТипЗнч(НастройкиКомпоновки) = Тип("КомпоновщикНастроекКомпоновкиДанных") Тогда
        ВыполняемыеНастройки    = НастройкиКомпоновки.ПолучитьНастройки();
    ИначеЕсли ТипЗнч(НастройкиКомпоновки) = Тип("Строка") И ЭтоАдресВременногоХранилища(НастройкиКомпоновки) Тогда
        ВыполняемыеНастройки    = ПолучитьИзВременногоХранилища(НастройкиКомпоновки);
    Иначе 
        ВыполняемыеНастройки    = НастройкиКомпоновки; 
    КонецЕсли;
    
    Если НЕ ТипЗнч(ВыполняемыеНастройки) = Тип("НастройкиКомпоновкиДанных") Тогда
        Возврат;
    КонецЕсли;
    

    //Инициализируем дополнительные параметры вывода
    ПараметрыВывода    = Новый Структура;
    ПараметрыВывода.Вставить("МакетОформления"                        , Неопределено);
    ПараметрыВывода.Вставить("ПроверятьДоступностьПолей"              , Истина);
    ПараметрыВывода.Вставить("ПараметрыФункциональныхОпций"           , Новый Структура);
    ПараметрыВывода.Вставить("ВозможностьИспользованияВнешнихФункций" , Ложь);
    
    Если НЕ ДополнительныеПараметры = Неопределено Тогда
        ЗаполнитьЗначенияСвойств(ПараметрыВывода, ДополнительныеПараметры);
    КонецЕсли;
    
    //Определяем тип генератора
    Если ТипЗнч(Результат) = Тип("ТаблицаЗначений") ИЛИ ТипЗнч(Результат) = Тип("ДеревоЗначений") Тогда
        ВыводВКоллекциюЗначений = Истина;
        ТипГенератораВывода     = Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений");
    Иначе
        ВыводВКоллекциюЗначений = Ложь;
        ТипГенератораВывода     = Тип("ГенераторМакетаКомпоновкиДанных");
    КонецЕсли;
    
    //Формируем макет, с помощью компоновщика макета
    КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
    
    //Передаем в макет компоновки схему, настройки и данные расшифровки
    МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, ВыполняемыеНастройки, 
    ДанныеРасшифровки, ПараметрыВывода.МакетОформления, ТипГенератораВывода, 
    ПараметрыВывода.ПроверятьДоступностьПолей, ПараметрыВывода.ПараметрыФункциональныхОпций);
    
    //Выполним компоновку с помощью процессора компоновки
    ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
    ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки, ВнешниеНаборыДанных, 
    ДанныеРасшифровки, ПараметрыВывода.ВозможностьИспользованияВнешнихФункций);
    
    //Выводим результат
    Если ВыводВКоллекциюЗначений Тогда
        ПроцессорВывода    = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
        ПроцессорВывода.УстановитьОбъект(Результат);
    Иначе
        ПроцессорВывода    = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
        ПроцессорВывода.УстановитьДокумент(Результат);
    КонецЕсли;
    
    ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);

КонецПроцедуры

И вот Васина универсальная "обёртка" для вывода СКД. С ней он может не вставлять шаблонный набор строк, а просто вызвать заготовленную процедуру из общего модуля. Осталось теперь добавить описание...

 

6. Документирование

 

Василий добавляет описание к своему методу. Старается соблюдать "шаблоны" и рекомендации. Чтобы контекстная подсказка отображалась красиво и подхватывала и типы и описания.

// Выполняет компоновку СКД по переданным настройкам
//
// Параметры:
//  Результат               - ТабличныйДокумент,ТаблицаЗначений,ДеревоЗначений                      - результат выполнения
//  СхемаКомпоновкиДанных   - СхемаКомпоновкиДанных                                                 - выполняемая СКД
//  НастройкиКомпоновки     - НастройкиКомпоновкиДанных,КомпоновщикНастроекКомпоновкиДанных,Строка  - выполняемые настройки или адрес временного хранилища или компоновщик с настройками
//  ДанныеРасшифровки       - ДанныеРасшифровкиКомпоновкиДанных, Неопределено                       - данные расшифровки
//  ВнешниеНаборыДанных     - Структура, Неопределено                                               - коллекция внешних наборов данных
//  ДополнительныеПараметры - Структура, Неопределено                                               - коллекция внешних наборов данных
//       * МакетОформления              - МакетОформленияКомпоновкиДанных   - Макет оформления, в соответствии с которым необходимо оформлять макет компоновки данных.
//       * ПроверятьДоступностьПолей    - Булево - Определяет, выполнять ли проверку прав на просмотр полей и проверку доступности поля во включенных функциональных возможностях.
//       * ПараметрыФункциональныхОпций - Булево - Содержит параметры функциональных опций, используемые при исполнении отчета.
//       * ВозможностьИспользованияВнешнихФункций - Булево - Указывает возможность использования функции общих модулей конфигурации в выражениях компоновки данных.
//

Приходит время опробовать метод на практике.

 

7. Примеры использования

 

"Нужно сделать банальный програмный вывод СКД? Нате!"

//Стандартный программный вывод
СкомпоноватьРезультатОтчета(ДокументРезультат, СхемаКомпоновкиДанных, КомпоновщикНастроек, ДанныеРасшифровки);

Или же вывести результат в таблицу значений?

//Вывод в коллекцию значений
ДанныеРезультата = Новый ТаблицаЗначений;
СкомпоноватьРезультатОтчета(ДанныеРезультата, СхемаКомпоновкиДанных, КомпоновщикНастроек);

А может наоборот вывести СКД, используя содержимое таблицы значений?

//Программный вывод с внешними наборами данных
ВнешниеНаборыДанных    = Новый Структура("ТаблицаДанных", ТаблицаДанных);
СкомпоноватьРезультатОтчета(ДокументРезультат, СхемаКомпоновкиДанных, КомпоновщикНастроек, ДанныеРасшифровки, ВнешниеНаборыДанных);

Можно сделать стандартный вывод, но с возможностью использования "внешних функций"

//Вывод с возможностью использования внешних функций
ПараметрыВывода    = Новый Структура("ВозможностьИспользованияВнешнихФункций", Истина);
СкомпоноватьРезультатОтчета(ДокументРезультат, СхемаКомпоновкиДанных, КомпоновщикНастроек, ДанныеРасшифровки,, ПараметрыВывода);

Или, например, со своим макетом оформления

//Вывод с использованием своего макета оформления
ПараметрыВывода    = Новый Структура("МакетОформления", ПолучитьМакет("МакетОформления"));
СкомпоноватьРезультатОтчета(ДокументРезультат, СхемаКомпоновкиДанных, КомпоновщикНастроек, ДанныеРасшифровки,, ПараметрыВывода);

Васе нравится метод. Возможно, он не идеален. Возможно, эту процедуру никто и не заметит в закоулках модулей этой покрытой костылями и багами конфигурации. Но Вася всё равно доволен своей работой. Ведь на самом деле:

"Я делаю это, потому что мне просто нравится"

Вася похвалил себя, почесал ЧСВ и пошёл дальше заниматься своей работой. Ещё столько всего нужно скопипастить... 

 

8. Поддержка (UPDATE 29.06.2021)

Прошло время. Вася с удовольствием пользовался своей универсальной процедуркой. Использовал её где только можно - и в отчетах, и в обработках, и в расширениях. 

А тем временем платформа развивалась и наделила программный вывод СКД новой возможностью. Передавать при формировании менеджер временных таблиц

Ранее в запросах СКД нельзя было использовать заранее подготовленные временные таблицы. И приходилось использовать костыли и связи наборов в СКД. 

О, ужас! Хорошо, что это время прошло!

Но вот незадача. Текущая Васина процедура не позволяет использовать менеджер временных.

Пришло время доработки!

И так, для начала начала программист оглядел синтаксис-помощник. Что именно появилось нового?

 

ПроцессорКомпоновкиДанных.Инициализировать(<Макет>, <ВнешниеНаборыДанных>, <ДанныеРасшифровки>, <ВозможностьИспользованияВнешнихФункций>, <ОграничиватьПолучениеПолейПоСсылкамПоПравуПросмотр>, <МенеджерВременныхТаблиц>)

 

<ОграничиватьПолучениеПолейПоСсылкамПоПравуПросмотр> (необязательный)

Тип: Булево. 
Если значение параметра равно Истина, то при отображении результата запроса учитывается право пользователя "Просмотр" на таблицы и поля, участвующие в запросе. Если в отчете или динамическом списке присутствует значение поля недоступного по праву "Просмотр", то выводится пустая ячейка.
Если значение параметра равно Ложь и параметр ПроверятьДоступностьПолей установлен в Истина, то значение выводится, даже если у пользователя нет права "Просмотр".
Значение по умолчанию: Истина.

<МенеджерВременныхТаблиц> (необязательный)

Тип: МенеджерВременныхТаблиц. 
Менеджер временных таблиц, который будет установлен для исполняемых запросов.
В процессе работы процессора компоновки данных таблицы из этого менеджера могут быть получены, но не могут быть удалены или добавлены новые.
Значение по умолчанию: Неопределено.

 

1С всё расширяет количество параметров метода. А вот у Васи есть для этого структура ДополнительныеПараметры =)

//Инициализируем дополнительные параметры вывода
ПараметрыВывода    = Новый Структура;
ПараметрыВывода.Вставить("МакетОформления"                        , Неопределено);
ПараметрыВывода.Вставить("ПроверятьДоступностьПолей"              , Истина);
ПараметрыВывода.Вставить("ПараметрыФункциональныхОпций"           , Новый Структура);
ПараметрыВывода.Вставить("ВозможностьИспользованияВнешнихФункций" , Ложь);
ПараметрыВывода.Вставить("МенеджерВременныхТаблиц"                , Неопределено);
ПараметрыВывода.Вставить("ОграничиватьПолучениеПолейПоСсылкамПоПравуПросмотр" , Истина);
	
Если НЕ ДополнительныеПараметры = Неопределено Тогда
	ЗаполнитьЗначенияСвойств(ПараметрыВывода, ДополнительныеПараметры);
КонецЕсли;

Вот и всё, теперь в ДополнительныеПараметры можно передать новые параметры компоновки.

Осталось только передать их в сам метод платформы:

 

//Выполним компоновку с помощью процессора компоновки
ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновкиДанных.Инициализировать(
МакетКомпоновки, ВнешниеНаборыДанных, ДанныеРасшифровки, 
ПараметрыВывода.ВозможностьИспользованияВнешнихФункций,
ПараметрыВывода.ОграничиватьПолучениеПолейПоСсылкамПоПравуПросмотр,
ПараметрыВывода.МенеджерВременныхТаблиц);

Этого уже достаточно, чтобы Васин универсальный метод соответствовал новым возможностям платформы.

Но юный программист чувствует, что этого недостаточно...

Так ли удобно передавать в СКД менеджер временных таблиц? А вот и не всегда. 

Иногда просто хочется передать таблицу значений, которую сформировали программно \ прочитали из файла \ получили из хранилища \ <ваш вариант>

Для этого разработчику придется: создавать запрос с менеджером временных таблиц, описывать текст запроса с выборкой всех полей таблицы, передавать эту таблицу и выполнять запрос.

Это нужно автоматизировать!

И Вася взялся за дело:

Если ТипЗнч(ПараметрыВывода.МенеджерВременныхТаблиц) = Тип("Структура") Тогда
	МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;
	Для Каждого КлючИЗначение Из ПараметрыВывода.МенеджерВременныхТаблиц Цикл
		//Здесь мы будем добавлять таблицу в МВТ
	КонецЦикла;
	ПараметрыВывода.МенеджерВременныхТаблиц = МенеджерВременныхТаблиц;
КонецЕсли;

Теперь, в доп. параметре МенеджерВременныхТаблиц можно передать и структуру. А на основе её мы сделаем МВТ.

Ключем этой структуры будет Имя временной таблицы, которую нужно создать в менеджере. А значением будет сама таблица. 

И тут наш 1Сник решил сделать отдельный метод, в котором он будет добавлять таблицу в менеджер.

В этой процедуре запрос генерируется сам. И через него в МВТ попадают нужные данные.

Процедура ДобавитьТаблицуВМенеджерВременныхТаблиц(МенеджерВременныхТаблиц, ИмяТаблицы, ДанныеТаблицы) Экспорт
	
	ИменаКолонок = Новый Массив;
	Для Каждого Колонка Из ДанныеТаблицы.Колонки Цикл
		ИменаКолонок.Добавить(Колонка.Имя);
	КонецЦикла;
	ИменаКолонок = СтрСоединить(ИменаКолонок, ",");
	
	ТекстЗапроса = "ВЫБРАТЬ %1 ПОМЕСТИТЬ %2 ИЗ &ТЗ КАК ТЗ";
	ТекстЗапроса = СтрШаблон(ТекстЗапроса, ИменаКолонок, ИмяТаблицы);
	
	Запрос = Новый Запрос(ТекстЗапроса);
	Запрос.МенеджерВременныхТаблиц = МенеджерВременныхТаблиц;
	Запрос.УстановитьПараметр("ТЗ", ДанныеТаблицы);
	Запрос.Выполнить();
	
КонецПроцедуры

Теперь нужно этот новый метод вызвать:

Если ТипЗнч(ПараметрыВывода.МенеджерВременныхТаблиц) = Тип("Структура") Тогда
	МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;
	Для Каждого КлючИЗначение Из ПараметрыВывода.МенеджерВременныхТаблиц Цикл
		ДобавитьТаблицуВМенеджерВременныхТаблиц(МенеджерВременныхТаблиц, КлючИЗначение.Ключ, КлючИЗначение.Значение);
	КонецЦикла;
	ПараметрыВывода.МенеджерВременныхТаблиц = МенеджерВременныхТаблиц;
КонецЕсли;

Можно код из метода "встроить" внутрь основного. Тогда будет так:

Если ТипЗнч(ПараметрыВывода.МенеджерВременныхТаблиц) = Тип("Структура") Тогда
	МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;
	Для Каждого КлючИЗначение Из ПараметрыВывода.МенеджерВременныхТаблиц Цикл
		
		ИмяТаблицы    = КлючИЗначение.Ключ;
		ДанныеТаблицы = КлючИЗначение.Значение;
		
		ИменаКолонок = Новый Массив;
		Для Каждого Колонка Из ДанныеТаблицы.Колонки Цикл
			ИменаКолонок.Добавить(Колонка.Имя);
		КонецЦикла;
		ИменаКолонок = СтрСоединить(ИменаКолонок, ",");
		
		ТекстЗапроса = "ВЫБРАТЬ %1 ПОМЕСТИТЬ %2 ИЗ &ТЗ КАК ТЗ";
		ТекстЗапроса = СтрШаблон(ТекстЗапроса, ИменаКолонок, ИмяТаблицы);
		
		Запрос = Новый Запрос(ТекстЗапроса);
		Запрос.МенеджерВременныхТаблиц = МенеджерВременныхТаблиц;
		Запрос.УстановитьПараметр("ТЗ", ДанныеТаблицы);
		Запрос.Выполнить();
		
	КонецЦикла;
	ПараметрыВывода.МенеджерВременныхТаблиц = МенеджерВременныхТаблиц;
КонецЕсли;

 

Дело сделано! Осталось подправить описание.

 

// Выполняет компоновку СКД по переданным настройкам
//
// Параметры:
//  Результат               - ТабличныйДокумент,ТаблицаЗначений,ДеревоЗначений                      - результат выполнения
//  СхемаКомпоновкиДанных   - СхемаКомпоновкиДанных                                                 - выполняемая СКД
//  НастройкиКомпоновки     - НастройкиКомпоновкиДанных,КомпоновщикНастроекКомпоновкиДанных,Строка  - выполняемые настройки или адрес временного хранилища или компоновщик с настройками
//  ДанныеРасшифровки       - ДанныеРасшифровкиКомпоновкиДанных, Неопределено                       - данные расшифровки
//  ВнешниеНаборыДанных     - Структура, Неопределено                                               - коллекция внешних наборов данных
//  ДополнительныеПараметры - Структура, Неопределено                                               - коллекция внешних наборов данных
//       * МакетОформления              - МакетОформленияКомпоновкиДанных    - Макет оформления, в соответствии с которым необходимо оформлять макет компоновки данных.
//       * МенеджерВременныхТаблиц      - МенеджерВременныхТаблиц, Структура - Временные таблицы, которые будут доступны в запросе СКД. Или МВТ или структура, где Ключ - Имя, а Значение - Таблица
//       * ПроверятьДоступностьПолей    - Булево - Определяет, выполнять ли проверку прав на просмотр полей и проверку доступности поля во включенных функциональных возможностях.
//       * ПараметрыФункциональныхОпций - Булево - Содержит параметры функциональных опций, используемые при исполнении отчета.
//       * ВозможностьИспользованияВнешнихФункций - Булево - Указывает возможность использования функции общих модулей конфигурации в выражениях компоновки данных.
//       * ОграничиватьПолучениеПолейПоСсылкамПоПравуПросмотр - Булево - Указывает обязательность наличия роли Просмотр для используемых метаданных в запросе СКД

И, конечно же, закрепить примерами использования:

 

//Вывод с передачей менеджера временных таблиц
ПараметрыВывода    = Новый Структура("МенеджерВременныхТаблиц", Запрос.МенеджерВременныхТаблиц);
СкомпоноватьРезультатОтчета(ДокументРезультат, СхемаКомпоновкиДанных, КомпоновщикНастроек, ДанныеРасшифровки,, ПараметрыВывода);
//Вывод с передачей таблиц, которые попадут в МВТ
ПараметрыВывода    = Новый Структура("МенеджерВременныхТаблиц", Новый Структура);
ПараметрыВывода.МенеджерВременныхТаблиц.Вставить("МояВТ", МояТЗ);
СкомпоноватьРезультатОтчета(ДокументРезультат, СхемаКомпоновкиДанных, КомпоновщикНастроек, ДанныеРасшифровки,, ПараметрыВывода);

Теперь Вася прошел весь цикл. Идея, релиализация и поддержка универсальной процедуры. И доволен окончательно. Или же нет?

Надо сделать общий модуль с гибкими методами по работе с СКД!

 

Понравилась статья?

 

Не стойте в стороне! Не будьте равнодушными. Каждый поставленный вами "лайк" покажет автору, что он не зря пропустил возможность пропустить по стаканчику, когда писал эту статью.

И переходите к другим работам:

Сервис регистрации ошибок 1С (пример создания)

Новое отображение ошибок в 1С

История формирования отчетов (расширение для типовых конфигураций)

 

P.S.: И вот вдогонку под спойлером окончательный вариант процедуры. Авось, кому пригодится.

Окончательная Васина процедура
// Выполняет компоновку СКД по переданным настройкам
//
// Параметры:
//  Результат               - ТабличныйДокумент,ТаблицаЗначений,ДеревоЗначений                      - результат выполнения
//  СхемаКомпоновкиДанных   - СхемаКомпоновкиДанных                                                 - выполняемая СКД
//  НастройкиКомпоновки     - НастройкиКомпоновкиДанных,КомпоновщикНастроекКомпоновкиДанных,Строка  - выполняемые настройки или адрес временного хранилища или компоновщик с настройками
//  ДанныеРасшифровки       - ДанныеРасшифровкиКомпоновкиДанных, Неопределено                       - данные расшифровки
//  ВнешниеНаборыДанных     - Структура, Неопределено                                               - коллекция внешних наборов данных
//  ДополнительныеПараметры - Структура, Неопределено                                               - коллекция внешних наборов данных
//       * МакетОформления              - МакетОформленияКомпоновкиДанных   - Макет оформления, в соответствии с которым необходимо оформлять макет компоновки данных.
//       * МенеджерВременныхТаблиц      - МенеджерВременныхТаблиц,Структура - Временные таблицы, которые будут доступны в запросе СКД. Или МВТ или структура, где Ключ - Имя, а Значение - Таблица
//       * ПроверятьДоступностьПолей    - Булево - Определяет, выполнять ли проверку прав на просмотр полей и проверку доступности поля во включенных функциональных возможностях.
//       * ПараметрыФункциональныхОпций - Булево - Содержит параметры функциональных опций, используемые при исполнении отчета.
//       * ВозможностьИспользованияВнешнихФункций - Булево - Указывает возможность использования функции общих модулей конфигурации в выражениях компоновки данных.
//       * ОграничиватьПолучениеПолейПоСсылкамПоПравуПросмотр - Булево - Указывает обязательность наличия роли Просмотр для используемых метаданных в запросе СКД
//
//Подробнее об использовании метода: //infostart.ru/public/1082944/?ref=1159
//
Процедура СкомпоноватьРезультатОтчета(Результат, СхемаКомпоновки, НастройкиКомпоновки, 
    ДанныеРасшифровки = Неопределено, ВнешниеНаборыДанных = Неопределено, ДополнительныеПараметры = Неопределено) Экспорт
           
    
	//Инициализируем настройки
	Если ТипЗнч(НастройкиКомпоновки) = Тип("КомпоновщикНастроекКомпоновкиДанных") Тогда
		ВыполняемыеНастройки    = НастройкиКомпоновки.ПолучитьНастройки();
	ИначеЕсли ТипЗнч(НастройкиКомпоновки) = Тип("Строка") И ЭтоАдресВременногоХранилища(НастройкиКомпоновки) Тогда
		ВыполняемыеНастройки    = ПолучитьИзВременногоХранилища(НастройкиКомпоновки);
	Иначе 
		ВыполняемыеНастройки    = НастройкиКомпоновки;   
	КонецЕсли;
    
	Если НЕ ТипЗнч(ВыполняемыеНастройки) = Тип("НастройкиКомпоновкиДанных") Тогда
		Возврат;
	КонецЕсли;
    

	//Инициализируем дополнительные параметры вывода
	ПараметрыВывода    = Новый Структура;
	ПараметрыВывода.Вставить("МакетОформления"                        , Неопределено);
	ПараметрыВывода.Вставить("ПроверятьДоступностьПолей"              , Истина);
	ПараметрыВывода.Вставить("ПараметрыФункциональныхОпций"           , Новый Структура);
	ПараметрыВывода.Вставить("ВозможностьИспользованияВнешнихФункций" , Ложь);
	ПараметрыВывода.Вставить("МенеджерВременныхТаблиц"                , Неопределено);
	ПараметрыВывода.Вставить("ОграничиватьПолучениеПолейПоСсылкамПоПравуПросмотр" , Истина);
	
	Если НЕ ДополнительныеПараметры = Неопределено Тогда
		ЗаполнитьЗначенияСвойств(ПараметрыВывода, ДополнительныеПараметры);
	КонецЕсли;
	
	Если ТипЗнч(ПараметрыВывода.МенеджерВременныхТаблиц) = Тип("Структура") Тогда
		МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;
		Для Каждого КлючИЗначение Из ПараметрыВывода.МенеджерВременныхТаблиц Цикл
			ДобавитьТаблицуВМенеджерВременныхТаблиц(МенеджерВременныхТаблиц, КлючИЗначение.Ключ, КлючИЗначение.Значение);
		КонецЦикла;
		ПараметрыВывода.МенеджерВременныхТаблиц = МенеджерВременныхТаблиц;
	КонецЕсли;
    
	//Определяем тип генератора
	Если ТипЗнч(Результат) = Тип("ТаблицаЗначений") ИЛИ ТипЗнч(Результат) = Тип("ДеревоЗначений") Тогда
		ВыводВКоллекциюЗначений = Истина;
		ТипГенератораВывода     = Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений");
	Иначе
		ВыводВКоллекциюЗначений = Ложь;
		ТипГенератораВывода     = Тип("ГенераторМакетаКомпоновкиДанных");
	КонецЕсли;
    
	//Формируем макет, с помощью компоновщика макета
	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
    
	//Передаем в макет компоновки схему, настройки и данные расшифровки
	МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновки, ВыполняемыеНастройки, 
	ДанныеРасшифровки, ПараметрыВывода.МакетОформления, ТипГенератораВывода, 
	ПараметрыВывода.ПроверятьДоступностьПолей, ПараметрыВывода.ПараметрыФункциональныхОпций);
    
	//Выполним компоновку с помощью процессора компоновки
	ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКомпоновкиДанных.Инициализировать(
	МакетКомпоновки, ВнешниеНаборыДанных, ДанныеРасшифровки, 
	ПараметрыВывода.ВозможностьИспользованияВнешнихФункций,
	ПараметрыВывода.ОграничиватьПолучениеПолейПоСсылкамПоПравуПросмотр,
	ПараметрыВывода.МенеджерВременныхТаблиц);
    
	//Выводим результат
	Если ВыводВКоллекциюЗначений Тогда
		ПроцессорВывода    = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
		ПроцессорВывода.УстановитьОбъект(Результат);
	Иначе
		ПроцессорВывода    = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
		ПроцессорВывода.УстановитьДокумент(Результат);
	КонецЕсли;
    
	ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);

КонецПроцедуры

// Процедура добавляет таблицу в менеджер временных таблиц
//
// Параметры:
//  МенеджерВременныхТаблиц	 - МенеджерВременныхТаблиц - Менеджер, в который нужно добавить таблицу
//  ИмяТаблицы				 - Строка - Имя временной таблицы
//  ДанныеТаблицы			 - ТаблицаЗначений - Данные таблицы
//
Процедура ДобавитьТаблицуВМенеджерВременныхТаблиц(МенеджерВременныхТаблиц, ИмяТаблицы, ДанныеТаблицы) Экспорт
	
	ИменаКолонок = Новый Массив;
	Для Каждого Колонка Из ДанныеТаблицы.Колонки Цикл
		ИменаКолонок.Добавить(Колонка.Имя);
	КонецЦикла;
	ИменаКолонок = СтрСоединить(ИменаКолонок, ",");
	
	ТекстЗапроса = "ВЫБРАТЬ %1 ПОМЕСТИТЬ %2 ИЗ &ТЗ КАК ТЗ";
	ТекстЗапроса = СтрШаблон(ТекстЗапроса, ИменаКолонок, ИмяТаблицы);
	
	Запрос = Новый Запрос(ТекстЗапроса);
	Запрос.МенеджерВременныхТаблиц = МенеджерВременныхТаблиц;
	Запрос.УстановитьПараметр("ТЗ", ДанныеТаблицы);
	Запрос.Выполнить();
	
КонецПроцедуры

 

практика программирование СКД пример шаблон

См. также

SALE! 20%

Infostart Toolkit: Инструменты разработчика 1С 8.3 на управляемых формах

Инструментарий разработчика Роли и права Запросы СКД Платформа 1С v8.3 Управляемые формы Запросы Система компоновки данных Конфигурации 1cv8 Платные (руб)

Набор инструментов программиста и специалиста 1С для всех конфигураций на управляемых формах. В состав входят инструменты: Консоль запросов, Консоль СКД, Консоль кода, Редактор объекта, Анализ прав доступа, Метаданные, Поиск ссылок, Сравнение объектов, Все функции, Подписки на события и др. Редактор запросов и кода с раскраской и контекстной подсказкой. Доработанный конструктор запросов тонкого клиента. Продукт хорошо оптимизирован и обладает самым широким функционалом среди всех инструментов, представленных на рынке.

10000 8000 руб.

02.09.2020    122421    673    389    

716

Генератор схемы компоновки данных (СКД), написание кода схемы программно

Инструментарий разработчика СКД Платформа 1С v8.3 Конфигурации 1cv8 1С:Зарплата и Управление Персоналом 3.x Абонемент ($m)

По выбранной схеме компоновки данных генерирует программный код, который генерирует СКД, аналогичную исходной схеме. Есть дополнительные инструменты для просмотра дерева схемы, сравнение исходной схемы и полученной по коду, а также сравнение изменений в сгенерированном коде для исходной схемы и для измененной.

3 стартмани

05.02.2024    4061    26    obmailok    17    

64

Набор-объект для СКД по тексту или запросу

Запросы СКД Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Абонемент ($m)

Есть список полей в виде текста, или запрос - закидываем в набор СКД.

1 стартмани

31.01.2024    2007    2    Yashazz    0    

29

СКД на JavaScript в 1С

СКД WEB-интеграция Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Долгое время поддерживаю web-портал, в котором появилась необходимость создавать отчеты. Просмотрев различные фреймворки на js, я решил сделать свое решение, которое позволяло бы быстро разрабатывать и добавлять новые отчеты на web-портал.

2 стартмани

11.12.2023    8173    20    John_d    25    

123

Использование менеджера временных таблиц в СКД

СКД Платформа 1С v8.3 Система компоновки данных Конфигурации 1cv8 Бесплатно (free)

Рассмотрим еще не получивший широкого распространения способ работы с внешними данным в СКД. В процессе обсуждения работы с СКД выяснилось, что многие не знакомы со способом помещения туда временной таблицы, полученной предварительно. Статья будет полезна разработчикам, знакомым с программным созданием СКД.

05.12.2023    4664    PROSTO-1C    13    

61

Модель СКД

Инструментарий разработчика СКД Платформа 1С v8.3 Система компоновки данных Абонемент ($m)

DSL для работы с СКД.

1 стартмани

15.11.2023    5817    15    kalyaka    5    

86

Пользовательские настройки отчетов 1С. Часть 1. Простые и расширенные настройки

СКД Инструкции пользователю Платформа 1С v8.3 Конфигурации 1cv8 1С:Бухгалтерия 3.0 Россия Бесплатно (free)

Простые приемы работы с отчетами на СКД. Что нужно знать пользователю про настройку отчетов, чтобы использовать их на полную катушку.

18.09.2023    6747    accounting_cons    5    

29

Разрыв страницы в СКД. Легко!

СКД Платформа 1С v8.3 Система компоновки данных Бесплатно (free)

Когда отчет надо разделить по страницам, это всегда проблема для разработчика. Поскольку в СКД нет стандартных вариантов, как это сделать. Нашел (на свой взгляд) самое простое и оптимальное решение.

01.09.2023    4538    KVIKS    15    

80
Отзывы
8. SeiOkami 3423 04.07.19 11:04 Сейчас в теме
Кстати, забыл добавить.
Программист Вася - это кот.
Не спрашивайте почему. Просто так вышло.
user591389_aska_rabota; CheBurator; dadssoup; SergeyTerentyev; user986734; brr; v_den_v; an35@mail.ru; zakiap; Jimbo; Tangram; PRESTRus; shaportoval; chebser; DoctorRoza; waol; Andreeei; user1067792; dock; torbeev; MikeI; nicxxx; denmax; О.Ж; wowik; Nelli_A86; botokash; Teut_Vlad; acanta; +29 1 Ответить
Остальные комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. leosoft 165 04.07.19 10:10 Сейчас в теме
2. Поручик 4670 04.07.19 10:12 Сейчас в теме
У меня есть что-то подобное. Я тоже люблю универсальные методы, выношу их в отдельные модули, стараюсь улучшать всё вокруг в разумных пределах.. Что в этом плохого?
maksa2005; Cерый; brr; YPermitin; acanta; pavlov_dv; DenisCh; +7 Ответить
3. SeiOkami 3423 04.07.19 10:14 Сейчас в теме
Что в этом плохого?

(2) ничего плохого, сам их люблю и практикую. В принципе, об этом и статья )
Jimbo; YPermitin; acanta; +3 Ответить
41. Crazy_Max 82 05.07.19 13:11 Сейчас в теме
(2)Возможно, в этом и заключается смысл жизни, между прочим.
Причём, не только человеческой жизни, а и вообще феномена под названием "жизнь"...
4. SlavaKron 04.07.19 10:33 Сейчас в теме
Иногда, при использовании таблицы значений в качестве внешних наборов данных, требуется формировать ее с учетом отборов из НастройкиКомпоновки. Как бы Вася решил эту задачу?
ixijixi; dadssoup; romankoav; +3 Ответить
5. DoctorRoza 04.07.19 10:35 Сейчас в теме
Подобных участков кода можно много привести. И, как вариант, добавлять их в свой шаблон и вызывать по комбинации клавиш. Хорошая статья
6. genayo 04.07.19 10:55 Сейчас в теме
Хороший пример. Поделитесь с общественностью всей своей библиотекой полезностей :))
romankoav; RFP; json; CyberCerber; +4 Ответить
7. acanta 04.07.19 11:02 Сейчас в теме
Вариант с Леней Голубковым как то привычнее.
8. SeiOkami 3423 04.07.19 11:04 Сейчас в теме
Кстати, забыл добавить.
Программист Вася - это кот.
Не спрашивайте почему. Просто так вышло.
user591389_aska_rabota; CheBurator; dadssoup; SergeyTerentyev; user986734; brr; v_den_v; an35@mail.ru; zakiap; Jimbo; Tangram; PRESTRus; shaportoval; chebser; DoctorRoza; waol; Andreeei; user1067792; dock; torbeev; MikeI; nicxxx; denmax; О.Ж; wowik; Nelli_A86; botokash; Teut_Vlad; acanta; +29 1 Ответить
10. Teut_Vlad 180 04.07.19 11:19 Сейчас в теме
(8)
odinsmot; TimkoNzt; Roootru; klaus38; Maxx2008; IVVoronov; donkey; Crazy_Max; DoctorRoza; bulpi; dock; CnupT; SirAlexIT; AlenaR; Marliiin; t.v.s.; wowik; CyberCerber; nporrep; +19 Ответить
9. herfis 498 04.07.19 11:14 Сейчас в теме
А потом приходит Петя. Ему нужно доработать отчет.
Он открывает его и видит вызов нескольких универсальных процедур с тонной возможных параметров. Он начинает погружаться в дебри реализации, пытаясь понять, сможет ли он красиво вклиниться в эту чудесную, красивую и стройную архитектуру, подкупающую своей универсальностью.
Через час он понимает, что из всех предусмотренных этим чудесным швейцарским ножом на тысячи строк кода возможностей, в этом конкретном отчете используется от силы процента три. И они бы уложились в двадцать строк простого, понятного но шаблонного кода, куда бы он без труда смог бы начать добавлять требуемую функциональность уже через секунду после открытия незнакомого ему отчета.
Увы, в итоге он осознает что несколько нужных ему опций в прекрасной подсистеме не предусмотрено. Что же делать? Петя "правильный" программист, и старается выбирать "правильные" пути, а не "простые". Спустя еще час напряженной работы мозга, Петю озаряет как правильно нужно доработать подсистему, чтобы она красиво покрыла его кейсы (а заодно и десяток смежных!). Он добавляет новые опции в подсистему, расширяя ее функциональность и тщательно их документирует. Петя счастлив - он всегда выступал против "велосипедов" и всегда готов поддержать единомышленников. Ведь всем известно, что копипаст - это зло.
Теперь Антон, которому предстоит дорабатывать этот отчет, сможет сделать свою работу еще быстрее и качественнее.
Возможно, в процессе он даже напишет удобный DSL, который выведет универсальность подсистемы на невиданный ранее уровень.
user1609888; unknown181538; Irwin; Merkalov; memb3r; logarifm; rmIvanT; krukoleg@mail.ru; maldinitaly; fvadim; user774630; astrallight; it_tungus; link_l; estima-1c; bulpi; dock; boln; SirAlexIT; sansys; ids79; Jeka44; qwinter; Xatori111; PowerBoy; lmnlmn; wowik; acanta; CyberCerber; AntonSm; +30 Ответить
21. genayo 04.07.19 12:23 Сейчас в теме
(9) Тут ведь главное - вовремя остановиться :))
23. herfis 498 04.07.19 12:35 Сейчас в теме
(21) Не совсем так. Иногда не стоит и начинать. Когда берется простой, понятный код небольшого размера и "универсализируется" за счет покрытия большого количества кейсов его использования - это как раз тот случай, когда вреда больше чем пользы. ИМХО, конечно.
memb3r; krukoleg@mail.ru; Бубузяка; it_tungus; bulpi; boln; FreeArcher; Krio2; RFP; ids79; qwinter; json; ZOMI; acanta; +14 Ответить
25. acanta 04.07.19 12:39 Сейчас в теме
(23) точно. Пишите на ассемблере. Он для каждого производителя компьютеров и для каждой модели свой.
Нафих кто-то си придумал..
И тем самым прекратил появление новых производителей компьютеров во всем мире и закрытие производства и ликвидацию разработок в бывшем СССР в том числе?
krukoleg@mail.ru; SeiOkami; +2 1 Ответить
26. herfis 498 04.07.19 13:05 Сейчас в теме
(25) Не очень понял комментарий. Типа я против добавления новых абстракций, облегчающих разработку? Вовсе нет. Я хотел сказать, что хорошая абстракция должна быть "глубокая", а не "широкая". Чем абстракция "уже" и "глубже" - тем сильнее она помогает и тем легче с ней работать. Польза "широкой" и "неглубокой" абстракции - минимальна. Вплоть до вреда. Да, экономим несколько строчек кода. Но за счет чего? Не за счет того, что мы инкапсулировали сложную реализацию. А за счет того, что мы засунули несколько вариантов реализации в один пакет и прилепили сверху выбор "программы". Завтра список "программ" захочется расширить еще больше, а послезавтра этим никто не захочет пользоваться, потому что быстрее написать эти несчастные несколько строчек, чем оживлять в мозгу эту неудобную абстракцию.
PLAstic; Capitullo; Irwin; Bazil; memb3r; bulpi; dock; user701287_darkowntheworld; Krio2; RFP; +10 Ответить
27. acanta 04.07.19 13:07 Сейчас в теме
(26) вооо́оо́т. Между завтра и послезавтра вполне может пройти несколько десятков лет.
И на что Вася будет жить все это время?
33. qwinter 671 04.07.19 15:59 Сейчас в теме
(25) А при чем тут ассемблер?
28. genayo 04.07.19 13:20 Сейчас в теме
(23) Ну в этом конкретном случае вроде как раз вовремя :) Хотя как по мне, я бы эту процедуру разбил на более мелкие, но это уже вкусовщина в общем :))
32. palsergeich 04.07.19 14:46 Сейчас в теме
(9) В итоге получается БСП на обслуживание которой через пару лет придется выделить отдел, потому что в 1с что то поменяли и все сломалось
unknown181538; Chai Nic; Lazy_Stranger; krukoleg@mail.ru; boln; ixijixi; +6 Ответить
37. boln 1040 05.07.19 08:09 Сейчас в теме
(9) Ну да. Принцип программиста: LOW COUPLING, HIGH COHESION. А принцип (идеал) одинэсника: одна процедура для всего-всего-всего.
:)))
11. user705698_bursev 04.07.19 11:33 Сейчас в теме
Мне кажется, или в пятом пункте ошибка?

Если мы в качестве параметра НастройкиКомпоновки будем передавать сами настройки компоновки, то переменная ВыполняемыеНастройки будет Неопределено, и соответственно возврат. Думаю, нужно учесть тип данных НастройкиКомпоновкиДанных.
14. SeiOkami 3423 04.07.19 11:36 Сейчас в теме
(11)
в качестве параметра НастройкиКомпоновки будем передавать сами настройки компоновки, то переменная ВыполняемыеНастройки будет Неопределено, и соответственно возврат. Думаю, нужно учесть тип данных НастройкиКомпоновкиДанных.

Большое спасибо, глаз замылился и не заметил косяка. Изначально хотел добавить в статью пункт про "Тестирование", в котором Вася нашёл свой косяк. А потом убрал его, а поправить процедуру забыл) Поправим-с
40. boln 1040 05.07.19 10:57 Сейчас в теме
(11)
Мне кажется, или в пятом пункте ошибка?
Только прожившие полжизни в СССР способны оценить смысл этой фразы :)))
Chernik; krukoleg@mail.ru; +2 Ответить
12. Synoecium 778 04.07.19 11:34 Сейчас в теме
пока читал, почему-то думал, что Вася в конце сравнит вызов своей процедуры и типовую обвязку для СКД и поймет, что это примерно одно и тоже, только теперь новому программисту ещё придется разбираться с мыслями автора, чтобы вызвать Васину процедуру.
Я не против универсальных процедур, просто всегда стоит задавать вопрос, надо ли городить огород в конкретном случае.
krukoleg@mail.ru; CyberCerber; +2 Ответить
13. shalimski 6 04.07.19 11:34 Сейчас в теме
Параметр НастройкиКомпоновки не поддерживает передачу типа НастройкиКомпоновкиДанных - баг.
krukoleg@mail.ru; +1 Ответить
18. SeiOkami 3423 04.07.19 11:47 Сейчас в теме
15. CyberCerber 853 04.07.19 11:43 Сейчас в теме
Все ждал в конце подвоха, что в конце будет разоблачение Васи, к каким печальным последствиям это привело, но нет... :-)
Еще писали такие универсальные методы?
krukoleg@mail.ru; AllexSoft; boln; +3 Ответить
16. CyberCerber 853 04.07.19 11:44 Сейчас в теме
Получилось решить вопрос с версиями платформы, когда параметры методов зависят от конкретной версии?
19. SeiOkami 3423 04.07.19 11:49 Сейчас в теме
(16) изучаю тему. Думаю собрать все возможные варианты и описать в статье. И сравнить с тем, как это делают в других языках.
17. CyberCerber 853 04.07.19 11:46 Сейчас в теме
И если уж соблюдать все стандартны и правила разработки, то в получившемся методе слишком много параметров. Кажется, максимум 5 допускается. Иначе нужно объединять в структуры. Я сам для себя еще не решил, было бы мне это удобнее, но стандарт говорит так.
20. пользователь 04.07.19 11:59
(0) отличный материал!
22. acanta 04.07.19 12:32 Сейчас в теме
Это похоже на холивар по поводу использования БСП и функций общих модулей в доработках.
И по поводу замков на объектах метаданных типовых конфигураций.
24. пользователь 04.07.19 12:36
Сообщение было скрыто модератором.
...
29. herfis 498 04.07.19 13:24 Сейчас в теме
Да, забыл добавить. Я не против непосредственно авторской процедуры. Она вполне себе нормальная. Хоть я ее использовать и не буду. Но это вкусовщина уже. У меня есть что-то подобное, выполняющее простую компоновку в табличный документ, но для специальных задач. В простых отчетах я ничего такого не использую.
Если бы я увидел эту процедуру как готовую в качестве просто "вот такие инструменты я использую" - ну, норм, чо...
Меня зацепил именно не очень удачный выбор ее в качестве иллюстрации к процессу создания новых абстракций, потому что описанный путь может очень легко увести несколько не туда :) "ДополнительныеПараметры" в этой процедуре еще в рамках, но уже на грани. И имеют большой потенциал, методика реализации которого излагается в статье :)
30. denmax 388 04.07.19 13:41 Сейчас в теме
У вас в коде копипаста? Значит у вас есть проблема! Для решения проблемы добавили универсальный метод? Теперь у вас две проблемы!
Merkalov; memb3r; krukoleg@mail.ru; bulpi; boln; acanta; +6 Ответить
31. cuztam 04.07.19 13:49 Сейчас в теме
Отлично, жду новых похождений кота Василия по миру 1С
SeiOkami; acanta; +2 Ответить
34. qwinter 671 04.07.19 17:12 Сейчас в теме
Неправильные аксиомы = неправильные решения = неправильные события.
krukoleg@mail.ru; boln; +2 Ответить
35. riposte 384 04.07.19 18:32 Сейчас в теме
Существует 15 шаблонов для копипасты кода программного вывода отчета на СКД.
Так нельзя! Нужно универсальную функцию! Рррряя!
Существует 16 шаблонов для копипасты кода программного вывода отчета на СКД.

Шутка. Лойс за многофункциональные комбайны с трехтомником инструкций и поллитрой в комплекте.
CyberCerber; boln; +2 Ответить
36. muskul 05.07.19 05:18 Сейчас в теме
Походу такие васи типовые конфигурации и пишут. В результате при простом поиске где же заполняняется Фамилия ипэшника в УПД открывается 10 модулей в которые прыгаешь туда сюда. куча временных менеджеров запросов из которых толком не выделить блок получения ответсвенных лиц и посмотреть что же его не устраивает.
buzzzard; Slypower; MulderCelica; XACHAPURIN; memb3r; AurumFlare; ids79; Lazy_Stranger; krukoleg@mail.ru; asg.aleks; CoolSpawn; itozersk; 1cdevelopment; Pryanishnikov_Vladimir; Crazy_Max; CyberCerber; СаморезикРу; ixijixi; bulpi; boln; user701287_darkowntheworld; +21 Ответить
38. CnupT 69 05.07.19 08:27 Сейчас в теме
(36) это как в детстве было "ставь лайк, если любишь маму", теперь "ставь плюсик, если тоже задрался искать где формируется ФИО ИПшника" :)
user1002882; klaus38; +2 Ответить
46. ids79 8291 14.07.19 07:59 Сейчас в теме
(36)А еще любят методы платформы в свои оборачивать. Например СообщениеПользователю. Зачем? Мне не понятно.
Проще от этого не становится. Вместо того, чтобы методы платформы изучать,
приходится изучать методы БСП, которые не сильно проще. А если не подходит этот метод, по какой-то причине, то приходится все равно дополнительно разбираться с методами платформы.
Написать 6 строк кода, если знать, что пишешь - минута времени.
Зато хоть понимаешь, ЧТО ты пишешь. И, если нужно сделать что-то не совсем стандартное, делаешь это быстро. А Вася то забудет через пару месяцев как отчет программно формируется, и зависнет, если метод его не подойдет по какой-то причине.

Но пусть Вася на меня не обижается, это просто мое мнение, а статья очень веселая и позитивная.
Chai Nic; +1 Ответить
39. zqzq 23 05.07.19 10:42 Сейчас в теме
Давно уже использую подобную процедуру для СКД. Очень удобно. Нет этого низкоуровнего мусора от 1С (по формированию СКД) в основных модулях.
42. AllexSoft 05.07.19 13:52 Сейчас в теме
В данной функции параметр НастройкиКомпоновки надо бы по умолчанию Неопределено сделать, а что если мне нужно с настройками компоновки по умолчанию сформировать схему? Зачем мне инициализировать компановщик где то и передавать его процедуре.. недоработка в общем )
Имею аналогичную функцию, только параметров побольше, и универсальности то же) из нужного: можно передавать параметры и отборы в виде структуры, и не париться с НастройкамиКомпановки, ну и отладка, можно возвращать результирующие запросы (скомпанованные СКД) для целей отладки
43. SeiOkami 3423 05.07.19 14:37 Сейчас в теме
(42) СкомпоноватьРезультатОтчета(Результат, СКД, СКД.НастройкиПоУмолчанию);
44. AllexSoft 05.07.19 15:04 Сейчас в теме
(43) как вариант должно прокатить
45. jekichan 12.07.19 11:22 Сейчас в теме
Спасибо, интересно. Ждем следующих новелл
47. skv_79 353 02.08.19 14:59 Сейчас в теме
Хороший пример того, как нужно писать универсальные процедуры.
48. awk 741 04.09.19 12:05 Сейчас в теме
А я бы переписал этот кусок:

    //Определяем тип генератора
    Если ТипЗнч(Результат) = Тип("ТаблицаЗначений") ИЛИ ТипЗнч(Результат) = Тип("ДеревоЗначений") Тогда
        ВыводВКоллекциюЗначений = Истина;
        ТипГенератораВывода     = Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений");
    Иначе
        ВыводВКоллекциюЗначений = Ложь;
        ТипГенератораВывода     = Тип("ГенераторМакетаКомпоновкиДанных");
    КонецЕсли;
Показать

Как:
    //Определяем тип генератора
    ВыводВКоллекциюЗначений = Ложь;
    ТипГенератораВывода     = Тип("ГенераторМакетаКомпоновкиДанных");

    Если Результат = Неопределено Тогда
        Результат = Новый ТабличныйДокумент;
    ИначеЕсли ТипЗнч(Результат) <> Тип("ТабличныйДокумент") Тогда
        ВыводВКоллекциюЗначений = Истина;
        ТипГенератораВывода     = Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений");
    КонецЕсли;
Показать
49. herfis 498 06.09.19 09:52 Сейчас в теме
(48) Теорема Эскобара, как по мне. Я бы переделал процедуру на функцию, а требуемый тип результата вынес в необязательные параметры.
50. DoctorRoza 25.10.19 13:51 Сейчас в теме
Понял, я понял, где тут ошибка. В начале речь идет о Васе, а уже в конце нужно писать об Василии Ивановиче! ))
51. logarifm 1118 12.05.20 10:07 Сейчас в теме
А еще здесь не хватает программного создания саомй схемы компоновки данных. То-есть посмотреть если ТипПараметра СхемаКомпоновки = Неопределенно следовательно вызвать инициализацию создания самой схемы компоновки.
52. kns77 101 02.06.21 19:48 Сейчас в теме
1. Ненавижу когда выносят в общие модули то что вызывается 1, максимум 2 раза, а в 95% случаев это так, не лучше ли подумать до разработки таких моментов, подумать, а понадобится ли оно в дальнейшем. А в 1С так сплошь и рядом, при этом сколько я правил ошибок, при поиске где используется данный модуль в поиске 1-2, реже 3 ссылки. Спрашивается нафига тогда надо было его выносить в общие.

2. Ненавижу 1Совскую структуру и описание модулей. Модули почти во всех конфах наляпаны как попало и бессистемно. А документации нет нормальной, кусками с ИТС и форумов ищешь какой же общий модуль взять для получения чего либо. И особенно напрягает удаление и изменение модулей, когда после обновления раз и перестали работать с сентября 2019 года все кадровый отчеты, а 1с всего лишь убрали общий модуль по получению кадровой информации. Для примера и образца можно взять Парус 8-й версии. Совершенно не зная структуру системы можно всегда подглядеть какие разделы процедуры используются при выполнении любой операции. И так как все модули, таблицы, вьюшки, процедуры системно называются однотипно, найти нужное даже без консоли легко. Плюс есть система хранения сценариев, в которой задокументировано все. В 1с же у которой ресурсов гораздо больше в свободном доступе этого нет. Сидишь гадаешь или отладчиком смотришь похожее. В общем идиотизм.

3. Метаться по общим модулям, как я вчера смотрел формирования П-4, это долбануться можно, 17 вызовов общих модулей для формирования 4 цифр. Да идите вы лесом с такой унификацией.
user591389_aska_rabota; buzzzard; +2 Ответить
53. SeiOkami 3423 02.06.21 19:52 Сейчас в теме
(52)
Это всё принципы "правильного" программирования. Когда все пути кода ведут в Рим. И единичные изменения влияют на логику всего приложения. Иногда с этим перебарщивают, согласен.

Но программный вывод СКД - это достаточно часто используемая потребность, чтобы вынести в общий модуль.
54. ВасяЧ 06.08.21 16:13 Сейчас в теме
В следующий раз пиши про Виталика
55. timeforlive 15 01.04.22 18:08 Сейчас в теме
Васе дали задачу на пару часов, а он растянул ее на неделю со своими разработками и тестированием (отладкой). А еще окажется, что в конфе уже есть подобное универсальное решение и Вася поленился заглянуть в общие модули.
Статья хорошая. А я скажу словами из сов.фильма:
"Вася, не вздумай!"
"Эх, Вася, Вася"
unknown181538; +1 Ответить
Оставьте свое сообщение