Как в 8.3 определить и удалить спящие сеансы?

&НаКлиенте
Процедура УдалитьСпящиеСеансыЭтойБазы(Команда)
	УдалитьСпящиеСеансыЭтойБазыНаСервере();
КонецПроцедуры

&НаСервере
Процедура УдалитьСпящиеСеансыЭтойБазыНаСервере()
	СтрокаСоединения = СтрокаСоединенияИнформационнойБазы();
	Если Лев(СтрокаСоединения, 5) <> "Srvr=" Тогда
		Сообщить("Это не клиент-серверное соединение");
		Возврат
	КонецЕсли;
	
	ИмяСервера = Сред(СтрокаСоединения, 7);
	ИмяСервера = Лев(ИмяСервера, Найти(ИмяСервера, """") - 1);
	ПортСервера = 1540;
	ПортКластера = 1541;
	
	ПозицияДвоеточия = Найти(ИмяСервера, ":");	
	Если ПозицияДвоеточия > 0 Тогда		
		ПортКластера = Число(Сред(ИмяСервера, ПозицияДвоеточия + 1));
		ПортСервера = ПортКластера - 1;
		
		ИмяСервера = Лев(ИмяСервера, ПозицияДвоеточия - 1);
	КонецЕсли;
	
	СерверИПорт = ИмяСервера + ":" + Формат(ПортСервера, "ЧГ=");
	
	ИмяБазы = Сред(СтрокаСоединения, Найти(СтрокаСоединения, "Ref=") + 5);
	ИмяБазы = Лев(ИмяБазы, Найти(ИмяБазы, """") - 1);
	
	
	Соединитель = Новый COMОбъект("V83.COMConnector");
	СоединениеСАгентом = Соединитель.ConnectAgent(СерверИПорт);
	 
	// найдём наш кластер
	НашКластер = Неопределено;	
	Для Каждого Кластер Из СоединениеСАгентом.GetClusters() Цикл
		Если Кластер.MainPort = ПортКластера Тогда
			НашКластер = Кластер;
			Прервать
		КонецЕсли;
	КонецЦикла;
	
	Если НашКластер = Неопределено Тогда
		Сообщить("Кластер не найден");
		Возврат
	КонецЕсли;	
	
	// аутентификация в нашем кластере
	ИмяАдминистратораКластера = "";
	ПарольАдминистратораКластера = "";
	СоединениеСАгентом.Authenticate(НашКластер, ИмяАдминистратораКластера, ПарольАдминистратораКластера);
	
	// найдём нашу базу
	НашаБаза = Неопределено;
	Базы = СоединениеСАгентом.GetInfoBases(НашКластер);
	Для Каждого База Из Базы Цикл		
		Если НРег(База.Name) = НРег(ИмяБазы) Тогда			
			НашаБаза = База;
			Прервать
		КонецЕсли;		
	КонецЦикла;
	
	Если НашаБаза = Неопределено Тогда
		Сообщить("База не найдена");
		Возврат
	КонецЕсли;
	
	СеансыНашейБазы = СоединениеСАгентом.GetInfoBaseSessions(НашКластер, НашаБаза);
	Для Каждого Сеанс Из СеансыНашейБазы Цикл
		Если Сеанс.Hibernate Тогда
			СоединениеСАгентом.TerminateSession(НашКластер, Сеанс);
			Сообщить(Сеанс.SessionID);
		КонецЕсли;
	КонецЦикла;
КонецПроцедуры