Не получается взять выбранное значение из формы выбора

Question

Здравствуйте! Подскажите, пожалуйста, в таком вопросе. Есть в отчете поле с типом "контрагент", но при начале выбора должна открываться форма выбора справочника "партнеры", а потом уже форма выбора справочника "контрагенты" с отбором по выбранному партнеру . 
[1C-CODE]&НаКлиенте
Процедура КонтрагентНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)
	СтандартнаяОбработка = Ложь;
	ОткрытьФорму("Справочник.Партнеры.ФормаВыбора", , Элемент);
КонецПроцедуры

&НаКлиенте
Процедура КонтрагентОбработкаВыбора(Элемент, ВыбранноеЗначение, СтандартнаяОбработка)
	СтандартнаяОбработка = Ложь;
	Форма = ОткрытьФорму("Справочник.Контрагенты.ФормаВыбора",,ЭтаФорма.УникальныйИдентификатор,); 
	Отбор = Форма.Список.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных")); 
	Отбор.ВидСравнения = ВидСравненияКомпоновкиДанных.Равно;  
	Отбор.Использование = Истина; 
	Отбор.ЛевоеЗначение = Форма.Список.Отбор.ДоступныеПоляОтбора.Элементы.Найти("Партнер").Поле; 
	Отбор.ПравоеЗначение = ВыбранноеЗначение; 
	
КонецПроцедуры

[/1C-CODE]
а как мне теперь обратиться к значению, которое выбрал пользователь из справочника "контрагенты"?

Accepted Answer

[CODE]
&НаКлиенте
Процедура КонтрагентНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)
	
	СтандартнаяОбработка = Ложь;
	
	ОП = Новый ОписаниеОповещения("ПослеВыбораПартнераПродолжение",ЭтаФорма);
    ОткрытьФорму("Справочник.Партнеры.ФормаВыбора", , ЭтаФорма,,,,ОП);	
КонецПроцедуры

&НаКлиенте
Процедура ПослеВыбораПартнераПродолжение(Партнер, ДопПараметры) Экспорт
	
	Если Партнер = Неопределено Тогда
		Возврат;
	КонецЕсли;
	
	// Теперь выберем контрагента
	ПараметрыОткрытия = Новый Структура("Отбор",Новый Структура("Партнер",Партнер));	
	ОП = Новый ОписаниеОповещения("ПослеВыбораКонтрагента",ЭтаФорма, Партнер);
    ОткрытьФорму("Справочник.Контрагенты.ФормаВыбора",ПараметрыОткрытия, ЭтаФорма,,,,ОП);
	
КонецПроцедуры

&НаКлиенте
Процедура ПослеВыбораКонтрагента(Контрагент,Партнер) Экспорт
	
	Если Контрагент = Неопределено Тогда
		Возврат;
	КонецЕсли;
	
	/// Ваши действия с Контрагентом	
	
КонецПроцедуры
[/CODE]