Функция ВыгрузитьПоПравилу - мощный инструмент расширения возможностей ваших правил конвертации. Конвертация данных 2.1

09.11.15

Интеграция - Обмен между базами 1C

Казалось бы, всего лишь одна функция из арсенала разработчика правил обмена на Конвертации данных 2.1, но понимание этой функции расширяет ваши возможности при написании качественных правил обмена в несколько раз. Да, что там писать эти правила? Сопоставил реквизиты, сопоставил табличные части, да еще помощник автоматически создаст необходимые ПКО, ПКС, ПВД. А как быть, когда нужно передать Регистр сведений в регистр сведений, да не просто передать, а привязать это действие к выгрузке определенных элементов, например, элементов справочника Физические лица? Или как передать табличную часть справочника в документы, да так, чтобы одна строка табличной части создавала ровно один документ на стороне приемника? А как быть, если невозможно сделать соответствия между объектами и данные для приемника необходимо собирать из разных источников? Именно для подобных задач вам может понадобиться функция ВыгрузитьПоПравилу.

Здесь, я расскажу вам о тех ситуациях, в которых мне понадобилась эта функция, и как она меня не раз выручила. Все свое повествование я сопровожу реальными примерами, которые реализовывались мной в одном из проектов.

Описание функции ВыгрузитьПоПравилу().

Функция ВыгрузитьПоПравилу() используется для выгрузки объекта в xml-узел и возвращает узел ссылки на этот объект.

В процессе выгрузки эта функция вызывается из:

ПВД, когда объект из выборки получен и необходимо произвести его конвертацию.

ПКО, когда необходимо выгрузить связанную с выгружаемым объектом информацию.

ПКС, когда свойство имеет ссылочный тип и необходимо выгрузить по ссылке из этого свойства объект.

Из функции ВыгрузитьПоПравилу() могут быть вызваны другие функции, выгружающие субконто, свойства и т.д. этого объекта, а из этих функций – рекурсивно может быть вызвана функция ВыгрузитьПоПравилу(). После того, как объект со всеми необходимыми свойствами выгружен, управление возвращается в то место кода, откуда функция была вызвана. Таким образом, вызов этой функции из обработчиков событий какого-либо правила (ПВД, ПКО, ПКС), не изменяет процесса выгрузки объекта по этому правилу.

Функция ВыгрузитьПоПравилу() имеет ряд параметров

ВыгрузитьПоПравилу(Источник,
                                   Приемник,
                                   ВходящиеДанные,
                                   ИсходящиеДанные,
                                   ИмяПКО,
                                   УзелСсылки,
                                   ТолькоПолучитьУзелСсылки,
                                   ПКО,
                                   ЭтоПравилоСГлобальнойВыгрузкойОбъектов,
                                   ВыборкаДляВыгрузкиДанных)


Все эти параметры в функции имеют значения по умолчанию, и, как правило, передавать имеет смысл только параметр ИмяПКО, а также параметры Источник и/или ВходящиеДанные – в зависимости от того, как настроено ПКО.

ИмяПКО – строка, название ПКО, в которое передаем управление.
Источник – ссылка на элемент объекта-источника, который передаем для конвертации.
ВходящиеДанные – структура. Элементы в ней должны быть названы аналогично ПКС, у которых стоит флаг «Получить из входящих данных». Если таких ПКС нет, передавать этот параметр не нужно. Если в ПКО у всех ПКС стоит флаг «Получить из входящих данных», то, наоборот, необходимо передать структуру ВходящиеДанные, а Источник тогда передавать не нужно.

Выгрузка произвольной выборки данных через стандартную выборку с регистрацией объекта источника.

Необходимость в такой задаче может возникнуть, когда объект "источника" и объект "приемника" имеют различную смысловую или функциональную структуру.

Например, документ "источника" позволяет вводить информацию по нескольким подразделениям предприятия, документ "приемника" позволяет вводить информацию только об одном подразделении предприятия.

Данная задача отлично решается при помощи произвольного алгоритма выборки в ПВД, но данное решение имеет два недостатка:

  1. Мы лишаемся механизма регистрации изменений;
  2. Алгоритм произвольной выборки отказывается работать в БСП.

БСП - библиотека стандартных подсистем. В частности, имеет своем составе подсистему "Обмен данными", данная подсистема реализует механизмы автоматической синхронизации данных между конфигурациями, по правилам написанным в Конвертации данных.

  1. Создаем ПВД со Стандартным алгоритмом выборки;
  2. Указываем объект выборки;
  3. Пишем обработчик "Перед выгрузкой"(хочу подчеркнуть, что нужно использовать именно этот обработчик). Например, следующего содержания:
 
 
//Начинаем отбор данных для выгрузки
Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ РАЗЛИЧНЫЕ
		| ПриемНаРаботуВОрганизациюРаботникиОрганизации.Сотрудник,
		| ПриемНаРаботуВОрганизациюРаботникиОрганизации.ПодразделениеОрганизации КАК Подразделение,
		| ПриемНаРаботуВОрганизациюРаботникиОрганизации.Должность,
		| ПриемНаРаботуВОрганизациюРаботникиОрганизации.ЗанимаемыхСтавок КАК Ставка,
		| ПриемНаРаботуВОрганизациюРаботникиОрганизации.ДатаПриема,
		| ПриемНаРаботуВОрганизациюРаботникиОрганизации.Сотрудник.ВидЗанятости КАК ВидЗанятости,
		| ПриемНаРаботуВОрганизациюРаботникиОрганизации.Ссылка.Дата,
		| ПриемНаРаботуВОрганизациюРаботникиОрганизации.Ссылка.Номер,
		| ПриемНаРаботуВОрганизациюРаботникиОрганизации.Ссылка.Проведен,
		| ВЫБОР
		| КОГДА ПриемНаРаботуВОрганизациюОсновныеНачисления.ВидРасчета = ЗНАЧЕНИЕ(ПланВидовРасчета.ОсновныеНачисленияОрганизаций.ОкладПоЧасам)
		| ТОГДА ИСТИНА
		| ИНАЧЕ ЛОЖЬ
		| КОНЕЦ КАК СдельнаяОплатаТруда,
		| ПриемНаРаботуВОрганизациюОсновныеНачисления.ВидРасчета КАК ВидРасчета
		|ИЗ
		| Документ.ПриемНаРаботуВОрганизацию.РаботникиОрганизации КАК ПриемНаРаботуВОрганизациюРаботникиОрганизации
		| ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.ПриемНаРаботуВОрганизацию.ОсновныеНачисления КАК ПриемНаРаботуВОрганизациюОсновныеНачисления
		| ПО ПриемНаРаботуВОрганизациюРаботникиОрганизации.Ссылка = ПриемНаРаботуВОрганизациюОсновныеНачисления.Ссылка
		| И ПриемНаРаботуВОрганизациюРаботникиОрганизации.Сотрудник = ПриемНаРаботуВОрганизациюОсновныеНачисления.Сотрудник
		|ГДЕ
		| ВЫБОР
		| КОГДА &ИспользоватьОтборПоПодразделениям ТОГДА
		| ПриемНаРаботуВОрганизациюРаботникиОрганизации.ПодразделениеОрганизации В ИЕРАРХИИ (&Подразделения)
		| ИНАЧЕ 
		| ИСТИНА
		| КОНЕЦ
		| И ВЫБОР
		| КОГДА &ИспользоватьОтборПоВидамРасчета ТОГДА
		| ПриемНаРаботуВОрганизациюОсновныеНачисления.ВидРасчета В ИЕРАРХИИ (&ВидРасчета)
		| ИНАЧЕ 
		| ИСТИНА
		| КОНЕЦ
		| И ПриемНаРаботуВОрганизациюРаботникиОрганизации.Ссылка = &Ссылка";
Выполнить(Алгоритмы.ЗаполнитьПараметрыОтбораПоВидамРасчета);
Запрос.УстановитьПараметр("Ссылка", Объект.Ссылка);
Выполнить(Алгоритмы.ЗаполнитьПараметрыОтбораПоПодразделениям);
ВыбранныеДанные = Неопределено;
ПустаяТабличнаяЧасть = Неопределено;
Выполнить(Алгоритмы.ПолучитьСтруктуруВыгрузкиКадровыхДокументов);
РезультатЗапроса = Запрос.Выполнить().Выгрузить();
Сотрудники = ПустаяТабличнаяЧасть.Скопировать();
СтрокаДокумента = Неопределено;
Для Каждого СтрокаРезультата Из РезультатЗапроса Цикл 
	ДанныеИзВнешнихСистем = "Выгружено из ЗиКБУ, документ ""Прием на работу в организацию"" №" + СтрокаРезультата.Номер + " от " + Формат(СтрокаРезультата.Дата, "ДФ=dd.MM.yyyy") + 
	", " + СтрокаРезультата.Подразделение.Наименование;
	
	СтрокаДокумента = ВыбранныеДанные.Найти(ДанныеИзВнешнихСистем);
	
	Если СтрокаДокумента = Неопределено Тогда 
		СтрокаДокумента = ВыбранныеДанные.Добавить();
		СтрокаДокумента.Дата = СтрокаРезультата.ДатаПриема;
		СтрокаДокумента.Кафедра = СтрокаРезультата.Подразделение;
		СтрокаДокумента.Проведен = СтрокаРезультата.Проведен;
		СтрокаДокумента.ДокументСАктивнымиДолжностями = Истина;
		СтрокаДокумента.ДанныеИзВнешнихСистем = ДанныеИзВнешнихСистем;
		СтрокаДокумента.АктивныеДолжности = ПустаяТабличнаяЧасть.Скопировать();
		СтрокаДокумента.НеактивныеДолжности = ПустаяТабличнаяЧасть.Скопировать();
	КонецЕсли; 
	
	СтрокаРаботников = СтрокаДокумента.АктивныеДолжности.Добавить();
	СтрокаРаботников.Должность = СтрокаРезультата.Должность;
	СтрокаРаботников.Сотрудник = СтрокаРезультата.Сотрудник.Физлицо;
	СтрокаРаботников.Ставка = СтрокаРезультата.Ставка * 100;
	СтрокаРаботников.ВидНачисления = СтрокаРезультата.ВидРасчета; 
	СтрокаРаботников.ВидЗанятости = СтрокаРезультата.ВидЗанятости;
КонецЦикла;
//Переводим отобранные данные из Таблицы значений в Массив структур для дальнейшей передачи в ПКО
ДокументыЗакреплениеЗаКафедрой = Неопределено;
Выполнить(Алгоритмы.ПереводТаблицыЗначенийВМассивЗакреплениеЗаКафедрой);
//Обходим отобранные данные и выгружаем с помощью функции ВыгрузитьПоПравилу
Для каждого Документ Из ДокументыЗакреплениеЗаКафедрой Цикл
	ВыгрузитьПоПравилу(,,Документ,,"ЗакреплениеЗаКафедройИзВходящихДанных");
КонецЦикла;
//Отменяем стандартную выгрузку объекта
Отказ = Истина;

Большую часть этого обработчика, как вы можете видеть, занимает отбор данных необходимых для выгрузки. Тут и множество фильтров: по подразделениям, по видам расчетов и механизм разбиения одного документа "источника" на несколько документов "приемника". Если коротко, то в данном примере табличная часть одного документа "источника" разносится по табличным частям нескольких документов "приемника", а значением разбиения данных является значение Подразделения.

Для удобства работы при отборе данных мы использовали Таблицу значений, наш алгоритм подразумевает ПКО с получением данных из "входящих данных", которые будут переданы в функцию ВыгрузитьПоПравилу, поэтому в соответсвующем алгоритме мы производим перевод Таблицы значений в Массив структур.

На следующем шаге мы обходим отобранные данные и вот уже в этом месте мы используем нашу функцию ВыгрузитьПоПравилу. Параметр Документ, здесь является структурой, которую мы передаем как входящие данные, а второй передаваемый нами параметр, это название ПКО, которому мы передаем наши данные.

В самом конце мы отменяем выполнение стандартной выгрузки, так как все необходимые данные связанные с объектом выборки мы уже выгрузили.

Тем самым мы сохраняем функциональность регистрации изменений - документ изменился, зарегистрировался для выгрузки, данные выгрузили. И в то же время делаем произвольный отбор необходимых нам данных.

В ПКО в этом случае для свойств необходимо указать, что они получаются из "Входящих данных".

 

 

 

Выгрузка Регистр сведений -> Регистр сведений с зависимостью от переноса другого объекта.

Типичным примером такой задачи является перенос контактной информации физического лица. Простейший способ решения задачи - это перенос всех "Физических лиц" и всего регистра сведений "Контактная информация" физических лиц. Что делать если нам необходимо переносить не всех физических лиц? Например, только тех физических лиц, которые упоминаются в каком-либо переносимом нами документе. В таком случае, как известно, ПКС документа вызывает ПКО справочника "Физические лица" и тем самым обеспечивается перенос физических лиц упоминаемых в документе.

В переносе "Контактной информации" физических лиц в данной ситуации может помочь функция ВыгрузитьРегистр, очень похожая на функцию ВыгрузитьПоПравилу.

Хочу отметить, что потребность в использовании функции ВыгрузитьРегистр у меня появилась, когда я начал адаптировать правила под БСП уже отлаженные на обработке Универсальный обмен XML. Регистры через обработку спокойно выгружались с использованием функции ВыгрузитьПоПравилу, но БСП ни как не хотело правильно понимать такую выгрузку, в результате чего пришлось переписывать код через ВыгрузитьРегистр.

В обработчике"После выгрузки в файл" ПКО "Физические лица", пишем код следующего вида:



//////////////////////////////////////////////////////
//Выгрузим контактную информацию типа Адрес
Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ
                | КонтактнаяИнформация.Представление,
                | КонтактнаяИнформация.Вид,
                | КонтактнаяИнформация.Тип,
                | КонтактнаяИнформация.Объект
                |ИЗ
                | РегистрСведений.КонтактнаяИнформация КАК КонтактнаяИнформация
                |ГДЕ
                | КонтактнаяИнформация.Тип = ЗНАЧЕНИЕ(Перечисление.ТипыКонтактнойИнформации.Адрес)
                | И КонтактнаяИнформация.Вид В (ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.ЮрАдресФизЛица), ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.ФактАдресФизЛица))
                | И КонтактнаяИнформация.Объект = &Объект";
Запрос.УстановитьПараметр("Объект", Источник);
Выборка = Запрос.Выполнить ().Выбрать ();
Пока Выборка.Следующий () Цикл
          Отбор = Новый ТаблицаЗначений;
          Отбор.Колонки.Добавить ("Имя");
          Отбор.Колонки.Добавить ("Значение");
          Отбор.Колонки.Добавить ("Использование");

          СтрокаОтбора = Отбор.Добавить ();
          СтрокаОтбора.Имя = "Объект";
          СтрокаОтбора.Значение = Выборка.Объект;
          СтрокаОтбора.Использование = Истина;

          Строки = Новый ТаблицаЗначений;
          Строки.Колонки.Добавить("Представление");
          Строки.Колонки.Добавить("Вид");
          Строки.Колонки.Добавить("Тип");
          Строки.Колонки.Добавить("Объект");

          Строка = Строки.Добавить();
          Строка.Представление = Выборка.Представление;
          Строка.Вид = Выборка.Вид;
          Строка.Тип = Выборка.Тип;
          Строка.Объект = Выборка.Объект;

          НаборЗаписей = Новый Структура("Отбор, Строки");
          НаборЗаписей.Отбор = Отбор;
          НаборЗаписей.Строки = Строки;

          ВыгрузитьРегистр(НаборЗаписей,,,,"КонтактнаяИнформация");

КонецЦикла;

Как видно, в коде отбираются все записи регистра сведений, относящиеся к текущему выгружаемому Физическому лицу, а полученная выборка обходится в цикле.

Для того, чтобы выгрузить записи регистра сведений через функцию ВыгрузитьРегистр, необходимо подготовить структуру НаборЗаписей, которая имеет два поля: Отбор и Строки.

ПКО "КонтактнаяИнформация" имеет следующий вид:

 

Выгрузка Табличная часть -> Регистр сведений.

По своему решению задача аналогична предыдущей. С той лишь разницей, что информацию для регистра сведений "приемника" брать придется из других объектов "источника", а точнее табличной части того объекта, который на данный момент выгружается. Если бы на стороне "приемника" была так же табличная часть, то задача легко решалась бы в виде ПГКС. Поэтому снова воспользуемся функцией ВыгрузитьРегистр.

Рассмотрим пример переноса информации по ученым степеням Физического лица. Опять создаем код в обработчике "После выгрузки в файл" ПКО "Физические лица". Так как задача аналогичная предыдущей привожу только, код отбора и выгрузки данных из обработчика:

///////////////////////////////////////////////////////
//Выгрузим информацию по ученым степеням
Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ
		|	ФизическиеЛицаУченыеСтепени.Ссылка,
		|	ФизическиеЛицаУченыеСтепени.УченаяСтепень,
		|	ФизическиеЛицаУченыеСтепени.ОтрасльНауки,
		|	ФизическиеЛицаУченыеСтепени.ДипломСерияНомер,
		|	ФизическиеЛицаУченыеСтепени.ДатаПрисужденияУченойСтепени
		|ИЗ
		|	Справочник.ФизическиеЛица.УченыеСтепени КАК ФизическиеЛицаУченыеСтепени
		|ГДЕ
		|	ФизическиеЛицаУченыеСтепени.Ссылка = &ФизЛицо";

Запрос.УстановитьПараметр("ФизЛицо", Источник);

Выборка = Запрос.Выполнить().Выбрать();

Пока Выборка.Следующий() Цикл
	
	Отбор = Новый ТаблицаЗначений;
	Отбор.Колонки.Добавить ("Имя");
	Отбор.Колонки.Добавить ("Значение");
	Отбор.Колонки.Добавить ("Использование");
	
	СтрокаОтбора = Отбор.Добавить ();
	СтрокаОтбора.Имя = "ФизическоеЛицо";
	СтрокаОтбора.Значение = Выборка.Ссылка;
	СтрокаОтбора.Использование = Истина;
	
	Строки = Новый ТаблицаЗначений;
	Строки.Колонки.Добавить("Ссылка");
	Строки.Колонки.Добавить("ФизическоеЛицо");
	Строки.Колонки.Добавить("УченаяСтепень");
	Строки.Колонки.Добавить("Специальность");
	Строки.Колонки.Добавить("НомерДиплома");
	Строки.Колонки.Добавить("Период");
	
	Строка = Строки.Добавить();
	Строка.ФизическоеЛицо = Выборка.Ссылка;
	Строка.УченаяСтепень = Выборка.УченаяСтепень;
	Строка.Специальность = Выборка.ОтрасльНауки;
	Строка.НомерДиплома = Выборка.ДипломСерияНомер;
	Строка.Период = Выборка.ДатаПрисужденияУченойСтепени;
	
	НаборЗаписей = Новый Структура("Отбор, Строки");
	НаборЗаписей.Отбор = Отбор;
	НаборЗаписей.Строки = Строки;
	
	ВыгрузитьРегистр(НаборЗаписей,,,Истина,"УченыеСтепениФизическихЛиц");

КонецЦикла;

Выгрузка Табличная часть -> Документ.

Предположим, в "источнике" информация для переноса хранится в менее детализированном виде, чем в приемнике, но достаточном для переноса. Например, мной решалась задача по переносу информации об образовании физических лиц из ЗиКБУ в Университет. Понятно, что на стороне кадровой программы нужна минимальная информация об образовании физических лиц, главное что сотрудник обладает необходимой квалификацией и хватит. А вот на стороне университета, информация об образовании, а точнее о дипломах хранится куда более подробно, в связи со спецификой учереждения.

И опять задача решается, при помощи все той же функции ВыгрузитьПоПравилу.

Вот пример выгрузки Дипломов физических лиц. Все тот же обработчик "После выгрузки в файл" ПКО "Физические лица", пишем следующий код:

