Добавление отчетов в типовые конфигурации 1С

20.06.19

Разработка - Универсальные функции

Описание различных способов добавления общих и контекстных отчетов в конфигурации 1С, построенные на базе БСП. Основные моменты и нюансы.

Речь пойдет об отчетах, созданных на базе СКД (на всякий случай пишу, если еще остались люди, которые делают отчеты не на СКД). 

Добавить отчет в типовую конфигурацию 1С, построенную на базе БСП, можно одним из следующих способов:

Добавляемый отчет может быть:

Вроде все должно быть просто и интуитивно понятно, но есть нюансы, и в каждом случае добавление происходит по разному. В общем, разработчики БСП и других типовых продуктов не дают соскучиться J.

Общая схема добавления отчетов

 

Варианты отчетов

Прежде чем приступить к описанию добавления отчетов, хочется сказать несколько слов о вариантах.

Варианты отчетов - это встроенный механизм СКД, который позволяет создавать для отчета произвольное количество предопределенных и пользовательских вариантов. По своей сути варианты – это отдельные отчеты, созданные на базе одной и той же системы компоновки данных.

Существует отдельная подсистема БСП, для управления вариантами отчетов, которая встроена во все типовые конфигурации. Подсистема предоставляет общее хранилище вариантов, общие формы для вывода и настройки отчетов, механизмы для отображения отчетов – формирование специальных панелей для каждого раздела системы. Пользователь может управлять настройками предопределенных вариантов отчетов, создавать и настраивать собственные варианты в режиме 1С Предприятие. Также подсистема позволяет создавать контекстные отчеты, привязанные к определенным объектам метаданных. 

Для каждого отчета существует основной предопределенный вариант. В дальнейшем, говоря об отчете, я буду подразумевать именно его основной вариант.

 

Общая сравнительная таблица:

Тип добавления

В основную конфигурацию

В расширение конфигурации

В качестве внешнего отчета

Обновление вспомогательных данных (идентификаторы объектов)

Не требуется

Не требуется

Не требуется

Обновление вспомогательных данных (варианты отчетов)

Требуется

Не требуется

Не требуется

Предопределенные настройки вариантов

Общий модуль: ВариантыОтчетовПереопределяемый

Модуль менеджера отчета

Нет

Возможность добавление обработчиков событий формы

Указывается в общем модуле: ВариантыОтчетовПереопределяемый

Указывается в модуле менеджера отчета:

ПриОпределенииНастроек

Доступна по умолчанию

Описание назначения для контекстного отчета

Модуль менеджера отчета, модуль менеджера объекта назначения

Модуль менеджера отчета

Модель объекта отчета

Описание основного варианта (по умолчанию)

Нет

Свойство отчета «Пояснение»

Нет

Добавление пользовательских вариантов отчета

Есть

Есть

Есть

 

Добавление нового отчета в основную конфигурацию

Рассмотрим добавление отчета в основную конфигурацию. В более старых конфигурациях типа УТ 10.3, УПП все было предельно просто. Добавляешь отчет, выводишь его в меню интерфейса или на панели быстрого доступа, и все работает.

В новых все несколько сложнее, и есть свои нюансы.

Для того, чтобы отчет выводился в основном окне раздела в группе «Отчеты», достаточно просто включить отчет в необходимую подсистему.

Однако, в этом случае, отчет не будет виден на специальной панели отчетов, которую предоставляет БСП. Панель открывается при переходе по ссылке «Отчеты по <Наименование раздела>» из каждого раздела системы:

Открыть панель отчетов

Отчеты выводятся с разбивкой по подгруппам согласно иерархии подсистем, и имеют описания. Причем, могут быть выведены несколько вариантов одного и того же отчета. Если просто добавить отчет в конфигурацию и включить в нужную подсистему, отчет не будет виден в указанной панели. Отчет будет доступен только в группе «Отчеты» основного окна раздела. Кстати, не так давно, он бы даже не работал, пока не будут обновлены идентификаторы объектов метаданных.

Обновить идентификаторы можно одним из трех способов:

  1. Запустить 1С Предприятие в режиме обновления ИБ, задав параметр запуска: «ЗапуститьОбновлениеИнформационнойБазы»:

Запуск 1С Предприятия в режиме обновления

 

  1. Увеличить номер версии конфигурации.
  2. Воспользоваться обработкой из состава БСП: «Обновление вспомогательных данных»

В текущих версиях, идентификаторы обновляются при запуске 1С в пользовательском режиме автоматически. Наконец-то разработчики сделали это, слава богам!

Однако, для того, чтобы отчет, добавленный в основную конфигурацию появился на панели отчетов, все же необходимо обновить вспомогательные данные вручную, выбрав пункт «Варианты отчетов»:

Обновить варианты отчетов

После выполнения этих действия, отчет будет добавлен в специальные справочники: «Варианты отчетов» и «Предопределенные варианты отчетов», и его основной вариант будет виден в панелях отчетов согласно указанной подсистемы.

Конечно, все дальнейшие настройки, такие как добавление описания, вывод отчета или других его вариантов в другие подразделы или панели отчетов, можно выполнить непосредственно в пользовательском режиме, перейдя по ссылке «Все отчеты»:

Настройка вариантов отчетов

Но, более правильно указать основные (предопределенные) настройки в конфигурации. Тем более, что некоторые виды настроек, например видимость варианта отчета в зависимости от функциональных опций, нельзя настроить в пользовательском режиме.

Настройки вариантов отчетов задаются в процедуре общего модуля: «ВариантыОтчетовПереопределяемый >> НастроитьВариантыОтчетов». Здесь описаны все типовые отчеты и их варианты. Все настройки необходимо создавать для двух объектов: «Описание отчета» и «Описание варианта», которые можно получить из общего списка настроек, переданных в процедуру:

ОписаниеОтчета = ВариантыОтчетов.ОписаниеОтчета(Настройки, Метаданные.Отчеты.ВыручкаИСебестоимостьПродаж);
ОписаниеВарианта = ВариантыОтчетов.ОписаниеВарианта(Настройки, ОписаниеОтчета, "ДинамикаПродаж");

 

Объект «ОписаниеОтчета» имеет следующие свойства:

Включен - если свойство имеет значение «ложь», отчет не регистрируется в справочнике «Варианты отчетов».  

ОпределитьНастройкиФормы – свойство определяет наличие в модуле объекта отчета экспортной процедуры «ОпределитьНастройкиФормы». В данной процедуре указывается наличие дополнительных обработчиков для событий модуля формы отчета, которые также должны присутствовать в модуле объекта отчета:

Процедура ОпределитьНастройкиФормы(Форма, КлючВарианта, Настройки) Экспорт
    Настройки.События.ПриСозданииНаСервере = Истина;
    Настройки.События.ПередЗагрузкойВариантаНаСервере = Истина;
    Настройки.События.ПриЗагрузкеВариантаНаСервере = Истина;
    Настройки.События.ПередЗагрузкойНастроекВКомпоновщик = Истина;
КонецПроцедуры

 

Объект «ОписаниеВарианта» имеет следующие свойства:

Описание - Описание варианта отчета, которое выводится на панели отчетов.

ВидимостьПоУмолчанию - если свойство имеет значение «ложь», вариант не виден по умолчанию в панели отчетов, но в справочнике «Варианты отчетов» он регистрируется.

Размещение – настройка размещения отчета. По умолчанию, коллекция содержит все подсистемы, выбранные для отчета. Можно добавить новые подсистемы для размещения или удалить существующие. Дополнительно, можно указать важность размещения: «Важный» или «СмТакже»:

Подсистема = Метаданные.НайтиПоПолномуИмени("Подсистема.Продажи.Подсистема.ОптовыеПродажи");
ОписаниеВарианта.Размещение.Вставить(Подсистема, «СмТакже»);
Подсистема = Метаданные.НайтиПоПолномуИмени("Подсистема.ФинансовыйРезультатИКонтроллинг.Подсистема.ФинансовыйРезультат");
ОписаниеВарианта.Размещение.Удалить(Подсистема);

ФункциональныеОпции – подключенные к команде вывода варианта отчета функциональные опции:

ОписаниеВарианта.ФункциональныеОпции.Добавить("НеИспользоватьБизнесРегионы");

НастройкиДляПоиска – дополнительные сведения для поиска варианта отчета

Для вступления настроек в силу, требуется обновить вспомогательные данные, выбрав пункт «Варианты отчетов».

В пользовательском режиме, можно переопределить эти настройки для текущего пользователя или всех пользователей системы. Тем не менее, всегда остается возможность вернуться к предопределенным настройкам, заданным в конфигурации:

 Предопределенные настройки по умолчанию

 

Добавление нового отчета в расширение конфигурации

На первый взгляд, добавление отчета в расширении не должно отличаться от его добавления в основную конфигурацию, но это не так.

Во-первых, для того, чтобы отчет был виден на панели отчетов, не нужно выполнять обновление вспомогательных данных.  Необходимая информация в справочники: «Варианты отчетов» и «Предопределенные варианты отчетов» добавляется автоматически, при начале работы системы. Я думаю логика разработчиков следующая: расширение может подключить обычный пользователь в режиме 1С Предприятия. И он не должен знать о необходимости обновлении вспомогательных данных.

Для отчетов, добавленных в расширениях, также существует возможность описания предопределенных настроек: описание, подсистемы, функциональные опции. Однако, эти настройки выполняются не в переопределяемом общем модуле, а непосредственно в модуле менеджера отчета:

Процедура НастроитьВариантыОтчета(Настройки, НастройкиОтчета) Экспорт
      ...
КонецПроцедуры

Все настройки аналогичны тем, которые выполнялись для отчетов основной конфигурации. Отличие только в том, что объект «НастройкиОтчета» уже передан в процедуру в качестве параметра.

Для применения созданных настроек обязательно должен быть установлен параметр «НастроитьВариантыОтчета» в экспортной процедуре модуля менеджера отчета «ПриОпределенииНастроек»:

Процедура ПриОпределенииНастроек(Настройки) Экспорт
     Настройки.НастроитьВариантыОтчета = Истина;
КонецПроцедуры

Если флаг установлен, предопределенные настройки обновляются автоматически, без необходимости обновления вспомогательных данных.

В этой же процедуре указывается наличие дополнительных обработчиков событий модуля формы отчета:

Настройки.ОпределитьНастройкиФормы = Истина;

 На заметку. Для отчетов созданных в расширениях, есть возможность указания описания для основного варианта без использования менеджера отчета. Для задания описания «по умолчанию» используется свойство отчета «Пояснение»:

Описание отчета по умолчанию

 

Добавление контекстного отчета в основную конфигурацию или в расширение

Алгоритм добавления контекстных отчетов одинаков для отчетов созданных в основной конфигурации и для отчетов, созданных в расширениях.

В обоих случаях, необходимо определить экспортную процедуру «ПриОпределенииНастроек» в модуле менеджера отчета, и указать объекты назначения:

Процедура ПриОпределенииНастроек(Настройки) Экспорт
     Настройки.ДобавитьКомандыОтчетов = Истина;
     Настройки.Размещение.Добавить(Метаданные.Документы.РеализацияТоваров);
КонецПроцедуры

Сами команды необходимо описать в отдельной процедуре:

Процедура ДобавитьКомандыОтчетов(КомандыОтчетов, Параметры) Экспорт
     Команда = КомандыОтчетов.Добавить();
     Команда.Представление = НСтр("ru = 'Представление команды'");
     Команда.КлючВарианта = "ИдентификаторВариантаОтчета";
КонецПроцедуры

 

Основные свойства команды:

Представление – наименование команды в интерфейсе объекта назначения,

КлючВарианта – идентификатор варианта отчета компоновки данных, который требуется запустить.

 

Дополнительные свойства команды:

Важность - группы в подменю «Отчеты», в которой следует вывести команду открытия отчета. Доступные значения: "Важное", "Обычное" и "СмТакже".

Порядок - порядок размещения отчета по отношению к другим отчетам.

