Заполнение табличной части документа (8.3 УФ) через ОткрытиеФормы

Question

Перестала работать обработка ЗТЧ для Бухгалтерии 3.0 (8.3.7). Мне кажется платформа обновилась и что-то пошло не так...

Обработка заполняет остатками ТМЦ табличную часть документа ТребованиеНакладная.

Как известно, ЗТЧ можно сделать двумя способами - через [B]ОткрытиеФормы [/B]или [B]ВызовКлиентскогоМетода[/B].
Мне нужно сделать через ОткрытиеФормы, так как я должен предоставить юзеру возможность на форме задать счета, по которым надо получить остатки.

Только не срабатывает процедура заполнения. 
Хотя запрос на получение остатков корректен, проверял в консоли.

Помогите, пожалуйста. Что я сделал не так?

модуль обработки
Код:
[1C-CODE]Функция СведенияОВнешнейОбработке() Экспорт
   
    МассивНазначений = Новый Массив;
    МассивНазначений.Добавить("Документ.ТребованиеНакладная");
   
    ПараметрыРегистрации = Новый Структура;
   
    ПараметрыРегистрации.Вставить("Вид", "ЗаполнениеОбъекта");
    //ПараметрыРегистрации.Вставить("Назначение", ПолучитьНазначениеОбработки());
    ПараметрыРегистрации.Вставить("Назначение", МассивНазначений);
   
    ПараметрыРегистрации.Вставить("Наименование", НСтр("ru = 'Заполнить документ ТребованиеНакладная'"));
    ПараметрыРегистрации.Вставить("Версия", "1.0");
    ПараметрыРегистрации.Вставить("БезопасныйРежим", Истина);
    ПараметрыРегистрации.Вставить("Информация", НСтр("ru = 'Обработка заполнения документа ТребованиеНакладная'"));
   
    ТаблицаКоманд = ПолучитьТаблицуКоманд();
   
    ДобавитьКоманду(ТаблицаКоманд,
                    "Заполнить табличную часть документа ТребованиеНакладная",
                    "ЗаполнитьТЧТребованиеНакладная",
                    "ОткрытиеФормы",
                    Истина
    );
  
    ПараметрыРегистрации.Вставить("Команды", ТаблицаКоманд);
   
    Возврат ПараметрыРегистрации;
   
КонецФункции
[/1C-CODE]
а вот фрагменты кода модуля формы
Код:
[1C-CODE]&НаКлиенте
Процедура ЗаполнитьДокумент()
   
    ОбъектыНазначенияМассив = Параметры.ОбъектыНазначения;
   
    Для каждого ЭлементОбъектовНазначения из ОбъектыНазначенияМассив Цикл

        КлючПоиска = Новый Структура("Ключ", ЭлементОбъектовНазначения);

        Окна = ПолучитьОкна();

        Для каждого Окно из Окна Цикл
            Если НЕ Окно.Основное
                И Найти(Окно.Заголовок, ЭлементОбъектовНазначения) Тогда
                Форма = ОткрытьФорму("Документ.ТребованиеНакладная.Форма.ФормаДокумента",КлючПоиска,,,Окно);
                НовыйОбъект = Форма.Объект;
                ЗаполнитьДокументНаСервере(НовыйОбъект);
                КопироватьДанныеФормы(НовыйОбъект, Форма.Объект);
            КонецЕсли;
        КонецЦикла;
           
        ЭтаФорма.Закрыть();
    КонецЦикла;


КонецПроцедуры[/1C-CODE]

[1C-CODE]&НаСервере
Процедура ЗаполнитьДокументНаСервере(НовыйОбъект) Экспорт
   
    Если НЕ ЗначениеЗаполнено(НовыйОбъект.Склад) Тогда
        ОбщегоНазначенияКлиентСервер.СообщитьПользователю("Укажите склад!");
        Возврат;
    КонецЕсли;
   
    МассивСчетов = ПолучитьФильтрСчетов();
   
    Запрос = Новый Запрос;
    Запрос.УстановитьПараметр("Склад",                НовыйОбъект.Склад);
    Запрос.УстановитьПараметр("МассивСчетов",        МассивСчетов);
    Запрос.УстановитьПараметр("ДатаОстатков",        НовыйОбъект.Дата);
    Запрос.УстановитьПараметр("Организация",        НовыйОбъект.Организация);
   
    Запрос.Текст = "ВЫБРАТЬ
    |    ХозрасчетныйОстатки.Субконто1 КАК Номенклатура,
    |    ХозрасчетныйОстатки.Счет КАК Счет,
    |    ХозрасчетныйОстатки.КоличествоОстаток КАК Количество
    |ИЗ
    |    РегистрБухгалтерии.Хозрасчетный.Остатки(&ДатаОстатков, Счет В ИЕРАРХИИ (&МассивСчетов), ,Организация=&Организация) КАК ХозрасчетныйОстатки
    |ГДЕ 
    |    ХозрасчетныйОстатки.Субконто3 = &Склад
    |АВТОУПОРЯДОЧИВАНИЕ";
   
   
    РезультатЗапроса = Запрос.Выполнить();
    Если не РезультатЗапроса.Пустой() Тогда
       
        Выборка = РезультатЗапроса.Выбрать();
        НовыйОбъект.Материалы.Очистить();
        Пока Выборка.Следующий() Цикл
           
            СтрокаТабличнойЧасти = НовыйОбъект.Материалы.Добавить();
           
            СтрокаТабличнойЧасти.Номенклатура   = Выборка.Номенклатура;
            СтрокаТабличнойЧасти.Количество    = Выборка.Количество;
            СтрокаТабличнойЧасти.Счет            = Выборка.Счет;
                       
        КонецЦикла;
    иначе
        ОбщегоНазначенияКлиентСервер.СообщитьПользователю("Запрос остатков вернул пустой результат!");
    КонецЕсли;
   
КонецПроцедуры
[/1C-CODE]

Accepted Answer

(9) El_Loco, Насколько я понимаю, основное и активное окно это разные вещи.
Я использую другой синтаксис. Работает вполне корректно.
Смысл в том, что активное окно находим как форму объекта, ссылку которого нам передали.

[CODE]&НаКлиенте
Процедура ВыполнитьКоманду(ИдентификаторКоманды, ОбъектыНазначения) Экспорт
       Для каждого ОбъектНазначение из ОбъектыНазначения Цикл
            ПараметрыФормы = Новый Структура("Ключ", ОбъектНазначение); //это передали в форму заполнения
            Форма = ПолучитьФорму("Документ.ПриходныйОрдерНаТовары.ФормаОбъекта",ПараметрыФормы); //окна не ищем, переполучаем уже открытое
			
            КопироватьДанныеФормы(Форма.Объект,ЭтотОбъект.ОбъектПриходныйОрдерНаТовары);
			
            НашаОбработкаНаСервере();

            КопироватьДанныеФормы(ЭтотОбъект.ОбъектПриходныйОрдерНаТовары,Форма.Объект);
			
	КонецЦикла;
КонецПроцедуры	
[/CODE]