Открытие форм нескольких новых документов в тонком и толстом клиенте, УФ

29.09.15

Разработка - Работа с интерфейсом

Если Вам необходимо создать несколько документов, а затем открыть их формы для пользователя.

Читая этот ресурс и безудержно юзая Гугл, мне так и не удалось найти информацию о том, как выполнить следующую задачу.

Итак:

Необходимо программно сформировать несколько документов Поступления товаров и показать пользователю формы этих документов. Формироваться эти документы должны на сервере, количество их неизвестно и зависит от текущего состояния информационной базы (к примеру, от остатков на складах).
Конфигурация - типовая УТ 11. Править ее крайне нежелательно.
Работают пользователи в клиент-серверном режиме, используют тонкий и толстый клиенты...

Как создать один новый документ и открыть его форму написано тут или тут.

Однако мне надо было несколько документов.

Вариант решения такой. Для толстого клиента все более/менее ясно:

1. На сервере создаем массив новых объектов типа документ "ПоступлениеТоваровУслуг" с разным заполнением.

2. На клиенте обходим этот массив в цикле, попутно создавая новые формы документов и заполняя их значениями тех объектов, что были созданы ранее.

 

&НаСервере
Функция ПолучитьМассивНовыхДокументовНаСервере()
	
    // Создадим массив из нескольких документов 
    // с разным наполнением (для примера - разные организации)
    // для того, чтобы при открытии форм было сразу понятно, что 
    // это два разных документа
	
    МассивНовыхДокументов = Новый Массив;
    
    НовДок = Документы.ПоступлениеТоваровУслуг.СоздатьДокумент();
    НовДок.Организация = Справочники.Организации.НайтиПоНаименованию("Компания 1");
    
    МассивНовыхДокументов.Добавить(НовДок);
    
    
    НовДок = Документы.ПоступлениеТоваровУслуг.СоздатьДокумент();
    НовДок.Организация = Справочники.Организации.НайтиПоНаименованию("Компания 2");
    
    МассивНовыхДокументов.Добавить(НовДок);
    
    Возврат МассивНовыхДокументов;

КонецФункции

&НаСервере
Функция ЗаполнитьДанныеФормыНаСервере(ДанныеФормыДокумента, НовыйДокументОбъект)
	
    // Здесь происходит непосредственное заполнение
    // Объекта из данных формы документа
    // тем документом, который был создан
    // в процедуре ПолучитьМассивДокументовНаСервере() 
	
    мОбъект = ДанныеФормыВЗначение(ДанныеФормыДокумента, ТипЗнч(НовыйДокументОбъект));
    ЗаполнитьЗначенияСвойств(мОбъект, НовыйДокументОбъект);
    ЗначениеВДанныеФормы(мОбъект, ДанныеФормыДокумента);
    
КонецФункции

&НаКлиенте
Процедура кнОткрытьФормыНовыхДокументов(Команда)
	
    // Кнопка на клиенте (на форме обработки) 
    // из которой необходимо создать 
    // и заполнить несколько новых документов.
    // Количество создаваемых объектов определяется в
    // процедуре ПолучитьМассивДокументовНаСервере()
    
    // 1. На сервере создаем массив новых объектов типа документ "ПоступлениеТоваровУслуг" с разным заполнением.
    МассивНовыхДокументов = ПолучитьМассивНовыхДокументовНаСервере();
    // 2. На клиенте обходим этот массив в цикле, попутно создавая новые формы документов и заполняя их значениями тех объектов, что были созданы ранее.
    Для Каждого НовыйДокументОбъект Из МассивНовыхДокументов Цикл
        
        ФормаДокумента = ПолучитьФорму("Документ.ПоступлениеТоваровУслуг.ФормаОбъекта",,,Истина);
        ДанныеФормыДокумента = ФормаДокумента.Объект;
        
        ЗаполнитьДанныеФормыНаСервере(ДанныеФормыДокумента, НовыйДокументОбъект);
        
        КопироватьДанныеФормы(ДанныеФормыДокумента, ФормаДокумента.Объект);
        
        ФормаДокумента.Открыть();
        
    КонецЦикла;
    
