Закрытие месяца в КА 2

ВЫБРАТЬ
	ТоварыОрганизацийКПередачеОстаткиИОбороты.Период КАК Период,
	ТоварыОрганизацийКПередачеОстаткиИОбороты.Регистратор КАК Регистратор,
	ТоварыОрганизацийКПередачеОстаткиИОбороты.ОрганизацияВладелец КАК ОрганизацияВладелец,
	ТоварыОрганизацийКПередачеОстаткиИОбороты.ВидЗапасовПродавца КАК ВидЗапасовПродавца,
	ТоварыОрганизацийКПередачеОстаткиИОбороты.АналитикаУчетаНоменклатуры КАК АналитикаУчетаНоменклатуры,
	ТоварыОрганизацийКПередачеОстаткиИОбороты.НомерГТД КАК НомерГТД,
	ТоварыОрганизацийКПередачеОстаткиИОбороты.КоличествоКонечныйОстаток КАК КоличествоКонечныйОстаток
ИЗ
	РегистрНакопления.ТоварыОрганизацийКПередаче.ОстаткиИОбороты(&НачалоПериода, &ОкончаниеПериода, Регистратор, , ) КАК ТоварыОрганизацийКПередачеОстаткиИОбороты
ГДЕ
	ТоварыОрганизацийКПередачеОстаткиИОбороты.КоличествоКонечныйОстаток < 0

УПОРЯДОЧИТЬ ПО
	Регистратор
ИТОГИ
	КОЛИЧЕСТВО(РАЗЛИЧНЫЕ ВидЗапасовПродавца),
	КОЛИЧЕСТВО(РАЗЛИЧНЫЕ АналитикаУчетаНоменклатуры)
ПО
	Регистратор
АВТОУПОРЯДОЧИВАНИЕ

ВЫБРАТЬ
	ПроданныеТовары.ОрганизацияВладелец,
	ПроданныеТовары.ВидЗапасовПродавца,
	ПроданныеТовары.АналитикаУчетаНоменклатуры,
	ПроданныеТовары.КоличествоОстаток
ПОМЕСТИТЬ ТоварыПредварительная
ИЗ
	РегистрНакопления.ТоварыОрганизацийКПередаче.Остатки(&ГраницаКонецПериода, ОрганизацияВладелец В (&МассивОрганизаций)) КАК ПроданныеТовары

ИНДЕКСИРОВАТЬ ПО
	ПроданныеТовары.ВидЗапасовПродавца
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ПроданныеТовары.ОрганизацияВладелец КАК ОрганизацияПродавец,
	ВидыЗапасов.Организация КАК ОрганизацияПолучатель,
	ПроданныеТовары.АналитикаУчетаНоменклатуры КАК АналитикаУчетаНоменклатуры,
	СУММА(ПроданныеТовары.КоличествоОстаток) КАК Количество,
	ВЫБОР
		КОГДА &УчитыватьСебестоимостьТоваровПоВидамЗапасов
			ТОГДА ВидыЗапасов.ВидЗапасовВладельца
		ИНАЧЕ ЗНАЧЕНИЕ(Справочник.ВидыЗапасов.ПустаяСсылка)
	КОНЕЦ КАК ВидЗапасовПродавца,
	ВЫБОР
		КОГДА &УчитыватьСебестоимостьТоваровПоВидамЗапасов
			ТОГДА ВидыЗапасов.Ссылка
		ИНАЧЕ ЗНАЧЕНИЕ(Справочник.ВидыЗапасов.ПустаяСсылка)
	КОНЕЦ КАК ВидЗапасовПолучателя
ПОМЕСТИТЬ Товары
ИЗ
	ТоварыПредварительная КАК ПроданныеТовары
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.ВидыЗапасов КАК ВидыЗапасов
		ПО ПроданныеТовары.ВидЗапасовПродавца = ВидыЗапасов.Ссылка
ГДЕ
	ВидыЗапасов.ТипЗапасов = ЗНАЧЕНИЕ(Перечисление.ТипыЗапасов.Товар)

СГРУППИРОВАТЬ ПО
	ПроданныеТовары.ОрганизацияВладелец,
	ВидыЗапасов.Организация,
	ПроданныеТовары.АналитикаУчетаНоменклатуры,
	ВЫБОР
		КОГДА &УчитыватьСебестоимостьТоваровПоВидамЗапасов
			ТОГДА ВидыЗапасов.ВидЗапасовВладельца
		ИНАЧЕ ЗНАЧЕНИЕ(Справочник.ВидыЗапасов.ПустаяСсылка)
	КОНЕЦ,
	ВЫБОР
		КОГДА &УчитыватьСебестоимостьТоваровПоВидамЗапасов
			ТОГДА ВидыЗапасов.Ссылка
		ИНАЧЕ ЗНАЧЕНИЕ(Справочник.ВидыЗапасов.ПустаяСсылка)
	КОНЕЦ
