Сохранение/восстановление настроек на форме обработки.

Процедура СохранитьНастройки()
	
	ПараметрыПредварительнойФормы = Новый Структура;
	ПараметрыПредварительнойФормы.Вставить("СвойствоТипСтруктурногоПодразделения", СвойствоТипСтруктурногоПодразделения);
	ПараметрыПредварительнойФормы.Вставить("ЗначениеТипСтруктурногоПодразделения", ЗначениеТипСтруктурногоПодразделения);
	ПараметрыПредварительнойФормы.Вставить("ЧерезКого" , ЧерезКого);
	ПараметрыПредварительнойФормы.Вставить("Затребовал", Затребовал);
	ПараметрыПредварительнойФормы.Вставить("Отпустил"  , Отпустил);
	ПараметрыПредварительнойФормы.Вставить("Получил"   , Получил);

	
	//ВладелецНастройки = Справочники.Пользователи.ПустаяСсылка();
	ВладелецНастройки = ПараметрыСеанса.ТекущийПользователь;
	
	СтруктураНастройки = Новый Структура;
	СтруктураНастройки.Вставить("Пользователь",				ВладелецНастройки);
	СтруктураНастройки.Вставить("ИмяОбъекта",				"МАГНИТ_ВнешняяПечатнаяФорма_ВнешняяПечатнаяФормаМ11");
	СтруктураНастройки.Вставить("НаименованиеНастройки",	"Основная");
	СтруктураНастройки.Вставить("СохраненнаяНастройка",		ПараметрыПредварительнойФормы);
	
	Результат = СохранитьНастройку(СтруктураНастройки);
	
КонецПроцедуры


Функция СохранитьНастройку(СтруктураНастройки) Экспорт
	
	Если ТипЗнч(СтруктураНастройки) <> Тип("Структура") Тогда
		
		Возврат Ложь;
		
	КонецЕсли;
		
	НаборЗаписей =  РегистрыСведений.СохраненныеНастройки.СоздатьНаборЗаписей();
	
	НаборЗаписей.Отбор.Пользователь.Значение = СтруктураНастройки.Пользователь;
	НаборЗаписей.Отбор.Пользователь.Использование = Истина;
	
	НаборЗаписей.Отбор.ИмяОбъекта.Значение = СтруктураНастройки.ИмяОбъекта;
	НаборЗаписей.Отбор.ИмяОбъекта.Использование = Истина;
	
	НаборЗаписей.Отбор.НаименованиеНастройки.Значение = СтруктураНастройки.НаименованиеНастройки;
	НаборЗаписей.Отбор.НаименованиеНастройки.Использование = Истина;
		
	ЗаписьНабора = НаборЗаписей.Добавить();
	
	ЗаписьНабора.Пользователь = СтруктураНастройки.Пользователь;
	ЗаписьНабора.ИмяОбъекта = СтруктураНастройки.ИмяОбъекта;
	ЗаписьНабора.НаименованиеНастройки = СтруктураНастройки.НаименованиеНастройки;
	ЗаписьНабора.СохраненнаяНастройка = Новый ХранилищеЗначения(СтруктураНастройки.СохраненнаяНастройка, Новый СжатиеДанных(9));
	
	НаборЗаписей.ОбменДанными.Получатели.АвтоЗаполнение = Ложь;
	НаборЗаписей.ОбменДанными.Получатели.Очистить();
	
	Попытка
		НаборЗаписей.Записать();
	Исключение
		ОбщегоНазначенияКлиентСервер.СообщитьПользователю(СтрШаблон("Ошибка при сохранении настройки. %1", ОписаниеОшибки()));
		Возврат Ложь;
	Конецпопытки;
	
	Возврат Истина;
	
КонецФункции 

Процедура ВосстановитьНастройки()
	
	//ВладелецНастройки = Справочники.Пользователи.ПустаяСсылка();
	
	ВладелецНастройки = ПараметрыСеанса.ТекущийПользователь;
	
	СтруктураНастройки = Новый Структура;
	СтруктураНастройки.Вставить("Пользователь", 			ВладелецНастройки);
	СтруктураНастройки.Вставить("ИмяОбъекта", 				"МАГНИТ_ВнешняяПечатнаяФорма_ВнешняяПечатнаяФормаМ11");
	СтруктураНастройки.Вставить("НаименованиеНастройки", 	"Основная");
	
	Результат = УниверсальныеМеханизмы.ПолучитьНастройку(СтруктураНастройки);
	
	Если Результат Тогда
		ПараметрыПредварительнойФормы = Неопределено;
		Если СтруктураНастройки.Свойство("СохраненнаяНастройка", ПараметрыПредварительнойФормы) Тогда
			Если ТипЗнч(ПараметрыПредварительнойФормы) = Тип("Структура") Тогда
				ПараметрыПредварительнойФормы.Свойство("СвойствоТипСтруктурногоПодразделения", СвойствоТипСтруктурногоПодразделения);
				ПараметрыПредварительнойФормы.Свойство("ЗначениеТипСтруктурногоПодразделения", ЗначениеТипСтруктурногоПодразделения);
				ПараметрыПредварительнойФормы.Свойство("ЧерезКого" , ЧерезКого);
				ПараметрыПредварительнойФормы.Свойство("Затребовал", Затребовал);
				ПараметрыПредварительнойФормы.Свойство("Отпустил"  , Отпустил);
				ПараметрыПредварительнойФормы.Свойство("Получил"   , Получил);
			КонецЕсли;
		КонецЕсли;
	КонецЕсли;
КонецПроцедуры