Добавление записи в непериодический независимый регистр сведений

Форум Программирование Общие вопросы программирования (Dev)

Платформа 1С v8.3

1. Olga_NN 20.10.16 09:52 Сейчас в теме

Конфигурация 1С:ЗУП 3.0. В регистре есть одна запись: ФИО = "Иванов Иван", НомерПоПорядку = 1
ФИО и НомерПоПорядку - это измерения регистра сведений НаградыФизическихЛиц.
Программно добавляю еще одну запись:

&НаСервере
Процедура ЗагрузитьНаградыФизЛиц_НаСервере();
        Сотрудник = Справочники.ФизическиеЛица.НайтиПоКоду("0000004372");
	МенеджерЗаписи = РегистрыСведений.НаградыФизическихЛиц.СоздатьМенеджерЗаписи();
	МенеджерЗаписи.ФизическоеЛицо = Сотрудник;
	МенеджерЗаписи.НомерПоПорядку = 2;
	МенеджерЗаписи.Награда = Справочники.Награды.НайтиПоНаименованию("Грамота");
	МенеджерЗаписи.Записать();
КонецПроцедуры;

Показать

Пишет ошибку:
Ошибка при вызове метода контекста (Записать)
МенеджерЗаписи.Записать();
по причине:
Запись не верна! Значение поля не соответствует установленному отбору: НаградыФизическихЛиц: Иванов Иван Иванович, 1 (Регистр сведений: Награды; Поле: НомерПоПорядку)

Какой бы я номер не присваивала, ВСЕГДА воспринимает 1. Что я не так делаю?
Спасибо!!!

По теме из базы знаний

Ответы

Подписаться на ответы Инфостарт бот

Свернуть все

2. Olga_NN 20.10.16 10:10 Сейчас в теме

После присвоения МенеджерЗаписи.НомерПоПорядку = 2. Это проверено!

Но в момент выполнения МенеджерЗаписи.Записать() МенеджерЗаписи.НомерПоПорядку = 1

3. Xatori111 18 20.10.16 10:23 Сейчас в теме

Правильно говорит, Попробуйте примерно так:

ТекДата = ТекущаяДата();
	Исполнитель = ПараметрыСеанса.ТекущийПользователь;
	НаборЗаписей = РегистрыСведений.БП_КомментарииКЗаявкам.СоздатьНаборЗаписей();
	
	НаборЗаписей.Отбор.Дата.Значение  = ТекДата;
	НаборЗаписей.Отбор.Дата.Использование = Истина;
	НаборЗаписей.Отбор._Объект.Значение  = Ссылка;
	НаборЗаписей.Отбор._Объект.Использование = Истина;
	НаборЗаписей.Отбор.Исполнитель.Значение =  Исполнитель;
	НаборЗаписей.Отбор.Исполнитель.Использование = Истина;
	
	НоваяЗапись = НаборЗаписей.Добавить();
	НоваяЗапись._Объект = Ссылка; 
	НоваяЗапись.Дата = ТекДата; 
	НоваяЗапись.Исполнитель = Исполнитель; 
	НоваяЗапись.Комментарий = Комментарий; 
	НоваяЗапись.БП_ТипКомментария = Перечисления.БП_ТипыКомментариев.Комментарий;
	НаборЗаписей.Записать(Истина);

Показать

5. Olga_NN 20.10.16 10:46 Сейчас в теме

(3) Xatori111,
Предлагаете так?

Сотрудник = Справочники.ФизическиеЛица.НайтиПоКоду("0005001"); 

НаборЗаписей = РегистрыСведений.НаградыФизическихЛиц.СоздатьНаборЗаписей(); 
НаборЗаписей.Отбор.ФизическоеЛицо.Значение = Сотрудник; 
НаборЗаписей.Отбор.ФизическоеЛицо.Использование = Истина; 
НаборЗаписей.Отбор.НомерПоПорядку.Значение = 2; 
НаборЗаписей.Отбор.НомерПоПорядку.Использование = Истина; 

НоваяЗапись = НаборЗаписей.Добавить(); 
НоваяЗапись.ФизическоеЛицо = Сотрудник; 
НоваяЗапись.НомерПоПорядку = 2; 
НаборЗаписей.Записать(Истина);

Показать

И здесь такая же ошибка:
НаборЗаписей.Записать(Истина);
по причине:
Запись не верна! Значение поля не соответствует установленному отбору: НаградыФизическихЛиц: Иванов Иван Иванович, 1 (Регистр сведений: Награды; Поле: НомерПоПорядку)

6. Xatori111 18 20.10.16 10:58 Сейчас в теме

(5) Olga_NN, а какая структура у вашего регистра?

7. Olga_NN 20.10.16 11:05 Сейчас в теме

(6) Xatori111,

Прикрепленные файлы:

8. Xatori111 18 20.10.16 11:15 Сейчас в теме

(7) Olga_NN, а после установки отборов если Прочитать набор записей там есть что то?

4. Olga_NN 20.10.16 10:46 Сейчас в теме

Предлагаете так?

Сотрудник = Справочники.ФизическиеЛица.НайтиПоКоду("0005001");
  
        НаборЗаписей = РегистрыСведений.НаградыФизическихЛиц.СоздатьНаборЗаписей(); 
	НаборЗаписей.Отбор.ФизическоеЛицо.Значение = Сотрудник; 
	НаборЗаписей.Отбор.ФизическоеЛицо.Использование = Истина; 
	НаборЗаписей.Отбор.НомерПоПорядку.Значение = 2; 
	НаборЗаписей.Отбор.НомерПоПорядку.Использование = Истина; 
	
	НоваяЗапись = НаборЗаписей.Добавить(); 
	НоваяЗапись.ФизическоеЛицо = Сотрудник; 
	НоваяЗапись.НомерПоПорядку = 2; 
	НаборЗаписей.Записать(Истина);

Показать

9. herfis 515 20.10.16 11:29 Сейчас в теме

Проверьте модуль этого регистра и подписки на него.
Где-то еще какое-то шаманство зашито.
Вполне возможно, что ожидается запись в этот регистр через какой-то программный интерфейс и "напрямую" в него лазить не след.

10. Olga_NN 20.10.16 11:40 Сейчас в теме

Проблема решена! Всем спасибо! Необходимо было убрать галочку из ПодпискиНаСобытие.ПроверитьЗаписиДанныхФизическихЛиц

11. ig7777 18.04.17 16:04 Сейчас в теме

(10)

ПроверитьЗаписиДанныхФизическихЛиц

или НаборЗаписей.ОбменДанными.Загрузка = Истина;

13. mnb-next 15 31.10.18 16:26 Сейчас в теме

(10)Спасибо, Ольга! Столкнулась с этой же проблемой - мучилась пол-дня, пока не нашла Ваш совет!

15. Jokemas 193 17.01.19 14:03 Сейчас в теме

(10) Зря, достаточно посмотреть, как работает типовой механизм. Всего-то нужно для набора данных включить доп.свойства.
К примеру в ЗУП 3.1 это будет выглядеть так:

НаборЗаписей.ДополнительныеСвойства.Вставить("НеПроверятьЗаписиДанныхФизическихЛиц");
НаборЗаписей.Записать(Ложь);

После чего этой ошибки быть уже не должно.

20. ЛИК1111 11.07.24 08:36 Сейчас в теме

(15) Спасибо! и в 2024 это актуально :)

12. Kirk157 27.02.18 10:43 Сейчас в теме

Столкнулся с такой же проблемой, действительно помогло убрать РС из ПодпискиНаСобытие

14. user633533_encantado 12 31.10.18 16:30 Сейчас в теме

Пример из шаблонов к учебнику:
3.87. Добавление записи в непериодический независимый регистр сведений

НаборЗаписей = РегистрыСведений.ЗначенияСвойств.СоздатьНаборЗаписей();
	
НаборЗаписей.Отбор.Номенклатура.Установить(ТекущаяНоменклатура);
НаборЗаписей.Отбор.Свойство.Установить(ТекущееСвойство);
	
НоваяЗапись = НаборЗаписей.Добавить();

НоваяЗапись.Номенклатура = ТекущаяНоменклатура;
НоваяЗапись.Свойство 	 = ТекущееСвойство;
НоваяЗапись.Значение 	 = ТекущееЗначение;

НаборЗаписей.Записать();

Показать

16. natik1 16.11.20 14:23 Сейчас в теме

Спасибо, тоже пол дня мучалась, пока нашла эту статью.Помогло:
НаборЗаписей.ДополнительныеСвойства.Вставить("НеПроверятьЗаписиДанныхФизическихЛиц");
НаборЗаписей.Записать(Ложь);

19. jobkostya1c_ERP 101 11.01.22 10:10 Сейчас в теме

(16)

ня мучалась, пока нашла эту статью.Помогло:
НаборЗаписей.Дополнительны

и Записать(ложь) чтоб гарантировано не затереть новые данные.

17. nikserg 15.04.21 19:09 Сейчас в теме

Всем большое спасибо, кто указал на доп/свойства.
Не всегда удается все учебники пробежать, а тем более запомнить.

18. jobkostya1c_ERP 101 10.01.22 16:11 Сейчас в теме

Да, большое спасибо. Пол-дня тоже с ЗУП 3.1 потратил, а структура не изменилась за 5 лет.
Лучше явно доп. свойство ставить "НеПроверятьЗаписиДанныхФизическихЛиц"

Оставьте свое сообщение

E-mail: