Расчет контрольной суммы строки по алгоритму CRC32 методами встроенного языка платформы "1С:Предприятие" (версии ранее 8.3)

10.11.23

Разработка - Механизмы платформы 1С

Расширение типового функционала прикладного решения путем добавления возможности выполнения двоичных операций с числами.

Скачать файлы

Наименование Файл Версия Размер
РасширениеФункционалаПрикладногоРешения.epf
.epf 23,80Kb
21
.epf 23,80Kb 21 Скачать

В платформе "1С:Предприятие" версии 8.3 появилось много дополнительных возможностей: в том числе вычисления результатов хеш-функций, что в практике программирования зачастую бывает востребовано. А что предпринять тем, кто по каким-либо причинам не перешёл на новую платформу? Вывод очевиден - расширять функционал своих прикладных решений методами используемой платформы. В этой публикации я расскажу, как методами встроенного языка реализовать алгоритм расчета контрольной суммы строки по алгоритму CRC32, а также получить индекс цвета на основе его составляющих.

Для начала нам потребуется написать несколько вспомогательных функций для перевода чисел с одним основанием в числа с другим основанием и  выполнения расчета бинарных операций. Таких функций написано немало, поэтому на оригинальность не претендую. Но всё же код этих функций приведу.

Функция ТекстОшибки(ИмяФункции, ОписаниеОшибки) Экспорт
	
	Возврат ИмяФункции + ": " + ОписаниеОшибки;
	
КонецФункции // ТекстОшибки()
Функция ПреобразоватьЧислоВСтрокуСДругимОснованием(Знач Значение, Основание, Результат, МинимальнаяДлинаТипаЧисла = 0) Экспорт
	
	Перем ШаблонПреобразования;
	Перем ИмяФункции;
	Перем ОписаниеОшибки;
	
	ИмяФункции 				= "ПреобразоватьЧислоВСтрокуСДругимОснованием";
	ШаблонПреобразования	= "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ";
	ОписаниеОшибки 			= "";
	Результат 				= "";
	
	Попытка
		
		Значение = Число(Значение);
		Если (Основание < 2) ИЛИ (Основание > 36) ИЛИ (НЕ (Основание - Цел(Основание) = 0)) Тогда
			ВызватьИсключение(ТекстОшибки(ИмяФункции, "Основание числа должно находиться в диапазоне от 2 до 36!"));
		ИначеЕсли Значение < 0 ИЛИ НЕ (Значение - Цел(Значение) = 0) Тогда 	
			ВызватьИсключение(ТекстОшибки(ИмяФункции, "Значение числа должно быть целым положительным!"));
		ИначеЕсли Значение = 0 Тогда 	
			Результат = "0";
		Иначе
			// Перевод в систему с другим основанием
			Пока Значение > 0 Цикл
				Результат = Сред(ШаблонПреобразования, Значение % Основание + 1, 1) + Результат;
				Значение = Цел(Значение / Основание);
			КонецЦикла;
		КонецЕсли; 
		
		// Если требуется, дополняем строку до требуемой длины нолями
		Для Счетчик = СтрДлина(Результат) + 1 По МинимальнаяДлинаТипаЧисла Цикл
			Результат = "0" + Результат;
		КонецЦикла; 
		
	Исключение
		ОписаниеОшибки = ОписаниеОшибки();
	КонецПопытки;
	
	Возврат ОписаниеОшибки;
	
КонецФункции

Функция ПреобразоватьСтрокуСДругимОснованиемВЧисло(Знач Значение, Основание, Результат) Экспорт
	
	Перем ШаблонПреобразования;
	Перем ИмяФункции;
	Перем ОписаниеОшибки;
	
	ИмяФункции 				= "ПреобразоватьСтрокуСДругимОснованиемВЧисло";
	ШаблонПреобразования	= "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ";
	ОписаниеОшибки 			= "";
	Результат 				= "";
	
	Попытка
		
		Результат = 0;
		Значение = Врег(СокрЛП(Значение));
		Если (Основание < 2) ИЛИ (Основание > 36) ИЛИ (НЕ (Основание - Цел(Основание) = 0)) Тогда
			ВызватьИсключение(ТекстОшибки(ИмяФункции, "Основание числа должно  быть целым и находиться в диапазоне от 2 до 36!"));
		ИначеЕсли (Значение = "0") ИЛИ (СтрДлина(Значение) = 0) Тогда 	
			Результат = 0;	
		Иначе	
			// Проверка правильности исходного значения
			ШаблонПроверки = Лев(ШаблонПреобразования, Основание);
			Для НомерСимвола = 1 По СтрДлина(Значение) Цикл
				Если Не Найти(ШаблонПроверки, Сред(Значение, НомерСимвола, 1)) Тогда
					ВызватьИсключение("Преобразуемое значение содержит недопустимые символы!");
				КонецЕсли; 		
			КонецЦикла; 
			
			// Перевод в систему с основанием 10
			ДлинаЗначения = СтрДлина(Значение);
			Для НомерСимвола = 1 По ДлинаЗначения Цикл
				МножительПорядкаЧисла = 1;
				Для СчетчикЦикла = 1 По ДлинаЗначения - НомерСимвола Цикл
					МножительПорядкаЧисла = МножительПорядкаЧисла * Основание;
				КонецЦикла;
				Результат = Результат + (Найти(ШаблонПреобразования, Сред(Значение, НомерСимвола, 1)) - 1) * МножительПорядкаЧисла;
			КонецЦикла;
		КонецЕсли; 
		
		
	Исключение
		ОписаниеОшибки = ОписаниеОшибки();
	КонецПопытки;
	
	Возврат ОписаниеОшибки;
	
КонецФункции

Функция ПреобразоватьСтрокуСОднимОснованиемВСтрокуСДругимОснованием(ПредставлениеИсходногоЧисла, ИсходноеОснование, ЦелевоеОснование, МинимальнаяДлинаТипаЧисла = 0, РезультатПреобразования) Экспорт
	
	Перем ОписаниеОшибки;
	Перем ИмяФункции;
	Перем ЧисловойРезультатПреобразования;
	
	ОписаниеОшибки = "";
	ИмяФункции = "ПреобразоватьСтрокуСОднимОснованиемВСтрокуСДругимОснованием";
	
	Попытка
		ОписаниеОшибки = ПреобразоватьСтрокуСДругимОснованиемВЧисло(ПредставлениеИсходногоЧисла, ИсходноеОснование, ЧисловойРезультатПреобразования);
		Если Не ПустаяСтрока(ОписаниеОшибки) Тогда
			ВызватьИсключение(ОписаниеОшибки);
		КонецЕсли; 
		ОписаниеОшибки = ПреобразоватьЧислоВСтрокуСДругимОснованием(ЧисловойРезультатПреобразования, ЦелевоеОснование, РезультатПреобразования, МинимальнаяДлинаТипаЧисла);
		Если Не ПустаяСтрока(ОписаниеОшибки) Тогда
			ВызватьИсключение(ОписаниеОшибки);
		КонецЕсли; 
	Исключение
		ОписаниеОшибки = ИмяФункции + ": " + ОписаниеОшибки();
	КонецПопытки;
	
	Возврат ОписаниеОшибки;
	
КонецФункции // ПреобразоватьСтрокуСОднимОснованиемВСтрокуСДругимОснованием() 

Функция ВыполнитьБинарнуюОперацию(Знач Операнд1, Знач Операнд2, Оператор, РезультатВычисления, ОснованиеОперандов = 10, ОснованиеРезультата = 10) Экспорт
	
	Перем ПредставлениеОперанда1;
	Перем ПредставлениеОперанда2;
	Перем ИмяФункции;
	Перем ОписаниеОшибки;
	ИмяФункции 	   = "ВыполнитьБинарнуюОперацию";
	ОписаниеОшибки = "";
	ПредставлениеРезультата = "";
	РезультатВычисления = 0;
	
	Попытка
		
		Если НЕ ОснованиеОперандов = 2 Тогда
			//{ Получаем двоичное представление переданных операндов
			ОписаниеОшибки = ПреобразоватьЧислоВСтрокуСДругимОснованием(Операнд1, 2, ПредставлениеОперанда1);
			Если НЕ ПустаяСтрока(ОписаниеОшибки) Тогда
				ВызватьИсключение(ТекстОшибки(ИмяФункции, ОписаниеОшибки));
			КонецЕсли; 
			ОписаниеОшибки = ПреобразоватьЧислоВСтрокуСДругимОснованием(Операнд2, 2, ПредставлениеОперанда2);
			Если НЕ ПустаяСтрока(ОписаниеОшибки) Тогда
				ВызватьИсключение(ТекстОшибки(ИмяФункции, ОписаниеОшибки));
			КонецЕсли; 
			//} Получаем двоичное представление переданных операндов
		Иначе
			// проверяем переданные операнды
			Если НЕ ТипЗнч(Операнд1) = Тип("Строка") ИЛИ НЕ ТипЗнч(Операнд2) = Тип("Строка") Тогда
				ВызватьИсключение(ТекстОшибки(ИмяФункции, "Переданный в качестве операндов параметры должны иметь строковый тип!"));
			КонецЕсли; 
			ПредставлениеОперанда1 = Операнд1;
			ПредставлениеОперанда2 = Операнд2;
		КонецЕсли; 
		
		// длина операндов должна быть одинаковой
		МаксимальнаяДлина = Макс(СтрДлина(ПредставлениеОперанда1), СтрДлина(ПредставлениеОперанда2));
		Для СчетчикЦикла = СтрДлина(ПредставлениеОперанда1) + 1 По МаксимальнаяДлина Цикл
			ПредставлениеОперанда1 = "0" + ПредставлениеОперанда1;
		КонецЦикла; 
		Для СчетчикЦикла = СтрДлина(ПредставлениеОперанда2) + 1 По МаксимальнаяДлина Цикл
			ПредставлениеОперанда2 = "0" + ПредставлениеОперанда2;
		КонецЦикла; 
		
		// производим необходимые бинарные операции и получаем двоичное представление результата в 32-битном формате
		Для НомерСимвола = 1 По МаксимальнаяДлина Цикл
			Если Оператор = "XOR" Тогда
				ПредставлениеРезультата = ПредставлениеРезультата + ?(Число(Сред(ПредставлениеОперанда1, НомерСимвола, 1)) + Число(Сред(ПредставлениеОперанда2, НомерСимвола, 1)) = 1, "1", "0");	
			ИначеЕсли Оператор = "AND" Тогда 	
				ПредставлениеРезультата = ПредставлениеРезультата + ?(Число(Сред(ПредставлениеОперанда1, НомерСимвола, 1)) + Число(Сред(ПредставлениеОперанда2, НомерСимвола, 1)) = 2, "1", "0");	
			ИначеЕсли Оператор = "OR" Тогда 	
				ПредставлениеРезультата = ПредставлениеРезультата + ?(Число(Сред(ПредставлениеОперанда1, НомерСимвола, 1)) + Число(Сред(ПредставлениеОперанда2, НомерСимвола, 1)) = 0, "0", "1");	
			КонецЕсли; 
		КонецЦикла;
		Если НЕ ОснованиеРезультата = 2 Тогда
			ОписаниеОшибки = ПреобразоватьСтрокуСДругимОснованиемВЧисло(ПредставлениеРезультата, 2, РезультатВычисления);
			Если НЕ ПустаяСтрока(ОписаниеОшибки) Тогда
				ВызватьИсключение(ТекстОшибки(ИмяФункции, ОписаниеОшибки));
			КонецЕсли; 
		Иначе
			РезультатВычисления = ПредставлениеРезультата; 	
		КонецЕсли; 
	Исключение
		ОписаниеОшибки = ОписаниеОшибки();
	КонецПопытки;
	
	Возврат ОписаниеОшибки;
		
