Рассчет итогов по конкретным группировкам

ВЫБРАТЬ
	ПартииТоваровНаСкладахОстаткиИОбороты.Номенклатура,
	ПартииТоваровНаСкладахОстаткиИОбороты.Период КАК Период,
	СУММА(ПартииТоваровНаСкладахОстаткиИОбороты.КоличествоКонечныйОстаток) КАК КоличествоКонечныйОстаток,
	ПартииТоваровНаСкладахОстаткиИОбороты.ХарактеристикаНоменклатуры,
	ПартииТоваровНаСкладахОстаткиИОбороты.СтоимостьКонечныйОстаток,
	ПартииТоваровНаСкладахОстаткиИОбороты.Склад
ПОМЕСТИТЬ Остатки
ИЗ
	РегистрНакопления.ПартииТоваровНаСкладах.ОстаткиИОбороты(&НачалоПериода, &КонецПериода, День, , {(Номенклатура).* КАК Номенклатура}) КАК ПартииТоваровНаСкладахОстаткиИОбороты
{ГДЕ
	ПартииТоваровНаСкладахОстаткиИОбороты.Номенклатура.*,
	ПартииТоваровНаСкладахОстаткиИОбороты.ХарактеристикаНоменклатуры.*,
	ПартииТоваровНаСкладахОстаткиИОбороты.Склад.Подразделение.Владелец.* КАК Организация}

СГРУППИРОВАТЬ ПО
	ПартииТоваровНаСкладахОстаткиИОбороты.Номенклатура,
	ПартииТоваровНаСкладахОстаткиИОбороты.Период,
	ПартииТоваровНаСкладахОстаткиИОбороты.ХарактеристикаНоменклатуры,
	ПартииТоваровНаСкладахОстаткиИОбороты.СтоимостьКонечныйОстаток,
	ПартииТоваровНаСкладахОстаткиИОбороты.Склад
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	РегламентированныйПроизводственныйКалендарь.ДатаКалендаря КАК Период
ПОМЕСТИТЬ Календарь
ИЗ
	РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь
ГДЕ
	РегламентированныйПроизводственныйКалендарь.ДатаКалендаря <= &КонецПериода
	И РегламентированныйПроизводственныйКалендарь.ДатаКалендаря >= &НачалоПериода
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	Остатки.Номенклатура,
	Календарь.Период КАК ПериодКалендаря,
	Остатки.Период КАК ПериодПоОстатку,
	Остатки.КоличествоКонечныйОстаток,
	Остатки.ХарактеристикаНоменклатуры,
	Остатки.СтоимостьКонечныйОстаток,
	Остатки.Склад
ПОМЕСТИТЬ КалендИОстаткиОбщая
ИЗ
	Календарь КАК Календарь
		ЛЕВОЕ СОЕДИНЕНИЕ Остатки КАК Остатки
		ПО Календарь.Период >= Остатки.Период
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	КалендИОстаткиОбщая.Номенклатура,
	КалендИОстаткиОбщая.ПериодКалендаря,
	МАКСИМУМ(КалендИОстаткиОбщая.ПериодПоОстатку) КАК ПериодПоОстатку,
	КалендИОстаткиОбщая.ХарактеристикаНоменклатуры,
	КалендИОстаткиОбщая.Склад
ПОМЕСТИТЬ МаксДатаИзОстатка
ИЗ
	КалендИОстаткиОбщая КАК КалендИОстаткиОбщая

СГРУППИРОВАТЬ ПО
	КалендИОстаткиОбщая.Номенклатура,
	КалендИОстаткиОбщая.ПериодКалендаря,
	КалендИОстаткиОбщая.ХарактеристикаНоменклатуры,
	КалендИОстаткиОбщая.Склад
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	КалендИОстаткиОбщая.Номенклатура,
	КалендИОстаткиОбщая.ПериодКалендаря,
	СУММА(КалендИОстаткиОбщая.КоличествоКонечныйОстаток) КАК КоличествоКонечныйОстаток,
	КалендИОстаткиОбщая.ХарактеристикаНоменклатуры,
	СУММА(КалендИОстаткиОбщая.СтоимостьКонечныйОстаток) КАК СтоимостьКонечныйОстаток,
	КалендИОстаткиОбщая.Склад.Подразделение.Владелец КАК Организация
