Программно получить остатки товаров

Question

Коллеги, помогите написать запрос или как в 1с 8 Бухгалтерия (обычное приложение) получить остатки товаров на определенный момент. Делаю зарос
[1C-CODE]Запрос = Новый Запрос;
	Запрос.Текст = 
		"ВЫБРАТЬ
		|	ХозрасчетныйОстатки.КоличествоОстаток КАК ТекОстаток,
		|	ХозрасчетныйОстатки.КоличествоОстатокДт Как ТекОстатокДТ
		|ИЗ
		|	РегистрБухгалтерии.Хозрасчетный.Остатки(&Дата, , , ) КАК ХозрасчетныйОстатки
		|ГДЕ
		|	ХозрасчетныйОстатки.Субконто1 = &ВыбТМЦ
		|	И ХозрасчетныйОстатки.Субконто3 = &ВыбСклад
		|	И ХозрасчетныйОстатки.Счет.Код = &ВыбСчет
		|	И ХозрасчетныйОстатки.Организация = &ВыбОрганизация";
	
	Запрос.УстановитьПараметр("ВыбОрганизация", ЭтотОбъект.Организация.Ссылка);
	Запрос.УстановитьПараметр("ВыбСклад", ЭтотОбъект.Склад.Родитель);
	Запрос.УстановитьПараметр("ВыбСчет", ПланыСчетов.Хозрасчетный.ТоварыНаСкладе.Код);
	Запрос.УстановитьПараметр("ВыбТМЦ", СтрокаТЧ.Номенклатура.Ссылка);
	Запрос.УстановитьПараметр("Дата",ТекущаяДата());
	
	РезультатЗапроса = Запрос.Выполнить();
	
	ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();
Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
		

		// Вставить обработку выборки ВыборкаДетальныеЗаписи
	КонецЦикла;

[/1C-CODE]

Но в данном случае запрос ничего не выбирает. Почему? Или вообще не так нужно делать?

Заранее спасибо.

Accepted Answer

[CODE]    Запрос.Текст = 
        "ВЫБРАТЬ
        |	ХозрасчетныйОстатки.КоличествоОстаток КАК ТекОстаток,
        |	ХозрасчетныйОстатки.КоличествоОстатокДт КАК ТекОстатокДТ
        |ИЗ
        |	РегистрБухгалтерии.Хозрасчетный.Остатки(
        |			&Дата,
        |			Счет = &Счет,
        |			&МассивСубконто,
        |			Организация = &Организация
        |				И Субконто1 = &Номенклатура
        |				И Субконто2 = &Склад) КАК ХозрасчетныйОстатки";
		
	МассивСубконто = Новый Массив;	
	МассивСубконто.Добавить(ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.Номенклатура);
	МассивСубконто.Добавить(ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.Склады);
	
	Запрос.УстановитьПараметр("МассивСубконто", МассивСубконто);
    Запрос.УстановитьПараметр("Организация", Организация);
	Запрос.УстановитьПараметр("Номенклатура", СтрокаТЧ.Номенклатура);
    Запрос.УстановитьПараметр("Склад", Склад);
    Запрос.УстановитьПараметр("Счет", ПланыСчетов.Хозрасчетный.ТоварыНаСкладе);
    Запрос.УстановитьПараметр("Дата",ТекущаяДата());
    
    РезультатЗапроса = Запрос.Выполнить();[/CODE]