Получить текущую должность сотрудника

Форум Программирование Общие вопросы программирования (Dev)

1. SnakePlisskin 3 02.02.17 15:55 Сейчас в теме

Доброго дня!
Как программно получить текущую должность сотрудника в Бух 3.0 ?

По теме из базы знаний

Найденные решения

9. forseil 214 02.02.17 16:27 Сейчас в теме

Функция ПолучитьДолжностьСотрудника(Сотрудник)
	ЗапросПоСотрудникам = Новый Запрос;
	ЗапросПоСотрудникам.Текст = "ВЫБРАТЬ ТекущиеКадровыеДанныеСотрудников.ТекущаяДолжность
	                            |ИЗ РегистрСведений.ТекущиеКадровыеДанныеСотрудников КАК ТекущиеКадровыеДанныеСотрудников
	                            |ГДЕ ТекущиеКадровыеДанныеСотрудников.Сотрудник = &Сотрудник";
	ЗапросПоСотрудникам.Параметры.Вставить("Сотрудник", Сотрудник);
	Результат = ЗапросПоСотрудникам.Выполнить(); 
	Если Не Результат.Пустой() Тогда
		Выборка = Результат.Выбрать();
		Выборка.Следующий();
		Возврат Выборка.ТекущаяДолжность;
	Иначе
		Возврат Неопределено
	КонецЕсли;	

КонецФункции

Показать

Ответить

Остальные ответы

Подписаться на ответы Инфостарт бот

Свернуть все

2. ture 611 02.02.17 16:02 Сейчас в теме

(1) ну в регистре сведений посмотреть (запросом можно)

3. DJDUH 17 02.02.17 16:04 Сейчас в теме

рс.СрезПоследних()

4. SnakePlisskin 3 02.02.17 16:08 Сейчас в теме

(3) более конкретно можно ?

5. starik-2005 3087 02.02.17 16:11 Сейчас в теме

(4) а зачем? Или нужно название регистра сведений? Так это может зависит от того, в какой конфигурации Вы это пытаетесь делать...

7. SnakePlisskin 3 02.02.17 16:19 Сейчас в теме

(5)Бух 3.0

6. xraf 17 02.02.17 16:13 Сейчас в теме

(0) Регистр сведений Кадровая история сотрудников

8. SnakePlisskin 3 02.02.17 16:20 Сейчас в теме

(6)можно пример кинуть ?

9. forseil 214 02.02.17 16:27 Сейчас в теме

Функция ПолучитьДолжностьСотрудника(Сотрудник)
	ЗапросПоСотрудникам = Новый Запрос;
	ЗапросПоСотрудникам.Текст = "ВЫБРАТЬ ТекущиеКадровыеДанныеСотрудников.ТекущаяДолжность
	                            |ИЗ РегистрСведений.ТекущиеКадровыеДанныеСотрудников КАК ТекущиеКадровыеДанныеСотрудников
	                            |ГДЕ ТекущиеКадровыеДанныеСотрудников.Сотрудник = &Сотрудник";
	ЗапросПоСотрудникам.Параметры.Вставить("Сотрудник", Сотрудник);
	Результат = ЗапросПоСотрудникам.Выполнить(); 
	Если Не Результат.Пустой() Тогда
		Выборка = Результат.Выбрать();
		Выборка.Следующий();
		Возврат Выборка.ТекущаяДолжность;
	Иначе
		Возврат Неопределено
	КонецЕсли;	

КонецФункции

Показать

Ответить

10. japopov 68 02.02.17 16:28 Сейчас в теме

Штатный (правильный) способ - через функцию КадровыйУчет.КадровыеДанныеСотрудников():

//получаем, собссно, должность

&НаСервереБезКонтекста
Функция ДолжностьСотрудника(Сотрудник)
	МассивСотрудников = Новый Массив;
	МассивСотрудников.Добавить(Сотрудник);
	ТЗСведения = КадровыйУчет.КадровыеДанныеСотрудников(Истина,МассивСотрудников,"Организация,Должность");
	Если ТЗСведения.Количество()>0 Тогда
		Должность = ТЗСведения[0].Должность;
	Иначе
		Должность = ПредопределенноеЗначение("Справочник.Должности.ПустаяСсылка");
	КонецЕсли;
	Возврат Должность;