///////////////////////////////////////////////////////
//Выгрузим образование Физического лица
Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ
	        |	ФизическиеЛицаОбразование.Ссылка КАК Студент,
	        |	ФизическиеЛицаОбразование.ВидОбразования,
	        |	ФизическиеЛицаОбразование.УчебноеЗаведение,
	        |	ФизическиеЛицаОбразование.Специальность.Наименование КАК Специальность,
	        |	ФизическиеЛицаОбразование.Диплом,
	        |	ФизическиеЛицаОбразование.ГодОкончания,
	        |	ФизическиеЛицаОбразование.Квалификация
	        |ИЗ
	        |	Справочник.ФизическиеЛица.Образование КАК ФизическиеЛицаОбразование
	        |ГДЕ
	        |	ФизическиеЛицаОбразование.Ссылка = &ФизЛицо";


Запрос.УстановитьПараметр("ФизЛицо", Источник);
РезультатЗапроса = Запрос.Выполнить();

ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();

Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
	ВходящиеДанные = Новый Структура;
	ВходящиеДанные.Вставить("Студент", ВыборкаДетальныеЗаписи.Студент);
	ВходящиеДанные.Вставить("ВидОбразования", ВыборкаДетальныеЗаписи.ВидОбразования);
	ВходящиеДанные.Вставить("ОбразовательноеУчреждениеПриОкончании", ВыборкаДетальныеЗаписи.УчебноеЗаведение);
	ВходящиеДанные.Вставить("Специальность", ВыборкаДетальныеЗаписи.Специальность);
	
	СерияНомерДиплома = ВыборкаДетальныеЗаписи.Диплом;
	СерияДиплома = "";
	НомерДиплома = "";
	
	Выполнить(Алгоритмы.ПолучитьСериюИНомер);
	
	ВходящиеДанные.Вставить("СерияДиплома", СерияДиплома);
	ВходящиеДанные.Вставить("НомерДиплома", НомерДиплома);
	
	Если НЕ ВыборкаДетальныеЗаписи.ГодОкончания = 0 Тогда
		ВходящиеДанные.Вставить("ГодЗавершения", Дата(ВыборкаДетальныеЗаписи.ГодОкончания, 1, 1));
		ВходящиеДанные.Вставить("ДатаВыдачи", Дата(ВыборкаДетальныеЗаписи.ГодОкончания, 1, 1));
	Иначе
		ВходящиеДанные.Вставить("ГодЗавершения", Дата("00010101"));
		ВходящиеДанные.Вставить("ДатаВыдачи", Дата("00010101"));
	КонецЕсли;
	
	ВходящиеДанные.Вставить("Квалификация", ВыборкаДетальныеЗаписи.Квалификация);
	
	ВыгрузитьПоПравилу(,,ВходящиеДанные,,"ДипломИзВходящихДанных");
КонецЦикла;

Тут мы отбираем данные из табличной части и формируем входящие данные для документа на стороне "приемника", после чего при помощи функции ВыгрузитьПоПравилу, передаем входящие данные ПКО ДипломИзВходящихДанных, которое имеет следующий вид:

В общем, как вы понимаете, можно приводить еще много вариаций перегрузок: справочники, документы, регистры. Главное, надо понимать, что не стоит фанатично бросаться на функции ВыгрузитьПоПравилу и ВыгрузитьРегистр.

Замечания по перегрузке.

     1. У меня возникли сложности при использовании правил в БСП, в части выгрузки объектов по ссылкам, проблема решилась принудительной установкой параметра ВыгрузитьОбъект в значение Истина, для каждого ПКС ссылочного типа:

     2. Надо помнить, что при выгрузке через указанные функции, зачастую отсутствует УникальныйИдентификатор объекта, например, когда объект для выгрузки собирается по частям в виде структуры ВходящихДанных, поэтому поиск по уникальному идентификатору придется отключить.

Подводим итоги. Когда использовать эти функции?

  1. Вам необходимо перегрузить объекты с сильно различной структурой или на стороне "источника" необходимо собирать объекты для выгрузки из разных объектов.
  2. Вам необходимо перегружать объекты с привязкой к выгрузке других объектов.

UPDATE от 11.11.2015 

А что если оптимизировать выше написанное?

Пишу дополнение к статье, после оставленного пользователем TarasovAV комментария. Данный пользователь заметил, что можно оптимизировать выгрузку связанной информации, путем накопления списка тех объектов, информацию о которых надо будет отдельно выгружать, а потом через один запрос отобрать сразу всю информацию.

Описываю алгоритм предложенный вышеуказанным пользователем:

     1. В правиле конвертации "После загрузки правил обмена", создается параметр типа ТаблицаЗначений, в который будет накапливаться список объектов, для которых в последующем будет выгружаться информация:

Параметры.Вставить("СписокФизическихЛиц", Новый ТаблицаЗначений());
Параметры.СписокФизическихЛиц.Колонки.Добавить("ФизическоеЛицо");

2. В в обработчике "После выгрузки" ПКО "Физические лица" (именно для них в примерах мы выгружаем контактные данные, образование и т.п.), мы пополняем нашу таблицу значений новым физическим лицом, проверяя перед этим, а не добавлено ли уже это физическое лицо в таблицу:

 

НайденнаяСтрока = Параметры.СписокФизическихЛиц.Найти(Источник);
Если НайденнаяСтрока = Неопределено Тогда
	НоваяСтрока = Параметры.СписокФизическихЛиц.Добавить();
	НоваяСтрока.ФизическоеЛицо = Источник;
КонецЕсли;

3. И финальным действием, будет непосредственная выгрузка информации, только уже с отбором по все физическим лицам сразу. Для этого все обработчики, что были приведены выше начиная, необходимо перенести в правило конвертации "После выгрузки данных", запросы же необходимо изменить, чтобы в них проверялось не равенство одному элементу, а вхождение значения реквизита в массив элементов:

 

Обратите внимание, как изменилась установка параметра запроса и проверка условия в запросе:

//...
"|	И КонтактнаяИнформация.Объект В &СписокФизЛицо";

Запрос.УстановитьПараметр("СписокФизЛицо", Параметры.СписокФизическихЛиц.ВыгрузитьКолонку("ФизическоеЛицо"));
//...

Привожу полный код, исправленных ранее приведенных примеров:

//////////////////////////////////////////////////////
//Выгрузим контактную информацию типа Адрес
Запрос = Новый Запрос;
Запрос.Текст = 
	"ВЫБРАТЬ
	|	КонтактнаяИнформация.Представление,
	|	КонтактнаяИнформация.Вид,
	|	КонтактнаяИнформация.Тип,
	|	КонтактнаяИнформация.Объект
	|ИЗ
	|	РегистрСведений.КонтактнаяИнформация КАК КонтактнаяИнформация
	|ГДЕ
	|	КонтактнаяИнформация.Тип = ЗНАЧЕНИЕ(Перечисление.ТипыКонтактнойИнформации.Адрес)
	|	И КонтактнаяИнформация.Вид В (ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.ЮрАдресФизЛица), ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.ФактАдресФизЛица))
	|	И КонтактнаяИнформация.Объект В &СписокФизЛицо";

Запрос.УстановитьПараметр("СписокФизЛицо", Параметры.СписокФизическихЛиц.ВыгрузитьКолонку("ФизическоеЛицо"));

Выборка = Запрос.Выполнить ().Выбрать ();

Пока Выборка.Следующий () Цикл
	Отбор = Новый ТаблицаЗначений;
	Отбор.Колонки.Добавить ("Имя");
	Отбор.Колонки.Добавить ("Значение");
	Отбор.Колонки.Добавить ("Использование");
	
	СтрокаОтбора = Отбор.Добавить ();
	СтрокаОтбора.Имя = "Объект";
	СтрокаОтбора.Значение = Выборка.Объект;
	СтрокаОтбора.Использование = Истина;
	
	Строки = Новый ТаблицаЗначений;
	Строки.Колонки.Добавить("Представление");
	Строки.Колонки.Добавить("Вид");
	Строки.Колонки.Добавить("Тип");
	Строки.Колонки.Добавить("Объект");
	
	Строка = Строки.Добавить();
	Строка.Представление = Выборка.Представление;
	Строка.Вид = Выборка.Вид;
	Строка.Тип = Выборка.Тип;
	Строка.Объект = Выборка.Объект;
	
	НаборЗаписей = Новый Структура("Отбор, Строки");
	НаборЗаписей.Отбор = Отбор;
	НаборЗаписей.Строки = Строки;
	
	ВыгрузитьРегистр(НаборЗаписей,,,,"КонтактнаяИнформация");
	
КонецЦикла;

///////////////////////////////////////////////////////
//Выгрузим образование Физического лица
Запрос = Новый Запрос;
Запрос.Текст = 
	"ВЫБРАТЬ
	|	ФизическиеЛицаОбразование.Ссылка КАК Студент,
	|	ФизическиеЛицаОбразование.ВидОбразования,
	|	ФизическиеЛицаОбразование.УчебноеЗаведение,
	|	ФизическиеЛицаОбразование.Специальность.Наименование КАК Специальность,
	|	ФизическиеЛицаОбразование.Диплом,
	|	ФизическиеЛицаОбразование.ГодОкончания,
	|	ФизическиеЛицаОбразование.Квалификация
	|ИЗ
	|	Справочник.ФизическиеЛица.Образование КАК ФизическиеЛицаОбразование
	|ГДЕ
	|	ФизическиеЛицаОбразование.Ссылка В &СписокФизЛицо";

Запрос.УстановитьПараметр("СписокФизЛицо", Параметры.СписокФизическихЛиц.ВыгрузитьКолонку("ФизическоеЛицо"));

