Пропала кнопка печать после обновления Бух 3.0 (3.0.52.32) в своих документах

Форум Программирование Общие вопросы программирования (Dev)
Конфигурации 1cv8 1С:Бухгалтерия 3.0
1. lenna1c 89 12.09.17 19:16 Сейчас в теме
Добрый день!
Кто нибудь столкнулся уже с штатной кнопкой Печать в своих документах?
У меня во всех моих документах она пропала.

пытаюсь сделать все как в типовых документах - все повторяю - но что то никак
явно где то что то упускаю а вот что не пойму ???

фактически в типовой - все стандартные типовые подключения выделены коментарием
// СтандартныеПодсистемы.ПодключаемыеКоманды

============================================================­======

в форме документа добавила: 
======================================
&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	// СтандартныеПодсистемы.ПодключаемыеКоманды
	ПодключаемыеКоманды.ПриСозданииНаСервере(ЭтотОбъект);
	// Конец СтандартныеПодсистемы.ПодключаемыеКоманды
	
	
	// СтандартныеПодсистемы.ВерсионированиеОбъектов
	ВерсионированиеОбъектов.ПриСозданииНаСервере(ЭтотОбъект);
	// Конец СтандартныеПодсистемы.ВерсионированиеОбъектов
КонецПроцедуры


&НаСервере
Процедура ПриЧтенииНаСервере(ТекущийОбъект)
	
	// СтандартныеПодсистемы.ДатыЗапретаИзменения
	ДатыЗапретаИзменения.ОбъектПриЧтенииНаСервере(ЭтотОбъект, ТекущийОбъект);
	// Конец СтандартныеПодсистемы.ДатыЗапретаИзменения
	
	
	// СтандартныеПодсистемы.ПодключаемыеКоманды
	ПодключаемыеКомандыКлиентСервер.ОбновитьКоманды(ЭтотОбъект, Объект);
	// Конец СтандартныеПодсистемы.ПодключаемыеКоманды
КонецПроцедуры



// СтандартныеПодсистемы.ПодключаемыеКоманды
&НаКлиенте
Процедура Подключаемый_ВыполнитьКоманду(Команда)
	ПодключаемыеКомандыКлиент.ВыполнитьКоманду(ЭтотОбъект, Команда, Объект);
КонецПроцедуры

&НаСервере
Процедура Подключаемый_ВыполнитьКомандуНаСервере(Контекст, Результат)
	ПодключаемыеКоманды.ВыполнитьКоманду(ЭтотОбъект, Контекст, Объект, Результат);
КонецПроцедуры

&НаКлиенте
Процедура Подключаемый_ОбновитьКоманды()
	ПодключаемыеКомандыКлиентСервер.ОбновитьКоманды(ЭтотОбъект, Объект);
КонецПроцедуры
// Конец СтандартныеПодсистемы.ПодключаемыеКоманды

&НаКлиенте
Процедура ПриОткрытии(Отказ)
	// СтандартныеПодсистемы.ПодключаемыеКоманды
	ПодключаемыеКомандыКлиент.НачатьОбновлениеКоманд(ЭтотОбъект);
	// Конец СтандартныеПодсистемы.ПодключаемыеКоманды
	
КонецПроцедуры

============================================================­====
Показать

группу кнопок "ГруппаКнопкиКоманднойПанели" - скопировала из типового документа

че не хватает не пойму ?

да модуль менеджера тупо скопировала из типового - всеравно не появляется кнопка печать

Помогите кто сталкивался
Suslik_Johns; katbuhalter; +2 – Ответить
Ответы
Подписаться на ответы Инфостарт бот Сортировка: Древо развёрнутое
Свернуть все
2. Prikum 3 12.09.17 21:25 Сейчас в теме
В типовых сняли режим совместимости, наверное проблема порылась там.
+ – Ответить
3. lenna1c 89 12.09.17 21:34 Сейчас в теме
я еще сделала так
скопировала типовой документ АвансовыйОтчет - получился документ "АвансовыйОтчет3"
и внем так же пропала кнопка печать

