Ошибки в предопределённых элементах

06.10.15

Разработка - Механизмы платформы 1С

В 8.3.3 в 1С добавилась возможность программно привязывать предопределенные элементы к элементам ИБ.
Периодически при сбоях, обменах либо ошибках в используемом программном коде соответствие между предопределенными элементами и элементами ИБ может сбиваться.
Какие ситуации бывают, как они возникают и как с ними бороться.

Сама идея программной работы с предопределенными элемементами, на мой взгляд, очень правильная. Просто есть нюансы, которые нужно учитывать при работе.

Для начала необходимо четко осознать для себя, что есть предопределенные элементы в конфигурации и есть предопределенные элементы в информационной базе (ИБ). Технически предопределенные элементы ИБ это самые обычные элементы справочников, у которых в реквизите "ИмяПредопределенныхДанных" указано, какому предопределенному элементу конфигурации они соответствуют. Ничем больше они от обычных элементов не отличаются. Соответственно, любой обычный элемент ИБ можно сделать предопределенным, любой предопределенный обычным. Для этого достаточно вписать нужное значение в реквизит "ИмяПредопределенныхДанных". 

Периодически в этом свойстве оказывается не то значение, которое предусмотрел разработчик. В результате возникают ошибки в работе 1С. От критичных, при которых работа в принципе невозможна, до некритичных, при которых нарушается логика работы алгоритмов.

Условно можно выделить три типа ошибок:
1. "Предопределенный элемент отсутствует в данных";
2. "Предопределенный элемент не уникален";
3.  Неверное указание предопределенного элемента;

1. "Предопределенный элемент отсутствует в данных" - отсутствие описанного в конфигурации предопределённого элемента в данных ИБ. 

Это наиболее простой в отладке и исправлении тип ошибки. Его простота в том, что платформа достаточно корректно сообщает об этой ситуации "Предопределенный элемент отсутствует в данных" и вполне понятно, как её исправить.

При обращении к отсутствующему элементу в коде "Справочники.ВидыКонтактнойИнформации.EmailКонтактногоЛица"  выдается сообщение

предопределенный элемент отсутствуетв данных

При обращении к элементу в запросе "ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.EmailКонтактногоЛица)" выдается сообщение:

предопределенный элемент отсутствуетв данных

Такая ошибка возникает в случае, если элемент в конфигурации описан, но в базе ему элемент не сопоставлен. 

Для начала уточним, что такая ситуация не всегда является ошибочной. Вполне возможным является использование предопределённых данных в какой-то программной логике, которая для большинства пользователей может не использоваться. В этом случае, чтобы не захломлять справочник у всех пользователей конфигурации, логично определить предопределенные элементы в конфигурации, но не создавать их во всех ИБ, а лишь для тех ИБ, в которых нужная логика конфигурации используется. В этом случае программист может указать для справочника свойство "Не обновлять предопределенные данные" и создать элементы програмно при обращении к функционалу модуля. Либо дать возможность пользователю самостоятельно привязать предопределенные элементы модуля к имеющимся у него обычным элементам.

Также не используется автоматическое создание предопределенных элементов при работе в режиме РИБ. Так как новые элементы должны передаваться из центральной базы, а не создаваться в узлах с отличающимися УИДами.

Т.е. иногда ошибкой является обращение в несопоставленному элементу, а не само наличие такого элемента.

Необходимо проанализировать, почему элемент не создан. Возможно, он должен создаться при выполнении какого-либо режима программы. Например, после выполнения обмена в РИБ. А возможно, его просто случайно удалили.

Если логикой предусмотрено заполнение предопределенных элементов не автоматически, а отдельным режимом, то перед использование обращения по имени "Справочники.ВидыКонтактнойИнформации.EmailКонтактногоЛица" для предотвращения исключительной ситуации желательно проверить, что элемент уже есть в базе. Если элемент отсутствует, то сообщить пользователю об этом и объяснить, какой режим ему нужно выполнить для заполнения элемента. Для такой проверки можно выполнить запрос к данным. 

	Запрос = Новый Запрос;
	Запрос.Текст = 
		"ВЫБРАТЬ
		|	ВидыКонтактнойИнформации.Ссылка
		|ИЗ
		|	Справочник.ВидыКонтактнойИнформации КАК ВидыКонтактнойИнформации
		|ГДЕ
		|	ВидыКонтактнойИнформации.ИмяПредопределенныхДанных = ""EmailКонтактногоЛица""";
	ЭлементОтсутсвуетВДанных = Запрос.Выполнить().Пустой();

Если это все-таки ошибка в данных базы, то необходимо выполнить привязку к предопределенному элементу элемента ИБ. Т.е. необходимо объяснить системе, к какому элементу ИБ должен обратиться программный код по данному имени. Технически привязка это просто указание имени предопределенного элемента в свойстве "ИмяПредопределенныхДанных" элемента ИБ. Для ее установки достаточно выполнить код:

ОбновляемыйОбъект = СсылкаНаОбъект.ПолучитьОбъект();
ОбновляемыйОбъект.ИмяПредопределенныхДанных = "НашеИмяПредопределенногоЭлемента";
ОбновляемыйОбъект.ОбменДанными.Загрузка = Истина;
ОбновляемыйОбъект.Записать();

2. "Предопределенный элемент не уникален" - задвоенные предопределенные элементы:

Эта ситуация заключается в том, что к одному предопределенному элементу привязано несколько элементов ИБ. В этом случае при обращении к предопределенному имени элемент будет выбираться случайным образом. Такая ситуация всегда ошибочна. Ее сложность в том, что платформа никак о ней не сообщает. Просто алгоритмы начинают работать неверно.

Платформа сообщит об ошибке "Предопределенный элемент не уникален" лишь при попытке редактирования задублированного элемента.

Предопределенный элемент не уникален

До тех пор, пока никому не понадобится редактировать элемент, об ошибке никто не узнает.

Такие дубли могут создаться, например, если для справочника используеися РИБ и в свойствах для предопределенных данных указан режим "Обновлять автоматически". В этом случае при выполнении обмена один экземпляр предопределенных данных создастся при обновлении конфигурации. Второй экземпляр предопределенных элементов с тем же именем передастся из центральной базы при обмене.

Также эти дубли возникнут при использовании обработок обмена между конфигурациями в случае, если в разных базах предопределенным элементам соответствеют разные элементы ИБ. В этом случае один экземпляр предопределенных данных в базе уже есть, второй придет при выполнении загрузки данных с другим УИДом. Если вы выполняете переносы данных, необходимо решить, элементы какой базы считаются основными и использовать их же в подчиненной базе. В подчиненной базе необходимо заменить использование старых элементов на элементы основной базы. 

Такие ошибки в базе данных можно выявить запросом вида:

ВЫБРАТЬ
    ВидыКонтактнойИнформации.ИмяПредопределенныхДанных,
    КОЛИЧЕСТВО(РАЗЛИЧНЫЕ ВидыКонтактнойИнформации.Ссылка) КАК КоличествоПредопределенных
ИЗ
    Справочник.ВидыКонтактнойИнформации КАК ВидыКонтактнойИнформации
СГРУППИРОВАТЬ ПО
    ВидыКонтактнойИнформации.ИмяПредопределенныхДанных
ИМЕЮЩИЕ
    КОЛИЧЕСТВО(РАЗЛИЧНЫЕ ВидыКонтактнойИнформации.Ссылка) > 1

Этот запрос вернет перечень предопределенных элементов, с которым связано более одного элемента ИБ.

При наличии таких элементов необходимо убрать для одного из них связь с предопределенным. Т.е. необходимо однозначно определить для системы, к какому элементу ИБ должен обратиться программный код при использовании данного имени.  Для этого достаточно выполнить код.

ОбновляемыйОбъект = СсылкаНаЭлемент.ПолучитьОбъект();
ОбновляемыйОбъект.ИмяПредопределенныхДанных = "";
ОбновляемыйОбъект.ОбменДанными.Загрузка = Истина;
ОбновляемыйОбъект.Записать();

 

3. Неверное указание предопределенного элемента. 

Ошибка заключается в том, что предопределенному элементу соответствует не тот элемент, который предусмотрен логикой программы.  Такие ошибки наиболее сложны в диагностике. В отличие от первых двух типов, на наличие этих ошибок автоматически проверить конфигурацию нельзя.  Их можно выявить только анализируя логику работы. При возникновении сомнений можно проверить, нужный ли элемент используется.

Для этого достаточно выполнить одну из команд.

//Определение элемента ИБ, который привязан к нужному предопределенному
Сообщить(Справочники.ВидыКонтактнойИнформации.EmailКонтактногоЛица) 
//Определяем предопределенный элемент, к которому привязан выбранный
Сообщить(СсылкаНаЭлемент.ИмяПредопределенныхДанных)

При выявлении таких ошибок необходимо убрать некорректную связь со старым элементом и добавить связь с новым элементом. Код операций аналогичен коду исправления первых двух типов ошибок.

Ну и кратко об ошибках при программной работе или в режиме конфигуратора:

"Предопределенный элемент не принадлежит <Имя справочника>" - ошибка возникает при попытке записать предопределенный элемент с именем, не совпадающим с именем в коонфигураторе.

"Не предопределенные объекты не могут иметь предопределенные записи видов субконто" - ошибка возникает при попытке сделать элемент предопределенный плана счетов непредопределенным. Для устранения ошибок необходимо у каждой строки субконта элемента снять признак "Предопределенное".

"Не предопределенные объекты не могут иметь предопределенные записи ведущих видов расчетов"  - ошибка возникает при попытке сделать предопределенный элемент плана видов расчета непредопределенным. Для устранения ошибок необходимо у каждой строки ведущего вида расчета элемента снять признак "Предопределенное".

"Предопределенные элементы не уникальны" - ошибка выдается в конфигураторе при обновлении информационной базы на релиз конфигурации без режима совместимости с 8.3.4. Необходимо до обновления проверить дубли и устранить их.

"Имя предопределенного элемента не уникально" - ошибка возникает при наличии в конфигурации нескольких одноименных предопределенных элементов при обновлении на платформу 8.3.6.2332 и выше. Необходимо устранить дубли в конфигурации.

Для работы с предопределенными данными рекоммендую обработку "Установка предопределенных элементов: просмотр, исправление и поиск ошибок (задвоенных и отсутствующих)". Она умеет выполнять любые действия с предопределенными данными, а также может проверить конфигурацию вцелом на наличие во всех объектах ИБ (справочниках, планах счетов, ПВХ, ПВР) ошибок первых двух типов (задвоенных и отсутствующих элементов). 

Предопределенный элемент отсутствует в данных Предопределенный элемент не уникален

См. также

Поинтегрируем: сервисы интеграции – новый стандарт или просто коннектор?

Обмен между базами 1C Администрирование СУБД Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

В платформе 8.3.17 появился замечательный механизм «Сервисы интеграции». Многие считают, что это просто коннектор 1С:Шины. Так ли это?

11.03.2024    4514    dsdred    53    

71

Как готовить и есть массивы

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Все мы используем массивы в своем коде. Это один из первых объектов, который дают ученикам при прохождении обучения программированию. Но умеем ли мы ими пользоваться? В этой статье я хочу показать все методы массива, а также некоторые фишки в работе с массивами.

24.01.2024    5290    YA_418728146    25    

63

Планы обмена VS История данных

Обмен между базами 1C Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Вы все еще регистрируете изменения только на Планах обмена и Регистрах сведений?

11.12.2023    6408    dsdred    36    

111

1С-ная магия

Механизмы платформы 1С Бесплатно (free)

Язык программирования 1С содержит много нюансов и особенностей, которые могут приводить к неожиданным для разработчика результатам. Сталкиваясь с ними, программист начинает лучше понимать логику платформы, а значит, быстрее выявлять ошибки и видеть потенциальные узкие места своего кода там, где позже можно было бы ещё долго медитировать с отладчиком в поисках источника проблемы. Мы рассмотрим разные примеры поведения кода 1С. Разберём результаты выполнения и ответим на вопросы «Почему?», «Как же так?» и «Зачем нам это знать?». 

06.10.2023    18473    SeiOkami    46    

118

Дефрагментация и реиндексация после перехода на платформу 8.3.22

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Начиная с версии платформы 8.3.22 1С снимает стандартные блокировки БД на уровне страниц. Делаем рабочий скрипт, как раньше.

14.09.2023    12087    human_new    27    

74

Валидация JSON через XDTO (включая массивы)

WEB-интеграция Универсальные функции Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

При работе с интеграциями рано или поздно придется столкнуться с получением JSON файлов. И, конечно же, жизнь заставит проверять файлы перед тем, как записывать данные в БД.

28.08.2023    8820    YA_418728146    6    

141

Внешние компоненты Native API на языке Rust - Просто!

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Внешние компоненты для 1С можно разработывать очень просто, пользуясь всеми преимуществами языка Rust - от безопасности и кроссплатформенности до удобного менеджера библиотек.

20.08.2023    6279    sebekerga    54    

94

Все скопируем и вставим! (Буфер обмена в 1С 8.3.24)

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Рассмотрим новую возможность 8.3.24 и как её можно эффективно использовать

27.06.2023    15986    SeiOkami    31    

103
Вознаграждение за ответ
Показать полностью
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. monkbest 115 06.11.14 13:15 Сейчас в теме
2. buval 65 22.03.15 16:56 Сейчас в теме
Спасибо за сведения. В РИБ была аналогичная ошибка
"Справочник.УдалитьСтатусыНалогоплательщиковПоНДФЛ.Резидент. Предопределенный элемент отсутствует в данных"

Изменил предложенный код и всё получилось
СсылкаНаОбъект=Справочники.УдалитьСтатусыНалогоплательщиковПоНДФЛ;
ОбновляемыйОбъект = СсылкаНаОбъект.СоздатьЭлемент();// .ПолучитьОбъект();
ОбновляемыйОбъект.ИмяПредопределенныхДанных = "Резидент";
ОбновляемыйОбъект.Наименование= "Резидент";
ОбновляемыйОбъект.ОбменДанными.Загрузка = Истина;
ОбновляемыйОбъект.Записать();
mpvrus21; Aspire1C; d.zhukov; valentinanb; Ioryk; +5 Ответить
18. Ioryk 25.01.17 13:33 Сейчас в теме
(2) Спасибо, и у меня получилось, хотя то же пришлось поправить...:
&НаСервере
Процедура НС_Установить()
СсылкаНаОбъект =ОбектПредопределенных;
ОбновляемыйОбъект = СсылкаНаОбъект.ПолучитьОбъект();
ОбновляемыйОбъект.ИмяПредопределенныхДанных = "РазрешитьВыборКартыБезEmailПодтверждения";
ОбновляемыйОбъект.Наименование= "Разрешить Выбор Карты Без Email Подтверждения";
ОбновляемыйОбъект.ОбменДанными.Загрузка = Истина;
ОбновляемыйОбъект.Записать();
КонецПроцедуры
Показать
3. capitan 2466 07.04.15 19:36 Сейчас в теме
Хорошая статья. Помогла.
А не пробовали разбираться, что меняется в базе, чтобы в периферийном узле предопределенные элементы не обновлялись из конфигуратора ?
Вариант - отстутствие главного узла не проходит.
Не пробовал правда саму базу сделать на время главной.
4. ekaruk 4896 07.04.15 19:52 Сейчас в теме
(3) capitan, Зависит от свойства "Обновление предопределеныых данных" конкретного справочника.
Если "Авто", то в подчиненных базах предопределенные элементы создаваться не будут. Должны прийти с обменом.
Если "обновлять автоматически", то всегда будут создаваться.
5. capitan 2466 07.04.15 23:14 Сейчас в теме
(4) Не поняли мой вопрос.
Откуда база узнает ,что она периферийная ?
Вариант - отстутствие главного узла не проходит.
Удалял главный узел, все равно предопределенные элементы не создаются.
Т.е. база еще где то помнит, что она была периферийной.
MaxDen; KirinaAS; mea27; +3 Ответить
6. ekaruk 4896 08.04.15 11:24 Сейчас в теме
(5) capitan, Теоретически должны пересоздаться при следующем обновлении конфигурации.
Т.е. отключить от центрального узла и что-то изменить в конфигурации (банально пробел где-то добавить)
Либо запустить с ключем /SetPredefinedDataUpdate

Еще зависит от конфигурации.
Может быть программно установлен другой режим обновления методом УстановитьОбновлениеПредопределенныхДанных()
38. user1338598 12.04.23 17:34 Сейчас в теме
(5)здравствуйте, решили эту проблему?
7. maikl007 91 27.04.15 07:58 Сейчас в теме
Спасибо хорошая статейка, и обработка помогла
8. markers 274 22.07.15 12:20 Сейчас в теме
Полезная статья, спасибо!
9. KliMich 26.10.15 23:07 Сейчас в теме
Очень вовремя, спасибо!
Обработка как раз кстати...
10. dsp123 10.11.15 17:02 Сейчас в теме
По поводу "самого простого способа №1"
при переходе с БП на БСО в конфигураторе появились несколько специфических предопределенных «строительных» счетов. в базе данных есть соответствующие им элементы, но связать их никак не получается. При обращении обработками из режима предприятие счета не видны (ни обработкам, ни пользователю). То есть, чтобы связать предопределенные элементы с данными их надо увидеть из пользовательского режима, а для этого они должны быть уже связаны… Как выйти из этого порочного круга?
11. ekaruk 4896 10.11.15 19:33 Сейчас в теме
(10) dsp123, Что имеется в виду под "Не видны"?
Если они есть в базе, то их просто нужно выбрать.
Если нету, то создать элементы в базе и привязать.
12. Tolyasik 15.03.16 12:59 Сейчас в теме
Здравствуйте! Ребят подскажите что можно сделать. В плане счетов ЕПСБУ в счете 104.36 появилась галочка "Нет учета по КПС" хотя галочки "Заболансовый" нет, при попытке изменить выдает сообщение что предопределенный элемент не уникален. Я не особый специалист 1С, я только учусь, по этому прошу вашей помощи!
13. ekaruk 4896 15.03.16 16:16 Сейчас в теме
(12) Tolyasik, Как раз об этом второй раздел данной статьи
2. "Предопределенный элемент не уникален" - задвоенные предопределенные элементы:
Несколько элементов ИБ привязаны к одному предопределенному в конфигурации.
Эти проблемы отлично решает обработка
http://infostart.ru/public/305892/
14. Spacer 355 05.04.16 10:52 Сейчас в теме
Добрый день!

"Предопределенный элемент не принадлежит <Имя справочника>" - ошибка возникает при попытке записать предопределенный элемент с именем, не совпадающим с именем в коонфигураторе.

А почему такая ошибка возникает в запросе, в типовом ЗУП 3.0?

Я добавил в справочник "ПоказателиРасчетаЗарплаты" новый предопределенный элемент, и теперь выскакивает соответствующая ошибка.

Общий модуль "СтандартныеПодсистемыПовтИсп", функция "ПредопределенныйЭлемент()", текст запроса:

ВЫБРАТЬ РАЗРЕШЕННЫЕ ПЕРВЫЕ 1
	ПОКАЗАТЕЛИРАСЧЕТАЗАРПЛАТЫ.Ссылка КАК Ссылка
ИЗ
	Справочник.ПоказателиРасчетаЗарплаты КАК ПОКАЗАТЕЛИРАСЧЕТАЗАРПЛАТЫ
ГДЕ
	ПОКАЗАТЕЛИРАСЧЕТАЗАРПЛАТЫ.ИмяПредопределенныхДанных = &ИмяПредопределенного

-----------------------------------
Вопрос снят. Протупил. В запрос передавалось неправильное имя предопределенного.
15. mixqn 21.08.16 21:55 Сейчас в теме
(14) Spacer, столкнулся с аналогичной ситуацией. хоть убей не понимаю, почему это должно вызывать ошибку, а не просто пустой результат запроса, как при поиске по любому другому реквизиту строкового типа. бред какой-то...
16. cbu23 22.12.16 12:31 Сейчас в теме
Добрый день! В бух. 3.0 Что то случилось со справочником ВидыКонтактнойИнформации. Когда открываешь справочник, то он пуст. Скачала Вашу обработку, но она видит все предопределенные элементы справочника и ошибок не находит. При этом в любом справочнике, где используется контактная информация ни адрес ни телефон заполнить нет возможности, просто нет гиперссылок. Может вы встречались с такой ситуацией и можете что то посоветовать? Бьюсь уже 2 дня.
17. Den_Zenit 18 21.01.17 16:24 Сейчас в теме
Спасибо! очень помогло...ошибка возникла в справочнике "Страны Мира"
19. Sean1s 8 13.04.17 10:26 Сейчас в теме
У нас, в ЗУП 2.5, после очередного обновления конфы потребовалось перейти на 8.3. Это было в середине марта. И вот вчера обнаружилось что в документе "Начисление страховых взносов" перестали рассчитываться ФСС НС и ПЗ. Колонка ФСС заполняется, а ФСС НС и ПЗ - нет.
Два дня искал причину и нашёл - в справочнике ДоходыПоСтраховыхВзносам в предопределенном элементе "ОблагаетсяЦеликом" значение реквизита ВходитВБазуФСС_НС стало Ложь.
Что характерно у нас несколько баз ЗУП. И в двух из них всё в порядке, а в остальных такое вот.
Почему? Мне вот не понятно.
20. markovki 19 07.03.18 15:29 Сейчас в теме
Благодарю автора за статью.
Столкнулись с первой ошибкой, по факту решение пришло неожиданно, когда добавили в режиме предприятия исчезнувшую статью движения денежных средств "Оплата от покупателя", то система автоматически привязала его к предопределенному элементу с таким же наименованием.
При чем реквизиты создаваемого элемента "оплата от покупателя" ДОЛЖНЫ быть заполнены в точности, как в демо базе, по крайней мере в нашем случае ВидОперации должен был быть правильно заполнен.
21. HamitovaRaisa 24.06.18 13:15 Сейчас в теме
Добрый день) Видимо, я что-то недопонимаю, хотя в 1С работаю уже не 1-й год. Нет у меня в справочнике свойства ИмяПредопределенныхДанных через запрос. Вот код:

Процедура ()
Об=Справочники.Автоработы.НайтиПоКоду("ЦБ000000373").ПолучитьОбъект();
Об.ИмяПредопределенныхДанных="ОсмотрАвтомобиля";
Об.Записать();
КонецПроцедуры

Ругается:
Поле объекта не обнаружено (ИмяПредопределенныхДанных)

Откуда вы видите это свойство в справочнике?
22. spacecraft 24.06.18 15:08 Сейчас в теме
(21)
Поле объекта не обнаружено (ИмяПредопределенныхДанных)

Прямо вот точно так ругается? Или может там другая формулировка.
ИмяПредопределенныхДанных не назначает любому элементу справочника произвольное предопределенное имя.
Оно назначает уже имеющееся предопределенное имя выбранному элементу справочника, при условии, что этот предопределенный элемент никакому объекту не назначен (как вариант - удален из базы).

В качестве примера:
Предположим, что конфигурации в справочнике "Автоработы" есть предопределенный элемент "ОсмотрАвтомобиля".
Попытка
	ПредопределенныйЭлемент = Справочники.Автоработы.ОсмотрАвтомобиля.ПолучитьОбъект();
	ПредопределенныйЭлемент.ИмяПредопределенныхДанных = Неопределено;
	ПредопределенныйЭлемент.Записать();
Исключение
КонецПопытки;

НовыйПредопределенныйЭлемент = Справочники.Автоработы.НайтиПоКоду("ЦБ000000373").ПолучитьОбъект();
НовыйПредопределенныйЭлемент.ИмяПредопределенныхДанных = "ОсмотрАвтомобиля";
НовыйПредопределенныйЭлемент.Записать();
Показать
23. HamitovaRaisa 24.06.18 16:28 Сейчас в теме
Полностью Скопировала код. Вот такое сообщение выходит:

{ВнешнийОтчет.ВнешнийОтчет1.Форма.ФормаОтчета.Форма(3126)}: Поле объекта не обнаружено (ИмяПредопределенныхДанных)
НовыйПредопределенныйЭлемент.ИмяПредопределенныхДанных = "ОсмотрАвтомобиля";
24. HamitovaRaisa 24.06.18 16:30 Сейчас в теме
Полностью скопировала код. Вот такое сообщение выходит:

{ВнешнийОтчет.ВнешнийОтчет1.Форма.ФормаОтчета.Форма(3126)}: Поле объекта не обнаружено (ИмяПредопределенныхДанных)
НовыйПредопределенныйЭлемент.ИмяПредопределенныхДанных = "ОсмотрАвтомобиля";
25. HamitovaRaisa 24.06.18 16:32 Сейчас в теме
Полностью скопировала код. Вот такое сообщение выходит:

{ВнешнийОтчет.ВнешнийОтчет1.Форма.ФормаОтчета.Форма(3126)}: Поле объекта не обнаружено (ИмяПредопределенныхДанных)
НовыйПредопределенныйЭлемент.ИмяПредопределенныхДанных = "ОсмотрАвтомобиля";
(22)
26. spacecraft 24.06.18 16:53 Сейчас в теме
(25) версия платформы и режим совместимости?
В самой публикации в самом начале указано: "В 8.3.3".
27. HamitovaRaisa 24.06.18 21:24 Сейчас в теме
8.3.10.2580, режим совместимости: 8.2.16
28. spacecraft 24.06.18 22:33 Сейчас в теме
(27)
режим совместимости: 8.2.16

Вот и ответ. В 8.2 нет этого функционала.
29. HamitovaRaisa 26.06.18 22:49 Сейчас в теме
30. m.pikhota 39 14.08.18 15:47 Сейчас в теме
Спасибо за статью!
Добавлю что в типовых ЗУП 3.1 и БУХ 3 есть функция для получения ссылки предопределенного элемента по его полному имени
Например:
ОбщегоНазначенияКлиентСервер.ПредопределенныйЭлемент("Справочник.ВидыИспользованияРабочегоВремени.РаботаВечерниеЧасы")

// Возвращаемое значение:
// ЛюбаяСсылка - ссылка на предопределенный элемент.
// Неопределено - если предопределенный есть в метаданных, но не создан в ИБ.

При ее использовании не будет происходит ошибка ""Предопределенный элемент отсутствует в данных"", как при прямом обращении к предопределенному элементу например "Справочник.ВидыИспользованияРабочегоВремени.РаботаВечерниеЧасы"
в том случае, например, если в базе не используются "Вечерние часы" и элемент в ИБ не был поэтому целенаправленно создан.
31. shved 01.10.18 13:18 Сейчас в теме
вставлю 5 копеек для плана счетов (ругалось при обновлении на 65ый БП3)

М = Метаданные.ПланыСчетов.Хозрасчетный.ПолучитьИменаПредопределенных();
	Для каждого Имя Из М Цикл
		
		Попытка
			Ссылка = ПланыСчетов.Хозрасчетный[Имя].Ссылка;
			ОбновляемыйОбъект = Ссылка.ПолучитьОбъект();
			ОбновляемыйОбъект.ИмяПредопределенныхДанных = Имя;
			ОбновляемыйОбъект.ОбменДанными.Загрузка = Истина;
			ОбновляемыйОбъект.Записать();

		Исключение
		    ОбновляемыйОбъект = ПланыСчетов.Хозрасчетный.СоздатьСчет();
		    ОбновляемыйОбъект.ИмяПредопределенныхДанных = Имя;
			ОбновляемыйОбъект.ОбменДанными.Загрузка = Истина;
			ОбновляемыйОбъект.Записать();
		КонецПопытки;
	КонецЦикла;
Показать
Deda; Aspire1C; veselon; +3 Ответить
32. selez-a 17 20.03.19 11:29 Сейчас в теме
Спасибо, статья помогла. В БП3 в конфигураторе у справочника СтатьиЗатрат есть предопределенное значение "КомандировочныеРасходы" в режиме 1С Предприятия, такого элемента не было. Пришлось добавлять элемент, используя ваш код.
33. lev6975 09.11.20 12:24 Сейчас в теме
У меня было предопределенный элемент отсутствует в данных, после обновления, хотя, элемент был. Решилось установкой параметра Обновление предопределенных данных в "Обновлять", удалением предопределенного объекта и созданием нового
34. Mousecom 2 13.05.21 15:49 Сейчас в теме
Спасибо за статью. Очень выручила на бардачной базе при обновлении.
35. zan0zzza 25.10.21 13:03 Сейчас в теме
Спасибо! Очень пригодилась эта информация!
36. dream991 03.04.22 16:07 Сейчас в теме
37. Veika 25 24.06.22 13:05 Сейчас в теме
Сегодня такая же ошибка появилась при обновлении на базовой БП 3.0, подскажите, как базовую исправить?
39. GetNight 46 30.08.23 07:03 Сейчас в теме
в справочнике "Причины нетрудоспособности" при обновлении древней УПП на 1.3.68.1 появился предопределённый элемент "изоляция от COVID-19"

но в РИБ этот элемент не прилетел, а при первой загрузке написало:
Не найден предопределённый элемент COVID_19 для справочника Причины нетрудоспособности

в очередные обмены так ничего и не появилось, правда, больше об ошибке не сообщало

вопрос решился так:
на основном узле добавил/удалил 1 букву в наименовании (редактирование в списке)
после обмена предопределённый элемент прилетел в РИБ корректно
Оставьте свое сообщение