СочетаниеКлавиш - сочетание клавиш для быстрого открытия отчета (тип «СочетаниеКлавиш».

Пример:

Команда.СочетаниеКлавиш = Новый СочетаниеКлавиш(Клавиша.B, Ложь, Истина, Истина);

ВидимостьВФормах - используется для указания перечня форм, в которых требуется выводить отчет. По умолчанию, отчет выводится во всех формах объекта, подключенных к БСП.

ФункциональныеОпции - имена функциональных опций, определяющих видимость команды открытия отчета в форме.

УсловияВидимости – дополнительные условия, определяющие видимость команды отчета (массив). Для добавления новых условий рекомендуется использовать процедуру общего модуля «ПодключаемыеКоманды.ДобавитьУсловиеВидимостиКоманды(Команда, Реквизит, Значение, Знач ВидСравнения = Неопределено)».

Параметр «Реквизит» - это имя реквизита объекта назначения.

Пример:

ПодключаемыеКоманды.ДобавитьУсловиеВидимостиКоманды(КомандаОтчета, " Артикул", «»);

ДополнительныеПараметры – можно указать дополнительные параметры, и потом их обработать в переопределенном обработчике события модуля формы отчета «ПриСозданииНаСервере».

Ссылка на объект назначения передается в контекстный отчет в качестве параметра формы «ПараметрКоманды». Для указания отбора по переданному значению, необходимо переопределить событие модуля формы отчета «ПриСозданииНаСервере», и добавить значение параметра в структуру «ФормаПараметры.Отбор»:

Процедура ОпределитьНастройкиФормы(Форма, КлючВарианта, Настройки) Экспорт
     Настройки.События.ПриСозданииНаСервере = Истина;
КонецПроцедуры

Процедура ПриСозданииНаСервере(ЭтаФорма, Отказ, СтандартнаяОбработка) Экспорт
     Параметры = ЭтаФорма.Параметры;
     Если Параметры.Свойство("ПараметрКоманды") Тогда
          ЭтаФорма.ФормаПараметры.Отбор.Вставить("Номенклатура", Параметры.ПараметрКоманды);
     КонецЕсли;
КонецПроцедуры

При необходимости можно обработать данные, переданные в свойстве команды «ДополнительныеПараметры»:

Параметры.ОписаниеКоманды.ДополнительныеПараметры

Примечание. Описывать команды для вывода контекстных отчетов можно не только в модуле менеджера самого отчета, но и в модуле менеджера объекта назначения, в экспортной процедуре «ДобавитьКомандыОтчетов». В этом случае, команда должны иметь дополнительный обязательный параметр «Менеджер», в котором необходимо указать полное имя менеджера отчета. Контекстные отчеты в типовых конфигурациях описаны именно таким способом. 

 

Добавление отчетов с помощью механизма внешних отчетов и обработок

Процесс добавления общих и контекстных отчетов с использованием механизма дополнительных отчетов и обработок подробно описан во многих статьях, например в этой .

Я не думаю, что у кого-то возникают сложности при добавлении отчетов таким способом. Отмечу лишь, что в данном случае не нужно обновлять вспомогательные данные. Также, нет возможности указания предопределенных настроек для вариантов отчета. Все настройки вариантов указываются в пользовательском режиме, прямо в форме элемента дополнительного отчета:

Изменить вариант дополнительного отчета

Возможность добавления в модуль объекта обработчиков событий формы отчета доступна по умолчанию.

Если я ошибаюсь, и существуют вопросы и непонятные моменты в работе механизма дополнительных отчетов и обработок, пишите в комментариях, и я напишу отдельную статью на эту тему.

Дополнительно хочу отметить, что варианты отчетов, созданные в пользовательском режиме настраиваются одинаково для любого из способов добавления основного отчета.

 

На этом все, спасибо за внимание, и за то, что читаете мои статьи J.

 

Другие мои статьи по использованию механизмов БСП в типовых конфигурациях 1С

  1. Возможности типовых шаблонов БСП ограничения доступа на уровне записей

  2. Новый подход к обмену данными EnterpriseData

  3. EnterpriseData – часть 2. Процесс выгрузки данных

  4. Пример доработки правил конвертации без использования КД 3.0

  5. Использование подсистемы БСП "Заполнение объектов"

 

Добавление отчетов контекстные отчеты расширения дополнительные подсистема БСП варианты

См. также

Шаблоны новых объектов 1С для 1С:Бухгалтерии предприятия

Инструментарий разработчика БСП (Библиотека стандартных подсистем) Механизмы типовых конфигураций Платформа 1С v8.3 1С:Бухгалтерия 3.0 Бесплатно (free)

Используются для создания новых объектов в конфигурации, чтобы не забыть, что нужно сделать. Сделано на примере 1С:Бухгалтерия предприятия, в других конфигурациях могут быть другие, а могут быть и похожие объекты.

28.12.2023    4823    mrXoxot    11    

99

Переоткрытие внешних обработок

Универсальные функции Платформа 1С v8.3 Бесплатно (free)

На заключительных этапах, когда идет отладка или доработка интерфейса, необходимо много раз переоткрыть внешний объект. Вот один из способов автоматизации этого.

30.11.2023    3956    ke.92@mail.ru    16    

61

Валидация JSON через XDTO (включая массивы)

WEB-интеграция Универсальные функции Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

При работе с интеграциями рано или поздно придется столкнуться с получением JSON файлов. И, конечно же, жизнь заставит проверять файлы перед тем, как записывать данные в БД.

28.08.2023    8804    YA_418728146    6    

141

Печать непроведенных документов для УТ, КА, ERP. Настройка печати по пользователям, документам и печатным формам

Пакетная печать Печатные формы Адаптация типовых решений Универсальные функции Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Абонемент ($m)

Расширение для программ 1С:Управление торговлей, 1С:Комплексная автоматизация, 1С:ERP, которое позволяет распечатывать печатные формы для непроведенных документов. Можно настроить, каким пользователям, какие конкретные формы документов разрешено печатать без проведения документа.

2 стартмани

22.08.2023    2071    21    progmaster    7    

3

Многопоточное выполнение процедуры с помощью ДлительныеОперации

БСП (Библиотека стандартных подсистем) Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

В публикации: Приведен шаблон для запуска многопоточной операции для различных вариантов размещения многопоточной операции, в том числе в модуле объекта внешней обработки, встроенной в справочник Дополнительные отчеты и обработки; Представлен вариант корректного отображения прогресса многопоточной операции; Приведены замеры, демонстрирующие целесообразность использования нового механизма для увеличения производительности.

1 стартмани

26.02.2023    8539    egoriy111    26    

88

Пример многопоточной обработки (БСП)

HighLoad оптимизация БСП (Библиотека стандартных подсистем) Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Обработка-шаблон, на основе которой можно делать свои многопоточные обработки данных для конфигураций на БСП.

13.02.2023    9315    6    echo77    8    

93
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. nomadon 367 08.03.19 10:13 Сейчас в теме
Может есть пример-шаблончик?
2. ids79 8291 08.03.19 10:44 Сейчас в теме
(1)Какой именно шаблон Вам нужен?
3. ded20ded 08.03.19 18:43 Сейчас в теме
Шаблон для внешних печатных форм, для внешних отчетов.
4. ids79 8291 09.03.19 07:42 Сейчас в теме
(3)По ссылке в статье можно скачать такие шаблоны.
Правда, там не для всех случаев, да и статья уже давно написана.
Выложу статью с актуальными шаблонами доп. отчетов и обработок
в ближайшее время.
5. пользователь 11.03.19 17:15
Сообщение было скрыто модератором.
...
6. Sherzod1984 11.03.19 17:20 Сейчас в теме
(4) Добрый день! Дмитрий Иванов, как можно с вами связаться?
8. пользователь 12.03.19 09:59
Сообщение было скрыто модератором.
...
19. ids79 8291 24.04.19 19:51 Сейчас в теме
7. chuff 12.03.19 07:28 Сейчас в теме
Узнал кое-что интересное. Только вот "в панелЕ", "на панелЕ" жутко режет глаза
9. ids79 8291 12.03.19 10:02 Сейчас в теме
(7)Самое интересное, я сперва так и написал.
Перед самой модерацией, мне показалось, что правильно именно так.
Еще раз посмотрел, все-таки Вы правы, исправил.
С грамотностью у меня беда, к сожалению.
Спасибо.
10. @Sonya 27 21.03.19 10:31 Сейчас в теме
Может кто сталкивался, при добавлении внешнего отчета, закладка Варианты не появляется. В свойствах отчета выбрано ХранилищеВариантовОтчетов. Что-то еще надо сделать?
11. @Sonya 27 21.03.19 10:56 Сейчас в теме
(10) Отвечаю сама. При регистрации отчета было написано
РегистрационныеДанные.Вставить("Вид", "Отчет");
а не
РегистрационныеДанные.Вставить("Вид", "ДополнительныйОтчет");
12. user599492_oskomleva 27.03.19 13:18 Сейчас в теме
Добрый день, а можно шаблон для отчета через расширение общего? Как присоединить и с какого релиза БСП для регистрации в справочнике достаточно просто Настройки.НастроитьВариантыОтчета = Истина;
Делаю следующие действия (отчет на СКД):
1. Создаю отчет в расширении
2. В свойствах добавляю ХранилищеВариантовОтчетов
3. В модуле Менеджера:

Процедура ПриОпределенииНастроек(Настройки) Экспорт
	
	Настройки.НастроитьВариантыОтчета = Истина;
	
КонецПроцедуры

Процедура НастроитьВариантыОтчета(Настройки, НастройкиОтчета) Экспорт
	
	НастройкиВарианта = ВариантыОтчетов.ОписаниеВарианта(Настройки, НастройкиОтчета, "ТестСотрудники");
	НастройкиВарианта.Описание = НСтр("ru = 'Тест сотрудники'");
	
КонецПроцедуры
Показать

после запуска 1С в справочнике отчетов не появляется предопределенного элемента
что делаю не так?
13. user599492_oskomleva 27.03.19 16:43 Сейчас в теме
Закрываю, вопрос. Все заработало.
14. ids79 8291 27.03.19 17:27 Сейчас в теме
(12)Даже если ничего не написать в модуле менеджера, отчет должен появиться в панели отчетов автоматически (если конечно указана подсистема).
15. user599492_oskomleva 27.03.19 18:00 Сейчас в теме
мне нужна не панель отчетов, а в справочнике Отчеты, как предопределенный элемент, иначе на отчет нельзя настроить рассылку.
16. Indifference 28.03.19 08:26 Сейчас в теме
(15)
Добрый день! Подскажите, пожалуйста, что вы все таки сделали чтобы отчет появился в предопределенных? В модуль менеджера вообще не заходит ни в одну процедуру.
18. yefalex 24.04.19 14:25 Сейчас в теме
(16) По вышеприведенному описанию для отчетов в расширении тоже не заработало, т.к. описано не совсем точно.
Сделал согласно документации БСП

Кроме того, команды отчетов можно задавать в самих отчетах конфигурации (и в отчетах расширений конфигурации). Для этого отчет нужно включить в состав подсистемы ПодключаемыеОтчетыИОбработки и в его модуле менеджера в области ПрограммныйИнтерфейс определить процедуры ПриОпределенииНастроек и ДобавитьКомандыЗаполнения. Подробнее см. пукнт Подключение отчетов и обработок к механизмам конфигурации документации подсистемы Подключаемые команды. Пример:

#Область ПрограммныйИнтерфейс
// Определяет состав программного интерфейса для интеграции с конфигурацией.
//
// Параметры:
//   Настройки - Структура - Настройки интеграции этого объекта.
//       См. возвращаемое значение функции ПодключаемыеКоманды.НастройкиПодключаемыхОтчетовИОбработок().
//
Процедура ПриОпределенииНастроек(Настройки) Экспорт
    Настройки.Размещение.Добавить(Метаданные.Документы.ИмяДокумента);
    Настройки.ДобавитьКомандыОтчетов = Истина;
КонецПроцедуры
// Определяет список команд отчетов.
//
// Параметры:
//   КомандыОтчетов - ТаблицаЗначений - Таблица с командами отчетов. Для изменения.
//       См. описание 1 параметра процедуры ВариантыОтчетовПереопределяемый.ПередДобавлениемКомандОтчетов().
//   Параметры - Структура - Вспомогательные параметры. Для чтения.
//       См. описание 2 параметра процедуры ВариантыОтчетовПереопределяемый.ПередДобавлениемКомандОтчетов().
//
Процедура ДобавитьКомандыОтчетов(КомандыОтчетов, Параметры) Экспорт
КонецПроцедуры
#КонецОбласти
Показать
SagittariusA; d4rkmesa; kabantus; Flyerink; igee12; Maito; +6 Ответить
24. AgnepuS 11 20.06.19 22:11 Сейчас в теме
(18) Добрый день. Не помог и "ваш" вариант, для того чтобы в пользовательском режиме у отчета из расширения отобразить варианты отчета. Всё также доступен только один вариант. Может быть у вас припасено ещё пара тузов в рукаве?
25. AgnepuS 11 20.06.19 23:04 Сейчас в теме
Разобрался, расширение подключено в безопасном режиме. От этого и не удается перехватить НастроитьВариантыОтчетов.
Спасибо за статью.
28. ids79 8291 20.06.19 23:11 Сейчас в теме
(25)Ну да, по этому и не заходит в модуль менеджера.
26. ids79 8291 20.06.19 23:06 Сейчас в теме
(18) Да, Вы правы. Добавление в подсистему "ПодключаемыеОтчетыИОбработки" - обязательно.
JohnyDeath; igee12; +2 Ответить
17. user599492_oskomleva 28.03.19 10:22 Сейчас в теме
https://help1c.by/podklyuchenie-novogo-otcheta-k-podsisteme-variantov-otcheta/
пункт 5 , нашла в конфигураторе подобную процедуру дополнила обращением в модуль менеджера своего отчета в расширении с директивой & После
а так все как описано выше, единственное отчет появляется в предопределенных с именем, которое в настройках СКД в графе представление.
Вариант для расширения вместо Описания использовать свойство "Пояснение" почему-то не сработало...
Прикрепленные файлы:
27. ids79 8291 20.06.19 23:10 Сейчас в теме
(17)Похоже, что Вы подключаете отчет не в расширении, а в основной конфигурации. В описании, которое Вы приводите, отчет в конфигурацию добавляется.

"Вариант для расширения вместо Описания использовать свойство "Пояснение" - это только для расширений работает.
20. Alex1053669 18.06.19 23:55 Сейчас в теме
Статья очень пригодилась.
AlexandrSmith; +1 Ответить
22. ids79 8291 20.06.19 11:26 Сейчас в теме
(20) Спасибо, значит не зря писал
21. пользователь 18.06.19 23:57
Сообщение было скрыто модератором.
...
23. ids79 8291 20.06.19 11:26 Сейчас в теме
29. nla_a 26.06.19 17:56 Сейчас в теме
Подскажите, пожалуйста, как убрать отчет из основного окна раздела «Отчеты», после того как он добавлен на специальную панель отчетов.
30. ids79 8291 26.06.19 18:34 Сейчас в теме
(29)Можно исключить отчет из подсистемы, в разделе которой он выводится.
31. nla_a 26.06.19 18:40 Сейчас в теме
(30) Да, в командном интерфейсе надо было снять галку. Спасибо.
32. Wefast 11.07.19 08:26 Сейчас в теме
Где это окно Вспомогательные данные, чтобы выбрать обновление вариантов отчетов?
33. ids79 8291 11.07.19 16:07 Сейчас в теме
(32)Обработка "Обновление вспомогательных данных" из состава БСП
34. MrBisquit 16.08.19 09:37 Сейчас в теме
На общей форме ФормаОтчета автоматически создаются элементы из быстрого доступа (параметры, отборы).
Есть ли способ навесить свой обработчик на какое-нибудь из таких полей?
Допустим нам надо после установки параметра каким-нибудь образом его обработать. Например пользователь ввёл дату, а мы дописали время 08:00.
В модуле ОтчетыКлиентПереопределяемый обработчиков совсем мало. Хотелось бы обойтись без копирования и изменения общей формы.
35. ids79 8291 17.08.19 08:31 Сейчас в теме
(34)Да, только добавлять свою форму в отчет и ее модифицировать. Там как раз вывод быстрых пользовательских настроек программно делается.
36. Denic01 06.11.19 12:24 Сейчас в теме
Есть такая функция
Функция ВариантыОтчетов.НастройкиФормыОтчета(ОтчетСсылка, КлючВарианта, ОтчетОбъект) Экспорт

в ней код

НастройкиОтчета = ОтчетыКлиентСервер.ПолучитьНастройкиОтчетаПоУмолчанию();
ОтчетыСНастройками = ВариантыОтчетовПовтИсп.Параметры().ОтчетыСНастройками

ОтчетыСНастройками - содержит список типовых отчетов, "свои" отчеты никак не добавляются в него, соответственно там выход из процедуры дальше и функционал ФормыОтчета наполовину не используется, может кто сталкивался ?

всё из статьи уже перепробовал, понял что этот список хранится в виде хранилища значения в настройках, а вот где и когда он перезаполняется ...
maxunov95; TerveRus; +2 Ответить
37. ids79 8291 06.11.19 16:12 Сейчас в теме
(36)Для начала попробуйте запустить обработку "Обновление вспомогательных данных" из состава БСП
38. Denic01 06.11.19 16:19 Сейчас в теме
(37)
да запускал я, конечно, и эту обработку и конфигуратор с параметром ЗапуститьОбновлениеИнформационнойБазы
Убеждался в отладчике, что в процедуру отчета
Процедура НастроитьВариантыОтчета(Настройки, НастройкиОтчета) Экспорт

программа заходит
однако озвученный массив так и не изменился, еще забыл озвучить, что в справочнике ВыриантыОтчетов все прописалось, появилось с интерфейса открывается.
maxunov95; TerveRus; +2 Ответить
40. user1310976 15.11.19 11:02 Сейчас в теме
(36)
Работаю с ERP, ситуация похожая. Есть ФормаОтчета(типовая), процедура ПриСозданииНаСервере. При выполнении условия:
Если ВариантыОтчетовПовтИсп.Параметры().ОтчетыСНастройками.Найти(НастройкиОтчета.ОтчетСсылка) <> Неопределено управление передается в процедуру ПриСозданииНаСервере модуля объекта моего отчета. Но он не передается, потому что в массиве ОтчетыСНастройками находятся только типовые отчеты.
Идей тоже пока нет, если вами будет найдено решение - пожалуйста отпишитесь, выручите сильно.
maxunov95; +1 Ответить
49. alexfps79 20.09.20 22:35 Сейчас в теме
(40)
(39)
НастроитьВариантыОтчета


Здравствуйте! У меня тоже проблема с массивом "ОтчетыСНастройками":

https://forum.infostart.ru/forum29/topic248060/?result#postform

Расскажите, как вы ее обощли?
maxunov95; +1 Ответить
39. Denic01 15.11.19 10:51 Сейчас в теме
Вообщем появилось время разобрался отвечу сам на свой вопрос:
я написал

Процедура НастроитьВариантыОтчета(Настройки, НастройкиОтчета) Экспорт
	
        НастройкиВарианта = ВариантыОтчетов.ОписаниеВарианта(Настройки, НастройкиОтчета, "Основная");
	НастройкиВарианта.Описание = НСтр("ru = 'Состояние товарного кредита покупателя'");
	НастройкиВарианта.ОпределитьНастройкиФормы = Истина;

КонецПроцедуры


так делать нельзя - тут создается переменная НастройкиВарианта, не особо понятно зачем она вообще нужна т.к. если смотреть в отладчике значения приравненные таким образом не оказывают влияние на параметры процедуры
нужно писать так: (в типовых тоже так написано)

Процедура НастроитьВариантыОтчета(Настройки, НастройкиОтчета) Экспорт
	
	НастройкиОтчета.ОпределитьНастройкиФормы = Истина;
	НастройкиВарианта = ВариантыОтчетов.ОписаниеВарианта(Настройки, НастройкиОтчета, "Основная");
	НастройкиВарианта.Описание = НСтр("ru = 'Состояние товарного кредита покупателя'");

КонецПроцедуры


тогда всё ок, смотрел изначально совсем в другую сторону поэтому в первый вопрос не добавил этот код )
maxunov95; VVi3ard; alex99232014; buch-a; begemot; DmitrySinichnikov; +6 Ответить
41. Bolnov 05.12.19 15:33 Сейчас в теме
42. ids79 8291 07.12.19 11:04 Сейчас в теме
(41)А у Вас сама подсистема и отчет в ней отображаются? Отчет не отображается только в панели отчетов?
43. kjsdhlf 12.12.19 09:32 Сейчас в теме
(42)Дмитрий, здравствуйте! Очень познавательная статья. Так как в документации БСП в примере по процедуре "ПриОпределенииНастроек", ничего не сказано, что ее нужно добавлять в модуль менеджера, но вы смогли догадаться, и на самом деле работает. Скажите пожалуйста откуда вы смогли почерпнуть информацию?
44. ids79 8291 13.12.19 08:39 Сейчас в теме
(43)Если Вы про контекстные отчеты, то это есть в описании БСП, не помню точно уже, где именно.
45. kjsdhlf 13.12.19 12:40 Сейчас в теме
(44)Да, нашел, спасибо!
47. Bolnov 30.12.19 10:09 Сейчас в теме
Продублирую

