ПриАктивацииСтроки номер строки выходит за рамки массива

Question

Имею форму отбора заявок для последующей генерации всякой отчётной информации...
На форме две табличных части: Список заявок и Список сотрудников, упомянутых в этих заявках.
При изменении текущей строки в списке заявок, в списке сотрудников отображается список тех сотрудников, которые есть в этой заявке.
Имею вот такой код:
[1C-CODE]&НаСервере
Процедура ПеречитатьИсходныеДанные()
	Запрос=Новый Запрос;
	Запрос.Текст="ВЫБРАТЬ РАЗЛИЧНЫЕ
	             |	тгкЗаявкаРСФЛСписокСотрудников.Ссылка
// ............................................................................................................	
	             |ГДЕ
	             |	тгкЗаявкаРСФЛ.Проведен"
				 ;
	Объект.Заявки.Очистить();
	Запрос.УстановитьПараметр("Организация",Организация);
	Запрос.УстановитьПараметр("ДатаЗапроса",ДатаЗапроса);
	Рез=Запрос.Выполнить().Выбрать();
	Если Рез.Количество()>0 Тогда
		Пока Рез.Следующий() Цикл
			Нов=Объект.Заявки.Добавить();
			ЗаполнитьЗначенияСвойств(Нов,Рез);
		КонецЦикла;
	КонецЕсли;	
	
	// заполним табличную часть ВсеСотрудники, чтобы из неё потом такать данные для списка сотрудников из заявки, чтобы не обращаться на сервер
	// при событии ПриАктивацииСтроки в списке заявок
	Запрос.Текст="ВЫБРАТЬ РАЗЛИЧНЫЕ
	             |	тгкЗаявкаРСФЛСписокСотрудников.ТабельныйНомер,
	             |	тгкЗаявкаРСФЛСписокСотрудников.Сотрудник,
	             |	тгкЗаявкаРСФЛСписокСотрудников.Ссылка КАК ИзЗаявки,
	             |	тгкЗаявкаРСФЛСписокСотрудников.Сумма КАК СуммаПеревода
	             |ИЗ
	             |	Документ.тгкЗаявкаРСФЛ.СписокСотрудников КАК тгкЗаявкаРСФЛСписокСотрудников
	             |ГДЕ
	             |	НЕ тгкЗаявкаРСФЛСписокСотрудников.Принят
	             |	И тгкЗаявкаРСФЛСписокСотрудников.Ссылка.Организация = &Организация
	             |	И тгкЗаявкаРСФЛСписокСотрудников.Ссылка.Дата <= &ДатаЗапроса
	             |	И тгкЗаявкаРСФЛСписокСотрудников.Ссылка.Проведен"
				 ;
	ВсеСотрудники.Очистить();
	Запрос.УстановитьПараметр("Организация",Организация);
	Запрос.УстановитьПараметр("ДатаЗапроса",ДатаЗапроса);
	Рез=Запрос.Выполнить().Выбрать();
	Если Рез.Количество()>0 Тогда
		Пока Рез.Следующий() Цикл
			Нов=ВсеСотрудники.Добавить();
			ЗаполнитьЗначенияСвойств(Нов,Рез);
		КонецЦикла;
	КонецЕсли;	
КонецПроцедуры

&НаСервере
Процедура ПриОткрытииНаСервере()
	ПеречитатьИсходныеДанные();
КонецПроцедуры

&НаКлиенте
Процедура ПриОткрытии(Отказ)
	ПриОткрытииНаСервере();
КонецПроцедуры

&НаКлиенте
Процедура ОбновитьСписокСотрудников(ТекСтр)
	Если ТекСтр=Неопределено Тогда
		Возврат;
	КонецЕсли;
	Док=Объект.Заявки[ТекСтр].Документ;
	СписокСотрудников.Очистить();
	Для каждого Элем из ВсеСотрудники Цикл
		Если Элем.ИзЗаявки=Док Тогда
			Нов=СписокСотрудников.Добавить();
			ЗаполнитьЗначенияСвойств(Нов,Элем);
		КонецЕсли;
	КонецЦикла;
КонецПроцедуры

&НаКлиенте
Процедура ЗаявкиПриАктивизацииСтроки(Элемент)
	ОбновитьСписокСотрудников(ЭтаФорма.Элементы.Заявки.ТекущаяСтрока);
	ЭтаФорма.Элементы.СписокСотрудниковСумма.ТекстПодвала=Формат(СписокСотрудников.Итог("СуммаПеревода"),"ЧН=;ЧДЦ=2");
КонецПроцедуры

&НаКлиенте
Процедура ОбновитьСписок(Команда)
	ПеречитатьИсходныеДанные()
КонецПроцедуры
[/1C-CODE]
В ТЗ оговорено обновление списка заявок (см. процедуру  ОбновитьСписок(Команда))
Только она вылетает по ошибке "Индекс выходит за границы массива" в процедуре ОбновитьСписокСотрудников(ТекСтр). ТекСтр оказывается равной количеству строк в списке заявок...
Откуда берётся такое значение? Управление в ОбновитьСписокСотрудников передаётся только из ПриАктивацииСтроки...
И ещё... При открытии формы событие ПриАктивацииСтроки срабатывет дважды... Почему?

Accepted Answer

(1) Вы некорректно используете текущую строку таблицы формы.

Если Вам нужны данные активной строки (значения ячеек), то следует использовать ТекущиеДанные. Это свойство ссылается на выделенную строку. Если никакая строка не выделена, свойство равно Неопределено:
[CODE]ТекСтр = Элементы.Заявки.ТекущиеДанные;
Если ТекСтр = Неопределено Тогда
   Возврат;
КонецЕсли;
Док = ТекСтр.Документ;[/CODE]
ТекущаяСтрока - это [B]идентификатор[/B] строки. Т.к. для табличной части он имеет числовой тип, многие в моей практике его путают с индексом строки таблицы, но это не индекс! Это именно идентификатор, которой зачастую, но не всегда совпадает с индексом строки. Если известен идентификатор, данные строки можно получить так:
[CODE]ТекСтр = Элементы.Заявки.ТекущаяСтрока;
ТекДанные = Объект.Заявки.НайтиПоИдентификатору(ТекСтр);
Если ТекДанные = Неопределено Тогда
   Возврат;
КонецЕсли;
Док = ТекДанные.Документ;[/CODE]