Создание внешней печатной формы без формирования табличного документа

Question

Пытаюсь создать внешнюю печатную форму, на стандартных механизмах, но без формирования табличного документа, т.е. мне необходимо вывести некий шаблон в формате word сохраненный в макете обработки. 
все в принципе отрабатывает, т.е. файл word формируется и открывается, но выходит сообщение: 
{ОбщийМодуль.УправлениеПечатью.Модуль(1522)}: В обработчике печати не был сформирован табличный документ для: ПриемДМО
			ВызватьИсключение(ТекстСообщенияОбОшибке);
ошибка выходит в Процедуре ПечатьПоВнешнемуИсточнику

если передать в модуле документа обработки в процедуру Печать() некий табличный документ, допустим пустой то он выводится дополнительно, а это какбы не нужно, хотя ошибкатоже не красиво.

никто не пытался сделать подобное. 
немогу придумать как сие можно подобороть....

Accepted Answer

В сведениях о внешней обработке:
[CODE]НоваяКоманда.Использование = "ВызовКлиентскогоМетода";
НоваяКоманда.Модификатор = "Печать";[/CODE]

Создаете форму, и печать из нее уже программируете. Пример модуля процедуры Печать в самой форме:
[CODE]
&НаКлиенте
Процедура Печать(ИдентификаторКоманды, ОбъектыНазначения) Экспорт
	
	Объект.СсылкаНаОбъект = ОбъектыНазначения[0];
	
	ДанныеДляЗаполнения = ПолучитьДанныеДляЗаполнения(Объект.СсылкаНаОбъект);
	МакетФайл = ПолучитьМакет("Макет");
	ИмяФ = ПолучитьИмяВременногоФайла("docx");
	МакетФайл.Записать(ИмяФ);	
	MSWord = Новый COMОбъект("Word.Application");
	Doc = MSWord.Documents.ADD(ИмяФ);
	
	Попытка
		
		Для каждого СтрСтруктуры Из ДанныеДляЗаполнения Цикл
			
			СтрокаПоиска = "{" + СтрСтруктуры.Ключ + "}";
			
			Replace = Doc.Content.Find;
			
			FindText = СтрокаПоиска;     // что искать - имя_шаблона
			MatchCase = Ложь;                 // использовать регулярные выражения        
			MatchWholeWord = Истина;          // искать слово целиком
			MatchWildcards = Ложь;            // испоьзовать регулярные выражения 
			MatchSoundsLike = Неопределено;   // искать созвучные 
			MatchAllWordForms = Неопределено; // искать все формы слова
			Forward = Истина;                 // искать вперед
			Wrap = Неопределено;              // что должен вернуть Find-объект 
			Format_ = Ложь;                   // использовать форматирование
			ReplaceWith = СтрСтруктуры.Значение;              // текст, на который надо заменить имя_шаблона
			
			Попытка
				Replace.Execute(
				FindText, 
				MatchCase, 
				MatchWholeWord, 
				MatchWildcards, 
				MatchSoundsLike, 
				MatchAllWordForms, 
				Forward,
				Wrap,
				Format_,
				ReplaceWith, 2);
			Исключение
				Сообщить("Ошибка при замене: " + СтрокаПоиска + " на " + СтрСтруктуры.Значение);
			КонецПопытки;
			
		КонецЦикла;
		
		ТаблицаВорд = MSWord.ActiveDocument.Tables(3);
		
		ЗаполнитьТаблицуДокумента(Объект.СсылкаНаОбъект);
		
		Если НЕ Объект.ЕстьСкидка Тогда
			ТаблицаВорд.Columns.Item(6).Delete();
			ТаблицаВорд.Columns.Item(5).Delete();
			ТаблицаВорд.Columns.Item(2).Width = 300;
		КонецЕсли;
		
		Строка = 2;
		Для каждого СтрТовары Из Объект.ТаблицаДокумента Цикл
			
			ТаблицаВорд.Rows.Add();
			
			КолонкаТаблицы = ТаблицаВорд.Cell(Строка, 1).Range;
			КолонкаТаблицы.Text = СтрТовары.НомСтр;
			
			КолонкаТаблицы = ТаблицаВорд.Cell(Строка, 2).Range;
			КолонкаТаблицы.Text = СтрТовары.Номенклатура;
			
			КолонкаТаблицы = ТаблицаВорд.Cell(Строка, 3).Range;
			КолонкаТаблицы.Text = СтрТовары.Количество;
			
			КолонкаТаблицы = ТаблицаВорд.Cell(Строка, 4).Range;
			КолонкаТаблицы.Text = СтрТовары.Сумма;
			
			Если Объект.ЕстьСкидка Тогда
			
				КолонкаТаблицы = ТаблицаВорд.Cell(Строка, 5).Range;
				КолонкаТаблицы.Text = СтрТовары.СуммаСкидки;
				
				КолонкаТаблицы = ТаблицаВорд.Cell(Строка, 6).Range;
				КолонкаТаблицы.Text = СтрТовары.Итого;
				
				КолонкаТаблицы = ТаблицаВорд.Cell(Строка, 7).Range;
				КолонкаТаблицы.Text = СтрТовары.ДатаКон;
				
			Иначе
				
				КолонкаТаблицы = ТаблицаВорд.Cell(Строка, 5).Range;
				КолонкаТаблицы.Text = СтрТовары.ДатаКон;
				
			КонецЕсли;
			
			Строка = Строка + 1;
			
		КонецЦикла;
		
		// Вывод документа
		MSWord.Application.Visible = 1;
		MSWord.Activate();
		
		//+чтобы документ Word открылся перед лицом пользователя, нужен такой лайфхак
		MSWord.Application.WindowState = 2; //сворачиваем
		MSWord.Application.WindowState = 1; //разворачиваем
		
	Исключение
		Сообщить(ОписаниеОшибки());
		MSWord.Application.Quit();
	КонецПопытки; 
	
КонецПроцедуры // Печать()

&НаСервере
Функция ПолучитьМакет(ИмяМакета)
	
	Возврат РеквизитФормыВЗначение("Объект").ПолучитьМакет(ИмяМакета);
	
КонецФункции
[/CODE]

P.S. Для приведенного примера тип макета - двоичные данные.