УТ 11.4.9.98, БСП 3.0.3.87, https://its.1c.ru/db/bsp303doc#content:23:1

1) Вывел в командный интерфейс подсистему "СлужебныеПодсистемы"
2) Создал отчет в конфигураторе
3) Подключил подсистему к разделам командного интерфейса как в БСП 3.8:
-cоздал отдельную общую команду для открытия панели отчетов
-имя команды "ПанельОтчетовСлужебныеПодсистемы"
-синоним команды "Отчеты по служебным подсистемам"
-в модуле команды добавил:

&НаКлиенте
Процедура ОбработкаКоманды(ПараметрКоманды, ПараметрыВыполненияКоманды)
    ВариантыОтчетовКлиент.ПоказатьПанельОтчетов("СлужебныеПодсистемы", ПараметрыВыполненияКоманды);
КонецПроцедуры 


-раздел перечислил в процедуре ОпределитьРазделыСВариантамиОтчетов общего модуля ВариантыОтчетовПереопределяемый, добавив:

Если НЕ ПолучитьФункциональнуюОпцию("БазоваяВерсия") Тогда
    Разделы.Добавить(Метаданные.Подсистемы.СлужебныеПодсистемы,
    НСтр("ru= 'Отчеты по служебным подсистемам'"));
КонецЕсли; 