;

////////////////////////////////////////////////////////////­////////////////////
УНИЧТОЖИТЬ ТоварыПредварительная
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ЗНАЧЕНИЕ(ВидДвиженияНакопления.Расход) КАК ВидДвижения,
	Товары.АналитикаУчетаНоменклатуры КАК АналитикаУчетаНоменклатуры,
	Товары.ОрганизацияПродавец КАК Организация,
	ЗНАЧЕНИЕ(Перечисление.РазделыУчетаСебестоимостиТоваров.ТоварыНаСкладах) КАК РазделУчета,
	Товары.ВидЗапасовПродавца КАК ВидЗапасов,
	Товары.Количество КАК Количество
ПОМЕСТИТЬ ВтНетПередачТоваров
ИЗ
	Товары КАК Товары

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	ЗНАЧЕНИЕ(ВидДвиженияНакопления.Приход),
	Товары.АналитикаУчетаНоменклатуры,
	Товары.ОрганизацияПолучатель,
	ЗНАЧЕНИЕ(Перечисление.РазделыУчетаСебестоимостиТоваров.ТоварыНаСкладах),
	Товары.ВидЗапасовПолучателя,
	Товары.Количество
ИЗ
	Товары КАК Товары

ИНДЕКСИРОВАТЬ ПО
	АналитикаУчетаНоменклатуры
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	СписанныеТовары.ВидЗапасов,
	СписанныеТовары.АналитикаУчетаНоменклатуры,
	СписанныеТовары.КоличествоСписаноОстаток
ПОМЕСТИТЬ ВтНетОтчетовОСписанииПредварительная
ИЗ
	РегистрНакопления.ТоварыКОформлениюОтчетовКомитенту.Остатки(&ГраницаКонецПериода, ) КАК СписанныеТовары

ИНДЕКСИРОВАТЬ ПО
	СписанныеТовары.ВидЗапасов
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВидыЗапасов.Организация КАК Организация,
	ВидыЗапасов.Комитент КАК Владелец,
	СписанныеТовары.АналитикаУчетаНоменклатуры КАК АналитикаУчетаНоменклатуры,
	СУММА(СписанныеТовары.КоличествоСписаноОстаток) КАК Количество,
	ВЫБОР
		КОГДА &УчитыватьСебестоимостьТоваровПоВидамЗапасов
			ТОГДА ВидыЗапасов.Ссылка
		ИНАЧЕ ЗНАЧЕНИЕ(Справочник.ВидыЗапасов.ПустаяСсылка)
	КОНЕЦ КАК ВидЗапасов
ПОМЕСТИТЬ ВтНетОтчетовОСписании
ИЗ
	ВтНетОтчетовОСписанииПредварительная КАК СписанныеТовары
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.ВидыЗапасов КАК ВидыЗапасов
		ПО СписанныеТовары.ВидЗапасов = ВидыЗапасов.Ссылка
ГДЕ
	ВидыЗапасов.Организация В(&МассивОрганизаций)

СГРУППИРОВАТЬ ПО
	ВидыЗапасов.Организация,
	ВидыЗапасов.Комитент,
	СписанныеТовары.АналитикаУчетаНоменклатуры,
	ВЫБОР
		КОГДА &УчитыватьСебестоимостьТоваровПоВидамЗапасов
			ТОГДА ВидыЗапасов.Ссылка
		ИНАЧЕ ЗНАЧЕНИЕ(Справочник.ВидыЗапасов.ПустаяСсылка)
	КОНЕЦ

ИНДЕКСИРОВАТЬ ПО
	АналитикаУчетаНоменклатуры
;

////////////////////////////////////////////////////////////­////////////////////
УНИЧТОЖИТЬ ВтНетОтчетовОСписанииПредварительная
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	Остатки.Организация КАК Организация,
	Остатки.Номенклатура КАК Номенклатура,
	Остатки.Характеристика КАК Характеристика,
	Остатки.Серия КАК Серия,
	Остатки.Назначение КАК Назначение,
	Остатки.Подразделение КАК Подразделение,
	Остатки.КоличествоОстаток КАК Количество