следовательно что то в самом механизме БСП - не отрабатывает или нужно как то прописывать вручную

пока ищу - если кто решил помогите
+ – Ответить
4. lenna1c 89 12.09.17 21:35 Сейчас в теме
да для полной уверенности запускала 1с предприятие с параметром "ЗапуститьОбновлениеИнформационнойБазы"

таже хрень
+ – Ответить
5. lenna1c 89 12.09.17 23:57 Сейчас в теме
всем спасибо я разобралась
+ – Ответить
6. elmak 13.09.17 16:40 Сейчас в теме
(5)Будьте добры, расскажите в чем там дело было. С этой же проблемой столкнулась.
+ – Ответить
7. lenna1c 89 13.09.17 16:46 Сейчас в теме
в процедуре 

УправлениеПечатьюПереопределяемый.ПриОпределенииОбъектовСКомандамиПечати

добавь свои объекты и будет счастье: 
СписокОбъектов.Добавить(Документы._аНовыйДокумент);


так же не забудь в форме новые вставить стандартные процедуры 

форма документа:
=======================================================
#Область  КомандыФормы

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	// СтандартныеПодсистемы.ПодключаемыеКоманды
	ПодключаемыеКоманды.ПриСозданииНаСервере(ЭтотОбъект);
	// Конец СтандартныеПодсистемы.ПодключаемыеКоманды
	
КонецПроцедуры


// СтандартныеПодсистемы.ПодключаемыеКоманды
&НаКлиенте
Процедура Подключаемый_ВыполнитьКоманду(Команда)
	ПодключаемыеКомандыКлиент.ВыполнитьКоманду(ЭтотОбъект, Команда, Объект);
КонецПроцедуры

&НаСервере
Процедура Подключаемый_ВыполнитьКомандуНаСервере(Контекст, Результат)
	ПодключаемыеКоманды.ВыполнитьКоманду(ЭтотОбъект, Контекст, Объект, Результат);
КонецПроцедуры

&НаКлиенте
Процедура Подключаемый_ОбновитьКоманды()
	ПодключаемыеКомандыКлиентСервер.ОбновитьКоманды(ЭтотОбъект, Объект);
КонецПроцедуры
// Конец СтандартныеПодсистемы.ПодключаемыеКоманды


#КонецОбласти 
==========================================================

форма списка
=======================================================

#Область КомандыФормы

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	// СтандартныеПодсистемы.ПодключаемыеКоманды
	ПодключаемыеКоманды.ПриСозданииНаСервере(ЭтотОбъект);
	// Конец СтандартныеПодсистемы.ПодключаемыеКоманды
КонецПроцедуры

// СтандартныеПодсистемы.ПодключаемыеКоманды
&НаКлиенте
Процедура Подключаемый_ВыполнитьКоманду(Команда)
	ПодключаемыеКомандыКлиент.ВыполнитьКоманду(ЭтотОбъект, Команда, Элементы.Список);
КонецПроцедуры

&НаСервере
Процедура Подключаемый_ВыполнитьКомандуНаСервере(Контекст, Результат)
	ПодключаемыеКоманды.ВыполнитьКоманду(ЭтотОбъект, Контекст, Элементы.Список, Результат);
КонецПроцедуры

&НаКлиенте
Процедура Подключаемый_ОбновитьКоманды()
	ПодключаемыеКомандыКлиентСервер.ОбновитьКоманды(ЭтотОбъект, Элементы.Список);
КонецПроцедуры
// Конец СтандартныеПодсистемы.ПодключаемыеКоманды



#КонецОбласти 

======================================================
Показать