Команда отображается в разделе, открывает форму

4) Установил настройки вариантов отчетов:
-в процедуре НастроитьВариантыОтчетов общего модуля ВариантыОтчетовПереопределяемый разместил вызов модуля менеджера отчета

ВариантыОтчетов.НастроитьОтчетВМодулеМенеджера(Настройки, Метаданные.Отчеты.РасходГСМновый);

-в модуле менеджера отчета вставил процедуру

Процедура НастроитьВариантыОтчета(Настройки, НастройкиОтчета) Экспорт
    
    
    ОписаниеОтчета = ВариантыОтчетов.ОписаниеОтчета(Настройки, Метаданные.Отчеты.РасходГСМновый);
    
    ОписаниеВарианта = ВариантыОтчетов.ОписаниеВарианта(Настройки, ОписаниеОтчета, "Диаграмма");
    ОписаниеВарианта.Описание = "Это диаграмма если что";
    ОписаниеВарианта.ВидимостьПоУмолчанию = Истина;
    ОписаниеВарианта.Размещение.Вставить(Метаданные.Подсистемы.СлужебныеПодсистемы);
    
    ОписаниеВарианта = ВариантыОтчетов.ОписаниеВарианта(Настройки, ОписаниеОтчета, "Таблица");
    ОписаниеВарианта.Описание = "А это таблица, наберешь";
    ОписаниеВарианта.ВидимостьПоУмолчанию = Истина;
    ОписаниеВарианта.Размещение.Вставить(Метаданные.Подсистемы.СлужебныеПодсистемы.Подсистемы.ТранспортныеСредства);
 
