Различаются результаты запроса и отчета в СКД

1. olegmedvedev 65 06.09.16 17:03 Сейчас в теме
Добрый день!
Подскажите, пожалуйста в чем проблема:
Когда выполняю запрос - получаю одни данные (правильные).
Но если этот же запрос исполняется в СКД - то результаты получаются неверные.
На рисунке 01 - запрос верные результаты
На рисунке 02 - скд неверные результаты
Отчет в прикрепленных
ВЫБРАТЬ
	ХозрасчетныйОстатки.Субконто1 КАК Контрагент,
	ХозрасчетныйОстатки.Субконто2 КАК Договор,
	СУММА(ХозрасчетныйОстатки.СуммаОстаток) КАК НачальныйОстаток,
	NULL КАК Регистратор,
	NULL КАК Приход,
	NULL КАК Расход,
	NULL КАК КонечныйОстаток,
	NULL КАК КорректировкаДТ,
	NULL КАК КорректировкаКТ,
	NULL КАК Оплата,
	NULL КАК Реализации,
	NULL КАК ПриходДваМесяца,
	NULL КАК РасходДваМесяца
ПОМЕСТИТЬ ОстаткиИОбороты
ИЗ
	РегистрБухгалтерии.Хозрасчетный.Остатки(&ДатаНач, Счет = &Счет6201, , ) КАК ХозрасчетныйОстатки

СГРУППИРОВАТЬ ПО
	ХозрасчетныйОстатки.Субконто1,
	ХозрасчетныйОстатки.Субконто2

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	ХозрасчетныйОбороты.Субконто1,
	ХозрасчетныйОбороты.Субконто2,
	NULL,
	ХозрасчетныйОбороты.Регистратор,
	ХозрасчетныйОбороты.СуммаОборотДт,
	ХозрасчетныйОбороты.СуммаОборотКт,
	NULL,
	ВЫБОР
		КОГДА ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.КорректировкаДолга)
				ИЛИ ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.КорректировкаРеализации)
			ТОГДА ХозрасчетныйОбороты.СуммаОборотДт
		ИНАЧЕ 0
	КОНЕЦ,
	ВЫБОР
		КОГДА ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.КорректировкаДолга)
				ИЛИ ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.КорректировкаРеализации)
			ТОГДА ХозрасчетныйОбороты.СуммаОборотКт
		ИНАЧЕ 0
	КОНЕЦ,
	ВЫБОР
		КОГДА ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.ПриходныйКассовыйОрдер)
				ИЛИ ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.РасходныйКассовыйОрдер)
				ИЛИ ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.СписаниеСРасчетногоСчета)
				ИЛИ ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.ПоступлениеНаРасчетныйСчет)
			ТОГДА ХозрасчетныйОбороты.СуммаОборотКт
		ИНАЧЕ 0
	КОНЕЦ,
	ВЫБОР
		КОГДА ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.РеализацияТоваровУслуг)
			ТОГДА ХозрасчетныйОбороты.СуммаОборотДт
		ИНАЧЕ 0
	КОНЕЦ,
	NULL,
	NULL
ИЗ
	РегистрБухгалтерии.Хозрасчетный.Обороты(&ДатаНач, &ДатаКон, Регистратор, Счет = &Счет6201, , , , ) КАК ХозрасчетныйОбороты

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	ХозрасчетныйОстатки.Субконто1,
	ХозрасчетныйОстатки.Субконто2,
	NULL,
	NULL,
	NULL,
	NULL,
	СУММА(ХозрасчетныйОстатки.СуммаОстаток),
	NULL,
	NULL,
	NULL,
	NULL,
	NULL,
	NULL
ИЗ
	РегистрБухгалтерии.Хозрасчетный.Остатки(ДОБАВИТЬКДАТЕ(&ДатаКон, СЕКУНДА, 1), Счет = &Счет6201, , ) КАК ХозрасчетныйОстатки

СГРУППИРОВАТЬ ПО
	ХозрасчетныйОстатки.Субконто1,
	ХозрасчетныйОстатки.Субконто2

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	ХозрасчетныйОбороты.Субконто1,
	ХозрасчетныйОбороты.Субконто2,
	NULL,
	NULL,
	NULL,
	NULL,
	NULL,
	NULL,
	NULL,
	NULL,
	NULL,
	ХозрасчетныйОбороты.СуммаОборотДт,
	ХозрасчетныйОбороты.СуммаОборотКт
ИЗ
	РегистрБухгалтерии.Хозрасчетный.Обороты(ДОБАВИТЬКДАТЕ(&ДатаКон, МЕСЯЦ, -2), &ДатаКон, , Счет = &Счет6201, , , , ) КАК ХозрасчетныйОбороты
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ОстаткиИОбороты.Контрагент КАК Контрагент,
	ОстаткиИОбороты.Договор КАК Договор,
	СУММА(ОстаткиИОбороты.НачальныйОстаток) КАК НачальныйОстаток,
	ОстаткиИОбороты.Регистратор КАК Регистратор,
	СУММА(ОстаткиИОбороты.Приход) КАК Приход,
	СУММА(ОстаткиИОбороты.Расход) КАК Расход,
	СУММА(ОстаткиИОбороты.Реализации) КАК Реализации,
	СУММА(ОстаткиИОбороты.Оплата) КАК Оплата,
	СУММА(ОстаткиИОбороты.КорректировкаДТ) КАК КорректировкаДТ,
	СУММА(ОстаткиИОбороты.КорректировкаКТ) КАК КорректировкаКТ,
	СУММА(ОстаткиИОбороты.КонечныйОстаток) КАК КонечныйОстаток,
	РАЗНОСТЬДАТ(НАЧАЛОПЕРИОДА(&ДатаНач, ДЕНЬ), ДОБАВИТЬКДАТЕ(КОНЕЦПЕРИОДА(&ДатаКон, ДЕНЬ), СЕКУНДА, 1), ДЕНЬ) КАК КоличествоДней,
	СУММА(ОстаткиИОбороты.ПриходДваМесяца) КАК ПриходДваМесяца,
	СУММА(ОстаткиИОбороты.РасходДваМесяца) КАК РасходДваМесяца
ИЗ
	ОстаткиИОбороты КАК ОстаткиИОбороты

СГРУППИРОВАТЬ ПО
	ОстаткиИОбороты.Договор,
	ОстаткиИОбороты.Регистратор,
	ОстаткиИОбороты.Контрагент

УПОРЯДОЧИТЬ ПО
	Контрагент,
	Договор,
	Регистратор
Показать
Прикрепленные файлы:
1723_3_ОтчетПоЗадолженностиАбонентовСКоэффициентомИПериодомОборачиваемости.erf
По теме из базы знаний
Вознаграждение за ответ
Показать полностью
Найденные решения
11. bmk74 234 07.09.16 11:34 Сейчас в теме
Во первых первый запрос сделайте вложенным,

ВЫБРАТЬ * ПОМЕСТИТЬ ОстаткиИОбороты  ИЗ
 (ВЫБРАТЬ
    ХозрасчетныйОстатки.Субконто1 КАК Контрагент,
    ХозрасчетныйОстатки.Субконто2 КАК Договор,
    СУММА(ХозрасчетныйОстатки.СуммаОстаток) КАК НачальныйОстаток,
    NULL КАК Регистратор,
    NULL КАК Приход,
    NULL КАК Расход,
    NULL КАК КонечныйОстаток,
    NULL КАК КорректировкаДТ,
    NULL КАК КорректировкаКТ,
    NULL КАК Оплата,
    NULL КАК Реализации,
    NULL КАК ПриходДваМесяца,
    NULL КАК РасходДваМесяца

ИЗ
    РегистрБухгалтерии.Хозрасчетный.Остатки({(&ДатаНач)}, Счет = &Счет6201, , ) КАК ХозрасчетныйОстатки

СГРУППИРОВАТЬ ПО
    ХозрасчетныйОстатки.Субконто1,
    ХозрасчетныйОстатки.Субконто2

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
    ХозрасчетныйОбороты.Субконто1,
    ХозрасчетныйОбороты.Субконто2,
    NULL,
    ХозрасчетныйОбороты.Регистратор,
    ХозрасчетныйОбороты.СуммаОборотДт,
    ХозрасчетныйОбороты.СуммаОборотКт,
    NULL,
    ВЫБОР
        КОГДА ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.КорректировкаДолга)
                ИЛИ ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.КорректировкаРеализации)
            ТОГДА ХозрасчетныйОбороты.СуммаОборотДт
        ИНАЧЕ 0
    КОНЕЦ,
    ВЫБОР
        КОГДА ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.КорректировкаДолга)
                ИЛИ ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.КорректировкаРеализации)
            ТОГДА ХозрасчетныйОбороты.СуммаОборотКт
        ИНАЧЕ 0
    КОНЕЦ,
    ВЫБОР
        КОГДА ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.ПриходныйКассовыйОрдер)
                ИЛИ ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.РасходныйКассовыйОрдер)
                ИЛИ ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.СписаниеСРасчетногоСчета)
                ИЛИ ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.ПоступлениеНаРасчетныйСчет)
            ТОГДА ХозрасчетныйОбороты.СуммаОборотКт
        ИНАЧЕ 0
    КОНЕЦ,
    ВЫБОР
        КОГДА ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.РеализацияТоваровУслуг)
            ТОГДА ХозрасчетныйОбороты.СуммаОборотДт
        ИНАЧЕ 0
    КОНЕЦ,
    NULL,
    NULL
ИЗ
    РегистрБухгалтерии.Хозрасчетный.Обороты({(&ДатаНач)}, {(&ДатаКон)}, Регистратор, Счет = &Счет6201, , , , ) КАК ХозрасчетныйОбороты

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
    ХозрасчетныйОстатки.Субконто1,
    ХозрасчетныйОстатки.Субконто2,
    NULL,
    NULL,
    NULL,
    NULL,
    СУММА(ХозрасчетныйОстатки.СуммаОстаток),
    NULL,
    NULL,
    NULL,
    NULL,
    NULL,
    NULL
ИЗ
    РегистрБухгалтерии.Хозрасчетный.Остатки({(ДОБАВИТЬКДАТЕ(&ДатаКон, СЕКУНДА, 1))}, Счет = &Счет6201, , ) КАК ХозрасчетныйОстатки

СГРУППИРОВАТЬ ПО
    ХозрасчетныйОстатки.Субконто1,
    ХозрасчетныйОстатки.Субконто2

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
    ХозрасчетныйОбороты.Субконто1,
    ХозрасчетныйОбороты.Субконто2,
    NULL,
    NULL,
    NULL,
    NULL,
    NULL,
    NULL,
    NULL,
    NULL,
    NULL,
    ХозрасчетныйОбороты.СуммаОборотДт,
    ХозрасчетныйОбороты.СуммаОборотКт
ИЗ
    РегистрБухгалтерии.Хозрасчетный.Обороты({(&ДатаНачДваМесяц)}, {(&ДатаКон)}, , Счет = &Счет6201, , , , ) КАК ХозрасчетныйОбороты) КАК ВложенныйЗапрос
;

////////////////////////////////////////////////////////////­­////////////////////
Показать


иначе СКД может его упростить...такое бывает...и еще раз все даты оформляйте в фигуhных скобках как то так
{(ДОБАВИТЬКДАТЕ(&ДатаНач, МЕСЯЦ, -1))} если даты используются в выборке остатков или оборотов регистра т.е.
РегистрБухгалтерии.Хозрасчетный.Обороты({(ДОБАВИТЬКДАТЕ(&ДатаНач, МЕСЯЦ, -2))}, {(&ДатаКон)}, , Счет = &Счет6201, , , , ) КАК ХозрасчетныйОбороты
olegmedvedev; +1 Ответить
Остальные ответы
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
2. olegmedvedev 65 06.09.16 17:06 Сейчас в теме
отчет работает в типовой бухгалтерии
3. Anesk 17 07.09.16 08:04 Сейчас в теме
в СКД почему-то не работает выражение ДОБАВИТЬКДАТЕ(&ДатаКон, МЕСЯЦ, -2). Убери эту формулу с запроса, пропиши вычисление в параметрах запроса
olegmedvedev; +1 Ответить
4. olegmedvedev 65 07.09.16 09:08 Сейчас в теме
(3) Anesk, Точно! проверил - не работает! Спасибо за ответ. Сейчас попробую!
5. alex-l19041 8 07.09.16 09:41 Сейчас в теме
(4) olgerd666, а можно уточнить платформу ?
7. olegmedvedev 65 07.09.16 09:57 Сейчас в теме
(5) alex-l19041, 8.2.19.83. Сейчас поставил сделал дополнительный параметр для начала Периода Двамесяца - поставил на вкладку СКД Парметры - все равно пока не работает(
8. alex-l19041 8 07.09.16 10:06 Сейчас в теме
(7) olgerd666, обновите платформу до последней из 8.2.19
10. olegmedvedev 65 07.09.16 10:25 Сейчас в теме
(8) alex-l19041, не помогло
(9) bmk74, В запросе поменял на {&ДатаНачДваМесяц} такой параметр вообще из списка параметров пропал.

Код
9. bmk74 234 07.09.16 10:13 Сейчас в теме
(7) olgerd666, В запросе где у Вас параметр
&ДатаКон
ИЛИ
&ДатаНач
в фигурные скобки обрамите иначе он часто подменяет их своими периодами
{&ДатаНач}
olegmedvedev; +1 Ответить
6. spe1c 5 07.09.16 09:55 Сейчас в теме
Скорее всего ошибка платформы, я такую конструкцию ДОБАВИТЬКДАТЕ(&ДатаКон, МЕСЯЦ, ...) в отчетах на СКД использовал и работало нормально. Еще обратите внимание, в СКД есть свой оптимизатор запроса, который может менять исходный его текст. Из-за этого были случаи, когда при наложении определенных отборов в отчете оптимизатор выкидывал целую таблицу из запроса.
11. bmk74 234 07.09.16 11:34 Сейчас в теме
Во первых первый запрос сделайте вложенным,

ВЫБРАТЬ * ПОМЕСТИТЬ ОстаткиИОбороты  ИЗ
 (ВЫБРАТЬ
    ХозрасчетныйОстатки.Субконто1 КАК Контрагент,
    ХозрасчетныйОстатки.Субконто2 КАК Договор,
    СУММА(ХозрасчетныйОстатки.СуммаОстаток) КАК НачальныйОстаток,
    NULL КАК Регистратор,
    NULL КАК Приход,
    NULL КАК Расход,
    NULL КАК КонечныйОстаток,
    NULL КАК КорректировкаДТ,
    NULL КАК КорректировкаКТ,
    NULL КАК Оплата,
    NULL КАК Реализации,
    NULL КАК ПриходДваМесяца,
    NULL КАК РасходДваМесяца

ИЗ
    РегистрБухгалтерии.Хозрасчетный.Остатки({(&ДатаНач)}, Счет = &Счет6201, , ) КАК ХозрасчетныйОстатки

СГРУППИРОВАТЬ ПО
    ХозрасчетныйОстатки.Субконто1,
    ХозрасчетныйОстатки.Субконто2

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
    ХозрасчетныйОбороты.Субконто1,
    ХозрасчетныйОбороты.Субконто2,
    NULL,
    ХозрасчетныйОбороты.Регистратор,
    ХозрасчетныйОбороты.СуммаОборотДт,
    ХозрасчетныйОбороты.СуммаОборотКт,
    NULL,
    ВЫБОР
        КОГДА ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.КорректировкаДолга)
                ИЛИ ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.КорректировкаРеализации)
            ТОГДА ХозрасчетныйОбороты.СуммаОборотДт
        ИНАЧЕ 0
    КОНЕЦ,
    ВЫБОР
        КОГДА ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.КорректировкаДолга)
                ИЛИ ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.КорректировкаРеализации)
            ТОГДА ХозрасчетныйОбороты.СуммаОборотКт
        ИНАЧЕ 0
    КОНЕЦ,
    ВЫБОР
        КОГДА ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.ПриходныйКассовыйОрдер)
                ИЛИ ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.РасходныйКассовыйОрдер)
                ИЛИ ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.СписаниеСРасчетногоСчета)
                ИЛИ ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.ПоступлениеНаРасчетныйСчет)
            ТОГДА ХозрасчетныйОбороты.СуммаОборотКт
        ИНАЧЕ 0
    КОНЕЦ,
    ВЫБОР
        КОГДА ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) = ТИП(Документ.РеализацияТоваровУслуг)
            ТОГДА ХозрасчетныйОбороты.СуммаОборотДт
        ИНАЧЕ 0
    КОНЕЦ,
    NULL,
    NULL
ИЗ
    РегистрБухгалтерии.Хозрасчетный.Обороты({(&ДатаНач)}, {(&ДатаКон)}, Регистратор, Счет = &Счет6201, , , , ) КАК ХозрасчетныйОбороты

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
    ХозрасчетныйОстатки.Субконто1,
    ХозрасчетныйОстатки.Субконто2,
    NULL,
    NULL,
    NULL,
    NULL,
    СУММА(ХозрасчетныйОстатки.СуммаОстаток),
    NULL,
    NULL,
    NULL,
    NULL,
    NULL,
    NULL
ИЗ
    РегистрБухгалтерии.Хозрасчетный.Остатки({(ДОБАВИТЬКДАТЕ(&ДатаКон, СЕКУНДА, 1))}, Счет = &Счет6201, , ) КАК ХозрасчетныйОстатки

СГРУППИРОВАТЬ ПО
    ХозрасчетныйОстатки.Субконто1,
    ХозрасчетныйОстатки.Субконто2

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
    ХозрасчетныйОбороты.Субконто1,
    ХозрасчетныйОбороты.Субконто2,
    NULL,
    NULL,
    NULL,
    NULL,
    NULL,
    NULL,
    NULL,
    NULL,
    NULL,
    ХозрасчетныйОбороты.СуммаОборотДт,
    ХозрасчетныйОбороты.СуммаОборотКт
ИЗ
    РегистрБухгалтерии.Хозрасчетный.Обороты({(&ДатаНачДваМесяц)}, {(&ДатаКон)}, , Счет = &Счет6201, , , , ) КАК ХозрасчетныйОбороты) КАК ВложенныйЗапрос
;

////////////////////////////////////////////////////////////­­////////////////////
Показать


иначе СКД может его упростить...такое бывает...и еще раз все даты оформляйте в фигуhных скобках как то так
{(ДОБАВИТЬКДАТЕ(&ДатаНач, МЕСЯЦ, -1))} если даты используются в выборке остатков или оборотов регистра т.е.
РегистрБухгалтерии.Хозрасчетный.Обороты({(ДОБАВИТЬКДАТЕ(&ДатаНач, МЕСЯЦ, -2))}, {(&ДатаКон)}, , Счет = &Счет6201, , , , ) КАК ХозрасчетныйОбороты
olegmedvedev; +1 Ответить
12. olegmedvedev 65 07.09.16 11:48 Сейчас в теме
(11) bmk74, Спасибо за ответ! Вопрос такой вставил полностью текст вашего запроса - но в параметрах СКД не отображаются больше ни ДатаНач ни НачалоПериода, Только Счет отображается. что я делаю не так?
13. bmk74 234 07.09.16 12:04 Сейчас в теме
(12) olgerd666 А вот это очень странно...параметры у вас должны отобразиться автоматически...могу только предложить их руками в таком случае добавить...или релиз платформы обновить.
14. olegmedvedev 65 07.09.16 12:29 Сейчас в теме +0.01 $m
(13) bmk74, Все разобрался с кодом вложенного запроса и {} - работает, СКД показывает правильные результаты. Спасибо за решение!
15. user_2010 873 07.09.16 12:34 Сейчас в теме
(11) bmk74, объясните, плз, что значат фигурные скобки? почему с ними СКД выдает правильный резултат, а без них - неправильный?
16. bmk74 234 07.09.16 16:10 Сейчас в теме
(15) user_2010, Вообще фигурные скобки в СКД это необязательный параметр, НО есть одна фишка если допустим мы в запросе выбираем из регистра остатков или оборотов Ну например вы что то пишите и в запросе у вас есть выборка из оборотного регистра
ИЗ
	РегистрНакопления.ТоварыОрганизаций.Обороты(,,) КАК ТоварыОрганизацийОбороты

Здесь скобки поставил сам обычно без них конструктор рисует...
Так вот даже в таком варианте СКД по умолчанию будет строить запрос вот так
РегистрНакопления.ТоварыОрганизаций.Обороты(&НачалоПериода,&КонецПериода,)
И параметры начало период и конец у вас автоматом появятся в параметрах СКД
И вот если не ставить фигурные скобки на своих параметрах СКД любит их заменять на свои НачалоПериода и КонецПериода поэтому тут либо используем то что по умолчанию либо ставить скобки тогда СКД уж точно подставит нужные параметры...

Как то так....
olegmedvedev; +1 Ответить
17. user_2010 873 07.09.16 17:35 Сейчас в теме
Оставьте свое сообщение
Вакансии
1С аналитик
Москва
зарплата от 210 000 руб.
Полный день

Руководитель направления 1С
Москва
зарплата от 350 000 руб.
Полный день

1С Программист
Москва
зарплата от 180 000 руб.
Полный день

Программист 1С
Москва
зарплата от 180 000 руб. до 220 000 руб.
Полный день

Аналитик 1С / Бизнес-аналитик
Нижний Новгород
зарплата от 100 000 руб. до 250 000 руб.
Временный (на проект)