Изменить имя документа при сохранении

Функция СведенияОВнешнейОбработке() Экспорт
	
	//Заменяем всё что ЗАГЛАВНЫМИ БУКВАМИ
	
	//массив назначений: 	 Указываем только объект для которого предназначена печ.форма
	МассивНазначений = Новый Массив;
	МассивНазначений.Добавить("Документ.уатДоверенность"); //Документ к которому делаем внешнюю печ. форму
	
	//команды:          	 Не меняем!
	ТаблицаКоманд = Новый ТаблицаЗначений;
	ТаблицаКоманд.Колонки.Добавить("Представление"	 , Новый ОписаниеТипов("Строка")); //Как будет выглядеть описание печ.формы для пользователя
	ТаблицаКоманд.Колонки.Добавить("Идентификатор"	 , Новый ОписаниеТипов("Строка")); //Имя нашего макета печатной формы
	ТаблицаКоманд.Колонки.Добавить("Использование"	 , Новый ОписаниеТипов("Строка")); //здесь можно прописать использование как серверного так и клиентского, отличие в том, что серверный метод будет обращаться к экспортной процедуре из модуля объекта, клиентский - к экспортной процедуре из модуля формы объекта
	ТаблицаКоманд.Колонки.Добавить("ПоказыватьОповещение", Новый ОписаниеТипов("Булево")); //Истина
	ТаблицаКоманд.Колонки.Добавить("Модификатор"	 , Новый ОписаниеТипов("Строка")); //ПечатьМХL
	
	//новая команда:		 Заполняем необходимыми данными
	НоваяКоманда = ТаблицаКоманд.Добавить();
	НоваяКоманда.Представление	  = "Доверенность (М-2)(Печать и подпись)"; 			   //Синоним 
	НоваяКоманда.Идентификатор 	  = "ПараметрыПечати_Доверенность_Доверенность"; 				   //Наименование макета печатной формы
	НоваяКоманда.Использование 	  = "ВызовСерверногоМетода";				   //варианты: "ВызовКлиентскогоМетода или ВызовСерверногоМетода" 
	НоваяКоманда.ПоказыватьОповещение =  Истина;                                   //Без изменения
	НоваяКоманда.Модификатор		  = "ПечатьMXL";                               //Без изменения
	
	//параметры регистрации: Заполняем необходимыми данными
	ПараметрыРегистрации = Новый Структура;
	ПараметрыРегистрации.Вставить("Вид"	     , "ПечатнаяФорма"); 				//Варианты: "ПечатнаяФорма, ЗаполнениеОбъекта, ДополнительныйОтчет, СозданиеСвязанныхОбъектов"
	ПараметрыРегистрации.Вставить("Назначение"	     ,  МассивНазначений);
	ПараметрыРегистрации.Вставить("Наименование"   , "ПараметрыПечати_Доверенность_Доверенность");//Имя под которым обработка будет зарегестрирована в справочнике внешних обработок
	ПараметрыРегистрации.Вставить("Версия"		   , "1.0");                        //Номер версии
	ПараметрыРегистрации.Вставить("БезопасныйРежим",  ЛОЖЬ);
	ПараметрыРегистрации.Вставить("Информация"      , "Доверенность (М-2)(Печать и подпись)"); //Заполняем необходимой информаией(Полное Название и Назначение Печатной формы)
	ПараметрыРегистрации.Вставить("Команды"    	    ,  ТаблицаКоманд);
	
	Возврат ПараметрыРегистрации;
	
КонецФункции


Процедура Печать(МассивОбъектов, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода) Экспорт
	
	ПараметрыВывода.ДоступнаПечатьПоКомплектно = Истина;
	
	Если УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "ПараметрыПечати_Доверенность_Доверенность") Тогда
		УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, "ПараметрыПечати_Доверенность_Доверенность", "Доверенность (М-2)", ПечатнаяФорма(МассивОбъектов, ОбъектыПечати, "М2"));
		
		//////////ИначеЕсли УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "М2а") Тогда
		//////////	УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, "М2а", "Доверенность (М-2а)", ПечатнаяФорма(МассивОбъектов, ОбъектыПечати, "М2а"));
		
	КонецЕсли;
	
	//////////уатОбщегоНазначенияСервер.УстановитьРедактированиеПечатныхФормДокумента(КоллекцияПечатныхФорм);
	
	
	
КонецПроцедуры

Функция ПечатнаяФорма(МассивОбъектов, ОбъектыПечати, НазваниеМакета)
	
	ТабличныйДокумент = Новый ТабличныйДокумент;
	ТабличныйДокумент.КлючПараметровПечати = "ПараметрыПечати_Доверенность";
	
	ПервыйДокумент = Истина;
	
	Для Каждого ТекущийДокумент Из МассивОбъектов Цикл
		
		Если Не ПервыйДокумент Тогда
			ТабличныйДокумент.ВывестиГоризонтальныйРазделительСтраниц();
		КонецЕсли;
		ПервыйДокумент = Ложь;
		
		НомерСтрокиНачало = ТабличныйДокумент.ВысотаТаблицы + 1;
		
		Запрос = Новый Запрос();
		Запрос.УстановитьПараметр("ТекущийДокумент", ТекущийДокумент.Ссылка);
		Запрос.Текст = 
		"ВЫБРАТЬ
		|	Доверенность.Номер КАК НомерДокумента,
		|	Доверенность.Дата КАК ДатаДокумента,
		|	Доверенность.Организация КАК Руководители,
		|	Доверенность.Организация,
		|	Доверенность.Сотрудник,
		|	Доверенность.Сотрудник.Наименование КАК ФамилияИмяОтчествоДоверенного,
		|	Доверенность.БанковскийСчетОрганизации КАК БанковскийСчет,
		|	Доверенность.Контрагент КАК Поставщик,
		|	Доверенность.НаПолучениеОт КАК ПоставщикПредставление,
		|	Доверенность.ДатаДействия КАК СрокДействия,
		|	Доверенность.ПоДокументу КАК РеквизитыДокументаНаПолучение,
		|	Доверенность.Товары.(
		|		НомерСтроки КАК Номер,
		|		НаименованиеТовара КАК Ценности,
		|		НаименованиеТовара КАК ЦенностиПредставление,
		|		ЕдиницаПоКлассификатору КАК ЕдиницаИзмерения,
		|		ЕдиницаПоКлассификатору.Представление КАК ЕдиницаИзмеренияПредставление,
		|		Количество
		|	)
		|ИЗ
		|	Документ.уатДоверенность КАК Доверенность
		|ГДЕ
		|	Доверенность.Ссылка = &ТекущийДокумент";
		Шапка = Запрос.Выполнить().Выбрать();
		Шапка.Следующий();
		ВыборкаСтрокТовары = Шапка.Товары.Выбрать();
		
		ТабличныйДокумент.ИмяПараметровПечати = "ПараметрыПечати_Доверенность_Доверенность";
		//Макет = УправлениеПечатью.МакетПечатнойФормы("ОбщийМакет.ПФ_MXL_М2");
		Макет = ПолучитьМакет("ПФ_MXL_М3");
		
		ДанныеОФизЛице = уатОбщегоНазначенияТиповыеСервер.ДанныеФизЛица(ТекущийДокумент.Организация, ТекущийДокумент.Сотрудник.ФизическоеЛицо, ТекущийДокумент.Дата);
		
		ФамилияИмяОтчествоДоверенного = СокрЛП(ДанныеОФизЛице.Фамилия) + " " + СокрЛП(ДанныеОФизЛице.Имя) + " " + СокрЛП(ДанныеОФизЛице.Отчество);
		Должность                     = СокрЛП(ДанныеОФизЛице.Должность);
		
		Если НазваниеМакета = "М2" тогда
			ОбластьМакета = Макет.ПолучитьОбласть("Отрез");
			ОбластьМакета.Параметры.Заполнить(Шапка);
			ОбластьМакета.Параметры.НомерДокумента = уатОбщегоНазначенияТиповые.уатПолучитьНомерНаПечать(ТекущийДокумент);
			ОбластьМакета.Параметры.ФИОДоверенного = "" + ?(ПустаяСтрока(Должность), "", Должность + ", " + Символы.ПС) + (ФамилияИмяОтчествоДоверенного);
			ТабличныйДокумент.Вывести(ОбластьМакета);
			НазваниеФормы = "Типовая межотраслевая форма № М-2";
		Иначе
			НазваниеФормы = "Типовая межотраслевая форма № М-2а";
		КонецЕсли;
		
		Руководители = уатОбщегоНазначенияТиповые.уатОтветственныеЛицаОрганизаций(ТекущийДокумент.Организация, ТекущийДокумент.Дата);
		Руководитель = Руководители.Руководитель;
		Бухгалтер    = Руководители.ГлавныйБухгалтер;
		
		СведенияОбОрганизации = уатОбщегоНазначенияСервер.СведенияОЮрФизЛице(Шапка.Организация, Шапка.ДатаДокумента,, Шапка.БанковскийСчет);
		
		ОбластьМакета = Макет.ПолучитьОбласть("Шапка");
		ОбластьМакета.Параметры.Заполнить(Шапка);
		ОбластьМакета.Параметры.НомерДокумента               = уатОбщегоНазначенияТиповые.уатПолучитьНомерНаПечать(ТекущийДокумент);
		ОбластьМакета.Параметры.НазваниеФормы                = НазваниеФормы;
		ОбластьМакета.Параметры.ОрганизацияПредставление     = уатОбщегоНазначенияТиповыеСервер.ОписаниеОрганизации(СведенияОбОрганизации, "ПолноеНаименование,ИНН,КПП,ЮридическийАдрес,Телефоны,");
		ОбластьМакета.Параметры.РеквизитыСчета               = уатОбщегоНазначенияТиповыеСервер.ОписаниеОрганизации(СведенияОбОрганизации, "НомерСчета,Банк,БИК,КоррСчет,");
		ОбластьМакета.Параметры.РеквизитыПотребителя         = уатОбщегоНазначенияТиповыеСервер.ОписаниеОрганизации(СведенияОбОрганизации, "ПолноеНаименование,ИНН,КПП,ЮридическийАдрес,Телефоны,");
		Попытка //попытка сделана для корректной работе в УПП, т.к. там обе области называются РеквизитыПотребителя
			ОбластьМакета.Параметры.РеквизитыПлательщика      = уатОбщегоНазначенияТиповыеСервер.ОписаниеОрганизации(СведенияОбОрганизации, "ПолноеНаименование,ИНН,КПП,ЮридическийАдрес,Телефоны,");
		Исключение
		КонецПопытки;
		ОбластьМакета.Параметры.ОрганизацияКодПоОКПО          = СведенияОбОрганизации.КодПоОКПО;
		ОбластьМакета.Параметры.ПаспортСерия                  = ДанныеОФизЛице.ДокументСерия;
		ОбластьМакета.Параметры.ПаспортНомер                  = ДанныеОФизЛице.ДокументНомер;
		ОбластьМакета.Параметры.ПаспортВыдан                  = ДанныеОФизЛице.ДокументКемВыдан;
		ОбластьМакета.Параметры.ПаспортДатаВыдачи             = ДанныеОФизЛице.ДокументДатаВыдачи;
		ОбластьМакета.Параметры.ФамилияИмяОтчествоДоверенного = ФамилияИмяОтчествоДоверенного;
		ОбластьМакета.Параметры.ДолжностьДоверенного          = Должность;
		ТабличныйДокумент.Вывести(ОбластьМакета);
		
		ОбластьМакета = Макет.ПолучитьОбласть("ЗаголовокТаблицы");
		ТабличныйДокумент.Вывести(ОбластьМакета);
		
		ОбластьМакета = Макет.ПолучитьОбласть("Строка");
		
		Пока ВыборкаСтрокТовары.Следующий() Цикл
			
			ОбластьМакета.Параметры.Заполнить(ВыборкаСтрокТовары);
			ОбластьМакета.Параметры.КоличествоПрописью = ?(ВыборкаСтрокТовары.Количество = 0,
			"",
			Строка(ВыборкаСтрокТовары.Количество) + " (" + КоличествоПрописью(ВыборкаСтрокТовары.Количество) + ")");
			ТабличныйДокумент.Вывести(ОбластьМакета);
			
		КонецЦикла;
		
		ОбластьМакета = Макет.ПолучитьОбласть("Подвал");
		ОбластьМакета.Параметры.Заполнить(Шапка);
		
		Если ЗначениеЗаполнено(Руководитель) Тогда
			ОбластьМакета.Параметры.ФИОРуководителя       = Руководитель;
			ОбластьМакета.Параметры.Руководитель          = Руководитель;
		КонецЕсли;
		
		Если ЗначениеЗаполнено(Бухгалтер) Тогда
			ОбластьМакета.Параметры.ФИОГлавногоБухгалтера = Бухгалтер;
			ОбластьМакета.Параметры.ГлавныйБухгалтер      = Бухгалтер;
		КонецЕсли;
		
		//  Выводим Рисунки
		ОбластьМакета.Рисунки.Добавить(ТипРисункаТабличногоДокумента.Картинка);
		//
		
		ТабличныйДокумент.Вывести(ОбластьМакета);
		
		УправлениеПечатью.ЗадатьОбластьПечатиДокумента(ТабличныйДокумент, НомерСтрокиНачало, ОбъектыПечати, ТекущийДокумент);
		
	КонецЦикла;
	
	ТабличныйДокумент.АвтоМасштаб = Истина;
	
	Возврат ТабличныйДокумент;
	
КонецФункции // ПечатнаяФорма()


Функция КоличествоПрописью(Количество)
	
	ЦелаяЧасть   = Цел(Количество);
	ДробнаяЧасть = Окр(Количество - ЦелаяЧасть, 3);
	
	Если ДробнаяЧасть = Окр(ДробнаяЧасть,0) Тогда
		ПараметрыПрописи = ", , , , , , , , 0";
	ИначеЕсли ДробнаяЧасть = Окр(ДробнаяЧасть, 1) Тогда
		ПараметрыПрописи = "целая, целых, целых, ж, десятая, десятых, десятых, м, 1";
	ИначеЕсли ДробнаяЧасть = Окр(ДробнаяЧасть, 2) Тогда
		ПараметрыПрописи = "целая, целых, целых, ж, сотая, сотых, сотых, м, 2";
	Иначе
		ПараметрыПрописи = "целая, целых, целых, ж, тысячная, тысячных, тысячных, м, 3";
	КонецЕсли;
	
	Возврат ЧислоПрописью(Количество, ,ПараметрыПрописи);
	
КонецФункции // КоличествоПрописью()