КонецПроцедуры

 

Для тонкого клиента все сложнее. В тонком клиенте 1С начинает ругаться: "Ошибка передачи данных между клиентом и сервером. Значение недопустимого типа". Это в момент передачи массива новых документов с сервера на клиент.

Как пришлось выкручиваться:

1. Точно также создаем массив новых документов.

2. Помещаем этот массив во временное хранилище. На клиент передаем только адрес этого хранилища.

3. На клиенте создаем цикл из такого количества итераций, сколько элементов есть в массиве.

4. В цикле создаем формы новых документов, при этом заполняя их данными из созданного массива документов. А к массиву обращаемся через адрес хранилища.

&НаСервере
Функция ПолучитьМассивНовыхДокументовНаСервере()
	
    // Создадим массив из нескольких документов 
    // с разным наполнением (для примера - разные организации)
    // для того, чтобы при открытии форм было сразу понятно, что 
    // это два разных документа
	
    МассивНовыхДокументов = Новый Массив;
    
    НовДок = Документы.ПоступлениеТоваровУслуг.СоздатьДокумент();
    НовДок.Организация = Справочники.Организации.НайтиПоНаименованию("Компания 1");
    
    МассивНовыхДокументов.Добавить(НовДок);
    
    
    НовДок = Документы.ПоступлениеТоваровУслуг.СоздатьДокумент();
    НовДок.Организация = Справочники.Организации.НайтиПоНаименованию("Компания 2");
    
    МассивНовыхДокументов.Добавить(НовДок);
    
    Возврат МассивНовыхДокументов;

КонецФункции

&НаСервере
Функция ПолучитьАдресМассиваНовыхДокументовНаСервере()
	
    // Поместим массив с документами во временное хранилище
    // для того, чтобы иметь возможность обращаться к нему
    // со стороны клиента (передавая на сервер адрес хранилища)
	
    МассивНовыхДокументов = ПолучитьМассивНовыхДокументовНаСервере();
    
    // 2. Помещаем этот массив во временное хранилище. На клиент возвращаем только адрес этого хранилища.
    АдресМассиваНовыхДокументов = ПоместитьВоВременноеХранилище(МассивНовыхДокументов, Новый УникальныйИдентификатор);
    
    Возврат АдресМассиваНовыхДокументов;
        
КонецФункции

&НаСервере
Функция ЗаполнитьДанныеФормыТонкийКлиентНаСервере(ДанныеФормыДокумента, НомерОбъекта, АдресМассиваНовыхДокументов)
    
    // Здесь происходит непосредственное заполнение
    // Объекта из данных формы документа
    // тем документом, который был создан
    // в процедуре ПолучитьМассивДокументовНаСервере() 
	
    МассивНовыхДокументов = ПолучитьИзВременногоХранилища(АдресМассиваНовыхДокументов);
    НовыйДокументОбъект = МассивНовыхДокументов[НомерОбъекта];
    ЗаполнитьДанныеФормыНаСервере(ДанныеФормыДокумента, НовыйДокументОбъект);
    
КонецФункции

&НаСервере
Функция ПолучитьКоличествоНовыхДокументов(АдресМассиваНовыхДокументов)
    
    МассивНовыхДокументов = ПолучитьИзВременногоХранилища(АдресМассиваНовыхДокументов);
    
    Возврат МассивНовыхДокументов.Количество();
    
КонецФункции

&НаКлиенте
Процедура кнОткрытьФормыНовыхДокументовТонкийКлиент(Команда)

    // 1. Точно также создаем массив новых документов.
    АдресМассиваНовыхДокументов = ПолучитьАдресМассиваНовыхДокументовНаСервере();
    
    КоличествоНовыхДокументов = ПолучитьКоличествоНовыхДокументов(АдресМассиваНовыхДокументов);
	
    // 3. На клиенте создаем цикл из такого количества итераций, сколько элементов есть в массиве.
    Для НомерОбъекта = 0 По КоличествоНовыхДокументов - 1 Цикл
        
        ФормаДокумента = ПолучитьФорму("Документ.ПоступлениеТоваровУслуг.ФормаОбъекта",,,Истина);
        ДанныеФормыДокумента = ФормаДокумента.Объект;
		
        // 4. В цикле создаем формы новых документов, при этом заполняя их данными из созданного массива документов. А к массиву обращаемся через адрес хранилища.
        ЗаполнитьДанныеФормыТонкийКлиентНаСервере(ДанныеФормыДокумента, НомерОбъекта, АдресМассиваНовыхДокументов);
        
        КопироватьДанныеФормы(ДанныеФормыДокумента, ФормаДокумента.Объект);
        
        ФормаДокумента.Открыть();
        
    КонецЦикла;
    
КонецПроцедуры

Открытие формы нового документа

См. также

Богатый редактор картинок, хранимых в базе, с возможностью РИСОВАНИЯ. Редактор внешних файлов картинок. Объект, расширяющий возможности работы с картинками из встроенного языка (Три в одном) + Обработка «Стандартизация картинок»

Работа с интерфейсом Рабочее место Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Платные (руб)

Обработка предназначена для редактирования картинок в режиме «Предприятие», с возможностью РИСОВАТЬ на них. Поддерживается работа как в обычных формах (толстый клиент) так и на управляемых формах (тонкий клиент). Обработка позволяет редактировать как картинки, хранимые в базе, так и графические файлы с диска на файловой системе. Помимо базовых функций (изменение размеров, преобразование формата, обрезание картинки, повороты и т.п.) – редактор имеет богатый набор инструментов для рисования. Доступна функция вставки изображения из буфера обмена. Также обработка может быть использована из встроенного языка как объект для редактирования картинок. Объект может быть использован: на стороне клиента, на стороне сервера, из внешнего соединения. Данная обработка будет особенно полезна тем, кто вносит картинки в базу (изображения номенклатуры, фотографии физических лиц и т.п.). Функционал реализуется с использованием JavaScript и бесплатного ПО ImageMagick (без использования внешних компонент).

6000 руб.

16.01.2015    61800    43    59    

80

[Расширения] Динамическое управление видимостью и доступностью элементов форм (УФ) (8.3.6+)

Работа с интерфейсом Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Платные (руб)

Механизм «Динамическое управление доступом к элементам форм объектов 1С8» предназначен для обеспечения возможности оперативного управления видимостью и доступностью элементов форм документов и справочников продуктов фирмы «1С» «1С:Предприятие 8». Решение универсальное, встраивается в любую конфигурацию с минимальными доработками, что позволяет без проблем обновлять типовые решения.

5000 руб.

14.01.2016    54407    16    21    

42

Управление дашбордами

Работа с интерфейсом Платформа 1С v8.3 Конфигурации 1cv8 Платные (руб)

Обработка предназначена для создания и управления дашбордами.

2400 руб.

29.06.2020    16700    21    4    

35

Новогоднее оформление для 1С

Работа с интерфейсом Платформа 1С v8.3 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Зарплата и Управление Персоналом 3.x 1С:Управление нашей фирмой 3.0 Бесплатно (free)

Добавьте новогоднего настроения! Расширение создает декорацию в виде гирлянды на некоторых формах объектов.

27.12.2023    10743    750    elcoan    45    

106

Конструктор HTML, CSS и javascript

Инструментарий разработчика Работа с интерфейсом Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Подходит для создания web-страниц для замены управляемых форм 1С, красивых отчетов, интерфейса мобильного приложения на платформе 1С и для простых страниц веб-сайтов.

2 стартмани

10.04.2023    9623    151    acces969    31    

118

Модель состояния для MVC

Работа с интерфейсом Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

"MVC плохо применима в 1С" - познакомьтесь с моделью состояния и, возможно, ваше мнение поменяется! Представленное решение является эволюционным развитием идеи реализации MVC для 1С. В новой версии добавлены DSL для описания модели состояния, а также параметризация свойств параметров и элементов формы.

1 стартмани

05.07.2022    3669    kalyaka    2    

27

Табло очереди заказов на экран телевизора

WEB-интеграция Работа с интерфейсом Платформа 1С v8.3 1С:Розница 2 Платные (руб)

Связка из веб-приложения и расширения для 1С: Розница 2.3.

3600 руб.

29.04.2022    12085    1    5    

10
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. slazzy 42 30.09.15 10:18 Сейчас в теме
Зачем делать столько костылей...
2. Wezoowy 73 30.09.15 12:03 Сейчас в теме
(1) slazzy, если Вы напишите как это сделать без костылей - я буду очень благодарен.
3. slazzy 42 30.09.15 12:07 Сейчас в теме
&НаСервереБезКонтекста
Функция СформироватьМассивДокументов()
        
    МассивНовыхДокументов = Новый Массив;
    МассивНовыхДокументов.Добавить(Новый Структура("Организация", Справочники.Организации.НайтиПоНаименованию("Управленческая организация")));
    МассивНовыхДокументов.Добавить(Новый Структура("Организация", Справочники.Организации.НайтиПоНаименованию("Стройснаб")));
   
    Возврат МассивНовыхДокументов;

КонецФункции


&НаКлиенте
Процедура СоздатьДокументы(Команда)
	МассивДокументов = СформироватьМассивДокументов();
	
	Для Каждого Документ из МассивДокументов Цикл
		ПараметрыОткрытия = Новый Структура;
		ПараметрыОткрытия.Вставить("ЗначенияЗаполнения", Документ);
		ОткрытьФорму("Документ.ПоступлениеТоваровУслуг.Форма.ФормаДокумента", ПараметрыОткрытия, ЭтаФорма, Истина);
	КонецЦикла;
	
КонецПроцедуры
Показать


Всё зависит от того какие реквизиты надо заполнить при открытии и заполняются ли эти реквизиты автоматически в уже существующей процедуре ОбработкаЗаполнения. В типовой УТ11 заполняется часть реквизитов и их можно передать через параметр ЗначенияЗаполнения, в таком случае вызов аналогичен вызову из динамического списка с отборами.
Если эти реквизиты не заполняются(зависит от конфигурации) то можно придумать разные варианты. Можно дописать подписку, можно расширение, можно переопределяемый модуль(он создан для того чтобы его переписывать).

В любом случае программное открытие формы в 99% случаев надо делать через ОктрытьФорму(..) с параметрами...и как показывает практика почти всё и всегда можно решить через эти параметры.
ЗЫ В типовой УТ почему-то довольно криво описаны варианты заполнения конкретно для этих документов, но всё равно даже этим кодом можно воспользоваться.
zif74; Xershi; hasp_x; +3 Ответить
4. Wezoowy 73 30.09.15 12:24 Сейчас в теме
(3) slazzy, Спасибо, хороший вариант. Но суть как раз в том, что у меня нет возможности править конфу заказчика. Но при этом конфа изменена, добавлены реквизиты в документ, в ТЧ. Механизм нужен был полностью независимый.
5. Yashazz 4709 02.10.15 18:05 Сейчас в теме
(4) может, я чего не понял, но делать можно так.

а) Предположим, можно обойтись внешней обработкой по пинку пользователя. Тогда на сервере создаются документы, заполняются все нужные реквизиты, и возвращаются ссылки на свежесделанные документы, каковые в цикле на клиенте и открываются. Элементарно. Никакого вмешательства в типовую.