ПОМЕСТИТЬ ВтРаботыОстатки
ИЗ
	РегистрНакопления.МатериалыИРаботыВПроизводстве.Остатки(&ГраницаКонецПериода, Организация В (&МассивОрганизаций)) КАК Остатки
ГДЕ
	НЕ &ПартионныйУчетВерсии22
	И Остатки.КоличествоОстаток < 0
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	Остатки.Организация КАК Организация,
	Аналитика.КлючАналитики КАК АналитикаУчетаНоменклатуры,
	Остатки.Количество КАК Количество
ПОМЕСТИТЬ ВтРаботы
ИЗ
	ВтРаботыОстатки КАК Остатки
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.АналитикаУчетаНоменклатуры КАК Аналитика
		ПО (Аналитика.Номенклатура = Остатки.Номенклатура)
			И (Аналитика.Характеристика = Остатки.Характеристика)
			И (Аналитика.Серия = Остатки.Серия)
			И (Аналитика.Назначение = Остатки.Назначение)
			И (Аналитика.Склад = Остатки.Подразделение)
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.Номенклатура КАК СпрНоменклатура
		ПО Остатки.Номенклатура = СпрНоменклатура.Ссылка
ГДЕ
	СпрНоменклатура.ТипНоменклатуры = ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.Работа)

ИНДЕКСИРОВАТЬ ПО
	АналитикаУчетаНоменклатуры
;

////////////////////////////////////////////////////////////­////////////////////
УНИЧТОЖИТЬ ВтРаботыОстатки
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ
	"СебестоимостьТоваров" КАК ИмяРегистра,
	Т.Организация,
	Т.Период
ПОМЕСТИТЬ НекорректныйПереносДанных
ИЗ
	РегистрНакопления.СебестоимостьТоваров КАК Т
ГДЕ
	&ПартионныйУчетВерсии22
	И Т.Активность
	И НЕ Т.Регистратор ССЫЛКА Документ.КорректировкаРегистров
	И Т.ТипЗаписи = ЗНАЧЕНИЕ(Перечисление.ТипыЗаписейПартий.ПереносДанных)
	И Т.Период <> ДОБАВИТЬКДАТЕ(&ДатаПереходаНаПартионныйУчетВерсии22, СЕКУНДА, -1)

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ РАЗЛИЧНЫЕ
	"ДетализацияПартийТоваровДляНДСиУСН",
	Т.Организация,
	Т.Период
ИЗ
	РегистрНакопления.ДетализацияПартийТоваровДляНДСиУСН КАК Т
ГДЕ
	&ПартионныйУчетВерсии22
	И Т.Активность
	И НЕ Т.Регистратор ССЫЛКА Документ.КорректировкаРегистров
	И Т.ТипЗаписи = ЗНАЧЕНИЕ(Перечисление.ТипыЗаписейПартий.ПереносДанных)
	И Т.Период <> ДОБАВИТЬКДАТЕ(&ДатаПереходаНаПартионныйУчетВерсии22, СЕКУНДА, -1)
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	Т.РазделУчета,
	Т.ВидЗапасов,
	Т.Организация,
	Т.АналитикаУчетаНоменклатуры,
	Т.КоличествоОстаток
ПОМЕСТИТЬ СебестоимостьТоваровОстатки
ИЗ
	РегистрНакопления.СебестоимостьТоваров.Остатки(&ГраницаКонецПериода, Организация В (&МассивОрганизаций)) КАК Т
ГДЕ
	Т.РазделУчета <> ЗНАЧЕНИЕ(Перечисление.РазделыУчетаСебестоимостиТоваров.НезавершенноеПроизводство)

ИНДЕКСИРОВАТЬ ПО
	Т.АналитикаУчетаНоменклатуры
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	"Остатки" КАК ВидПроверки,
	Таб.РазделУчета КАК РазделУчета,
	Таб.ВидЗапасов КАК ВидЗапасов,
	Таб.Организация КАК Организация,
	Таб.Организация КАК Владелец,
	Таб.Номенклатура КАК Номенклатура,
	Таб.Характеристика КАК Характеристика,
	Таб.Серия КАК Серия,
	Таб.Склад КАК Склад,
	Таб.Назначение КАК Назначение,
	СУММА(Таб.Количество) КАК Количество
ИЗ
	(ВЫБРАТЬ
		Т.РазделУчета КАК РазделУчета,
		ВЫБОР
			КОГДА Аналитика.Склад ССЫЛКА Справочник.Партнеры
					ИЛИ Аналитика.Склад ССЫЛКА Справочник.СтруктураПредприятия
				ТОГДА НЕОПРЕДЕЛЕНО
			ИНАЧЕ Т.ВидЗапасов
		КОНЕЦ КАК ВидЗапасов,
		Т.Организация КАК Организация,
		Аналитика.Номенклатура КАК Номенклатура,
		Аналитика.Характеристика КАК Характеристика,
		Аналитика.Серия КАК Серия,
		Аналитика.Склад КАК Склад,
		Аналитика.Назначение КАК Назначение,
		Т.КоличествоОстаток КАК Количество
	ИЗ
		СебестоимостьТоваровОстатки КАК Т
			ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.КлючиАналитикиУчетаНоменклатуры КАК Аналитика
			ПО Т.АналитикаУчетаНоменклатуры = Аналитика.Ссылка
			ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.Номенклатура КАК СпрНоменклатура
			ПО (СпрНоменклатура.Ссылка = Аналитика.Номенклатура)
	ГДЕ
		(Т.РазделУчета <> ЗНАЧЕНИЕ(Перечисление.РазделыУчетаСебестоимостиТоваров.ПроизводственныеЗатраты)
				ИЛИ СпрНоменклатура.ТипНоменклатуры = ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.Работа)
				ИЛИ Аналитика.Склад ССЫЛКА Справочник.Склады)
	
	ОБЪЕДИНИТЬ ВСЕ
	
	ВЫБРАТЬ
		Т.РазделУчета,
		Т.ВидЗапасов,
		Т.Организация,
		Аналитика.Номенклатура,
		Аналитика.Характеристика,
		Аналитика.Серия,
		Аналитика.Склад,
		Аналитика.Назначение,
		ВЫБОР
			КОГДА Т.ВидДвижения = ЗНАЧЕНИЕ(ВидДвиженияНакопления.Приход)
				ТОГДА Т.Количество
			ИНАЧЕ -Т.Количество
		КОНЕЦ
	ИЗ
		ВтНетПередачТоваров КАК Т
			ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.КлючиАналитикиУчетаНоменклатуры КАК Аналитика
			ПО Т.АналитикаУчетаНоменклатуры = Аналитика.Ссылка
	
	ОБЪЕДИНИТЬ ВСЕ
	
	ВЫБРАТЬ
		ЗНАЧЕНИЕ(Перечисление.РазделыУчетаСебестоимостиТоваров.ТоварыНаСкладах),
		НЕОПРЕДЕЛЕНО,
		Т.Организация,
		Аналитика.Номенклатура,
		Аналитика.Характеристика,
		Аналитика.Серия,
		Аналитика.Склад,
		Аналитика.Назначение,
		Т.Количество
	ИЗ
		ВтНетОтчетовОСписании КАК Т
			ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.КлючиАналитикиУчетаНоменклатуры КАК Аналитика
			ПО Т.АналитикаУчетаНоменклатуры = Аналитика.Ссылка
	
	ОБЪЕДИНИТЬ ВСЕ
	
	ВЫБРАТЬ
		ЗНАЧЕНИЕ(Перечисление.РазделыУчетаСебестоимостиТоваров.ПроизводственныеЗатраты),
		НЕОПРЕДЕЛЕНО,
		Т.Организация,
		Аналитика.Номенклатура,
		Аналитика.Характеристика,
		Аналитика.Серия,
		Аналитика.Склад,
		Аналитика.Назначение,
		-Т.Количество
	ИЗ
		ВтРаботы КАК Т
			ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.КлючиАналитикиУчетаНоменклатуры КАК Аналитика
			ПО Т.АналитикаУчетаНоменклатуры = Аналитика.Ссылка) КАК Таб

СГРУППИРОВАТЬ ПО
	Таб.РазделУчета,
	Таб.ВидЗапасов,
	Таб.Организация,
	Таб.Номенклатура,
	Таб.Характеристика,
	Таб.Серия,
	Таб.Склад,
	Таб.Назначение,
	Таб.Организация

ИМЕЮЩИЕ
	СУММА(Таб.Количество) < 0

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	"Передачи",
	НЕОПРЕДЕЛЕНО,
	НЕОПРЕДЕЛЕНО,
	Таб.ОрганизацияПолучатель,
	Таб.ОрганизацияПродавец,
	НЕОПРЕДЕЛЕНО,
	НЕОПРЕДЕЛЕНО,
	НЕОПРЕДЕЛЕНО,
	АналитикаНоменклатуры.Склад,
	НЕОПРЕДЕЛЕНО,
	0
ИЗ
	Товары КАК Таб
		ЛЕВОЕ СОЕДИНЕНИЕ Справочник.КлючиАналитикиУчетаНоменклатуры КАК АналитикаНоменклатуры
		ПО Таб.АналитикаУчетаНоменклатуры = АналитикаНоменклатуры.Ссылка

СГРУППИРОВАТЬ ПО
	Таб.ОрганизацияПолучатель,
	Таб.ОрганизацияПродавец,
	АналитикаНоменклатуры.Склад

ИМЕЮЩИЕ
	СУММА(Таб.Количество) > 0

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	"Комиссия",
	НЕОПРЕДЕЛЕНО,
	НЕОПРЕДЕЛЕНО,
	Таб.Организация,
	Таб.Владелец,
	НЕОПРЕДЕЛЕНО,
	НЕОПРЕДЕЛЕНО,
	НЕОПРЕДЕЛЕНО,
	НЕОПРЕДЕЛЕНО,
	НЕОПРЕДЕЛЕНО,
	0
ИЗ
	ВтНетОтчетовОСписании КАК Таб

СГРУППИРОВАТЬ ПО
	Таб.Организация,
	Таб.Владелец

ИМЕЮЩИЕ
	СУММА(Таб.Количество) <> 0

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	"Работы",
	НЕОПРЕДЕЛЕНО,
	НЕОПРЕДЕЛЕНО,
	Таб.Организация,
	НЕОПРЕДЕЛЕНО,
	Аналитика.Номенклатура,
	Аналитика.Характеристика,
	Аналитика.Серия,
	Аналитика.Склад,
	Аналитика.Назначение,
	СУММА(Таб.Количество)
ИЗ
	ВтРаботы КАК Таб
		ЛЕВОЕ СОЕДИНЕНИЕ Справочник.КлючиАналитикиУчетаНоменклатуры КАК Аналитика
		ПО (Аналитика.Ссылка = Таб.АналитикаУчетаНоменклатуры)

СГРУППИРОВАТЬ ПО
	Таб.Организация,
	Аналитика.Номенклатура,
	Аналитика.Характеристика,
	Аналитика.Серия,
	Аналитика.Склад,
	Аналитика.Назначение

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	"ЛишниеПередачи",
	НЕОПРЕДЕЛЕНО,
	НЕОПРЕДЕЛЕНО,
	Таб.ОрганизацияПолучатель,
	Таб.ОрганизацияПродавец,
	АналитикаНоменклатуры.Номенклатура,
	АналитикаНоменклатуры.Характеристика,
	АналитикаНоменклатуры.Серия,
	АналитикаНоменклатуры.Склад,
	АналитикаНоменклатуры.Назначение,
	-СУММА(Таб.Количество)
ИЗ
	Товары КАК Таб
		ЛЕВОЕ СОЕДИНЕНИЕ Справочник.КлючиАналитикиУчетаНоменклатуры КАК АналитикаНоменклатуры
		ПО Таб.АналитикаУчетаНоменклатуры = АналитикаНоменклатуры.Ссылка

СГРУППИРОВАТЬ ПО
	Таб.ОрганизацияПолучатель,
	Таб.ОрганизацияПродавец,
	АналитикаНоменклатуры.Номенклатура,
	АналитикаНоменклатуры.Характеристика,
	АналитикаНоменклатуры.Серия,
	АналитикаНоменклатуры.Склад,
	АналитикаНоменклатуры.Назначение

ИМЕЮЩИЕ
	СУММА(Таб.Количество) < 0

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ РАЗЛИЧНЫЕ
	"ПереносДанных",
	НЕОПРЕДЕЛЕНО,
	НЕОПРЕДЕЛЕНО,
	Т.Организация,
	НЕОПРЕДЕЛЕНО,
	НЕОПРЕДЕЛЕНО,
	НЕОПРЕДЕЛЕНО,
	НЕОПРЕДЕЛЕНО,
	НЕОПРЕДЕЛЕНО,
	НЕОПРЕДЕЛЕНО,
	0
ИЗ
	НекорректныйПереносДанных КАК Т

УПОРЯДОЧИТЬ ПО
	ВидПроверки,
	Организация,
	РазделУчета,
	Номенклатура,
	Характеристика,
	Серия,
	Склад,
	Назначение,
	ВидЗапасов