Порядок субконто при выгрузке в ТЗ

Форум Программирование Общие вопросы программирования (Dev)

Платформа 1С v8.3

1. dfgdsfgsdfg2011 10.09.15 14:00 Сейчас в теме

набор записей регистра бухгалтерии выгружается в таблицу значений

 НаборЗаписей = РегистрыБухгалтерии.ЕПСБУ.СоздатьНаборЗаписей();
 НаборЗаписей.Отбор.Регистратор.Установить(Регистратор);
 
 НаборЗаписей.Прочитать();
 ТЗ = НаборЗаписей.Выгрузить();

если просмотреть в отладчике таблицу, то видно, что субконто поменялись местами.
Например, в плане счетов указано, что Субконто2 - Контрагент, Субконто3 - Договор,
а ТЗ выводит наоборот(Субконто2 - Договор, Субконто3 - Контрагент)

По теме из базы знаний

Ответы

Подписаться на ответы Инфостарт бот

Свернуть все

2. tango 546 11.09.15 00:47 Сейчас в теме

а подробности? со скринами?
с версией платформы и что такое ЕПСБУ

3. sergathome 4 10.04.18 12:33 Сейчас в теме

Автор абсолютно прав, есть такая проблема. Уже 10 лет есть...

4. dvsidelnikov 74 18.02.23 10:44 Сейчас в теме

Поделюсь ка своим велосипедом:

// НаборЗаписей.Выгрузить() не гарантирует соответствие порядка и нумерации Субконто.
// Данная Процедура это соответствие устанавливает
//Упорядочить Субконто Выгруженного Набора Записей
// Параметры:
//  Таблица  - ТаблицаЗначений - Результат НаборЗаписей.Выгрузить()
//                 <продолжение описания параметра>
//
Процедура УпорядочитьСубконтоВыгруженногоНабораЗаписей(Таблица)
     МассивДтКт = Новый Массив;
     МассивДтКт.Добавить("Дт");
     МассивДтКт.Добавить("Кт");
     
     Для Каждого ЗаписьТаблицы из Таблица Цикл
          Для Каждого ДтКт из МассивДтКт Цикл
               Счет = ЗаписьТаблицы["Счет" + ДтКт];
               Если Не ЗначениеЗаполнено(Счет) Тогда
                    Продолжить;
               КонецЕсли;
               
               Субконто = Новый Соответствие;
               ВидыСубконтоСчета = Счет.ВидыСубконто;
               КоличествоСубконто = ВидыСубконтоСчета.Количество();
               Для сч = 1 по КоличествоСубконто Цикл
                    Субконто.Вставить(ЗаписьТаблицы["ВидСубконто"+ДтКт+сч], ЗаписьТаблицы["Субконто"+ДтКт+сч]);
               КонецЦикла;
               Для сч = 1 по КоличествоСубконто Цикл
                    ВидСубконто = ВидыСубконтоСчета[сч-1].ВидСубконто;
                    ЗаписьТаблицы["ВидСубконто"+ДтКт+сч] = ВидСубконто;
                    ЗаписьТаблицы["Субконто"+ДтКт+сч] = Субконто[ВидСубконто];
               КонецЦикла;
          КонецЦикла;
     КонецЦикла;
КонецПроцедуры //УпорядочитьСубконтоВыгруженногоНабораЗаписей()

Показать

Оставьте свое сообщение

E-mail: