информационная база перемещена

// Определяет установлена ли блокировка работы с внешними ресурсами.
//
Функция УстановленаБлокировкаРаботыСВнешнимиРесурсами(ЭтоВызовПередНачаломРаботыСистемы = Ложь, ПоказатьФорму = Ложь) Экспорт
	
	УстановитьПривилегированныйРежим(Истина);
	
	Если Не ОбщегоНазначенияПовтИсп.ДоступноИспользованиеРазделенныхДанных() Тогда
		Возврат Ложь;
	КонецЕсли;
	
	СохраненныеПараметры = Константы.ПараметрыБлокировкиРаботыСВнешнимиРесурсами.Получить().Получить();
	
	Если СохраненныеПараметры = Неопределено Тогда
		Если ЭтоВызовПередНачаломРаботыСистемы Тогда
			ИнициализироватьПараметрыБлокировкиРаботыСВнешнимиРесурсами();
		КонецЕсли;
		Возврат Ложь;
	КонецЕсли;
	
	ПараметрыБлокировки = ПараметрыБлокировкиРаботыСВнешнимиРесурсами();
	ЗаполнитьЗначенияСвойств(ПараметрыБлокировки, СохраненныеПараметры);
	
	Если ПараметрыБлокировки.РаботаСВнешнимиРесурсамиЗаблокирована = Неопределено Тогда
		Возврат Истина; // Если признак уже был взведен ранее в регламентном задании.
	ИначеЕсли ПараметрыБлокировки.РаботаСВнешнимиРесурсамиЗаблокирована = Истина Тогда
		Возврат Не ПоказатьФорму; // Блокировка работы с внешними ресурсами подтверждена администратором.
	КонецЕсли;
	
	РазделениеВключено = ОбщегоНазначенияПовтИсп.РазделениеВключено();
	// При работе в модели сервиса факт переноса базы определяется менеджером сервиса.
	Если РазделениеВключено Тогда
		Возврат Ложь;
	КонецЕсли;
	
	Если РазделениеВключено <> ПараметрыБлокировки.РазделениеВключено Тогда
		// Разделение не включено.
		ТекстСообщения = НСтр("ru = 'Информационная база была перемещена из приложения в Интернете.'");
		УстановитьПризнакНеобходимостиПринятияРешенияОБлокировке(ПараметрыБлокировки, ТекстСообщения);
		Возврат Истина;
	КонецЕсли;
	
	СтрокаСоединения = СтрокаСоединенияИнформационнойБазы();
	ЭтоФайловаяБаза = ОбщегоНазначения.ИнформационнаяБазаФайловая(СтрокаСоединения);
	
	Если ЭтоФайловаяБаза <> ПараметрыБлокировки.ЭтоФайловаяБаза Тогда
		ТекстСообщения = ?(ЭтоФайловаяБаза, НСтр("ru = 'Информационная база была перемещена из клиент-серверного режима работы в файловый.'"),
			НСтр("ru = 'Информационная база была перемещена из файловый режима работы в клиент-серверный.'"));
		УстановитьПризнакНеобходимостиПринятияРешенияОБлокировке(ПараметрыБлокировки, ТекстСообщения);
		Возврат Истина;
	КонецЕсли;
	
	// Если строка соединения совпадает, то дальнейшую проверку не выполняем.
	Если СтрокаСоединения = ПараметрыБлокировки.СтрокаСоединения Тогда
		Возврат Ложь;
	КонецЕсли;
	
	Если ЭтоФайловаяБаза Тогда
		// Для файловой базы через строка соединения может быть разной при подключении с различных
		// компьютеров, поэтому проверку перемещения базы осуществляем через файл.
		ИмяФайлаПроверки = "DoNotCopy.txt";
		НайденныеФайлы = НайтиФайлы(ОбщегоНазначенияКлиентСервер.КаталогФайловойИнформационнойБазы(), "DoNotCopy.txt");
		Если НайденныеФайлы.Количество() = 0 Тогда
			// В каталоге базы отсутствует файл проверки.
			ТекстСообщения = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
				НСтр("ru = 'В каталоге информационной базы отсутствует файл проверки %1.'"), ИмяФайлаПроверки);
			УстановитьПризнакНеобходимостиПринятияРешенияОБлокировке(ПараметрыБлокировки, ТекстСообщения);
			Возврат Истина;
		КонецЕсли;
		ЧтениеТекста = Новый ЧтениеТекста(НайденныеФайлы[0].ПолноеИмя);
		ИдентификаторБазы =ЧтениеТекста.ПрочитатьСтроку();
		// Файл присутствует, но идентификатор внутри не соответствует ожидаемому.
		Если ИдентификаторБазы <> ПараметрыБлокировки.ИдентификаторБазы Тогда
			ТекстСообщения = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
				НСтр("ru = 'Идентификатор информационной базы в файле проверки %1 не соответствует идентификатору в текущей базе.'"), ИмяФайлаПроверки);
			УстановитьПризнакНеобходимостиПринятияРешенияОБлокировке(ПараметрыБлокировки, ТекстСообщения);
			Возврат Истина;
		КонецЕсли;
	Иначе // Клиент-серверная база
		ИмяБазы = НРег(СтроковыеФункцииКлиентСервер.ПолучитьПараметрыИзСтроки(СтрокаСоединения).Ref);
		ИмяКомпьютера = НРег(ИмяКомпьютера());
		ИмяСервера = НРег(СтроковыеФункцииКлиентСервер.ПолучитьПараметрыИзСтроки(СтрокаСоединения).Srvr);
		СохраненноеИмяБазы = НРег(СтроковыеФункцииКлиентСервер.ПолучитьПараметрыИзСтроки(ПараметрыБлокировки.СтрокаСоединения).Ref);
		СохраненноеИмяКомпьютера = НРег(ПараметрыБлокировки.ИмяКомпьютера);
		СохраненноеИмяСервера = НРег(СтроковыеФункцииКлиентСервер.ПолучитьПараметрыИзСтроки(ПараметрыБлокировки.СтрокаСоединения).Srvr);
		
		Если ИмяБазы <> СохраненноеИмяБазы
			Или (ПараметрыБлокировки.ПроверятьИмяСервера
			И (ИмяКомпьютера <> СохраненноеИмяКомпьютера
			И ИмяСервера <> СохраненноеИмяСервера)) Тогда
			ТекстСообщения = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
				НСтр("ru = 'Различаются имя информационной базы или имя компьютера.
					|Сохраненное имя базы: %1, текущее имя базы: %2.
					|Сохраненное имя компьютера: %3, текущее имя компьютера: %4'"),
				СохраненноеИмяБазы, ИмяБазы, СохраненноеИмяКомпьютера, ИмяКомпьютера);
			УстановитьПризнакНеобходимостиПринятияРешенияОБлокировке(ПараметрыБлокировки, ТекстСообщения);
			Возврат Истина;
		КонецЕсли;
	КонецЕсли;
	
	Возврат Ложь;
	
КонецФункции

	Если ИмяБазы <> СохраненноеИмяБазы
			Или (ПараметрыБлокировки.ПроверятьИмяСервера
			И (ИмяКомпьютера <> СохраненноеИмяКомпьютера
			И ИмяСервера <> СохраненноеИмяСервера)) Тогда