ПОМЕСТИТЬ ПодИтогОстатки
ИЗ
	КалендИОстаткиОбщая КАК КалендИОстаткиОбщая
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ МаксДатаИзОстатка КАК МаксДатаИзОстатка
		ПО КалендИОстаткиОбщая.Номенклатура = МаксДатаИзОстатка.Номенклатура
			И КалендИОстаткиОбщая.ПериодКалендаря = МаксДатаИзОстатка.ПериодКалендаря
			И КалендИОстаткиОбщая.ПериодПоОстатку = МаксДатаИзОстатка.ПериодПоОстатку
			И КалендИОстаткиОбщая.ХарактеристикаНоменклатуры = МаксДатаИзОстатка.ХарактеристикаНоменклатуры
			И КалендИОстаткиОбщая.Склад = МаксДатаИзОстатка.Склад

СГРУППИРОВАТЬ ПО
	КалендИОстаткиОбщая.Номенклатура,
	КалендИОстаткиОбщая.ПериодКалендаря,
	КалендИОстаткиОбщая.ХарактеристикаНоменклатуры,
	КалендИОстаткиОбщая.Склад.Подразделение.Владелец
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ПодИтогОстатки.Номенклатура,
	СУММА(ПодИтогОстатки.КоличествоКонечныйОстаток) КАК КоличествоКонечныйОстаток,
	ПодИтогОстатки.ХарактеристикаНоменклатуры,
	СУММА(ПодИтогОстатки.СтоимостьКонечныйОстаток) КАК СтоимостьКонечныйОстаток,
	ПодИтогОстатки.Организация,
	НАЧАЛОПЕРИОДА(ПодИтогОстатки.ПериодКалендаря, ДЕНЬ) КАК День,
	НАЧАЛОПЕРИОДА(ПодИтогОстатки.ПериодКалендаря, МЕСЯЦ) КАК МЕСЯЦ,
	НАЧАЛОПЕРИОДА(ПодИтогОстатки.ПериодКалендаря, КВАРТАЛ) КАК КВАРТАЛ,
	НАЧАЛОПЕРИОДА(ПодИтогОстатки.ПериодКалендаря, ГОД) КАК ГОД
ПОМЕСТИТЬ ИтогОстатки
ИЗ
	ПодИтогОстатки КАК ПодИтогОстатки
{ГДЕ
	ПодИтогОстатки.Организация.*}

СГРУППИРОВАТЬ ПО
	ПодИтогОстатки.Номенклатура,
	ПодИтогОстатки.ХарактеристикаНоменклатуры,
	ПодИтогОстатки.Организация,
	НАЧАЛОПЕРИОДА(ПодИтогОстатки.ПериодКалендаря, ДЕНЬ),
	НАЧАЛОПЕРИОДА(ПодИтогОстатки.ПериодКалендаря, МЕСЯЦ),
	НАЧАЛОПЕРИОДА(ПодИтогОстатки.ПериодКалендаря, КВАРТАЛ),
	НАЧАЛОПЕРИОДА(ПодИтогОстатки.ПериодКалендаря, ГОД)
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ПродажиОбороты.Номенклатура КАК Номенклатура,
	ПродажиОбороты.Организация КАК Организация,
	СУММА(ПродажиОбороты.СтоимостьОборот) КАК СтоимостьПродажи,
	СУММА(ЕСТЬNULL(ТаблицаРегистраПродажиСебестоимость.СтоимостьОборот, 0)) КАК СебестоимостьПродажи,
	СУММА(ПродажиОбороты.КоличествоОборот) КАК КоличествоПродажи,
	ПродажиОбороты.ХарактеристикаНоменклатуры,
	СУММА(ПродажиОбороты.СтоимостьОборот - ЕСТЬNULL(ТаблицаРегистраПродажиСебестоимость.СтоимостьОборот, 0)) КАК ВаловаяПрибыль,
	НАЧАЛОПЕРИОДА(ПродажиОбороты.Период, ДЕНЬ) КАК День,
	НАЧАЛОПЕРИОДА(ПродажиОбороты.Период, МЕСЯЦ) КАК Месяц,
	НАЧАЛОПЕРИОДА(ПродажиОбороты.Период, КВАРТАЛ) КАК Квартал,
	НАЧАЛОПЕРИОДА(ПродажиОбороты.Период, ГОД) КАК Год
ПОМЕСТИТЬ ВпТ2
ИЗ
	РегистрНакопления.Продажи.Обороты(&НачалоПериода, &КонецПериода, Регистратор, {(Организация).* КАК Организация, (Проект).* КАК Проект, (Подразделение).* КАК Подразделение, (Контрагент).* КАК Покупатель, (ДоговорКонтрагента).* КАК ДоговорПокупателя, (Номенклатура).* КАК Номенклатура, (ХарактеристикаНоменклатуры).* КАК ХарактеристикаНоменклатуры, (ЗаказПокупателя).* КАК ЗаказПокупателя}) КАК ПродажиОбороты
		ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
			ПродажиСебестоимость.Номенклатура КАК Номенклатура,
			ПродажиСебестоимость.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,
			ПродажиСебестоимость.ЗаказПокупателя КАК ЗаказПокупателя,
			ВЫБОР
				КОГДА ПродажиСебестоимость.ДокументДвижения <> НЕОПРЕДЕЛЕНО
					ТОГДА ПродажиСебестоимость.ДокументДвижения
				ИНАЧЕ ПродажиСебестоимость.Регистратор
			КОНЕЦ КАК Регистратор,
			СУММА(ПродажиСебестоимость.Стоимость) КАК СтоимостьОборот
		ИЗ
			РегистрНакопления.ПродажиСебестоимость КАК ПродажиСебестоимость
		ГДЕ
			ПродажиСебестоимость.Период МЕЖДУ &НачалоПериода И &КонецПериода
		{ГДЕ
			ПродажиСебестоимость.Проект.* КАК Проект,
			ПродажиСебестоимость.Подразделение.* КАК Подразделение,
			ПродажиСебестоимость.Номенклатура.* КАК Номенклатура,
			ПродажиСебестоимость.ХарактеристикаНоменклатуры.* КАК ХарактеристикаНоменклатуры,
			ПродажиСебестоимость.ЗаказПокупателя.* КАК ЗаказПокупателя}
		
		СГРУППИРОВАТЬ ПО
			ПродажиСебестоимость.Номенклатура,
			ПродажиСебестоимость.ХарактеристикаНоменклатуры,
			ПродажиСебестоимость.ЗаказПокупателя,
			ВЫБОР
				КОГДА ПродажиСебестоимость.ДокументДвижения <> НЕОПРЕДЕЛЕНО
					ТОГДА ПродажиСебестоимость.ДокументДвижения
				ИНАЧЕ ПродажиСебестоимость.Регистратор
			КОНЕЦ) КАК ТаблицаРегистраПродажиСебестоимость
		ПО (ТаблицаРегистраПродажиСебестоимость.Номенклатура = ПродажиОбороты.Номенклатура)
			И (ТаблицаРегистраПродажиСебестоимость.ХарактеристикаНоменклатуры = ПродажиОбороты.ХарактеристикаНоменклатуры)
			И (ТаблицаРегистраПродажиСебестоимость.ЗаказПокупателя = ПродажиОбороты.ЗаказПокупателя)
			И (ТаблицаРегистраПродажиСебестоимость.Регистратор = ПродажиОбороты.Регистратор)
{ГДЕ
	ПродажиОбороты.Номенклатура.*,
	ПродажиОбороты.ХарактеристикаНоменклатуры.*,
	ПродажиОбороты.Организация.*}

СГРУППИРОВАТЬ ПО
	ПродажиОбороты.Номенклатура,
	ПродажиОбороты.Организация,
	ПродажиОбороты.ХарактеристикаНоменклатуры,
	НАЧАЛОПЕРИОДА(ПродажиОбороты.Период, ДЕНЬ),
	НАЧАЛОПЕРИОДА(ПродажиОбороты.Период, КВАРТАЛ),
	НАЧАЛОПЕРИОДА(ПродажиОбороты.Период, МЕСЯЦ),
	НАЧАЛОПЕРИОДА(ПродажиОбороты.Период, ГОД)
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	СУММА(ВпТ2.СтоимостьПродажи) КАК СтоимостьПродажи,
	СУММА(ВпТ2.СебестоимостьПродажи) КАК СебестоимостьПродажи,
	СУММА(ВпТ2.КоличествоПродажи) КАК КоличествоПродажи,
	СУММА(ВпТ2.ВаловаяПрибыль) КАК ВаловаяПрибыль,
	ВпТ2.Номенклатура,
	ВпТ2.ХарактеристикаНоменклатуры,
	ВпТ2.Организация,
	СРЕДНЕЕ(ВЫБОР
			КОГДА ВпТ2.СебестоимостьПродажи ЕСТЬ NULL 
					ИЛИ ВпТ2.СебестоимостьПродажи = 0
				ТОГДА 0
			ИНАЧЕ ВпТ2.ВаловаяПрибыль / ВпТ2.СебестоимостьПродажи * 100
		КОНЕЦ) КАК СредняяНаценка,
	ВпТ2.День,
	ВпТ2.Месяц,
	ВпТ2.Квартал,
	ВпТ2.Год
ПОМЕСТИТЬ ИтогВП
ИЗ
	ВпТ2 КАК ВпТ2

СГРУППИРОВАТЬ ПО
	ВпТ2.Номенклатура,
	ВпТ2.ХарактеристикаНоменклатуры,
	ВпТ2.Организация,
	ВпТ2.День,
	ВпТ2.Месяц,
	ВпТ2.Год,
	ВпТ2.Квартал
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ИтогОстатки.Номенклатура,
	ИтогОстатки.КоличествоКонечныйОстаток,
	ИтогОстатки.ХарактеристикаНоменклатуры,
	ИтогОстатки.СтоимостьКонечныйОстаток,
	ИтогОстатки.Организация,
	ИтогОстатки.День,
	ИтогОстатки.МЕСЯЦ,
	ИтогОстатки.КВАРТАЛ,
	ИтогОстатки.ГОД,
	0 КАК СтоимостьПродажи,
	0 КАК СебестоимостьПродажи,
	0 КАК КоличествоПродажи,
	0 КАК ВаловаяПрибыль,
	0 КАК СредняяНаценка
ПОМЕСТИТЬ ПОдИтогГЛавный
ИЗ
	ИтогОстатки КАК ИтогОстатки

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	ИтогВП.Номенклатура,
	0,
	ИтогВП.ХарактеристикаНоменклатуры,
	0,
	ИтогВП.Организация,
	ИтогВП.День,
	ИтогВП.Месяц,
	ИтогВП.Квартал,
	ИтогВП.Год,
	ИтогВП.СтоимостьПродажи,
	ИтогВП.СебестоимостьПродажи,
	ИтогВП.КоличествоПродажи,
	ИтогВП.ВаловаяПрибыль,
	ИтогВП.СредняяНаценка
ИЗ
	ИтогВП КАК ИтогВП
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ПОдИтогГЛавный.Номенклатура КАК Номенклатура,
	СУММА(ПОдИтогГЛавный.КоличествоКонечныйОстаток) КАК КоличествоКонечныйОстаток,
	ПОдИтогГЛавный.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,
	СУММА(ПОдИтогГЛавный.СтоимостьКонечныйОстаток) КАК СтоимостьКонечныйОстаток,
	ПОдИтогГЛавный.Организация КАК Организация,
	ПОдИтогГЛавный.День КАК День,
	ПОдИтогГЛавный.МЕСЯЦ КАК МЕСЯЦ,
	ПОдИтогГЛавный.КВАРТАЛ КАК КВАРТАЛ,
	ПОдИтогГЛавный.ГОД КАК ГОД,
	СУММА(ПОдИтогГЛавный.СтоимостьПродажи) КАК СтоимостьПродажи,
	СУММА(ПОдИтогГЛавный.СебестоимостьПродажи) КАК СебестоимостьПродажи,
	СУММА(ПОдИтогГЛавный.КоличествоПродажи) КАК КоличествоПродажи,
	СУММА(ПОдИтогГЛавный.ВаловаяПрибыль) КАК ВаловаяПрибыль,
	СУММА(ПОдИтогГЛавный.СредняяНаценка) КАК СредняяНаценка
{ВЫБРАТЬ
	Номенклатура.*,
	КоличествоКонечныйОстаток,
	ХарактеристикаНоменклатуры.*,
	СтоимостьКонечныйОстаток,
	Организация.*,
	День,
	МЕСЯЦ,
	КВАРТАЛ,
	ГОД,
	СтоимостьПродажи,
	СебестоимостьПродажи,
	КоличествоПродажи,
	ВаловаяПрибыль,
	СредняяНаценка}
ИЗ
	ПОдИтогГЛавный КАК ПОдИтогГЛавный

СГРУППИРОВАТЬ ПО
	ПОдИтогГЛавный.Номенклатура,
	ПОдИтогГЛавный.КВАРТАЛ,
	ПОдИтогГЛавный.День,
	ПОдИтогГЛавный.ГОД,
	ПОдИтогГЛавный.ХарактеристикаНоменклатуры,
	ПОдИтогГЛавный.МЕСЯЦ,
	ПОдИтогГЛавный.Организация

Сумма(ВычислитьВыражениеСГруппировкойМассив("Среднее(КоличествоКонечныйОстаток)","Организация, номенклатура, ХарактеристикаНоменклатуры"))