РезультатЗапроса = Запрос.Выполнить();

ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();

Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
	ВходящиеДанные = Новый Структура;
	ВходящиеДанные.Вставить("Студент", ВыборкаДетальныеЗаписи.Студент);
	ВходящиеДанные.Вставить("ВидОбразования", ВыборкаДетальныеЗаписи.ВидОбразования);
	ВходящиеДанные.Вставить("ОбразовательноеУчреждениеПриОкончании", ВыборкаДетальныеЗаписи.УчебноеЗаведение);
	ВходящиеДанные.Вставить("Специальность", ВыборкаДетальныеЗаписи.Специальность);
	
	СерияНомерДиплома = ВыборкаДетальныеЗаписи.Диплом;
	СерияДиплома = "";
	НомерДиплома = "";
	
	Выполнить(Алгоритмы.ПолучитьСериюИНомер);
	
	ВходящиеДанные.Вставить("СерияДиплома", СерияДиплома);
	ВходящиеДанные.Вставить("НомерДиплома", НомерДиплома);
	
	Если НЕ ВыборкаДетальныеЗаписи.ГодОкончания = 0 Тогда
		ВходящиеДанные.Вставить("ГодЗавершения", Дата(ВыборкаДетальныеЗаписи.ГодОкончания, 1, 1));
		ВходящиеДанные.Вставить("ДатаВыдачи", Дата(ВыборкаДетальныеЗаписи.ГодОкончания, 1, 1));
	Иначе
		ВходящиеДанные.Вставить("ГодЗавершения", Дата("00010101"));
		ВходящиеДанные.Вставить("ДатаВыдачи", Дата("00010101"));
	КонецЕсли;
	
	ВходящиеДанные.Вставить("Квалификация", ВыборкаДетальныеЗаписи.Квалификация);
	
	ВыгрузитьПоПравилу(,,ВходящиеДанные,,"ДипломИзВходящихДанных");
КонецЦикла;

///////////////////////////////////////////////////////
//Выгрузим информацию по ученым степеням
Запрос = Новый Запрос;
Запрос.Текст = 
		"ВЫБРАТЬ
		|	ФизическиеЛицаУченыеСтепени.Ссылка,
		|	ФизическиеЛицаУченыеСтепени.УченаяСтепень,
		|	ФизическиеЛицаУченыеСтепени.ОтрасльНауки,
		|	ФизическиеЛицаУченыеСтепени.ДипломСерияНомер,
		|	ФизическиеЛицаУченыеСтепени.ДатаПрисужденияУченойСтепени
		|ИЗ
		|	Справочник.ФизическиеЛица.УченыеСтепени КАК ФизическиеЛицаУченыеСтепени
		|ГДЕ
		|	ФизическиеЛицаУченыеСтепени.Ссылка В &СписокФизЛицо";

Запрос.УстановитьПараметр("СписокФизЛицо", Параметры.СписокФизическихЛиц.ВыгрузитьКолонку("ФизическоеЛицо"));

Выборка = Запрос.Выполнить().Выбрать();

Пока Выборка.Следующий() Цикл
	
	Отбор = Новый ТаблицаЗначений;
	Отбор.Колонки.Добавить ("Имя");
	Отбор.Колонки.Добавить ("Значение");
	Отбор.Колонки.Добавить ("Использование");
	
	СтрокаОтбора = Отбор.Добавить ();
	СтрокаОтбора.Имя = "ФизическоеЛицо";
	СтрокаОтбора.Значение = Выборка.Ссылка;
	СтрокаОтбора.Использование = Истина;
	
	Строки = Новый ТаблицаЗначений;
	Строки.Колонки.Добавить("Ссылка");
	Строки.Колонки.Добавить("ФизическоеЛицо");
	Строки.Колонки.Добавить("УченаяСтепень");
	Строки.Колонки.Добавить("Специальность");
	Строки.Колонки.Добавить("НомерДиплома");
	Строки.Колонки.Добавить("Период");
	
	Строка = Строки.Добавить();
	Строка.ФизическоеЛицо = Выборка.Ссылка;
	Строка.УченаяСтепень = Выборка.УченаяСтепень;
	Строка.Специальность = Выборка.ОтрасльНауки;
	Строка.НомерДиплома = Выборка.ДипломСерияНомер;
	Строка.Период = Выборка.ДатаПрисужденияУченойСтепени;
	
	НаборЗаписей = Новый Структура("Отбор, Строки");
	НаборЗаписей.Отбор = Отбор;
	НаборЗаписей.Строки = Строки;
	
	ВыгрузитьРегистр(НаборЗаписей,,,Истина,"УченыеСтепениФизическихЛиц");

КонецЦикла;

конвертация данных выгрузитьпоправилу правила обмена

См. также

SALE! 20%

Перенос данных из УПП 1.3 в ERP 2 / УТ 11 / КА 2. Переносятся документы, справочная информация и остатки

Обмен между базами 1C Платформа 1С v8.3 1С:Управление производственным предприятием 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Платные (руб)

Перенос документов, начальных остатков и справочной информации из УПП 1.3 в ERP 2 | из УПП 1.3 в УТ 11 | из УПП в КА 2 | Правила конвертации (КД 2) в продаже с 2015 года, постоянно работаем над их развитием | Более 360 предприятий выполнили переход с использованием этого продукта! | Сэкономьте время - используйте готовое решение для перехода! | Позволяет перенести из УПП 1.3 в ERP / УТ 11 / КА 2 всю возможную информацию | В переносе есть фильтр по организации и множество других опциональных параметров выгрузки | Есть несколько алгоритмов выгрузки остатков на выбор

45650 36520 руб.

04.08.2015    159662    363    267    

345

SALE! 15%

[ED3] Обмен для ERP 2.5, КА 2.5, УТ 11.5 БП 3.0, Розница, УНФ и других с EnterpriseData (универсальный формат обмена), правила обмена

Обмен между базами 1C Файловый обмен (TXT, XML, DBF), FTP Платформа 1С v8.3 1С:Розница 2 1С:Управление нашей фирмой 1.6 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Управление нашей фирмой 3.0 1С:Розница 3.0 Россия Платные (руб)

Правила в универсальном формате обмена для ERP 2.5, КА 2.5, УТ 11.5, БП 3.0, Розница, УНФ, для последних версий конфигураций. Ссылки на другие конфигурации в описании публикации. Правила совместимы со всеми другими версиями конфигураций новыми и старыми, поддерживающими обмен в формате EnterpriseData. Не требуется синхронного обновления правил после обновления другой конфигурации, участвующей в обмене. Типовой обмен через планы обмена кнопкой Синхронизация вручную или автоматически по расписанию, или вручную обработкой.

25080 22572 руб.

12.06.2017    134915    722    291    

388

SALE! 20%

Перенос данных из ERP 2 / КА 2 / УТ 11 в БП 3.0. Переносятся документы, начальные остатки и справочники

Обмен между базами 1C Файловый обмен (TXT, XML, DBF), FTP Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Платные (руб)

Перенос данных из ERP в БП 3 | из КА 2 в БП 3 | из УТ 11 в БП 3 | из ЕРП в БП 3 | В продаже с 2019г. | Воспользовались более 176 предприятий! | Сэкономьте время - используйте готовое решение для перехода! | Перенос разработан в формате КД 2 (правила конвертации данных) | Переносятся все возможные виды документов, начальных остатков и нормативно-справочная информация| Можно опционально выгружать каждую пару "номенклатура+характеристика" как отдельную номенклатуру | Есть выгрузка настроек счетов учета и зарплатных данных из ERP / КА 2 | Можно проверить на вашем сервере перед покупкой, обращайтесь!

34650 27720 руб.

15.04.2019    68410    178    138    

111

SALE! 20%

Перенос данных из ERP 2 / КА 2 в ЗУП 3. Переносятся остатки, документы и справочники

Обмен между базами 1C Файловый обмен (TXT, XML, DBF), FTP Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Комплексная автоматизация 2.х 1С:Зарплата и Управление Персоналом 3.x Россия Бухгалтерский учет Управленческий учет Платные (руб)

Перенос данных из ERP в ЗУП 3 | из КА 2 в ЗУП | Воспользовались более 79 предприятий! | Предлагаем приобрести готовые правила конвертации данных (КД 2) для переноса остатков, документов с движениями и справочной информации 3 | В продаже с 2020г. | Оперативно обновляем правила до актуальных релизов 1С | Есть перенос начальной задолженности по зарплате и начальной штатной расстановки на выбранную дату | Обороты за прошлые годы (данные для расчета среднего) переносятся свернуто в документ "Перенос данных" | Есть фильтр по организациям | Документы за текущий период переносятся сразу с движениями, поэтому не потребуется делать перерасчеты | Перенос можно проверить перед покупкой, обращайтесь!

43450 34760 руб.

03.12.2020    34166    80    58    

78

SALE! 10%

Перенос данных из УТ 10.3 в УТ 11.5. Переносятся документы (обороты за период), справочная информация и остатки

Обмен между базами 1C Файловый обмен (TXT, XML, DBF), FTP Платформа 1С v8.3 Оперативный учет 1С:Управление торговлей 10 1С:Управление торговлей 11 Россия Управленческий учет Платные (руб)

Перенос данных из 1С:Управление торговлей 10.3 в 1С:Управление торговлей 11.5 с помощью правил обмена. Переносятся остатки, документы (обороты за период), справочная информация. Правила проверены на конфигурациях УТ 10.3 (10.3.87.x) и УТ 11.5 (11.5.16.x).

28000 25200 руб.

23.07.2020    46281    196    64    

157

SALE! 10%

Перенос данных из БП 3.0 в УТ 11 / КА 2 / ERP 2. Переносятся начальные остатки, документы и справочники

Обмен между базами 1C Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Платные (руб)

В продаже с 2014г. | Воспользовались более 122 предприятий! | Перенос данных из БП 3.0 в УТ 11 | из БП 3.0 в КА 2 | из БП 3.0 в ERP | Сэкономьте свое время - используйте готовое решение для перехода! | Постоянно работаем над развитием переноса данных | Обновляем на новые релизы 1С | Есть фильтр выгрузки по организациям | Переносятся начальные остатки на выбранную дату, документы за период времени и вся возможная справочная информация | Перенос сделан на технологии КД 2 (правила конвертации данных)

50722 45650 руб.

31.10.2014    231386    124    327    

295

Перенос данных из Парус 10 в ЗГУ ред.3

Внешние источники данных Кадровый учет Файловый обмен (TXT, XML, DBF), FTP Обмен между базами 1C Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и кадры государственного учреждения 3 Государственные, бюджетные структуры Россия Бухгалтерский учет Бюджетный учет Платные (руб)