ну вот и все
solary; Suslik_Johns; 1Cynep4eJIoBek; config; bds22; r24al; Rainar; SkyOl; smooth; katbuhalter; Comandante; anton1122; INSANE78; klinval; Kozlopuper; katilek; Alister; +17 – Ответить
8. elmak 13.09.17 16:56 Сейчас в теме
(7)Спасибо большое! Получилось!
+ – Ответить
25. UtSpar 134 27.12.17 06:14 Сейчас в теме
(7) Спасибо. СписокОбъектов.Добавить(Документы._аНовыйДокумент); лучше добавлять в расширении!
Program; +1 – Ответить
9. MGreg 32 24.09.17 18:37 Сейчас в теме
Спасибо я потратил пол дня. Надо было погуглить.
+ – Ответить
10. u-barbaris 27.09.17 23:13 Сейчас в теме
Спасибо большое, думал мистика какая то)
+ – Ответить
11. catlina 01.10.17 03:38 Сейчас в теме
Сделала все по аналогии. У меня кнопка появилась, но вот Печать не работает, что еще я делаю не так?
+ – Ответить
13. aldan 22 05.10.17 13:29 Сейчас в теме
(11) Если добавить свой документ в процедуре УправлениеПечатьюПереопределяемый.ПриОпределенииОбъектовСКомандамиПечати, то кнопка печать появится. Но она станет работать только после замены процедуры Подключаемый_ВыполнитьКомандуПечати(Команда) на
Подключаемый_ВыполнитьКоманду(Команда)
Подключаемый_ВыполнитьКомандуНаСервере(Контекст, Результат)
Подключаемый_ОбновитьКоманды()
в форме документа и/или списка
Nastya-chajkovskaya; config; syergio; grig_nv; Comandante; anton1122; +6 – Ответить
26. grig_nv 7 18.01.18 19:58 Сейчас в теме
(13) Спасибо, просто огромное спасибище. День на этом дибилизме потерял. А где это описывалось или вы сами докапывались?
+ – Ответить
12. Smal 03.10.17 13:42 Сейчас в теме
Можно для особо одаренных еще раз. У меня слетели все печатные формы для самодельных документов
+ – Ответить
14. aldan 22 05.10.17 13:33 Сейчас в теме
(12) Нужно добавить свой документ в общий модуль УправлениеПечатьюПереопределяемый в процедуру ПриОпределенииОбъектовСКомандамиПечати, а в форме документа или списка заменить процедуру Подключаемый_ВыполнитьКомандуПечати на три процедуры Подключаемый_ВыполнитьКоманду, Подключаемый_ВыполнитьКомандуНаСервере, Подключаемый_ОбновитьКоманды
syergio; Umnica; anton1122; +3 – Ответить
15. yamawa 50 09.10.17 17:47 Сейчас в теме
(14) добавили документ в модуль УправлениеПечатьюПереопределяемый но кнопка печать не появилась
+ – Ответить
20. Дайра 17.10.17 00:23 Сейчас в теме
(14) спасибо огромное, помогло!!
+ – Ответить
16. yamawa 50 09.10.17 18:41 Сейчас в теме
большое спасибо!!!
+ – Ответить
17. Smal 13.10.17 10:12 Сейчас в теме
спасибо. сделал
+ – Ответить
18. Vitvarg51 13.10.17 12:54 Сейчас в теме
Произвела все изменения, как описано выше, но кнопка так и не появилась.
+ – Ответить
19. YanTsys 12 13.10.17 21:45 Сейчас в теме
Для того чтобы появилась кнопка печать добавил в расширение МойДокумент и модуль УправлениеПечатьюПереопределяемый
и уже в расширении перехватываю ПриОпределенииОбъектовСКомандамиПечати и добавляю свой документ, так не будет слетать при обновлении 

#Область ПрограммныйИнтерфейс

&Перед("ПриОпределенииОбъектовСКомандамиПечати")
Процедура Расш1_ПриОпределенииОбъектовСКомандамиПечати(СписокОбъектов) Экспорт
	
	СписокОбъектов.Добавить(Документы.МойДокумент);
	
КонецПроцедуры

#КонецОбласти
Показать


Закоментировал 
// СтандартныеПодсистемы.Печать
//&НаКлиенте
//Процедура Подключаемый_ВыполнитьКомандуПечати(Команда)
//	
//	УправлениеПечатьюКлиент.ВыполнитьПодключаемуюКомандуПечати(Команда, ЭтаФорма, Объект);
//	
//КонецПроцедуры
// Конец СтандартныеПодсистемы.Печать
Показать


