Вопрос по типовой БП 8.3

Question

Народ, добра всем. Вопросик откуда удобнее всего в ВПО, для типовой БП 8.3 подтянуть для выгрузки красиво полные реквизиты контрагента, в печатную форму типо договора.
Заранее всем спс.

Accepted Answer

(1) [QUOTE]в печатную форму типо договора[/QUOTE]
говнокод... т.е. не оптимальный запрос... писал очень давно, но для понимания - пойдет.
[CODE]&НаСервере
Функция ПолучитьРеквизитыДокумента(ЭтотДоговор)
	
	РеквизитыДокумента = Новый Структура("НомерДоговора, ДатаДоговора, Организация, Контрагент, 
										| РуководительДолжность, РуководительФИО, 
										| КонтрагентРуководительДолжность, КонтрагентРуководительФИО,
										| ОрганизацияИНН, КонтрагентИНН, ОрганизацияКПП, КонтрагентКПП,
										| ОрганизацияПолное, КонтрагентПолное, 
										| ОрганизацияАдрес, ОрганизацияПочтовыйАдрес,
										| КонтрагентАдрес, КонтрагентПочтовыйАдрес,
										| ОрганизацияТелефон, КонтрагентТелефон,
										| ОрганизацияНомерСчета, ОрганизацияГородБанка,
										| ОрганизацияНаименованиеБанка, ОрганизацияКоррСчет,
										| КонтрагентНомерСчета, КонтрагентГородБанка,
										| КонтрагентНаименованиеБанка, КонтрагентКоррСчет,
										| ОрганизацияБИК, КонтрагентБИК");
										
	Запрос = Новый Запрос;
	Запрос.Текст = "ВЫБРАТЬ
	               |	ДоговорыКонтрагентов.Организация.Наименование КАК Организация,
	               |	ДоговорыКонтрагентов.Владелец.Наименование КАК Контрагент,
	               |	ДоговорыКонтрагентов.Организация.НаименованиеПолное КАК ОрганизацияПолное,
	               |	ДоговорыКонтрагентов.Владелец.НаименованиеПолное КАК КонтрагентПолное,
	               |	ДоговорыКонтрагентов.Номер КАК НомерДоговора,
	               |	ДоговорыКонтрагентов.Дата КАК ДатаДоговора,
	               |	ДоговорыКонтрагентов.Организация.ИНН КАК ОрганизацияИНН,
	               |	ДоговорыКонтрагентов.Организация.КПП КАК ОрганизацияКПП,
	               |	ДоговорыКонтрагентов.Владелец.ИНН КАК КонтрагентИНН,
	               |	ДоговорыКонтрагентов.Владелец.КПП КАК КонтрагентКПП,
	               |	ДоговорыКонтрагентов.Организация.ОсновнойБанковскийСчет.НомерСчета КАК ОрганизацияНомерСчета,
	               |	ДоговорыКонтрагентов.Организация.ОсновнойБанковскийСчет.Банк.Город КАК ОрганизацияГородБанка,
	               |	ДоговорыКонтрагентов.Организация.ОсновнойБанковскийСчет.Банк.Наименование КАК ОрганизацияНаименованиеБанка,
	               |	ДоговорыКонтрагентов.Организация.ОсновнойБанковскийСчет.Банк.КоррСчет КАК ОрганизацияКоррСчет,
	               |	ДоговорыКонтрагентов.Организация.ОсновнойБанковскийСчет.Банк.Код КАК ОрганизацияБИК,
	               |	ДоговорыКонтрагентов.Владелец.ОсновнойБанковскийСчет.НомерСчета КАК КонтрагентНомерСчета,
	               |	ДоговорыКонтрагентов.Владелец.ОсновнойБанковскийСчет.Банк.Город КАК КонтрагентГородБанка,
	               |	ДоговорыКонтрагентов.Владелец.ОсновнойБанковскийСчет.Банк.Наименование КАК КонтрагентНаименованиеБанка,
	               |	ДоговорыКонтрагентов.Владелец.ОсновнойБанковскийСчет.Банк.КоррСчет КАК КонтрагентКоррСчет,
	               |	ДоговорыКонтрагентов.Владелец.ОсновнойБанковскийСчет.Банк.Код КАК КонтрагентБИК,
	               |	ДоговорыКонтрагентов.Владелец.Ссылка КАК КонтрагентСсылка,
				   |	ДоговорыКонтрагентов.РуководительКонтрагента КАК КонтрагентРуководительФИО,
	               |	ДоговорыКонтрагентов.ДолжностьРуководителяКонтрагента КАК КонтрагентРуководительДолжность,
	               |	ДоговорыКонтрагентов.Владелец.КонтактнаяИнформация.(
	               |		Вид КАК Вид,
	               |		Представление КАК Представление) КАК КонтактнаяИнформация
	               |ИЗ
	               |	Справочник.ДоговорыКонтрагентов КАК ДоговорыКонтрагентов
	               |ГДЕ
	               |	ДоговорыКонтрагентов.Ссылка = &Ссылка";
	Запрос.УстановитьПараметр("Ссылка", ЭтотДоговор);
	РезультатЗапроса = Запрос.Выполнить();
	ВыборкаЗапроса = РезультатЗапроса.Выбрать();
	ВыборкаЗапроса.Следующий();
	ЗаполнитьЗначенияСвойств(РеквизитыДокумента, ВыборкаЗапроса);
	
	ВыборкаПоКонтактам = ВыборкаЗапроса.КонтактнаяИнформация.Выбрать();
	Пока ВыборкаПоКонтактам.Следующий() Цикл
		Если Строка(ВыборкаПоКонтактам.Вид) = "Юридический адрес" Тогда
			РеквизитыДокумента.КонтрагентАдрес = ВыборкаПоКонтактам.Представление;
		КонецЕсли;
		Если Строка(ВыборкаПоКонтактам.Вид) = "Почтовый адрес" Тогда
			РеквизитыДокумента.КонтрагентПочтовыйАдрес = ВыборкаПоКонтактам.Представление;
		КонецЕсли;
		Если Строка(ВыборкаПоКонтактам.Вид) = "Телефон" Тогда
			РеквизитыДокумента.КонтрагентТелефон = ВыборкаПоКонтактам.Представление;
		КонецЕсли;
	КонецЦикла;
	
	Возврат РеквизитыДокумента;

КонецФункции[/CODE]