Обработка позволяет перенести кадровую информацию и данные по заработной плате, фактических удержаниях, НДФЛ, вычетах, страховых взносах из базы Парус 10 учреждений в конфигурацию 1С:Зарплата и кадры государственного учреждения ред. 3 (ЗГУ) и начать с ней работать с любого месяца года.

60000 руб.

05.10.2022    9204    9    8    

10

SALE! 10%

Перенос данных из УПП 1.3 в БП 3.0. Переносятся документы (обороты за период), справочная информация и остатки

Обмен между базами 1C Файловый обмен (TXT, XML, DBF), FTP Платформа 1С v8.3 1С:Управление производственным предприятием 1С:Бухгалтерия 3.0 Россия Бухгалтерский учет Управленческий учет Платные (руб)

Перенос данных из 1С:Управление производственным предприятием 1.3 в 1С:Бухгалтерия предприятия 3.0 с помощью правил обмена. Переносятся остатки, документы (обороты за период), справочная информация. Правила проверены на конфигурациях УПП 1.3 (1.3.223.x) и БП 3.0 (3.0.149.x). Правила подходят для версии ПРОФ и КОРП.

28000 25200 руб.

15.12.2021    20232    132    38    

90
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. TarasovAV 11.11.15 10:28 Сейчас в теме
Статья хорошая. Есть замечание по поводу 2 примера.

По поводу переноса контактной информации физ. лиц (и вообще связанной информации), на мой взгляд, лучше делать так (пример для переноса КИ физ. лиц):
1. В процедуре конвертации "После загрузки правил обмена" определить параметр "ТаблицаФизЛиц" типа таблица значений с колонкой "Объект".
2. В процедуре ПКО справочника физ. лиц "После выгрузки" заполняем таблицу из пункта 1: если физ лицо присутствует в таблице - ничего не делаем, иначе добавляем.
3. В процедуре конвертации "После выгрузки данных" формируем запрос по РС "КонтактнаяИнформация" с отбором по массиву объектов из параметра "ТаблицаФизЛиц". После этого применяем функцию "ВыгрузитьПоПравилу" или "ВыгрузитьРегистр" для каждой строки результата запроса.

В данном случае имеем всего лишь 1 запрос к БД, в вашем же случае имеем столько обращений к БД за контактной информацией, сколько раз выгружаются объекты с типом "Физические лица", плюс к этому в вашем случае одна и та же информация по контактной информации может быть выгружена несколько раз (если одно и тоже физ. лицо выгружается несколько раз), что ведет к увеличению файла обмена.
temdj; VAAngelov; Pavel_Vladivostok; for_sale; sbcode; alest; lopatin; +7 Ответить
2. lopatin 680 11.11.15 10:44 Сейчас в теме
(1) TarasovAV, Согласен. Логичнее было бы сначала всех отобрать, а потом выгружать одним запросом. Как-то упустил этот нюанс)))
VAAngelov; +1 Ответить
4. alest 11.11.15 12:49 Сейчас в теме
(1) TarasovAV,
Делал немного по-другому- в ПВД ФЛ, т.к. регистрация ФЛ производилась и они выгружались по своему ПВД, а не по ссылке.
- ПВД.ПослеВыгрузки собирал ТЗ физлиц
- ПВД.ПослеОбработки делал запрос по этой ТЗ и выгружал паспортные данные и проч.

Но ваш вариант более универсален.
3. Region102 11.11.15 12:31 Сейчас в теме
КД интересна тем, что для решения задачи можно выбрать разные решения, в принципе каждый из ваших примеров можно сделать по другому, и каждый из этих способов будет правильным, но все таки хотелось бы избегать запросы в циклах как в вашем решении.
5. Zhilyakovdr 142 12.11.15 10:48 Сейчас в теме
Хорошая статья, однозначно плюс.
6. for_sale 971 25.11.15 18:23 Сейчас в теме
Очень интересная статья, спасибо!

Но сейчас я бьюсь над зеркальной задачей.
В базу-приёмник приходят данные по справочнику и регистру сведений, в котором данные по этому элементу справочника. И у справочника указано, что, при выполнении определённых условий, он не должен записывать элемент. Т.е. элемент справочника, хотя и пришёл в файле обмена, не создаётся в базе. Но проблема в том, что по нему пришли записи регистра сведений. И их тоже не надо записывать, если элемент справочника не был записан. Как проверить, был он записан или не был, если сама эта запись регистра и создала этот элемент справочника в момент загрузки.

Проблема в том, что все описанные в статье приёмы работают на стороне источника, а у меня все эти условия проверяются в приёмнике, где уже нет ВыгрузитьПоПравилу() или ЗагрузитьПоПравилу()

Знает кто-нибудь, как победить эту проблему?
7. lopatin 680 25.11.15 19:16 Сейчас в теме
(6) for_sale, Если в регистре только элемент справочника является ссылочным или если другие ссылочные измерения и реквизиты Регистра по определению должны уже существовать в базе приемнике можно попробовать отключить перенос по ссылка, если объекты не находятся:
Вкладка ПКО Настройки - Не выгружать объекты свойств источника по ссылкам.. и посмотреть какие ошибки выдаст обмен, когда у регистра не будет заполнено измерение

Какие вы условия проверяете, что они должны быть обязательно проверяться на стороне приемника? Может как-то перестроить эти условия, чтобы они проверялись на стороне Источника и не закачивать в файл вообще элементы?
8. Yuri1C 3 05.12.15 09:04 Сейчас в теме
Очень интересная и главное полезная статья.
Есть несколько вопросов:
1. ДокументыЗакреплениеЗаКафедрой = Неопределено;

Далее идет цикл по ДокументыЗакреплениеЗаКафедрой. Но оно же "Неопределено"?

2. можно увидеть текст алгоритма Алгоритмы.ПереводТаблицыЗначенийВМассивЗакреплениеЗаКафедрой ?
Спасибо!

//Переводим отобранные данные из Таблицы значений в Массив структур для дальнейшей передачи в ПКО
ДокументыЗакреплениеЗаКафедрой = Неопределено;
Выполнить(Алгоритмы.ПереводТаблицыЗначенийВМассивЗакреплениеЗаКафедрой);

//Обходим отобранные данные и выгружаем с помощью функции ВыгрузитьПоПравилу
Для каждого Документ Из ДокументыЗакреплениеЗаКафедрой Цикл
ВыгрузитьПоПравилу(,,Документ,,"ЗакреплениеЗаКафедройИзВходящихДанных");
КонецЦикла;
//Отменяем стандартную выгрузку объекта
9. lopatin 680 05.12.15 13:25 Сейчас в теме
(8) Yuri1C, ДокументыЗакреплениеЗаКафедрой, как раз в Алгоритме Перевода из ТЗ в Массив и заполняется.

В том алгоритме каждая строка ТЗ переводится в структуру с соответствующими ключевыми полями, и добавляется в массив, т.е. вместо ТЗ получается массив структур.

Сейчас этих правил нет под рукой.
10. Yuri1C 3 08.12.15 16:28 Сейчас в теме

Подскажите, пожалуйста!
в первом пункте: Выгрузка произвольной выборки данных через стандартную выборку с регистрацией объекта источника.
Все получилось. один вопрос. На последней картинке перед вторым пунктом "Выгрузка Регистр сведений -> Регистр сведений с зависимостью от переноса другого объекта." показано, но непонятно как сделать. Нужно загрузить данные именно в табличную часть, какой там код?
11. spa07 14.01.16 17:03 Сейчас в теме
Добрый день!
Подскажите пож-та как получить значение выгруженное с помощью этой функции?
Выгружаю т.ч. документа и в ней собираю справочник (объекта такого нет):
ТаблЧастьТовары.НоваяСтрока();
				ТаблЧастьТовары.Коэффициент = Объект.Коэффициент;

и т.д. далее :
ВходящиеДанные = СоздатьОбъект("СписокЗначений");
					ВходящиеДанные.ДобавитьЗначение(Наименование, "моенаименование");
					УзелСсылки=ВыгрузитьПоПравилу(,, ВходящиеДанные,, "ЕдиницыИзмеренияИнгредиенты");

объект выгружается в справочник успешно и вот теперь нужно получить и записать ссылку:
ТаблЧастьТовары.ЕдиницаИзмерения = УзелСсылки;
!!! но так не работает!
12. slawanix 9 19.01.16 20:20 Сейчас в теме
Я правильно понимаю, что в данных примерах, при использовании функции "ВыгрузитьПоПравилу()" как бы можно вообще не использовать ПВД? Ведь мы и так указываем что и по какому ПКО выгрузить. Так?
13. lopatin 680 20.01.16 11:58 Сейчас в теме
(12) slawanix, Для тех данных которые выгружаются с помощью этой функции ПВД, не то чтобы можно не использовать, его не нужно использовать. Потому что все данные будут выгружены через функцию, а через ПВД пойдут грузиться все зарегистрированные к выгрузке данные, т.е. могут выгрузиться лишние данные, не предусмотренные алгоритмом, который подразумевает использование функции ВыгрузитьПоПравилу().
14. slawanix 9 20.01.16 15:36 Сейчас в теме
(13) ок. Спасибо. И у меня возник еще вот такой вопрос, сейчас решаю свою задачу методами, взятыми на вооружение из статьи и нужно мне динамически добавить свой параметр типа ТЗ и заполнить его в обработчиках ПВД или ПКО, не важно. Делаю как в статье :
Параметры.Вставить("СписокФизическихЛиц", Новый ТаблицаЗначений());
Параметры.СписокФизическихЛиц.Колонки.Добавить("ФизическоеЛицо");