КонецФункции 

Функция ВыполнитьИнверсию(Знач Операнд, РезультатВычисления, ОснованиеОперанда = 10, ОснованиеРезультата = 10) Экспорт
	
	Перем ПредставлениеОперанда;
	Перем ИмяФункции;
	Перем ОписаниеОшибки;
	ИмяФункции 	   = "ВыполнитьИнверсию";
	ОписаниеОшибки = "";
	ПредставлениеРезультата = "";
	РезультатВычисления = 0;
	
	Попытка
		
		Если НЕ ОснованиеОперанда = 2 Тогда
			//{ Получаем двоичное представление переданного операнда в двоичном формате
			ОписаниеОшибки = ПреобразоватьЧислоВСтрокуСДругимОснованием(Операнд, 2, ПредставлениеОперанда, 32);
			Если НЕ ПустаяСтрока(ОписаниеОшибки) Тогда
				ВызватьИсключение(ТекстОшибки(ИмяФункции, ОписаниеОшибки));
			КонецЕсли; 
			//} Получаем двоичное представление переданного операнда в двоичном формате
		Иначе
			// проверяем переданный операнд
			Если НЕ ТипЗнч(Операнд) = Тип("Строка") Тогда
				ВызватьИсключение(ТекстОшибки(ИмяФункции, "Переданный в качестве операнда параметр должен иметь строковый тип!"));
			КонецЕсли; 
			ПредставлениеОперанда = Операнд;
		КонецЕсли; 
		
		МаксимальнаяДлина = 32;
		// Дополняем двоичное представление операнда до необходимой длины нулями
		Для Счетчик = СтрДлина(ПредставлениеОперанда) + 1 По МаксимальнаяДлина Цикл
			ПредставлениеОперанда = "0" + ПредставлениеОперанда;
		КонецЦикла; 
		
		// производим необходимые унарные операции и получаем двоичное представление результата в строковом формате
		Для НомерСимвола = 1 По МаксимальнаяДлина Цикл
			ПредставлениеРезультата = ПредставлениеРезультата + ?(Число(Сред(ПредставлениеОперанда, НомерСимвола, 1)) = 1, "0", "1");	
		КонецЦикла;
		Если НЕ ОснованиеРезультата = 2 Тогда
			ОписаниеОшибки = ПреобразоватьСтрокуСДругимОснованиемВЧисло(ПредставлениеРезультата, 2, РезультатВычисления);
			Если НЕ ПустаяСтрока(ОписаниеОшибки) Тогда
				ВызватьИсключение(ТекстОшибки(ИмяФункции, ОписаниеОшибки));
			КонецЕсли; 
		Иначе
			РезультатВычисления = ПредставлениеРезультата; 	
		КонецЕсли; 
	Исключение
		ОписаниеОшибки = ОписаниеОшибки();
	КонецПопытки;
	
	Возврат ОписаниеОшибки;
		
КонецФункции 

Для вычислений нам понадобится таблица символов ASCII для перевода символов в кодировке UTF-8 в символы кодовой страницы windows-1251
и массив чисел для реализации алгоритма CRC32. Эти данные находятся в макетах прилагаемой к публикации внешней обработки (для платформы 8.2).

Ну и наконец сами функции расчета:
 

Процедура ЗаполнитьТаблицуASCII()
	
	мТаблицаASCII = Новый ТаблицаЗначений;
	мТаблицаASCII.Колонки.Добавить("Код", Новый ОписаниеТипов("Число"));
	мТаблицаASCII.Колонки.Добавить("Символ", Новый ОписаниеТипов("Строка"));
	МакетТаблицыASCII = ПолучитьМакет("ТаблицаКодовASCII");
	ОбластьТаблицыASCII = МакетТаблицыASCII.ПолучитьОбласть("RU");
	Для НомерСтроки = 1 По ОбластьТаблицыASCII.ВысотаТаблицы Цикл
		НоваяСтрока = мТаблицаASCII.Добавить();
		НоваяСтрока.Код 	= Число(ОбластьТаблицыASCII.ПолучитьОбласть(НомерСтроки, 1).ТекущаяОбласть.Текст);
		НоваяСтрока.Символ 	= ОбластьТаблицыASCII.ПолучитьОбласть(НомерСтроки, 2).ТекущаяОбласть.Текст;
	КонецЦикла; 
	
КонецПроцедуры // ЗаполнитьТаблицуASCII()


Функция ПолучитьКонтрольнуюСуммуСтроки(Знач ИсходнаяСтрока, КонтрольнаяСумма, РассчетСредстамиВстроенногоЯзыка = Истина) Экспорт
	
	Перем ДвоичноеПредставлениеКонтрольнойСуммы;
	Перем ИмяФункции;
	Перем ОписаниеОшибки;
	ИмяФункции 	   = "ПолучитьКонтрольнуюСуммуСтроки";
	ОписаниеОшибки = "";
	
	Если Неопределено = мТаблицаASCII Тогда
		ЗаполнитьТаблицуASCII();
	КонецЕсли; 
	Если ПустаяСтрока(ИсходнаяСтрока) Тогда
		КонтрольнаяСумма = 0;
	Иначе
		МакетТаблицыРасчета = ПолучитьМакет("ТаблицаРасчетаCRC32");
		ОбластьТаблицыРасчета = МакетТаблицыРасчета.ПолучитьОбласть("CRC32TableBase2");
		КонтрольнаяСумма = 4294967295; // 0xFFFFFFFF
		Попытка
			
			Для НомерСимвола = 1 По СтрДлина(ИсходнаяСтрока) Цикл
				
				#Если Клиент Тогда
				ОбработкаПрерыванияПользователя();	
				#КонецЕсли
				
				// Алгоритм расчета CRC32 в цикле (С++)
				// dwCrc32 = ((dwCrc32) >> 8) ^ Crc32Table[(bSimbolCode) ^ ((dwCrc32) & 0x000000FF)];
				
				Символ = Сред(ИсходнаяСтрока, НомерСимвола, 1);
				// Получаем двоичное представление контрольной суммы в 32 битном формате
				ОписаниеОшибки = ПреобразоватьЧислоВСтрокуСДругимОснованием(КонтрольнаяСумма, 2, ДвоичноеПредставлениеКонтрольнойСуммы, 32);
				Если НЕ ПустаяСтрока(ОписаниеОшибки) Тогда
					ВызватьИсключение(ТекстОшибки(ИмяФункции, ОписаниеОшибки));
				КонецЕсли; 
				КонтрольнаяСуммаВправо8 = Лев(ДвоичноеПредставлениеКонтрольнойСуммы, 24);
				
				//{ Вычисление выражения Crc32Table[(bSimbolCode) ^ ((dwCrc32) & 0x000000FF)] 
				КодСимвола = КодСимвола(Символ);
				Если КодСимвола > 127 Тогда
					// Поскольку строка представлена в кодировке UTF-8
					// попытаемся перевести символы в кодировку ASCII 1251
					СтрокаТаблицы = мТаблицаASCII.Найти(Символ, "Символ");
					Если СтрокаТаблицы = Неопределено Тогда
                                           // Это - не символ кодовой таблицы 1251, 
                                           // заменим его на псевдосимвол из диапазона 1-256
                                           ОписаниеОшибки = ВыполнитьБинарнуюОперацию(КодСимвола, 255, "AND", КодСимвола);
                                           Если НЕ ПустаяСтрока(ОписаниеОшибки) Тогда
                                               ВызватьИсключение(ТекстОшибки(ИмяФункции, ОписаниеОшибки));
                                           КонецЕсли;
                                           КодСимвола = КодСимвола + 1;

					Иначе
						КодСимвола = СтрокаТаблицы.Код;
					КонецЕсли; 
				КонецЕсли; 
				
				НомерСтрокиТаблицы = 0;
				ПсевдослучайноеЧисло = 0;
				ОписаниеОшибки = ВыполнитьБинарнуюОперацию(ДвоичноеПредставлениеКонтрольнойСуммы, "00000000000000000000000011111111", "AND", ПсевдослучайноеЧисло, 2);
				Если НЕ ПустаяСтрока(ОписаниеОшибки) Тогда
					ВызватьИсключение(ТекстОшибки(ИмяФункции, ОписаниеОшибки));
				КонецЕсли; 
				ОписаниеОшибки = ВыполнитьБинарнуюОперацию(КодСимвола, ПсевдослучайноеЧисло, "XOR", НомерСтрокиТаблицы);
				Если НЕ ПустаяСтрока(ОписаниеОшибки) Тогда
					ВызватьИсключение(ТекстОшибки(ИмяФункции, ОписаниеОшибки));
				КонецЕсли; 
				ЧислоТаблицыРасчета = ОбластьТаблицыРасчета.ПолучитьОбласть(НомерСтрокиТаблицы + 1, 1).ТекущаяОбласть.Текст;
				//} Вычисление выражения Crc32Table[(bSimbolCode) ^ ((dwCrc32) & 0x000000FF)]}
				
				//{ Расчет контрольной суммы
				ОписаниеОшибки = ВыполнитьБинарнуюОперацию(КонтрольнаяСуммаВправо8, ЧислоТаблицыРасчета, "XOR", КонтрольнаяСумма, 2);
				Если НЕ ПустаяСтрока(ОписаниеОшибки) Тогда
					ВызватьИсключение(ТекстОшибки(ИмяФункции, ОписаниеОшибки));
				КонецЕсли; 
				//} Расчет контрольной суммы 
				
			КонецЦикла;
			
			// Инверсия контрольной суммы
			// dwCrc32 = ~dwCrc32
			ОписаниеОшибки = ВыполнитьИнверсию(КонтрольнаяСумма, КонтрольнаяСумма);
			Если НЕ ПустаяСтрока(ОписаниеОшибки) Тогда
				ВызватьИсключение(ТекстОшибки(ИмяФункции, ОписаниеОшибки));
			КонецЕсли; 
			
		Исключение
			ОписаниеОшибки = ОписаниеОшибки();
		КонецПопытки;
	КонецЕсли; 
	
	Возврат ОписаниеОшибки;
	
КонецФункции // ПолучитьКонтрольнуюСуммуСтроки()

Функция RGB(Знач R, Знач G, Знач B) Экспорт
	
	// Пример перевода цветовых составляющих в числовое значение 
	// Pascal
	// Result := (Integer(B) shl 16) + (Integer(G) shl 8) + R;	
	// C++
	// #define RGB(r,g,b) ((COLORREF)(((BYTE)(r)|((WORD)((BYTE)(g))<<8))|(((DWORD)(BYTE)(b))<<16)))

	
	Перем ДвоичноеПредставлениеR;
	Перем ДвоичноеПредставлениеG;
	Перем ДвоичноеПредставлениеB;
	Перем Результат;
	
	ПреобразоватьЧислоВСтрокуСДругимОснованием(R, 2, ДвоичноеПредставлениеR, 32);
	ПреобразоватьЧислоВСтрокуСДругимОснованием(G, 2, ДвоичноеПредставлениеG, 32);
	ПреобразоватьЧислоВСтрокуСДругимОснованием(B, 2, ДвоичноеПредставлениеB, 32);
	
	ПреобразоватьСтрокуСДругимОснованиемВЧисло(Прав(ДвоичноеПредставлениеB, 16) + "0000000000000000", 2, B);
	ПреобразоватьСтрокуСДругимОснованиемВЧисло(Прав(ДвоичноеПредставлениеG, 24) + "00000000", 2, G);
	
	Возврат B + G + R;
	
КонецФункции // RGB()

Таким образом мы наделили функционал нашего прикладного решения возможностью вычисления бинарных операций, без чего невозможно организовать вычисление более сложных алгоритмов. Конечно, функционал этот не наделён высокой скоростью работы, зато реализован исключительно средствами платформы "1С:Предприятие".

Область применения вышеизложенного функционала приводить не буду - недаром публикация размещена в разделе "Практика программирования".
Расскажу лишь то, каким образом использовал его я.

В одной из организаций, где я работал, существовала централизованая база данных, аккумулирующая информацию из различных систем.
В конфигурации базы были реализваны регистры сведений с различными реквизитами и всего двумя измерениями:  идентификатор информационной системы - импортера записи, и идентификатор записи таблицы системы-импортёра.
При импорте из систем с возможностью непосредственного обращения к таблицам баз данных сложностей не возникало - все они имели идентификатор записи в качестве первичного ключа. А вот при импорте записей регистра сведений из файлового варианта базы 1С сложности возникли - как получить инденитификатор записи регистра? Задача была решена следующим образом: ключевые поля записи преобразовывались к строковому типу, затем производилась их конкатенация, а результирующая строка хэшировалось алгоритмом CRC32, что и давало в результате необходимый идентификатор записи.

Функция же RGB использовалась для формирования палитры книги MS Excel с целью оформления её в необходимом стиле.

бинарные операции расчет контрольной суммы CRC32

См. также

Планы обмена VS История данных

Обмен между базами 1C Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Вы все еще регистрируете изменения только на Планах обмена и Регистрах сведений?

11.12.2023    6408    dsdred    36    

111

1С-ная магия

Механизмы платформы 1С Бесплатно (free)

Язык программирования 1С содержит много нюансов и особенностей, которые могут приводить к неожиданным для разработчика результатам. Сталкиваясь с ними, программист начинает лучше понимать логику платформы, а значит, быстрее выявлять ошибки и видеть потенциальные узкие места своего кода там, где позже можно было бы ещё долго медитировать с отладчиком в поисках источника проблемы. Мы рассмотрим разные примеры поведения кода 1С. Разберём результаты выполнения и ответим на вопросы «Почему?», «Как же так?» и «Зачем нам это знать?». 

06.10.2023    18471    SeiOkami    46    

118

Валидация JSON через XDTO (включая массивы)

WEB-интеграция Универсальные функции Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

При работе с интеграциями рано или поздно придется столкнуться с получением JSON файлов. И, конечно же, жизнь заставит проверять файлы перед тем, как записывать данные в БД.

28.08.2023    8818    YA_418728146    6    

141

Печать непроведенных документов для УТ, КА, ERP. Настройка печати по пользователям, документам и печатным формам

Пакетная печать Печатные формы Адаптация типовых решений Универсальные функции Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Абонемент ($m)

Расширение для программ 1С:Управление торговлей, 1С:Комплексная автоматизация, 1С:ERP, которое позволяет распечатывать печатные формы для непроведенных документов. Можно настроить, каким пользователям, какие конкретные формы документов разрешено печатать без проведения документа.

2 стартмани

22.08.2023    2071    21    progmaster    7    

3

Расширение глобального поиска 1С, или Глобальный поиск "на максималках"

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Мало кто знает, что поле "Глобального поиска" в 1С можно доработать. Добавить свои варианты поиска, кнопочки в результатах и даже целые пользовательские меню.

27.03.2023    6952    SeiOkami    10    

140

Версионирование объектов VS История данных

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Давайте разберемся в механизме «История данных» и поэкспериментируем для наглядности. Сравним «Версионирование объектов» и «Историю данных».

06.03.2023    18948    dsdred    54    

193

Практическая шпаргалка по новым возможностям языка запросов 1С

Механизмы платформы 1С Запросы Платформа 1С v8.3 Запросы Конфигурации 1cv8 Бесплатно (free)

В предлагаемой статье решил привести примеры применения новых возможностей языка запросов 1С, начиная с версии платформы 8.3.20.

21.11.2022    23424    quazare    36    

122

Расширение: Быстрые отборы через буфер [Alt+C] Копировать список, [Alt+V] Вставить список, [Ctrl+C] Копировать из файлов

Инструментарий разработчика Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 1С:Розница 2 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Зарплата и Управление Персоналом 3.x Абонемент ($m)

Копирует в буфер значения из списков, из ячеек отчетов, таблиц, настроек списков, других отборов и вставляет в выбранную настройку отбора. Работает с Объект не найден. Работает как в одной так и между разными базами 1С. Использует комбинации [Alt+C] Копировать список, [Alt+V] Вставить список. Также для копирования данных используется стандартная [Ctrl+C] (например из открытого xls, mxl, doc и т.п. файла скопировать список наименований)

1 стартмани

13.10.2022    16143    133    sapervodichka    112    

129
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. ildarovich 7850 03.04.15 13:36 Сейчас в теме
Нет ли ошибки в названии? Дело в том, что в 8.3 есть встроенная функция для решения этой задачи.
Второй вопрос: какой именно CRC32 вычисляли? - Там есть стандартный IEEE, CRC32С, CRC32Q.
Сравнивали результаты с полученными независимо другими методами?
2. premierex 204 03.04.15 15:42 Сейчас в теме
(1) В названии ошибки нет. Как раз в названии явно указано, что алгоритм предназначен для платформ 1С:Предприятие версий старше 8.3 (8.2, 8.1, 8.0, я так полагаю и на 7.7 можно алгоритм реализовать).
Какой именно вариант алгоритма применялся я уже и не помню, давно всё это писалось (лет 5 назад), а вот опубликовать решил только сейчас. Предполагаю, что стандартный.
Результаты проверял в онлайн калькуляторе NoName и написанной тогда мной на С++ программе, реализующей этот же алгоритм.
4. ildarovich 7850 03.04.15 17:30 Сейчас в теме
(2) мне кажется, что вы путаете слова "старше" и "старее". Версия 8.3 старше 8.2. Версия 8.2 старее 8.3. Или я ошибаюсь?
См.:Нумерация версий программного обеспечения
5. premierex 204 03.04.15 18:47 Сейчас в теме
(4) ildarovich, Вы, к сожалению, ошибаетесь. Слова "старше" и "старее" - синонимы. Приведу простой пример: если сравнить годы выпуска платформ 8.0 и 8.3, то по "возрасту" 8.0 окажется значительно старше (ну, или "старее" - кому как нравится). Сравните Ваш возраст и возраст Ваших родителей. Кто из вас старше?
6. ildarovich 7850 03.04.15 18:59 Сейчас в теме
(5) это "наивное" объяснение. И неправильное.
По ссылке в Википедии статью прочитали? Старшая версия - это более зрелая версия, вбирающая, как правило, в себя часть кода более ранней версии.
7. premierex 204 03.04.15 19:59 Сейчас в теме
(6) ildarovich, всё это - полемика по определению старшинства версий. Конечно, на первый взгляд кажется, что версия платформы 1С:Предприятие 8.3 "старше", чем версия 8.2. Но, в посте (4) я уже указал причину, по которой версия 8.3 является младшей - дату её выпуска. Материалы из "Википедии" - ни о чём. Ведь там за основу взят номер релиза (подрелиза) и т. д., а я имел в виду именно старшие по "возрасту" платформы 1С:Предприятия. Если Вам кажется, что название публикации может ввести пользователей InfoStart'а в заблуждение, я совсем не против изменить наименование публикации (если есть желание, можете подсказать, как "грамотно" с Вашей точки зрения, её именовать). Наверное, так и сделаю к моменту выхода еженедельного обзора. Хотя, если вдуматься в название публикации, можно даже удалить её из раздела публичного доступа. Ведь, по-вашему, в названии явная ошибка - не существует на данный момент платформы 1С:Предприятия "старше" версии 8.3. Предлагаю полемику о старшинстве версий ПО закончить. Если есть замечания по опубликованному функционалу - пишите. Критику воспринимаю адекватно.
8. ildarovich 7850 03.04.15 22:20 Сейчас в теме
(7) поскольку тема мне интересна, позволю себе высказать свои соображения по-поводу самого решения. Не хотел бы, чтобы вы воспринимали это как критику - это заметки для тех, кто захочет улучшить это решение, если увидит в этом необходимость.
1) кодовую таблицу utf-8 - windows 1251 можно не хранить в макете, а быстро и просто получить вот такой функцией:
Функция НаборСимволов(КодировкаТекста = "windows-1251", Ответ = "")
    Для КодСимвола = 1 По 255 Цикл 
        Ответ = Ответ + Символ(КодСимвола)
    КонецЦикла;
    ТекстовыйДокумент = Новый ТекстовыйДокумент;
    ТекстовыйДокумент.УстановитьТекст(Ответ);
    ПутьКФайлу = ПолучитьИмяВременногоФайла();
    ТекстовыйДокумент.Записать(ПутьКФайлу, "ISO-8859-1", "");
    ТекстовыйДокумент.Прочитать(ПутьКФайлу, КодировкаТекста, "");
    Ответ = ТекстовыйДокумент.ПолучитьТекст();
    Возврат Ответ     
КонецФункции
Показать
В строке символы utf-8, их позиция - это код windows-1251. Но, вообще говоря, непонятно, к чему это преобразования - почему не брать все байты utf-8?
2) При всем богатстве операций с числами в языке 1С есть ли необходимость использовать строку для представления и работы с двоичными числами? Сдвиг вправо - это деление на 256. Логическое "И" с FF это нахождение остатка от деления на 256. "ХОR" можно сделать побайтно (по-полубайтно) по таблицам (два байта - вход, один - выход). Тем более, что таблицы для предпросчета восьми сдвигов входного символа вы все же используете. Инверсия - это тот же XOR с FFFFFFFF. Таблицы лучше загнать заранее в массив. Насчет XOR можно еще подумать - как его смоделировать.
3) Таблицы в макете - очень не гибко. Лучше из все же рассчитывать и хранить, например, в параметрах обработки. Это не так уж долго.

В целом так может довольно большой выигрыш по быстродействию получиться.

Интересно, сколько времени занимает у вас сейчас расчет контрольной суммы для строки из 1222 символов?
Можно будет сравнить быстродействие. У меня, например, есть запрос, внутри которого вычисляется CRC32Q (или любой другой - там характеристический полином прямо в таблице задается).
Если будете делать замеры, чтобы привести их к общему знаменателю, лучше указать, сколько таких строк можно обработать за минуту.
9. premierex 204 04.04.15 09:07 Сейчас в теме
(8) ildarovich, по поводу Ваших заметок:
1. Изначально я предполагал, такой же подход, смотрите, что получается при вызове этой функции:
	Текст = НаборСимволов(, "АБВГД");
	Для НомерСимвола = 1 По СтрДлина(Текст) Цикл
		Символ = Сред(Текст, НомерСимвола, 1);
		Сообщить(Символ + " = " + Строка(КодСимвола(Символ)));
	КонецЦикла; 


И результат:
? = 63
? = 63
? = 63
? = 63
? = 63
= 1
= 2
= 3
= 4
= 5
= 6
= 7
= 8
= 9

= 10
........
А = 1 040
Б = 1 041
В = 1 042
Г = 1 043
Д = 1 044
Е = 1 045
Ж = 1 046
З = 1 047
И = 1 048
.........
Поэтому-то я и загнал таблицу кодов в макет (макет - из соображений не загромождать текст модуля).

2. Не спорю логика есть - операции с числами, несомненно производятся быстрее, но на момент написания этих алгоритмов, пришло такое вот решение. К тому же для выполнения "XOR" все равно понадобилось бы двоичное представление числа.

3. Про таблицы в макете я уже писал выше - не хотелось загромождать программный код.
Вот что я действительно не предусмотрел для расчета CRC, это проинициализировать массив данных для расчета перед выполнением функции, а не получать их из макета в цикле.

Интересно, сколько времени занимает у вас сейчас расчет контрольной суммы для строки из 1222 символов?
Заняло 21 сек. Много, конечно, но мне и не требовалось обрабатывать символные массивы таких размеров. Требовалось обрабатывать строки длиной порядка 30-40 символов, а это уже 1 сек. на выполнение, что в общем-то для моей задачи оказалось приемлемым.
Хотя, я, конечно, всё равно в последующем заменил функцию расчета CRC32 на аналогичную функцию внешней компоненты. А изложенную выше оставил, так сказать, для истории :).
10. premierex 204 04.04.15 09:17 Сейчас в теме
(8) ildarovich, забыл задать встречный вопрос к п.2: с операцией "AND" всё понятно, Вы привели пример, а как же остальные операции рассчитывать?
Инверсия - это тот же XOR с FFFFFFFF
Но Вы же не привели пример, как рассчитать XOR используя только числовые показатели и встроенные функции для работы с числами....
12. ildarovich 7850 04.04.15 10:36 Сейчас в теме
(10)
1) - чуть позже
21 сек. - это очень, очень много. Получается 3 хэша в минуту. Тогда как в статье Простая и быстрая хэш функция (hash) средствами 1С (оптимизированный вариант) предлагается решение, позволяющее рассчитать для такой строки 21000 хэшей в минуту! Притом 64-разрядных! Пусть не CRC32.
У меня в запросе (!!!) получалось (для CRC32) порядка 1000 хэшей минуту (сейчас не ручаюсь, нужно перепроверить). Я счел этот показатель ниже всякой критики и перешел на арифметический хэш, где в запросе получается примерно 12000 хэшей в минуту, а для коротких строк из цифр (всякие коды справочников) еще намного больше.

После обдумывания возможных путей достижения максимальной скорости предлагается вот такой рабочий вариант:
1) хранить текущее состояния регистра сдвига в "разреженном" числе. При этом на каждый бит регистра будет приходится три бита числа. Это нужно для того, чтобы заменить XOR обычным сложением, чтобы не мешали межразрядные переносы.
2) предрассчитать таблицу ОС (и загнать в массив 2^24) отображения младшего байта регистра (растянутого на три байта) в сумму, которые нужно добавлять к регистру через обратные связи. Хотя массив будет занимать 2^24, заполненным там будет всего 5^8 ~ 100000 элементов.
3) предрассчитать отображения символа в "разреженный" байт.
Алгоритм будет таким:
Для каждого символа:
1) Добавляем разреженный байт символа к регистру;
2) Выделяем младший разреженный байт через %;
3) Вычитаем его из регистра и делим регистр на 2^24, чтобы получить сдвиг на 8 реальных бит (24 разреженных);
4) Находим добавляемую суммы по разреженному байту из таблицы ОС;
5) Добавляем эту сумму к регистру

Записал просто, чтобы не забыть. Основная идея в том, что XOR - это четность, а четность суммы - это младший бит. В регистре делается всего четые сложения "за оборот", поэтому сумма не выйдет за "100" (двоичный код 4) и для ее хранения будет достаточно трех бит.
13. premierex 204 04.04.15 11:21 Сейчас в теме
(12) ildarovich, 21 сек. - это очень, очень много.
Конечно много! Я и сам утверждаю это в посте (9).
Ваши публикации, указанные в ссылках поста я прочитал. Очень познавательно! Надо будет вернуться и поставить "плюс".

Предложенный Вами рабочий вариант пока что не получилось осмыслить (вернусь к этому позже при необходимости).

Ну что же, исходя из того, что предложенные Вами решения (по ссылкам в посте (12)) оказались реально более скоростными, предлагаю рассматривать мою публикацию как "опыт неоптимального программирования" :). Ведь отрицательный опыт - тоже опыт, и надо только знать, как его использовать.
14. ildarovich 7850 04.04.15 14:28 Сейчас в теме
(13) это нужно рассматривать как хороший учебный пример.
Во-первых, код очень хорошо структурирован и замечательно оформлен, снабжен множеством нужных при отладке проверок.
Во-вторых, реализован один из возможных быстрых алгоритмов (при реализации на другом языке), где в отладчике можно проследить по шагам его работу, чтобы разобраться в выполняемых преобразованиях (символ за такт - это не символ за восемь тактов, как при решении задачи "в лоб").
Так что тщательно сделанная работа бесполезной не бывает.
11. premierex 204 04.04.15 10:20 Сейчас в теме
(8) ildarovich, не внимательно я прочитал Ваш ответ в п.1. и, соответственно, сделал неправильные выводы в посте 9.
Действительно, в возвращаемой функцией строке номер символа является его кодом в таблице ASCII. Ну, как говорится: "Век живи - век учись". Спасибо за подсказку.
3. premierex 204 03.04.15 16:00 Сейчас в теме
(1) Вот нашел исходные коды этого алгоритма на С++ http://www.opensource.apple.com/source/xnu/xnu-1456.1.26/bsd/libkern/crc32.c. Это алгоритм CRC-32-IEEE 802.3.
15. premierex 204 04.04.15 14:47 Сейчас в теме
Спасибо! Надеюсь, кому-нибудь пригодится.
16. kylux 20 28.11.16 17:41 Сейчас в теме
Ув. Максим! Вы если ставите флажек, насчет поддержки "Все платформы", то уж выкладывайте обработку в версии и 8.0! А так получился лохотрон, мне каким образом Ваш макет использовать в версии 8.1?
17. premierex 204 29.11.16 12:08 Сейчас в теме
(16) Ув. kylux. Вот уж просто не подумал, что кто-то ещё использует платформы версий 8.0 или 8.1. Когда я эту обработку писал, уже 8.2 вовсю использовали. Ну, файл-то Вы не скачивали, значит и не потеряли ничего )))
18. premierex 204 10.12.16 13:26 Сейчас в теме
(16) Прошу прощения за неточность: файл Вы скачивали (раньше подпись была у комментария "файл скачал", сейчас её убрали к сожалению, вот и получилось недоразумение). Если хотите, могу купить что-нибудь из Ваших наработок, чтобы вернуть Вам потраченные $m.
19. driveboy 19.07.17 09:58 Сейчас в теме
Доброго времени суток. Замечание - пришлось для нас сделать доработку, у вас исключаются из расчета контрольной суммы пустые строки, а нам это нужно. На пустых строках тоже все заработало без проблем. Спасибо за обработку :)
20. premierex 204 28.11.17 13:42 Сейчас в теме
(19) Очень интересно, как же вы контрольную сумму пустой строки вычисляете?
Оставьте свое сообщение