б) Предположим, действие должно происходить по событию, которое случается на сервере. Тогда подключаете глобальный обработчик ожидания с разумным периодом, делаете свой клиентский модуль с процедурой, или опять же обработку, которую этот обработчик пинает. Пинок можно выполнять по факту некоего триггера. Массив открываемых документов либо определяется "по месту", либо при создании загоняем в хранилище и потом берём из него. Не очень страшное вмешательство в типовую.

В любом случае, советую почитать ИТС и советы, как заполнять данными формы новых документов и как их вообще можно открывать.

P.S. УТ 11 может работать в режиме толстого клиента???
6. Wezoowy 73 03.10.15 00:31 Сейчас в теме
(5) Yashazz,
а) все верно, если документы записать, то да, просто передать ссылки и открыть. НО! Должны были быть открыты формы новых (незаписанных) документов (Я не указал в описании, извиняюсь).
б) Вмешательство в конфу - крайне нежелательно...

А насчет толстого клиента - таки а почему нет? УФ, толстый клиент.
7. webester 26 04.10.15 07:45 Сейчас в теме
В похожих статьях как раз есть статья в которой есть и процесс и отсылки в гугол и мой c##ч с автором на тему да RTFM же!
8. Sema76 1 01.11.15 08:58 Сейчас в теме
Спасибо! Отличная статья! Все работает! Я сначала пытался получить таблицу значений с сервера на клиенте. Оказывается это совсем не нужно. (Время зря только тратил.) Мне надо на основании одного документа создать несколько в зависимости от данных табличной части. Все получилось.
Для полноты. Как заполнить табличную часть.
http://its.1c.ru/db/metod8dev/content/2322/hdoc
9. Гость 30.05.16 00:57
Строка "ФормаДокумента.Объект" не работает. Пишет, что поле "Объект" не найдено.
10. vaidamirjan 1 16.11.17 13:52 Сейчас в теме
Сдается мне что ЗаполнитьДанныеФормыНаСервере надо заменить на ЗначениеВДанныеФормы

&НаСервере
Функция ЗаполнитьДанныеФормыТонкийКлиентНаСервере(ДанныеФормыДокумента, НомерОбъекта, АдресМассиваНовыхДокументов)
МассивНовыхДокументов = ПолучитьИзВременногоХранилища(АдресМассиваНовыхДокументов);
НовыйДокументОбъект = МассивНовыхДокументов[НомерОбъекта];
ЗначениеВДанныеФормы(НовыйДокументОбъект, ДанныеФормыДокумента);
КонецФункции

И, да! Спасибо! Отличная статья! Очень помогла.
11. oks-nt 45 26.01.18 13:40 Сейчас в теме
Создать одновременно несколько новых документов клиентскими методами без записи самих объектов используя метод ОткрытьФорму достижимо. Достаточно при вызове метода ОткрытьФорму указать различные значения параметра КлючУникальности, например Новый УникальныйИдентификатор.

Примерно таким образом:

мМассив = ПолучитьПараметрыЗаполненияДвижениеПродукции();
Для Каждого мЭлемент ИЗ мМассив Цикл
ОткрытьФорму("Документ.ДвижениеПродукцииИМатериалов.ФормаОбъекта", Новый Структура("Основание", мЭлемент), ЭтаФорма, Новый УникальныйИдентификатор);
КонецЦикла;

Первоисточник:
http://v8.1c.ru/metod/faq2/answer.jsp?id=609
zif74; odinsmot; Desnyanka; Fartovaya; Daynestro07; +5 Ответить
12. Dim.Gadget 19.08.18 17:48 Сейчас в теме
Спасибо огромное за статью!
13. rmIvanT 68 24.06.19 10:25 Сейчас в теме
Благодарю за статью! Хорошие костыли - рабочие)
Оставьте свое сообщение