КонецФункции

// это - обработчик нажатия кнопки, показывает должность сотрудника Реквизит1

&НаКлиенте
Процедура Команда1(Команда)
	ПоказатьЗначение(,ДолжностьСотрудника(Реквизит1));
КонецПроцедуры

Показать

Ответить

11. forseil 214 02.02.17 16:31 Сейчас в теме

(10) Да, так корректнее, согласен

14. lamur31 18.07.18 14:25 Сейчас в теме

(10)

ТЗСведения = КадровыйУчет.КадровыеДанныеСотрудников(Истина,МассивСотрудников,"Организация,Должность");
Если ТЗСведения.Количество()>0 Тогда

Помогите разобраться с кодом

15. lamur31 18.07.18 14:33 Сейчас в теме

(10)

Помогите разобраться с кодом

18. kaliuzhnyi 135 03.04.24 14:53 Сейчас в теме

(10) А я бы еще упростил))

Сведения = КадровыйУчет.КадровыеДанныеСотрудников(Истина, ОбщегоНазначенияКлиентСервер.ЗначениеВМассиве(Сотрудник), "Должность");
Должность = ?(Сведения.Количество(), Сведения[0].Должность, ПредопределенноеЗначение("Справочник.Должности.ПустаяСсылка"));

12. japopov 68 02.02.17 16:34 Сейчас в теме

Ну, и, разумеется, то что я дал - это шаблон, информация к размышлению. Я бы обрабатывал и организацию, и дату среза сведений... Читайте описание функции и экспериментируйте!

13. ture 611 02.02.17 16:37 Сейчас в теме

(12) Хороший шаблон! Думаю, ТС можно уже подумать о свой публикации на эту тему, учитывая его усилия на поиски (вероятно, кому-то пригодится то же).

16. user1036114 14.09.18 11:21 Сейчас в теме