КонецПроцедуры 
Показать



5. Запускаю приложение с параметром запуска ЗапуститьОбновлениеИнформационнойБазы

Вопрос: почему отчеты в панели отчета выбранной подсистемы не отображаются?

Если поменять путь с Метаданные.Подсистемы.СлужебныеПодсистемы на какую-нибудь другую подсистему, которая уже была, например, Метаданные.Подсистемы.Склад, то в подсистеме "Склад и доставка" они отобразятся.
48. ids79 8291 04.01.20 13:13 Сейчас в теме
(47)Вроде бы все сделали правильно. Пришлите выгрузку базы, если так и не разобрались, я посмотрю. В слепую сложно что-то сказать.
Если все-таки решили проблему, напишите, в чем была проблема.
46. Bolnov 30.12.19 08:52 Сейчас в теме
(42) Сама подсистема отображается. Если у отчета указать данную подсистему, то он отобразится в подразделе "Отчеты".
А в панели отчетов данной подсистемы не отображается. Если же указать другую подсистемы - в ней будет
50. frkbvfnjh 785 16.04.21 11:23 Сейчас в теме
Спасибо! Статья помогла. Я первый раз столкнулся с тем, что отчеты просто так не выведешь туда куда надо если их добавлять непосредственно в конфигурацию, но в новых БСП вроде уже чуть по другому - там вроде в модуль менеджера самих отчетов переехала часть кода и в новых отчетах обязательно нужно указывать хранилище вариантов. В статье вроде об этом не сказано. Может еще какие-то есть изменения и нюансы, если да, то может напишите обновленную статью для БСП 3.1?
51. DmitrySinichnikov 285 03.06.21 14:23 Сейчас в теме
Спасибо! Статья отличная, еще лучше обилие полезных комментариев под ней.

Автор, если есть возможность, добавьте в статью некоторые комментарии (например 39) и ссылку на описание БСП на ИТС, например: https://its.1c.ru/db/bsp314doc. Думаю многим будет полезно.
52. ids79 8291 17.06.21 11:17 Сейчас в теме
(51)Спасибо за замечание. Добавлю, как руки дойдут.
53. TeMochkiN 02.09.22 10:27 Сейчас в теме
Всем привет! Подскажите, пожалуйста, возможно ли для типового отчета добавить ещё один вариант отчета программно через расширение? Не хочется делать отдельный отчет, так как в типовом итак запрос в СКД со всеми нужными данными. Нужно просто донастроить его отдельным вариантом.
54. bocharovki 7 16.05.23 20:48 Сейчас в теме
(53) Старый наверное вопрос. Но придется скопировать и полностью подменить компоновку. И не получится воспользоваться процедурой НастроитьВариантыОтчета из модуля менеджера в случае ее доработки в расширении например &После. В процессе заполнения вариантов игнорируются расширения.
Оставьте свое сообщение