Запрос, чтобы получить оклад сотрудницы, находящейся в отпуске по уходу за ребенком ЗУП 3.1

Question

Помогите пожалуйста создать запрос, чтобы получить оклад сотрудницы, находящейся в отпуске по уходу за ребенком в ЗУП 3.1

Accepted Answer

Есть статья на эту тему.
[URL=https://infostart.ru/public/841337/]https://infostart.ru/public/841337/[/URL]


В свете этого, можно получить плановые начисления на любую дату:

[CODE]
Сотрудник = Справочники.Сотрудники.НайтиПоНаименованию("Иванов Иван Иванович");

ДатаПолученияДанных = ТекущаяДата();

Запрос = Новый Запрос;
Запрос.МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;

Запрос.Текст =
"ВЫБРАТЬ
|	&ДатаПолученияДанных КАК Период,
|	&Сотрудник КАК Сотрудник
|ПОМЕСТИТЬ ВТОтбораСотрудников";

Запрос.УстановитьПараметр("ДатаПолученияДанных",ДатаПолученияДанных);
Запрос.УстановитьПараметр("Сотрудник",Сотрудник);

Запрос.Выполнить();

ТолькоРазрешенные = Ложь;
ЗапросВТПлановыеНачисления= КадровыйУчетРасширенный.ЗапросВТПлановыеНачисленияСотрудников(
ТолькоРазрешенные, 
"ВТПлановыеНачисленияСотрудников", 
"ВТОтбораСотрудников");
ЗапросВТПлановыеНачисления.МенеджерВременныхТаблиц = Запрос.МенеджерВременныхТаблиц;

ЗапросВТПлановыеНачисления.Выполнить();

ЗапросВТПлановыеНачисления.Текст =
"ВЫБРАТЬ
|	 ВТПлановыеНачисленияСотрудников.Период,
|	 ВТПлановыеНачисленияСотрудников.ПериодЗаписи,
|	 ВТПлановыеНачисленияСотрудников.Регистратор,
|	 ВТПлановыеНачисленияСотрудников.Сотрудник,
|	 ВТПлановыеНачисленияСотрудников.Начисление,
|	 ВТПлановыеНачисленияСотрудников.ДокументОснование,
|	 ВТПлановыеНачисленияСотрудников.Размер,
|	 ВТПлановыеНачисленияСотрудников.ОсновнойПоказатель,
|	 ВТПлановыеНачисленияСотрудников.ЗначениеОсновногоПоказателя,
|	 ВТПлановыеНачисленияСотрудников.НачислениеТарифнойСтавки
|	ИЗ ВТПлановыеНачисленияСотрудников";


ТЗ = ЗапросВТПлановыеНачисления.Выполнить().Выгрузить();


Для каждого стр из ТЗ Цикл
	Для каждого колонка из ТЗ.колонки Цикл
	    сообщить(колонка.Имя + ": " + стр[колонка.Имя]);
	КонецЦикла;
	Сообщить("-----------");
КонецЦикла;
[/CODE]

Можете "поймать" текст запроса ЗапросВТПлановыеНачисления и посмотреть, как там берутся плановые начисления.