Обрезать qr код

Функция ОбработатьСобытиеСШК(Обработка, Объект, Клиент, Событие, Данные, СШК)
	
	Результат = мНетОшибки;

	ШК        = Неопределено;
	ТипШК     = Неопределено;
	Результат = Обработка.ОбработатьСобытиеСШК(Объект,
	                                           Событие,
	                                           Данные,
	                                           ШК,
	                                           ТипШК);
											   
    	
	Если ЗначениеЗаполнено(Результат) Тогда
		Возврат Результат;
	КонецЕсли;

	Если ПустаяСтрока(ШК) Тогда
		Возврат Результат;
	КонецЕсли;

	Если НЕ ЗначениеЗаполнено(ТипШК) Тогда
		Если РаботаСТорговымОборудованием.ТипШтрихкодаEAN8ТО(ШК) Тогда
			ТипШК = мEAN8;
		ИначеЕсли РаботаСТорговымОборудованием.ТипШтрихкодаEAN13ТО(ШК) Тогда
			ТипШК = мEAN13;
		ИначеЕсли РаботаСТорговымОборудованием.ТипШтрихкодаPDF417(ШК) Тогда
			ТипШК = "PDF417";
		ИначеЕсли РаботаСТорговымОборудованием.ТипШтрихкодаCODE39ТО(ШК) Тогда
			ТипШК = мCODE39;
		КонецЕсли;
	КонецЕсли;

	Запрос = Новый Запрос(
	"ВЫБРАТЬ ПЕРВЫЕ 1
	|    СпрСН.Ссылка КАК СерийныйНомер
	|ИЗ
	|    Справочник.СерийныеНомера КАК СпрСН
	|ГДЕ
	|    (ВЫРАЗИТЬ(СпрСН.Код КАК СТРОКА(" + Формат(СтрДлина(ШК), "ЧН=0; ЧГ=0") + "))) = &Код");
	Запрос.УстановитьПараметр("Код", ШК);
	РезультатЗапроса = Запрос.Выполнить();
	Если Не РезультатЗапроса.Пустой() Тогда
		РезультатЗапроса = РезультатЗапроса.Выбрать();
		РезультатЗапроса.Следующий();

		Ответ = Клиент.СШКСерийныйНомер(РезультатЗапроса.СерийныйНомер, СШК);
		Если Ответ Тогда
			Возврат Результат;
		КонецЕсли;
	КонецЕсли;

	Если ЗначениеЗаполнено(мПрефиксВесовогоТовара)
		 И ЗначениеЗаполнено(мДлинаКодаВесовогоТовара)
		 И ТипШК = мEAN13
		 И Лев(ШК, 2) = "2" + мПрефиксВесовогоТовара Тогда

		КодТовара        = Сред(ШК, 3, мДлинаКодаВесовогоТовара);
		КоличествоТовара = Сред(ШК, 3 + мДлинаКодаВесовогоТовара, 10 - мДлинаКодаВесовогоТовара);
		Запрос           = Новый Запрос(
		"ВЫБРАТЬ ПЕРВЫЕ 1
		|    РегКВТ.Номенклатура                         КАК Номенклатура,
		|    РегКВТ.Номенклатура.ЕдиницаХраненияОстатков КАК ЕдиницаИзмерения,
		|    РегКВТ.ХарактеристикаНоменклатуры           КАК ХарактеристикаНоменклатуры,
		|    " + КоличествоТовара + " / 1000             КАК Количество,
		|    РегКВТ.СерияНоменклатуры                    КАК СерияНоменклатуры,
		|    ВЫБОР
		|        КОГДА РегКВТ.Качество = &КачествоПустаяСсылка ТОГДА
		|            &КачествоНовый
		|        ИНАЧЕ
		|            РегКВТ.Качество
		|    КОНЕЦ                                       КАК Качество
		|ИЗ
		|    РегистрСведений.КодыВесовогоТовара          КАК РегКВТ
		|ГДЕ
		|    РегКВТ.Код = &Код");
		Запрос.УстановитьПараметр("КачествоПустаяСсылка", мКачествоПустаяСсылка);
		Запрос.УстановитьПараметр("КачествоНовый",        мКачествоНовый);
		Запрос.УстановитьПараметр("Код",                  Число(КодТовара));

		РезультатЗапроса = Запрос.Выполнить();
		Если Не РезультатЗапроса.Пустой() Тогда
			РезультатЗапроса = РезультатЗапроса.Выбрать();
			РезультатЗапроса.Следующий();

			Ответ = Клиент.СШКНоменклатура(РезультатЗапроса.Номенклатура,
			                               РезультатЗапроса.ХарактеристикаНоменклатуры,
			                               РезультатЗапроса.СерияНоменклатуры,
			                               РезультатЗапроса.Качество,
			                               РезультатЗапроса.ЕдиницаИзмерения,
			                               РезультатЗапроса.Количество,
			                               СШК);
			Если Ответ Тогда
				Возврат Результат;
			КонецЕсли;
		КонецЕсли;
	КонецЕсли;

	Запрос = Новый Запрос(
	"ВЫБРАТЬ ПЕРВЫЕ 1
	|    РегШК.Владелец                   КАК Владелец,
	|    РегШК.ЕдиницаИзмерения           КАК ЕдиницаИзмерения,
	|    РегШК.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,
	|    РегШК.СерияНоменклатуры          КАК СерияНоменклатуры,
	|    РегШК.Качество                   КАК Качество
	|ИЗ
	|    РегистрСведений.Штрихкоды        КАК РегШК
	|ГДЕ
	|    РегШК.Штрихкод = &Штрихкод");
	Запрос.УстановитьПараметр("Штрихкод", ШК);
	РезультатЗапроса = Запрос.Выполнить();
	Если Не РезультатЗапроса.Пустой() Тогда
		РезультатЗапроса = РезультатЗапроса.Выбрать();
		РезультатЗапроса.Следующий();
		Если ТипЗнч(РезультатЗапроса.Владелец) = Тип("СправочникСсылка.ИнформационныеКарты") Тогда
			Ответ = Клиент.СШКИнформационнаяКарта(РезультатЗапроса.Владелец, СШК);
			Если Ответ Тогда
				Возврат Результат;
			КонецЕсли;
		Иначе // Если ТипЗнч(РезультатЗапроса.Владелец) = Тип("СправочникСсылка.Номенклатура")
			Ответ = Клиент.СШКНоменклатура(РезультатЗапроса.Владелец,
			                               РезультатЗапроса.ХарактеристикаНоменклатуры,
			                               РезультатЗапроса.СерияНоменклатуры,
			                               РезультатЗапроса.Качество,
			                               РезультатЗапроса.ЕдиницаИзмерения,
			                               1,
			                               СШК);
			Если Ответ Тогда
				Возврат Результат;
			КонецЕсли;
		КонецЕсли;
	КонецЕсли;

	Если Не ЗначениеЗаполнено(Результат) и ТипШК = "PDF417" Тогда
		Клиент.СШКОбработатьШтрихкод(ШК);
		Возврат Результат;
	КонецЕсли;
	
	Ответ = Клиент.СШКНеизвестныйКод(ШК, ТипШК, СШК);
	Если Ответ Тогда
		Возврат Результат;
	КонецЕсли;

	Результат = мОшибкаНеизвестныйШтрихкод;
	Клиент.СШКОшибка(Результат, ШК, ТипШК, СШК);

	Возврат Результат;

КонецФункции // ОбработатьСобытиеСШК()