// Формирует временную таблицу, содержащую поля с запрашиваемыми кадровыми данными сотрудников, в том числе носящими
// периодический характер.
// Содержит обязательные поля Сотрудник, ФизическоеЛицо и Период, соответствующие переданным во временной таблице
// отборов.
//
// Параметры:
// ТолькоРазрешенные - Булево, если Истина то текст запроса будет построен с использованием
// ключевого слова РАЗРЕШЕННЫЕ.
// ОписательВременнойТаблицыОтборов - структура, описывающая временную таблицу, служащую фильтром
// по сотрудникам для получения кадровых данных
// см. КадровыйУчет.ОписаниеВременнойТаблицыОтборовСотрудников.
// КадровыеДанные - Строка, перечисление имен кадровых данных, разделенных запятыми.
// - Массив, содержащий строки имен кадровых данных.
// ФормироватьСПериодичностьДень - Булево, при получении кадровых данных, хранящихся в периодических
// регистрах сведений с периодичностью менее чем День, значение Истина позволяет
// отбирать самое последние значения в пределах дня.
// ИсточникиДанных - Соответствие, содержит служебную информацию об используемых в построении запроса
// источниках данных
// ИмяВТПостоянныеКадровыеДанныеСотрудников - Строка, указывает оригинальное имя временной таблицы,
// формируемой методом.
//
// Список полей, допустимых в параметре КадровыеДанные, если сведений в базе данных нет, возвращается
// NULL, исключения приведены в скобках, поле указания типа кадровых данных.
//
// - Все имена кадровых данных физических лиц (см. ЗапросВТКадровыеДанныеФизическихЛиц).
//
// - Все имена кадровых данных, разрешенных для метода ЗапросВТПостоянныеКадровыеДанныеСотрудников.
//
// Информация о рабочем месте.
// - РабочееМестоПериодРегистрации - Дата
// - РабочееМестоРегистратор - ДокументСсылка
// - Организация - СправочникСсылка.Организации
// - Подразделение - СправочникСсылка.ПодразделенияОрганизаций
// - Должность - СправочникСсылка.Должности
// - ВидЗанятости - ПеречисленияСсылка.ВидыЗанятости
// - ВидСобытия - ПеречисленияСсылка. ВидыКадровыхСобытий
// - КоличествоСтавок - Число, в этой конфигурации всегда 1.
// - ДолжностьПоШтатномуРасписанию - СправочникСсылка.ШтатноеРасписание
// - ВидДоговора - ПеречислениеСсылка.ВидыДоговоровССотрудниками
// - МестоВСтруктуреПредприятия - СправочникСсылка.СтруктураПредприятия.
//
// - РазрядКатегорияПериодРегистрации - Дата
// - РазрядКатегорияРегистратор - ДокументСсылка
// - РазрядКатегория - СправочникСсылка.РазрядыКатегорииДолжностей.
//
// - ПКУПериодРегистрации - Дата
// - ПКУРегистратор - ДокументСсылка
// - ПКУ - СправочникСсылка.РазрядыКатегорииДолжностей.
//
// - СостояниеПериодРегистрации - Дата
// - Состояние - ПеречислениеСсылка.СостоянияСотрудника.
//
// - ТерриторияПериодЗаписи - Дата
// - ТерриторияРегистратор
// - Территория - СправочникСсылка.ТерриторииВыполненияРабот.
//
// Информация о свойствах рабочего места.
// - ЯвляетсяЧленомЛетногоЭкипажа - Булево (Ложь)
// - ЯвляетсяШахтером - Булево (Ложь)
// - ЯвляетсяФармацевтом - Булево (Ложь)
// - ЯвляетсяРаботникомСДосрочнойПенсией - ПеречислениеСсылка.ВидыРаботСДосрочнойПенсией
// (Перечисления.ВидыРаботСДосрочнойПенсией.ПустаяСсылка).
// - ЯвляетсяЧленомЭкипажаСуднаПодФлагомРФ - Булево (Ложь)
// - ТарифнаяСетка - СправочникСсылка.ТарифныеСетки
// - ТарифнаяСеткаНадбавки - СправочникСсылка.ТарифныеСетки
// - КлассныйЧинРангДолжности - СправочникСсылка.КлассныеЧиныРанги.
//
// Информация об оплате труда.
// - ОплатаТрудаПериодЗаписи - Дата
// - ОплатаТрудаРегистратор - ДокументСсылка
// - ТарифнаяСтавка - Число
// - ФОТ - Число
// - Надбавка - Число, в этой конфигурации всегда 0.
// - ОсновноеНачисление - ПланВидовРасчета.Начисления
// - ПоказательТарифнойСтавки - СправочникСсылка.ПоказателиРасчетаЗарплаты.
//
// - СовокупнаяТарифнаяСтавкаПериодРегистрации - Дата
// - СовокупнаяТарифнаяСтавкаРегистратор - ДокументСсылка
// - СовокупнаяТарифнаяСтавка - Число
// - ВидСовокупнойТарифнойСтавки - ПеречислениеСсылка.ВидыТарифныхСтавок.
//
// - ПорядокРасчетаСтоимостиЕдиницыВремениПериодРегистрации - Дата
// - ПорядокРасчетаСтоимостиЕдиницыВремениРегистратор - ДокументСсылка
// - ПорядокРасчетаСтоимостиЕдиницыВремени - ПеречислениеСсылка.ПорядокРасчетаСтоимостиЕдиницыВремениОплатыТруда.
//
// - ГрейдПериодРегистрации - Дата
// - ГрейдРегистратор - ДокументСсылка
// - Грейд - СправочникСсылка.Грейды.
//
// - ГрафикРаботыПериодРегистрации - Дата
// - ГрафикРаботыРегистратор - ДокументСсылка
// - ГрафикРаботы - СправочникСсылка.ГрафикиРаботыСотрудников
// - СуммированныйУчетРабочегоВремени - Булево.
//
// - ДоляНеполногоРабочегоВремени - Число
//
// - АвансПериодЗаписи - Дата
// - АвансРегистратор - ДокументСсылка
// - СпособРасчетаАванса - ПеречислениеСсылка.СпособыРасчетаАванса
// - Аванс - Число.
//
// - ЗарплатныйПроектПериодРегистрации - Дата
// - ЗарплатныйПроектРегистратор - ДокументСсылка.ПодтверждениеОткрытияЛицевыхСчетовСотрудников
// - ЗарплатныйПроект - СправочникСсылка.ЗарплатныеПроекты
// - НомерЛицевогоСчета - Строка.
//
// Информация об учете затрат.
// - УчетЗатратПериодРегистрации - Дата
// - СтатьяФинансирования - СправочникСсылка.СтатьиФинансированияЗарплата
// - СпособОтраженияЗарплатыВБухучете - СправочникСсылка.СпособыОтраженияЗарплатыВБухУчете
// - ОтношениеКЕНВД - ПеречислениеСсылка.ОтношениеКЕНВДЗатратНаЗарплату
// - УчетЗатратДокументОснование - ДокументСсылка.ПриемНаРаботу.
//
// Основные данные контрактов, договоров сотрудников.
// - ДатаДоговораКонтракта - Дата, так же поддерживается идентификатор ТрудовойДоговорДата
// - НомерДоговораКонтракта - Строка, так же поддерживается идентификатор ТрудовойДоговорНомер
// - ДатаНачала - Дата
// - ПоступлениеНаСлужбуВпервые - Булево.
//
// Сведения контракта, договора сотрудника.
// - ПредставительНанимателя - СправочникСсылка.ФизическиеЛица
// - ДолжностьПредставителяНанимателя - СправочникСсылка.Должности
// - ОснованиеПредставителя - Строка
// - ВидАктаГосоргана - Строка
// - ДатаОкончания - Дата
// - СрочныйДоговор - Булево
// - СрокЗаключенияДоговора - Строка
// - ОборудованиеРабочегоМеста - Строка
// - ИныеУсловияДоговора - Строка
// - ОснованиеСрочногоДоговора - СправочникСсылка.ОснованияЗаключенияСрочныхКонтрактовГосслужащих
// - СправочникСсылка.ОснованияЗаключенияСрочныхДоговоровМуниципальныхСлужащих
// - СправочникСсылка.ОснованияЗаключенияСрочныхТрудовыхДоговоров.
//
// Информация о классах условий труда по результатам специальной оценки на рабочем месте.
// - КлассУсловийТрудаПериодРегистрации - Дата
// - КлассУсловийТруда - ПеречислениеСсылка.КлассыУсловийТрудаПоРезультатамСпециальнойОценки
// - КлассУсловийТрудаДатаРегистрацииИзменений - Дата.
//
Функция ЗапросВТКадровыеДанныеСотрудников(ТолькоРазрешенные, ОписательВременнойТаблицыОтборов, КадровыеДанные, ПоляОтбораПериодическихДанных, ФормироватьСПериодичностьДень, ИсточникиДанных, ИмяВТКадровыеДанныеСотрудников, ТаблицаОтборовСодержитПолеФизическоеЛицо, УничтожитьВспомогательныеТаблицы) Экспорт

Возврат КадровыйУчетРасширенный.ЗапросВТКадровыеДанныеСотрудников(ТолькоРазрешенные, ОписательВременнойТаблицыОтборов, КадровыеДанные, ПоляОтбораПериодическихДанных, ФормироватьСПериодичностьДень, ИсточникиДанных, ИмяВТКадровыеДанныеСотрудников, ТаблицаОтборовСодержитПолеФизическоеЛицо, УничтожитьВспомогательныеТаблицы);

КонецФункции

17. 1C_Casual 172 11.09.20 15:43 Сейчас в теме

УправлениеПользователями.ПолучитьЗначениеПоУмолчанию(ПараметрыСеанса.ТекущийПользователь, "Должность")

19. webresurs 228 11.11.24 06:37 Сейчас в теме

	ДанныеФизЛица = ОбщегоНазначенияБПВызовСервера.ДанныеФизЛица(СсылкаНаОбъект.Организация,СсылкаНаОбъект.Сотрудник,СсылкаНаОбъект.Дата);
	Область.Параметры.СотрудникДолжность = ДанныеФизЛица.Должность;
	Область.Параметры.СотрудникФИО = ДанныеФизЛица.Представление;

Оставьте свое сообщение

E-mail: