Расшифровку в СКД

Форум Программирование Общие вопросы программирования (Dev)

Платформа 1С v8.3

1. jsuh 28 20.11.15 14:40 Сейчас в теме

Всем привет. Помогите придумать как сделать)))
Нужно сделать отчет на СКД по активности, т.е. в отчет должны попасть
только те партнеры по которым не было продаж. При этом при расшифровки,
нужно чтоб выводились все реализации по этому клиенту за все время.

Есть ли мысли как это реализовать?

По теме из базы знаний

Ответы

Подписаться на ответы Инфостарт бот

Свернуть все

2. antz 20.11.15 14:55 Сейчас в теме

(1) jsuh, да, сделать свою форму для отчета и ловить обработку расшифровки.

4. superkuzja 3 20.11.15 16:49 Сейчас в теме

(1) jsuh, реализовать не сложно. Необходимо создать форму отчета. У табличного документа на форме добавить обработчики событий ОбработкаРасшифровки и/или ОбработкаДополнительнойРасшифровки. У меня, например, было так

&НаКлиенте
Процедура ОбработкаРасшифровкиДляПоляКредитныйДоговор(Элемент, Расшифровка, СтандартнаяОбработка)
	
	Перем ВыбранноеДействие;
	Перем ПараметрыВыбранногоДействия;
	
	ОписаниеОбработкиРасшифровки = Новый ОписаниеОбработкиРасшифровкиКомпоновкиДанных(ДанныеРасшифровки, Расшифровка, Отчет.КомпоновщикНастроек.Настройки);
	ЗначениеРасшифровки = ПолучитьЗначениеРасшифровки(ОписаниеОбработкиРасшифровки);
	
	Если ТипЗнч(ЗначениеРасшифровки) = Тип("ДокументСсылка.ДоговорНаКредит") Тогда									
		
		СтандартнаяОбработка = Ложь;
		ОбработкаРасшифровки = Новый ОбработкаРасшифровкиКомпоновкиДанных(ДанныеРасшифровки,
											Новый ИсточникДоступныхНастроекКомпоновкиДанных(Отчет));
		ДоступныеДействия = Новый Массив();
		ДоступныеДействия.Добавить(ДействиеОбработкиРасшифровкиКомпоновкиДанных.ОткрытьЗначение);
		
		ДополнительныеДействия = Новый СписокЗначений;
		ДополнительныеДействия.Добавить("ПогашениеНаРасчетныйСчет",   "Сформировать погашение на расчетный счет");
		ДополнительныеДействия.Добавить("СписокВозвратовКонтрагента", "Открыть список возвратов по контрагенту");
		
		ОбработкаРасшифровки.ВыбратьДействие(Расшифровка, ВыбранноеДействие, ПараметрыВыбранногоДействия,
												ДоступныеДействия, ДополнительныеДействия);
												
		Если ПараметрыВыбранногоДействия <> Неопределено Тогда
			
			Если ВыбранноеДействие = ДействиеОбработкиРасшифровкиКомпоновкиДанных.ОткрытьЗначение Тогда
				ОткрытьЗначение(ПараметрыВыбранногоДействия);
			КонецЕсли;
			
		Иначе 
			
			Если ВыбранноеДействие = "ПогашениеНаРасчетныйСчет" Тогда
				СформироватьПогашениеНаРасчетныйСчет(ОписаниеОбработкиРасшифровки);
				
			ИначеЕсли ВыбранноеДействие = "СписокВозвратовКонтрагента" Тогда
				ОткрытьСписокВозвратовПоКлиенту(ОписаниеОбработкиРасшифровки);
				
			КонецЕсли;
			
		КонецЕсли;										
	КонецЕсли;	
	
КонецПроцедуры // ОбработкаРасшифровкиДляПоляКредитныйДоговор() 

&НаКлиенте
Процедура РезультатОбработкаДополнительнойРасшифровки(Элемент, Расшифровка, СтандартнаяОбработка)
	
	ОбработкаРасшифровкиДляПоляКредитныйДоговор(Элемент, Расшифровка, СтандартнаяОбработка);	
	
КонецПроцедуры // РезультатОбработкаДополнительнойРасшифровки()

&НаКлиенте
Процедура РезультатОбработкаРасшифровки(Элемент, Расшифровка, СтандартнаяОбработка)

	ОбработкаРасшифровкиДляПоляКредитныйДоговор(Элемент, Расшифровка, СтандартнаяОбработка);
	
КонецПроцедуры // РезультатОбработкаРасшифровки()

Показать

5. superkuzja 3 20.11.15 16:53 Сейчас в теме

(4) В этом случае остался один стандартный пункт выподающего меню "Открыть значение" и добавлены два дополнительных: "Сформировать погашение на расчетный счет" и "Открыть список возвратов по контрагенту". Обработчики добавленых действий описываешь в отдельных процедурах. Вот и всё.

3. Chameleon1980 20.11.15 15:16 Сейчас в теме

Е.Ю. Хрусталева - разработка сложных отчетов

6. jsuh 28 22.11.15 22:30 Сейчас в теме

Всем спасибо)))) Разобрался!!!

Оставьте свое сообщение

E-mail: