Работа с построителем запроса.

ВЫБРАТЬ РАЗРЕШЕННЫЕ //РАЗЛИЧНЫЕ
    Продажи.Номенклатура КАК Номенклатура,
    СУММА(Продажи.СтоимостьОборот) КАК СуммаВыручки,
    КОЛИЧЕСТВО(РАЗЛИЧНЫЕ Продажи.Контрагент) КАК КоличествоПокупателей,
    СУММА(ВЫБОР КОГДА (ПродажиСебестоимость.СтоимостьОборот ЕСТЬ NULL ИЛИ ПродажиСебестоимость.КоличествоОборот ЕСТЬ NULL ИЛИ ПродажиСебестоимость.КоличествоОборот = 0) ТОГДА
        Продажи.СтоимостьОборот
    ИНАЧЕ
        Продажи.СтоимостьОборот - (ПродажиСебестоимость.СтоимостьОборот / ПродажиСебестоимость.КоличествоОборот) * Продажи.КоличествоОборот
    КОНЕЦ)                          КАК СуммаВаловойПрибыли,
    СУММА(Продажи.КоличествоОборот) КАК КоличествоПроданныхТоваров

    {ВЫБРАТЬ
        Продажи.Номенклатура.*,
        Продажи.Регистратор.*,
        Продажи.Номенклатура.*
    //СВОЙСТВА
    }

ИЗ

    (
    ВЫБРАТЬ
        Продажи.Номенклатура                                                КАК Номенклатура,
        Продажи.ХарактеристикаНоменклатуры                                  КАК ХарактеристикаНоменклатуры,
        Продажи.ДоговорКонтрагента.Владелец                                 КАК Контрагент,
        Продажи.ДокументПродажи.Ответственный                               КАК МенеджерПокупателя,
        Продажи.СтоимостьОборот                                             КАК СтоимостьОборот,
        Продажи.НДСОборот                                                   КАК НДСОборот,
        Продажи.КоличествоОборот                                            КАК КоличествоОборот,
        Продажи.Регистратор                                                 КАК Регистратор

    ИЗ

        РегистрНакопления.Продажи.Обороты(&ДатаНачала, &ДатаОкончания, Регистратор , (Номенклатура <> &ПустаяНоменклатура)) КАК Продажи

    ) КАК Продажи
//СОЕДИНЕНИЯ

    ЛЕВОЕ СОЕДИНЕНИЕ

    (
    ВЫБРАТЬ
        ПродажиСебестоимость.Номенклатура               КАК Номенклатура,
        ПродажиСебестоимость.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,
        СУММА(ПродажиСебестоимость.СтоимостьОборот)     КАК СтоимостьОборот,
        СУММА(ПродажиСебестоимость.КоличествоОборот)    КАК КоличествоОборот,
        ВЫБОР    КОГДА ПродажиСебестоимость.Регистратор ССЫЛКА Документ.РасходныйОрдерНаТовары
            ТОГДА ПродажиСебестоимость.Регистратор.ДокументПередачи
            ИНАЧЕ ПродажиСебестоимость.Регистратор
        КОНЕЦ                                            КАК Регистратор

    ИЗ
        РегистрНакопления.ПродажиСебестоимость.Обороты(&ДатаНачала, &ДатаОкончания, Регистратор , Номенклатура <> &ПустаяНоменклатура) КАК ПродажиСебестоимость

    СГРУППИРОВАТЬ ПО
        ПродажиСебестоимость.Номенклатура,
        ПродажиСебестоимость.ХарактеристикаНоменклатуры,
        ВЫБОР    КОГДА ПродажиСебестоимость.Регистратор ССЫЛКА Документ.РасходныйОрдерНаТовары
            ТОГДА ПродажиСебестоимость.Регистратор.ДокументПередачи
            ИНАЧЕ ПродажиСебестоимость.Регистратор
        КОНЕЦ

    ) КАК ПродажиСебестоимость

    ПО
        ПродажиСебестоимость.Номенклатура = Продажи.Номенклатура
        И
        ПродажиСебестоимость.ХарактеристикаНоменклатуры = Продажи.ХарактеристикаНоменклатуры
        И
        (ВЫБОР
        КОГДА  ПродажиСебестоимость.Регистратор ССЫЛКА Документ.РасходныйОрдерНаТовары
                ТОГДА ПродажиСебестоимость.Регистратор.ДокументПередачи = Продажи.Регистратор
            ИНАЧЕ ПродажиСебестоимость.Регистратор = Продажи.Регистратор
        КОНЕЦ)

{ГДЕ
    Продажи.Номенклатура.* КАК Номенклатура,
    Продажи.Контрагент.* КАК Контрагент,
    Продажи.МенеджерПокупателя.* КАК МенеджерПокупателя
    //СВОЙСТВА
    //КАТЕГОРИИ
    }

СГРУППИРОВАТЬ ПО
    Продажи.Номенклатура

{УПОРЯДОЧИТЬ ПО
    Продажи.Номенклатура.* КАК Номенклатура,
    Продажи.Контрагент.* КАК Контрагент,
    Продажи.МенеджерПокупателя.* КАК МенеджерПокупателя
    //СВОЙСТВА
    }

{ИТОГИ ПО
    Продажи.Номенклатура.* КАК Номенклатура,
    Продажи.Контрагент.* КАК Контрагент,
    Продажи.МенеджерПокупателя.* КАК МенеджерПокупателя,
    Продажи.Регистратор.* КАК ДокументПродажи
    //СВОЙСТВА
    }