Как после заполнения табличной части внешней обработкой пересчитать итоги документа?

Question

Доброго времени суток сообщество! Прошу помощи в следующем:
Дано: платформа 8.3.9, конфа "Розница 2.2.5.27", внешняя обработка заполнения документа "ЧекККМ", таблица значений "ТЗдляЧека"
[1C-CODE]
&НаКлиенте
Процедура СоздатьДокументЧек(Команда)
	//Защита от пустой ТЗ
	Если ТЗдляЧека.Количество() = 0 Тогда
		 Сообщить("НЕ прочитан документ Заказ-Наряд!");
		 Возврат;
	КонецЕсли;
	//Получаем форму нового документа
	ФормаЧека = ПолучитьФорму("Документ.ЧекККМ.ФормаОбъекта");
	//В переменную передаем данных полученой формы (так как напрямую их менять нельзя)
	ДанныеФормыЧека = ФормаЧека.Объект;
	//Заполняем форму чека данными
	ЗаполнитьЧекНаСервере(ДанныеФормыЧека);
	//копируем заполненные данные в исходную форму
	КопироватьДанныеФормы(ДанныеФормыЧека, ФормаЧека.Объект);
	
	//показываем форму нового заполненного документа пользователю
	ФормаЧека.Открыть();	
КонецПроцедуры

&НаСервере
Функция ЗаполнитьЧекНаСервере(ДанныеФормыЧека);
	// преобразуем данные формы ЧекККМ в документ ЧекККМ
    ДокументЧек = ДанныеФормыВЗначение(ДанныеФормыЧека, Тип("ДокументОбъект.ЧекККМ"));
	
	//Заполним титульную часть документ данными
	ДокументЧек.КассаККМ 	= Справочники.КассыККМ.НайтиПоКоду("00-000001");
	ДокументЧек.Магазин	 	= Справочники.Магазины.НайтиПоКоду("00-000001");
	ДокументЧек.Организация	= Справочники.Организации.НайтиПоКоду("00-000001");
	
	//подготовка данных для общих процедур 
	СтруктураДействий = Новый Структура;
	СтруктураДействий.Вставить("ПересчитатьСумму");

	//Заполним табличную часть документа
	Для Каждого СтрокаТЗ Из ТЗдляЧека Цикл
		СтрокаЧека = ДокументЧек.Товары.Добавить();
		СтрокаЧека.Номенклатура = СпроситьНоменклатуру(СтрокаТЗ.guid);
		СтрокаЧека.КоличествоУпаковок	= СтрокаТЗ.Количество;
		СтрокаЧека.Цена			= СтрокаТЗ.Цена;
		СтрокаЧека.СтавкаНДС	= Перечисления.СтавкиНДС.БезНДС;
		СтрокаЧека.Склад		= Справочники.Склады.НайтиПоКоду("00-000001");
		
		//Вызов общей процедуры
		ОбработкаТабличнойЧастиТоварыСервер.ОбработатьСтрокуТЧСервер(СтрокаЧека, СтруктураДействий, Неопределено);
	КонецЦикла;
		
	// преобразуем документа обратно в данные формы
    ЗначениеВДанныеФормы(ДокументЧек, ДанныеФормыЧека);
КонецФункции
[/1C-CODE]
Документ создаётся, заполняется, но, не вычисляются итоги, на форме они нулевые.
Если после открытия произвести какие либо действия с таблицей товары, как например перемещение строк стрелочками или попытку редактирования любой ячейки то всё рассчитываться - запускается процедурка формы "ОбновитьИтоговыеПоказатели" или "ОбновитьИтоговыеПоказателиСервер".
Вопрос первый как из внешней обработки после открытия формы запустить одну их этих процедур?
Вопрос второй, как из внешней обработки получить доступ к реквизиту формы, допустим к "СкидкиНаценкиИтогСумма"
чтобы заработал код (взял из процедуры "ОбновитьИтоговыеПоказатели")
[1C-CODE]
	СуммаРучнойСкидки = Объект.Товары.Итог("СуммаРучнойСкидки");
	СуммаАвтоматическойСкидки = Объект.Товары.Итог("СуммаАвтоматическойСкидки");
	СуммаСкидкиОплатыБонусом = Объект.Товары.Итог("СуммаСкидкиОплатыБонусом");
	СкидкиНаценкиИтогСумма = СуммаАвтоматическойСкидки + СуммаРучнойСкидки + СуммаСкидкиОплатыБонусом;
[/1C-CODE]

Accepted Answer

Спасибо Вам Елена и Николай!!!!

Решение методом Елена:
Добавил в процедуру "СоздатьДокументЧек" после ФормаЧека.Открыть();
строчку ФормаЧека.ОповещениеВыдатьПодаркиНаВыбор(Неопределено, Неопределено);
И уже через контекст формы выполнилась процедурка "ОбновитьИтоговыеПоказатели"
всё великолепно считается и документ готов к употреблению, НО будут выходить сообщения "Скидки (наценки), Скидки (наценки) рассчитаны" что может смутить рядового кассира...

Решение методом Елена&Николай:
Добавил расширение конфигурации.
загнал туда форму документа "ЧекККМ"
в расширении, в модуле формы документа "ЧекККМ"  написал
[CODE]
&НаКлиенте
Процедура ОбновитьИтоговыеПоказателиЭкспорт () Экспорт
	ОбновитьИтоговыеПоказатели();	
КонецПроцедуры
[/CODE]
Добавил в процедуру "СоздатьДокументЧек" после ФормаЧека.Открыть();
строчку ФормаЧека.ОбновитьИтоговыеПоказателиЭкспорт ();
Данные документа великолепно рассчитываться. 

Вывод, справедливо для УФ:
1) Из внешней обработки фиг доберёшься до реквизитов формы, доступ есть только до реквизитов документа!
2) Из внешней обработки любые другие действия с формой возможны только если "дергать" экспортные методы этой формы, или создавать свои экспортные процедурки через расширение и "дергать" уже их.