вместо этого добавил 
// СтандартныеПодсистемы.ПодключаемыеКоманды
&НаКлиенте
Процедура Подключаемый_ВыполнитьКоманду(Команда)
	
	ПодключаемыеКомандыКлиент.ВыполнитьКоманду(ЭтотОбъект, Команда, Объект);
	
КонецПроцедуры

&НаКлиенте
Процедура Подключаемый_ОбновитьКоманды()
	
	ПодключаемыеКомандыКлиентСервер.ОбновитьКоманды(ЭтотОбъект, Объект);
	
КонецПроцедуры
 //Конец СтандартныеПодсистемы.ПодключаемыеКоманды
Показать


Вроде всё работает
Подскажите зачем предлагается еще добавлять 
//&НаСервере
Процедура Подключаемый_ВыполнитьКомандуНаСервере(Контекст, Результат)
	ПодключаемыеКоманды.ВыполнитьКоманду(ЭтотОбъект, Контекст, Объект, Результат);
КонецПроцедуры

в какой момент она пригодится?

И вопрос по поводу расширения, возникли обоснованные сомнения, подскажите в текущей версии можно общий модуль добавлять так как я добавил или могут быть проблемы?
grig_nv; +1 – Ответить
21. Дайра 14.11.17 11:10 Сейчас в теме
исправляла старые документы - все заработало.

создаю новый документ, добавляю его в модуль УправлениеПечатьюПереопределяемый Но кнопка печати не появляется
+ – Ответить
22. Дайра 14.11.17 11:29 Сейчас в теме
(21)сама спросила - сама нашла

в форме документа надо привязать её к обработчику "ПриСозданииНаСервере". все сразу появилось
vikochkagridina; user777757; +2 – Ответить
27. user777757 25.04.18 09:20 Сейчас в теме
(22) Татьяна, спасибо огромное за ваш комментарий! У меня в модуле формы списка уже была процедура "ПриСозданииНаСервере" и другие необходимые для печати, но к самой форме ее забыл привязать разработчик. Кнопка "Печать" не выводилась в командую панель, хотя все вроде бы было прописано и в форме документа Печать была. Благодаря вашему комментарию посмотрел на свойства формы и увидел ошибку) Спасибо еще раз!
vikochkagridina; +1 – Ответить
23. and_r 29.11.17 15:50 Сейчас в теме
С каждым обновлением новые сложности... Спасибо, мне помогло!
+ – Ответить
24. svegl 16 26.12.17 19:47 Сейчас в теме
Большое спасибо! Все получилось.
+ – Ответить
28. Suslik_Johns 30.12.19 11:38 Сейчас в теме
Пишу спустя 2 года)
У меня кнопка печати в форме документа есть и работает.
В форме списка есть, но не активна.
Кто знает, в чем может быть дело?
+ – Ответить
29. Suslik_Johns 30.12.19 12:27 Сейчас в теме
(28) Кнопка стала активна после добавления:
в модуле менеджера:
Процедура ДобавитьКомандыПечати(КомандыПечати)
строчки:
КомандаПечати.СписокФорм = "ФормаСписка,ФормаДокумента";

Но все же при нажатии не работает.
Вылезает ошибка:
"Команда не может быть выполнена для указанного объекта".
Разбираемся дальше.
+ – Ответить
30. Suslik_Johns 30.12.19 13:22 Сейчас в теме
(29) Если кроме меня это еще кто-то прочитает, то решение неактивности кнопки Печать оказалось простым:
В форме списка документа добавила еще одно поле - поле Ссылка. После этого печать заработала (вдруг кому еще пригодится)!
Вот здесь это прочитала:
http://forum.infostart.ru/forum8/topic178004/message1903429/#message1903429
+ – Ответить
Оставьте свое сообщение

Для получения уведомлений об ответах подключите телеграм бот:
Инфостарт бот