Но за одним исключением: мне нужно чтобы этот параметр был доступен для чтения в обработчике "После загрузки данных" конвертации. То есть как будто я создал параметр в форме конвертации на закладке "Параметры" и поставил ему галку При загрузке. Как это можно сделать? Мне нужны эти параметры уже для их использования на стороне приемника.
Добавлю, что параметр создается нормально и заполняется тоже как надо. Но прочитать его после загрузки данных в приемник я не могу. Не доступен.
15. Kesak 12 11.04.16 09:55 Сейчас в теме
Выгрузка Табличная часть -> Регистр сведений.
а можно увидеть ПКО "УченыеСтепениФизическихЛиц". Какой тип источника? Если не указывать тип источника и в ПКО структуру конвертировать в РС, то получаем следующую ошибку:
{Обработка.КонвертацияОбъектовИнформационныхБаз.МодульОбъекта(9676)}: Ошибка в обработчике события ПередОбработкойВыгрузки группы свойств
    ПКО                    =  ГруппыПользователей  (Пользователи -> Группы пользователей)
    ПКГС                   =  4  (--> Состав)
    Объект                 =  ОТР  (Справочник объект: Пользователи)
    Обработчик             =  ПередОбработкойВыгрузкиГруппыСвойств
    ОписаниеОшибки         =  Поле объекта не обнаружено (Ссылка)
    ПозицияМодуля          =  Обработка.КонвертацияОбъектовИнформационныхБаз.МодульОбъекта(11286)
    КСообщенияОбОшибках    =  48
    ВызватьИсключение СтрокаСообщенияОбОшибке;
Показать
если имеем источник с пустым типом, то механизм в модуле объекта "КонвертацияОбъектовИнформационныхБаз" думает, что выгружается ссылочный объект. Можно ли обойти данную проблему без правки кода БСП?
e-9; rakhimov9; +2 Ответить
17. v.gonchar 09.12.16 13:28 Сейчас в теме
(15)
Столкнулся с аналогичной проблемой, решил путём добавления колонки с именем "Ссылка" в строки набора записей.
Рабочий пример для обработчика ПКО "После выгрузки в файл"

Запрос = Новый Запрос("
|ВЫБРАТЬ
|	ФизическиеЛицаКонтактнаяИнформация.Ссылка КАК Объект,
|	ФизическиеЛицаКонтактнаяИнформация.Тип КАК Тип,
|	ФизическиеЛицаКонтактнаяИнформация.Вид КАК Вид,
|	ФизическиеЛицаКонтактнаяИнформация.Представление КАК Представление,
|	ИСТИНА КАК Активность
|ИЗ
|	Справочник.ФизическиеЛица.КонтактнаяИнформация КАК ФизическиеЛицаКонтактнаяИнформация
|ГДЕ
|	ФизическиеЛицаКонтактнаяИнформация.Ссылка = &Ссылка");

Запрос.УстановитьПараметр("Ссылка", Источник.Ссылка);

Выборка = Запрос.Выполнить().Выбрать();

Пока Выборка.Следующий() Цикл
	
	Отбор = Новый ТаблицаЗначений;
	Отбор.Колонки.Добавить ("Имя");
	Отбор.Колонки.Добавить ("Значение");
	Отбор.Колонки.Добавить ("Использование");
	
	СтрокаОтбора = Отбор.Добавить();
	СтрокаОтбора.Имя = "Объект";
	СтрокаОтбора.Значение = Выборка.Объект;
	СтрокаОтбора.Использование = Истина;
	
	Строки = Новый ТаблицаЗначений;
	Строки.Колонки.Добавить("Представление");
	Строки.Колонки.Добавить("Вид");
	Строки.Колонки.Добавить("Тип");
	Строки.Колонки.Добавить("Объект");
	Строки.Колонки.Добавить("Активность");
	Строки.Колонки.Добавить("Ссылка"); // Добавленная колонка.
	
	Строка = Строки.Добавить();
	Строка.Представление = Выборка.Представление;
	Строка.Вид = Выборка.Вид;
	Строка.Тип = Выборка.Тип;
	Строка.Объект = Выборка.Объект;
	Строка.Активность = Выборка.Активность;
	
	НаборЗаписей = Новый Структура("Отбор, Строки");
	НаборЗаписей.Отбор = Отбор;
	НаборЗаписей.Строки = Строки;
	
	ВыгрузитьРегистр(НаборЗаписей,,,, "КонтактнаяИнформация");

КонецЦикла;
Показать
16. ut2k5 15 15.07.16 12:47 Сейчас в теме
а у меня ругается, не находит функцию "ВыгрузитьРегистр"
user632804_tak_tanya80; user702607_p.golovanov; and_r; vsesam80; Westbound; ixijixi; +6 Ответить
18. ghost1987 02.06.17 09:34 Сейчас в теме
Добрый день, подскажите как можно сделать следующее: в источнике получаем запросом таблицу проводок (запросом), а в приемнике ее необходимо загрузить в документ Операция (бухгалтерия)??? поможет ли сделать ВыгрузитьПоПравилу???
19. nord_semirami 23.08.17 13:29 Сейчас в теме
Спасибо, статья прям направила на путь истинный!
Хотелось бы еще аналогичную со стороны загрузки, какие преобразования и как выполняются. Потому что иногда в источнике есть данные, а в приемник их нужно преобразовать. Значение реквизита справочника, например, в строковое значение.
20. yegorovnv 02.09.17 17:56 Сейчас в теме
Спасибо за труд. Почерпнул для себя полезное. Поставлю +
21. Coole 12.11.17 05:44 Сейчас в теме
Ошибка в обработчике события ПослеВыгрузкиДанных (конвертация)
Обработчик = ПослеВыгрузкиДанных (конвертация)
ОписаниеОшибки = Ошибка компиляции при вычислении выражения или выполнении фрагмента кода: {(1,9)}: Переменная не определена (Источник)
ПозицияМодуля = Обработка.УниверсальныйОбменДаннымиXML.МодульОбъекта(12962)
КодСообщения = 63
Сначала сделала как в статье. Работает, но очень долго.
Сделала с учетом апдейт, ошибка выше, что я сделала не так(?
22. lopatin 680 13.11.17 15:28 Сейчас в теме
(21)Очень похоже на то, что в том обработчике каком вы пишите код, нет переменной Источник
23. Coole 13.11.17 16:00 Сейчас в теме
(22) да с этим разобралась.
теперь дургая тема, как значение Организации передать в приемник
https://forum.infostart.ru/forum15/topic181146/#message1880539
если можете, помогите)))
24. e-9 60 28.12.17 12:48 Сейчас в теме
Очень не хватает для последнего примера (табчасть => регистр сведений) скрина с ПКС для ПКО "УченыеСтепениФизическихЛиц".
Я выгружаю данные из табчасти документа, приемник регистр сведений (независимый, непериодический) - и никак не могу победить (см. скрин)...

...код в "После выгрузки данных" конвертации:
Запрос = Новый Запрос;
Запрос.Текст = 
	"ВЫБРАТЬ
	|	ЮИ_ПриемкаМолокаРасчетСтоимостиМолока.Ссылка,
	|	ЮИ_ПриемкаМолокаРасчетСтоимостиМолока.Ссылка.Номер КАК НомерПартии,
	|	ЮИ_ПриемкаМолокаРасчетСтоимостиМолока.Ссылка.Дата КАК ДатаПартии,
	|	ЮИ_ПриемкаМолокаРасчетСтоимостиМолока.Ссылка.Контрагент КАК Отправитель,
	|	ЮИ_ПриемкаМолокаРасчетСтоимостиМолока.Ссылка.НомерВходящегоДокумента КАК НомерВходящегоДокумента,
	|	ЮИ_ПриемкаМолокаРасчетСтоимостиМолока.Ссылка.Склад КАК ПунктПогрузки,
	|	ЮИ_ПриемкаМолокаРасчетСтоимостиМолока.Ссылка.Ферма КАК ПунктРазгрузки,
	|	ЮИ_ПриемкаМолокаРасчетСтоимостиМолока.НомерСтроки КАК НомерСтрокиДокумента,
	|	ЮИ_ПриемкаМолокаРасчетСтоимостиМолока.Белок,
	|	ЮИ_ПриемкаМолокаРасчетСтоимостиМолока.ГруппаЧистоты,
	|	ЮИ_ПриемкаМолокаРасчетСтоимостиМолока.Жирность,
	|	ЮИ_ПриемкаМолокаРасчетСтоимостиМолока.Кислотность,
	|	ЮИ_ПриемкаМолокаРасчетСтоимостиМолока.Плотность,
	|	ЮИ_ПриемкаМолокаРасчетСтоимостиМолока.Редуктаза,
	|	ЮИ_ПриемкаМолокаРасчетСтоимостиМолока.Сорт,
	|	ЮИ_ПриемкаМолокаРасчетСтоимостиМолока.Температура
	|ИЗ
	|	Документ.ЮИ_ПриемкаМолока.РасчетСтоимостиМолока КАК ЮИ_ПриемкаМолокаРасчетСтоимостиМолока
	|ГДЕ
	|	ЮИ_ПриемкаМолокаРасчетСтоимостиМолока.Ссылка В(&МассивСсылок)";

МассивСсылок = Параметры.ТЗДокументов.ВыгрузитьКолонку("Ссылка");
Запрос.УстановитьПараметр("МассивСсылок", МассивСсылок);

Выборка = Запрос.Выполнить().Выбрать();

Пока Выборка.Следующий() Цикл
    
    Отбор = Новый ТаблицаЗначений;
    Отбор.Колонки.Добавить ("Имя");
    Отбор.Колонки.Добавить ("Значение");
    Отбор.Колонки.Добавить ("Использование");
    
    СтрокаОтбора = Отбор.Добавить();
	СтрокаОтбора.Имя = "GUIN";
    СтрокаОтбора.Значение = XMLСтрока(Выборка.Ссылка);
    СтрокаОтбора.Использование = Истина;
    СтрокаОтбора = Отбор.Добавить();
    СтрокаОтбора.Имя = "НомерСтрокиДокумента";
    СтрокаОтбора.Значение = Выборка.НомерСтрокиДокумента;
    СтрокаОтбора.Использование = Истина;
    
    Строки = Новый ТаблицаЗначений;
	Строки.Колонки.Добавить("GUIN");
	Строки.Колонки.Добавить("Отправитель");
    Строки.Колонки.Добавить("НомерВходящегоДокумента");
	Строки.Колонки.Добавить("ПунктПогрузки");
	Строки.Колонки.Добавить("ПунктРазгрузки");
    Строки.Колонки.Добавить("Номенклатура");
    Строки.Колонки.Добавить("ДатаПартии");
    Строки.Колонки.Добавить("НомерПартии");
	Строки.Колонки.Добавить("НомерСтрокиДокумента");
    Строки.Колонки.Добавить("Белок");
    Строки.Колонки.Добавить("Жирность");
    Строки.Колонки.Добавить("Кислотность");
    Строки.Колонки.Добавить("Плотность");
    Строки.Колонки.Добавить("Редуктаза");
    Строки.Колонки.Добавить("Сорт");
    Строки.Колонки.Добавить("Температура");
    Строки.Колонки.Добавить("ГруппаЧистоты");
    
    Строка = Строки.Добавить();
	ЗаполнитьЗначенияСвойств(Строка, Выборка);
    
    НаборЗаписей = Новый Структура("Отбор, Строки");
    НаборЗаписей.Отбор = Отбор;
    НаборЗаписей.Строки = Строки;

	ВыгрузитьРегистр(НаборЗаписей,,,Истина,"ЮИ_СырьеМолокоДляAITS");

КонецЦикла;
Показать
Прикрепленные файлы:
26. e-9 60 29.12.17 11:37 Сейчас в теме
(24) ...сам себе же и отвечу: видимо, у автора (и тех, у кого "все получилось") совсем другая "кухня" КД, в которой все "варится" - т.е., та самая встроенная универсальная обработка, которая осуществляет функциональность конвертации. У меня это ОбменДаннымиXML.

Так вот, при раскуривании процедуры ВыгрузитьРегистр стало ясно, что никакую структуру("Отбор, Строки") она не поймет. Только НаборЗаписей регистра:
	Для Каждого СтрокаРегистра Из НаборЗаписейДляВыгрузки Цикл
		
		ВыгрузкаОбъектаВыборки(СтрокаРегистра, ПравилоВыгрузкиДанных, , ВходящиеДанные, НеВыгружатьОбъектыПоСсылкам, Истина, 
			Приемник, , ИмяПКО, ЛОЖЬ);
				
	КонецЦикла;


Т.е., в этой версии "кухни", эта функция годиться ТОЛЬКО для переноса регистра в регистр. И без доработки (неизвестно заранее, насколько глубокой - например, после того как я изменил выше на НаборЗаписейДляВыгрузки.СТРОКИ - полезли новые ошибки) не "взлетит".

П.С. Тут, кстати, пример, который ответил на мой следующий вопрос про "гранулярность" применения этой функции:
http://www.forum.mista.ru/topic.php?id=803805
Все-таки автор не вполне корректно применил функцию ВыгрузитьРегистр.

П.П.С.
А вот тут почерпнул для себя рабочую, в итоге, идею, как перенести таб.часть в регистр сведений:
http://novichok1c.ru/vygruzka-dannyh-iz-tablichnoy-chasti-dokumenta-ili-spravochnika-v-nezavisimyy-registr-svedeniy

Правда, там не учтен (или не раскрыт) один важный нЬюанс: при УДАЛЕНИИ записи табчасти в источнике, это удаление никак не отразится в приемнике - там запись останется!! Надо что-то мутить в правилах на стороне приемника...Вот над этим сейчас работаю - если добью, постараюсь поделиться.
ДимонД; Zurfik; eeeio; +3 Ответить
27. e-9 60 29.12.17 13:07 Сейчас в теме
(26) договорю сам с собой)
Итак, сделал успешно выгрузку из табчасти документа в РС, как в последней ссылке выше; теперь цель: перезаписывать при обмене наборы записей по "объекту" (в моем случае роль "объекта" играет строковое поле GUIN), чтобы не только добавлялись новые, но и очищались удаленные записи.

1. В обработчике КОНВЕРТАЦИИ "Перед загрузкой данных" инициируем глобальную ТЗ с полями, как у регистра-приемника (ОБЯЗАТЕЛЬНО явно типизируем поля):
Параметры.Вставить("ТЗЗаписей", Новый ТаблицаЗначений()); 
Параметры.ТЗЗаписей.Колонки.Добавить("GUIN", ОбщегоНазначения.ПолучитьОписаниеТиповСтроки(36));
Параметры.ТЗЗаписей.Колонки.Добавить("Отправитель", ОбщегоНазначения.ПолучитьОписаниеТиповСтроки(200));
Параметры.ТЗЗаписей.Колонки.Добавить("НомерВходящегоДокумента", ОбщегоНазначения.ПолучитьОписаниеТиповСтроки(12));
Параметры.ТЗЗаписей.Колонки.Добавить("ПунктПогрузки", ОбщегоНазначения.ПолучитьОписаниеТиповСтроки(200));
Параметры.ТЗЗаписей.Колонки.Добавить("ПунктРазгрузки", ОбщегоНазначения.ПолучитьОписаниеТиповСтроки(200));
Параметры.ТЗЗаписей.Колонки.Добавить("Номенклатура", ОбщегоНазначения.ПолучитьОписаниеТиповСтроки(200));
Параметры.ТЗЗаписей.Колонки.Добавить("ДатаПартии", ОбщегоНазначения.ПолучитьОписаниеТиповДаты(ЧастиДаты.Дата));
Параметры.ТЗЗаписей.Колонки.Добавить("НомерПартии", ОбщегоНазначения.ПолучитьОписаниеТиповСтроки(12));
Параметры.ТЗЗаписей.Колонки.Добавить("НомерСтрокиДокумента", ОбщегоНазначения.ПолучитьОписаниеТиповЧисла(10));
Параметры.ТЗЗаписей.Колонки.Добавить("Белок", ОбщегоНазначения.ПолучитьОписаниеТиповЧисла(5,2));
Параметры.ТЗЗаписей.Колонки.Добавить("Жирность", ОбщегоНазначения.ПолучитьОписаниеТиповЧисла(5,2));
Параметры.ТЗЗаписей.Колонки.Добавить("Кислотность", ОбщегоНазначения.ПолучитьОписаниеТиповЧисла(15,3));
Параметры.ТЗЗаписей.Колонки.Добавить("Плотность", ОбщегоНазначения.ПолучитьОписаниеТиповЧисла(15,3));
Параметры.ТЗЗаписей.Колонки.Добавить("Редуктаза", ОбщегоНазначения.ПолучитьОписаниеТиповСтроки(25));
Параметры.ТЗЗаписей.Колонки.Добавить("Сорт", ОбщегоНазначения.ПолучитьОписаниеТиповСтроки(10));
Параметры.ТЗЗаписей.Колонки.Добавить("Температура", ОбщегоНазначения.ПолучитьОписаниеТиповЧисла(3,1));
Параметры.ТЗЗаписей.Колонки.Добавить("ГруппаЧистоты", ОбщегоНазначения.ПолучитьОписаниеТиповЧисла(1));
Параметры.ТЗЗаписей.Колонки.Добавить("Активность", Новый ОписаниеТипов("Булево"));
Показать


2. В обработчике КОНВЕРТАЦИИ (хотя можно и в аналогичном ПКО) "После загрузки объекта" добавляем строчку в ТЗ, заполняем ее из объекта - и отказываемся от записи объекта:
Если объект <> Неопределено Тогда //Неопределено прилетает из "костыльного" ПКО, который называется "НеВажно"
	ЗаполнитьЗначенияСвойств(Параметры.ТЗЗаписей.Добавить(),Объект);
КонецЕсли;	
Отказ = Истина;


3. В обработчике КОНВЕРТАЦИИ "После загрузки данных" делаем всю работу:
Запрос = Новый Запрос;
Запрос.Текст = 
	"ВЫБРАТЬ
	|	ТЗЗаписей.*
	|ПОМЕСТИТЬ Записи
	|ИЗ
	|	&ТЗЗаписей КАК ТЗЗаписей
	|;
	|ВЫБРАТЬ
	|	Записи.*
	|ИЗ
	|	Записи КАК Записи
	|ИТОГИ ПО GUIN
	|";

Запрос.УстановитьПараметр("ТЗЗаписей", Параметры.ТЗЗаписей);

Выборка = Запрос.Выполнить().Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);
Пока Выборка.Следующий() Цикл
	
	НаборЗаписей = РегистрыСведений.ЮИ_СырьеМолокоДляAITS.СоздатьНаборЗаписей();
	НаборЗаписей.Отбор.GUIN.Установить(Выборка.GUIN);
	НаборЗаписей.Записать();

	ВыборкаДетали = Выборка.Выбрать();
	Пока ВыборкаДетали.Следующий() Цикл
		Строка = НаборЗаписей.Добавить();
		ЗаполнитьЗначенияСвойств(Строка, ВыборкаДетали);
	КонецЦикла;    

	НаборЗаписей.Записать();
	
КонецЦикла;
Показать


...It works!!!..
ДимонД; headMade; Zurfik; eeeio; +4 Ответить
25. e-9 60 28.12.17 15:15 Сейчас в теме
...И еще, вопрос ко всем кто "втыкнул" в эту тему: почему у автора "гранула обмена" (набор записей) для ВыгрузитьРегистр - это каждая ученая степень??? (последний пример)
Ведь отбор установили на уровне физ. лица!
...
 СтрокаОтбора.Имя = "ФизическоеЛицо";
 СтрокаОтбора.Значение = Выборка.Ссылка;

...
Не правильнее ли было в запрос добавить итоги по физ-лицу, и сделать обход двумя вложенными циклами, "отправляя" набор записей в ВыгрузитьРегистр во внешнем цикле (по физ. лицу), а не каждую ученую степень...
28. muzzombie 19.12.18 16:41 Сейчас в теме
Здравствуйте! Пожалуйста, помогите!
В "После загрузки правил обмена" написал:

Параметры.Вставить("СписокСотрудников", Новый ТаблицаЗначений());
Параметры.СписокСотрудников.Колонки.Добавить("Сотрудник");
Параметры.СписокСотрудников.Колонки.Добавить("ВидЗанятости");


В "После выгрузки" у справочника "Сотрудники" написал:
НайденнаяСтрока = Параметры.СписокСотрудников.Найти(Источник);
Если НайденнаяСтрока = Неопределено Тогда
    ЗапросВидаЗанятости = Новый Запрос;
    ЗапросВидаЗанятости.Текст = "ВЫБРАТЬ
    |    ВЫБОР
    |        КОГДА ВидыЗанятостиСотрудниковСрезПоследних.ВидЗанятости = ЗНАЧЕНИЕ(Перечисление.ВидыЗанятости.ОсновноеМестоРаботы)
    |            ТОГДА ""Основное место работы""
    |        КОГДА ВидыЗанятостиСотрудниковСрезПоследних.ВидЗанятости = ЗНАЧЕНИЕ(Перечисление.ВидыЗанятости.Совместительство)
    |            ТОГДА ""Внешнее совместительство""
    |        КОГДА ВидыЗанятостиСотрудниковСрезПоследних.ВидЗанятости = ЗНАЧЕНИЕ(Перечисление.ВидыЗанятости.ВнутреннееСовместительство)
    |            ТОГДА ""Внутреннее совместительство""
    |    КОНЕЦ КАК ВидЗанятости
    |ИЗ
    |    РегистрСведений.ВидыЗанятостиСотрудников.СрезПоследних КАК ВидыЗанятостиСотрудниковСрезПоследних
    |ГДЕ
    |    ВидыЗанятостиСотрудниковСрезПоследних.Сотрудник = &Сотрудник";
    ЗапросВидаЗанятости.УстановитьПараметр("Сотрудник", Источник);
    
    РезультатЗапросВидаЗанятости = ЗапросВидаЗанятости.Выполнить().Выбрать();
    Если РезультатЗапросВидаЗанятости.Следующий() Тогда
        НоваяСтрока = Параметры.СписокСотрудников.Добавить();
            НоваяСтрока.Сотрудник = Источник;
        НоваяСтрока.ВидЗанятости =  РезультатЗапросВидаЗанятости.ВидЗанятости;    
    КонецЕсли;

КонецЕсли;
Показать



С помощью оператора "Сообщить" я узнал, что параметр заполняется как надо. Однако в XML-файл параметр "СписокСотрудников" не попадает. Использую "Универсальный обмен данных". Выгрузку делаю из ЗУП 3.1.8.155.


В чем может быть причина?
29. lopatin 680 19.12.18 16:45 Сейчас в теме
(28)Попробуйте параметр объявить в самих правилах и выставить свойство используется в при загрузке. А в "После загрузки правил обмена", уже указать, что это таблица значений.
30. muzzombie 20.12.18 08:28 Сейчас в теме
(29) Увы, чуда не произошло. Параметр заполняется как надо, но в XML-файл не попадает.
Прикрепленные файлы:
31. lopatin 680 20.12.18 09:19 Сейчас в теме
(30)Передавать при выгрузке пробовали еще поставить?

Возможно это означает, что параметр будет помещен в файл выгрузки, когда будут выгружать данные.
32. muzzombie 20.12.18 10:14 Сейчас в теме
33. user603532_fan_club_chelsea 13.02.19 12:39 Сейчас в теме
Добрый день. Не подскажите почему у меня Функция ВыгрузитьПоПравилу не работает в БСП.

Выходит Ошибка при ЗаполнитьЗначениеСвойств(*, Источник) - где источник = Неопределенно выходит. И поэтому выходит ошибка во втором параметре. Хотя Источник мне нет необходимости выгружать, если у меня все через ВходящиеДанные выгружается.

Помогите с этим вопросом разобраться. Не могу узел из-за этого добавить
34. lopatin 680 13.02.19 12:47 Сейчас в теме
(33) А как вы собираетесь использовать функцию ЗаполнитьЗначениеСвойств, если вы не указываете откуда эта функция должна заполнять свойства?
35. user603532_fan_club_chelsea 13.02.19 13:26 Сейчас в теме
(34) ПервыйПараметр - *, Второй - Источник. Ругается именно на "Источник"...
36. user603532_fan_club_chelsea 13.02.19 13:29 Сейчас в теме
(34) И эта функция Типовая в КомплекснойАвтоматизации в Обрваботке "КонвертацияОбъектовИнформационнойБазы.

вот сама ошибка
{Обработка.КонвертацияОбъектовИнформационныхБаз.МодульОбъекта(4283)}: Ошибка в обработчике события ПередВыгрузкойОбъекта
ПВД = ЗаказКлиента
Объект = Заказ клиента 00АШ-000177 от 17.01.2019 9:49:00 (Документ объект: Заказ клиента)
Обработчик = ПередВыгрузкойОбъектаВыборки
ОписаниеОшибки = Ошибка при вызове метода контекста (ЗаполнитьЗначенияСвойств): Недопустимое значение параметра (параметр номер '2')
ПозицияМодуля = Обработка.КонвертацияОбъектовИнформационныхБаз.МодульОбъекта(324)
КСообщенияОбОшибках = 33
ВызватьИсключение СтрокаСообщенияОбОшибке;
38. lopatin 680 13.02.19 15:27 Сейчас в теме
(36) Как мне кажется это не типовая функция в обработке, а это ваш код, который вы вызываете в обработчике ПередВыгрузкойОбъектаВыборки...

Проверяйте код в этом обработчике. Вам же пишет Недопустимое значение параметра номер 2.

Вы сказали что Источник = Неопределено, ЭТО не правильно. Нельзя передавать неопределенный Источник. Там должен быть объект с свойствами.
39. user603532_fan_club_chelsea 14.02.19 04:59 Сейчас в теме
(38) ошибка именно в обработке которая типовая. Номер строки модуля указывает туда. Даже в самой статье указано... Что если все реквизиты документа получать из входящих данных тогда можно источник не указывать...
40. user603532_fan_club_chelsea 14.02.19 07:50 Сейчас в теме
(38)
Выгрузка Табличная часть -> Регистр сведений.
По своему решению задача аналогична предыдущей. С той лишь разницей, что информацию для регистра сведений "приемника" брать придется из других объектов "источника", а точнее табличной части того объекта, который на данный момент выгружается. Если бы на стороне "приемника" была так же табличная часть, то задача легко решалась бы в виде ПГКС. Поэтому снова воспользуемся функцией ВыгрузитьРегистр.

Надеюсь это решение моей проблемы.
37. пользователь 13.02.19 14:08
Сообщение было скрыто модератором.
...
41. gamletspb 100 17.05.19 11:56 Сейчас в теме
Может я чего не так понимаю, но.
В первом примере автор пишет:
Пишем обработчик "Перед выгрузкой"

и пихает в него свой запрос выборки данных и потом в цикле выгружает данные по этой выгрузку..

Причем подчеркивает, что нужно использовать именно этот обработчик (впрочем, никак не объясняя, почему).

Однако в описании данного обработчика сказано:
Перед выгрузкой объекта
Условия возникновения события
Событие выполняется при получении очередного объекта из выборки, до передачи этого объекта правилу конвертации.


соответственно если сделать так как говорит автор, то получим получение нашей выборки много много раз - столько раз, сколько возвращается объектов из стандартной выборки. То что мы в конце отменили стандартную выгрузку объекта вовсе не отменяет саму стандартную выборку.
43. olegbilas 20.03.20 16:37 Сейчас в теме
(41) Нужно использовать обработчик не "Перед выгрузкой", а "Перед обработкой"
42. Dracarys 03.02.20 12:55 Сейчас в теме
Здравствуйте!
Подскажите, при ВыгрузитьПоПравилу() Справочника, выгружается только один объект (по запросу первый). Как выгрузить все объекты справочника по правилу? При выгрузке из Регистра - проблем не возникает.

В примере выгружаю из справочника ФизЛица объект и вместе с ним нужно выгрузить из справочника РодственникиФизическихЛиц с отбором по владельцу(ФизЛицо) объекты.
44. Bru_10 29.03.20 14:10 Сейчас в теме
45. agata_v 16.02.21 13:04 Сейчас в теме
Помогите, пожалуйста, у меня ругается, не находит функцию "ВыгрузитьРегистр", пробовала ставить в обработчике "После выгрузкивФайл" и в обработчике "Послевыгрузкиданных".
48. Kesak 12 26.01.22 09:30 Сейчас в теме
(45) (16)
в УниверсальнойЗагрузкеВыгрузкеXML нет такого метода как "ВыгрузитьРегистр". Работает ВыгрузитьПоправилу и в отличие от "ВыгрузитьРегистр" работает не набором записей, а с записью, т.е. набор нужно перебирать, например, в цикле:
Для Каждого ЗаписьРС Из НаборРС Цикл
     ВыгрузитьПоПравилу(ЗаписьРС,,,,"КонтактнаяИнформация");
КонецЦикла;


в планах обмена, настроенных с БСП работает конструкция "ВыгрузитьРегистр":
ВыгрузитьРегистр(НаборЗаписей,,, Истина, "КонтактнаяИнформация");
and_r; Student1C; EvilMilko; +3 Ответить
46. agata_v 16.02.21 13:53 Сейчас в теме
ВыгрузитьПоПравилу работает
47. Aleksandr_prof 191 26.05.21 13:44 Сейчас в теме
адаптировать правила под БСП уже отлаженные на обработке Универсальный обмен XML

А можно об этом поподробнее? Сталкивался с ситуацией, когда правила работают через план обмена, но не работают через обработку Универсальный обмен XML.
49. vat-74 166 15.03.22 09:02 Сейчас в теме
Не могу понять, как выгрузить данные для постобработки.
т.е. В источнике документ один, а в приемнике тип документов один, но объектов может быть несколько, в зависимости от содержания ТЧ источника.
50. Pashkaa 16 23.08.23 07:55 Сейчас в теме
(49) Ответ в этом разделе публикации "Выгрузка произвольной выборки данных через стандартную выборку с регистрацией объекта источника."

Вы создаете два Правила конвертации объекта. ПКО №1 для нужного вида документа Источника, где Приемником будет Стандартная выборка. ПКО №2 будет с нужным видом документа Приемника и галкой что получать данные из Входящих данных.

В ПКО №1 выбираете ваши данные по документу и трансформируете их в наборы данных как вам они будут нужны в Приемнике, где каждая запись такого набора это Входящие данные для ПКО №2 создающие один документ в Приемнике.

Из ПКО №1 вызываете ПКО №2 передавая ему Входящие данные.
Оставьте свое сообщение