Вроде не пятница 13... Ошибка СКД

1. anterehin 15 25.06.14 10:39 Сейчас в теме
Коллеги привожу ошибку исполнения СКД, ниже код запроса. По факту параметра ПЗ нигде нет(

Ошибка при исполнении запроса набора данных
по причине:
{(40, 4)}: Ошибка обработки представления "РегистрСведений.ОсновныеСпецификацииНоменклатуры.СрезПоследних:Несоответствие типов (Параметр номер ""1"")"
<<?>>РегистрСведений.ОсновныеСпецификацииНоменклатуры.СрезПоследних(&П3, ) КАК ОсновныеСпецификацииНоменклатурыСрезПоследних


ВЫБРАТЬ
	Остатки.Артикул,
	СУММА(Остатки.КоличествоНачальныйОстаток) КАК КоличествоНачальныйОстаток,
	Остатки.Склад,
	Остатки.Номенклатура,
	Приход.КолВоПриход,
	Приход.Излишки,
	Приход.ПерекомплектацияПриход,
	Приход.КолВоПроизведено,
	ЕСТЬNULL(Приход.КолВоПриход, 0) КАК КолВоПриходNULL,
	РасходПроизводство.КолВоПоНорме,
	РасходПроизводство.КолВоПоФакту
ИЗ
	(ВЫБРАТЬ
		ТоварыНаСкладахОстаткиИОбороты.КоличествоНачальныйОстаток КАК КоличествоНачальныйОстаток,
		ТоварыНаСкладахОстаткиИОбороты.КоличествоКонечныйОстаток КАК КоличествоКонечныйОстаток,
		СпрНоменклатура.Артикул КАК Артикул,
		ТоварыНаСкладахОстаткиИОбороты.Склад КАК Склад,
		СпрНоменклатура.Ссылка КАК Номенклатура
	ИЗ
		РегистрНакопления.ТоварыНаСкладах.ОстаткиИОбороты(&НачалоПериода, &КонецПериода, , , Склад = &Склад) КАК ТоварыНаСкладахОстаткиИОбороты
			ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.Номенклатура КАК СпрНоменклатура
			ПО ТоварыНаСкладахОстаткиИОбороты.Номенклатура.Ссылка = СпрНоменклатура.Ссылка
	ГДЕ
		СпрНоменклатура.Ссылка = &Номенклатура) КАК Остатки
		ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
			СпецификацииНоменклатурыИсходныеКомплектующие.Номенклатура КАК Комплектующая,
			СУММА(ЕСТЬNULL(ВЫБОР
						КОГДА ТИПЗНАЧЕНИЯ(ТоварыНаСкладахОбороты.Регистратор) = ТИП(Документ.ОтчетПроизводстваЗаСмену)
							ТОГДА ТоварыНаСкладахОбороты.КоличествоПриход
					КОНЕЦ, 0) * СпецификацииНоменклатурыИсходныеКомплектующие.Количество) КАК КолВоПоНорме,
			СУММА(ЕСТЬNULL(ВЫБОР
						КОГДА ТИПЗНАЧЕНИЯ(МатериалыВПроизводствеОбороты.Регистратор) = ТИП(Документ.ОтчетПроизводстваЗаСмену)
							ТОГДА МатериалыВПроизводствеОбороты.КоличествоРасход
					КОНЕЦ, 0)) КАК КолВоПоФакту
		ИЗ
			РегистрСведений.ОсновныеСпецификацииНоменклатуры.СрезПоследних(&КонецПериода, ) КАК ОсновныеСпецификацииНоменклатурыСрезПоследних
				ЛЕВОЕ СОЕДИНЕНИЕ Справочник.СпецификацииНоменклатуры.ИсходныеКомплектующие КАК СпецификацииНоменклатурыИсходныеКомплектующие
				ПО ОсновныеСпецификацииНоменклатурыСрезПоследних.СпецификацияНоменклатуры = СпецификацииНоменклатурыИсходныеКомплектующие.Ссылка
				ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ТоварыНаСкладах.Обороты(&НачалоПериода, &КонецПериода, Регистратор, ) КАК ТоварыНаСкладахОбороты
				ПО ОсновныеСпецификацииНоменклатурыСрезПоследних.Номенклатура = ТоварыНаСкладахОбороты.Номенклатура,
			РегистрНакопления.МатериалыВПроизводстве.Обороты(&НачалоПериода, &КонецПериода, Регистратор, Затрата = &Номенклатура) КАК МатериалыВПроизводствеОбороты
		ГДЕ
			СпецификацииНоменклатурыИсходныеКомплектующие.Ссылка.Активная = ИСТИНА
			И СпецификацииНоменклатурыИсходныеКомплектующие.Ссылка.Состояние = ЗНАЧЕНИЕ(Перечисление.СостоянияОбъектов.Утвержден)
			И СпецификацииНоменклатурыИсходныеКомплектующие.Номенклатура = &Номенклатура
		
		СГРУППИРОВАТЬ ПО
			СпецификацииНоменклатурыИсходныеКомплектующие.Номенклатура) КАК РасходПроизводство
		ПО Остатки.Номенклатура = РасходПроизводство.Комплектующая
		ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
			СпрНоменклатура.Ссылка КАК Номенклатура,
			СУММА(ВЫБОР
					КОГДА ТИПЗНАЧЕНИЯ(ТоварыНаСкладахОбороты.Регистратор) = ТИП(Документ.ПоступлениеТоваровУслуг)
						ТОГДА ТоварыНаСкладахОбороты.КоличествоПриход
				КОНЕЦ) КАК КолВоПриход,
			ВЫБОР
				КОГДА ТИПЗНАЧЕНИЯ(ТоварыНаСкладахОбороты.Регистратор) = ТИП(Документ.ОприходованиеТоваров)
					ТОГДА ТоварыНаСкладахОбороты.КоличествоПриход
			КОНЕЦ КАК Излишки,
			ВЫБОР
				КОГДА ТИПЗНАЧЕНИЯ(ТоварыНаСкладахОбороты.Регистратор) = ТИП(Документ.КомплектацияНоменклатуры)
					ТОГДА ТоварыНаСкладахОбороты.КоличествоПриход
			КОНЕЦ КАК ПерекомплектацияПриход,
			ВЫБОР
				КОГДА ТИПЗНАЧЕНИЯ(ТоварыНаСкладахОбороты.Регистратор) = ТИП(Документ.ОтчетПроизводстваЗаСмену)
					ТОГДА ТоварыНаСкладахОбороты.КоличествоПриход
			КОНЕЦ КАК КолВоПроизведено
		ИЗ
			Справочник.Номенклатура КАК СпрНоменклатура
				ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ТоварыНаСкладах.Обороты(&НачалоПериода, &КонецПериода, Регистратор, ) КАК ТоварыНаСкладахОбороты
				ПО (ТоварыНаСкладахОбороты.Номенклатура = СпрНоменклатура.Ссылка)
		ГДЕ
			СпрНоменклатура.Ссылка = &Номенклатура
		
		СГРУППИРОВАТЬ ПО
			СпрНоменклатура.Ссылка,
			ВЫБОР
				КОГДА ТИПЗНАЧЕНИЯ(ТоварыНаСкладахОбороты.Регистратор) = ТИП(Документ.ОприходованиеТоваров)
					ТОГДА ТоварыНаСкладахОбороты.КоличествоПриход
			КОНЕЦ,
			ВЫБОР
				КОГДА ТИПЗНАЧЕНИЯ(ТоварыНаСкладахОбороты.Регистратор) = ТИП(Документ.КомплектацияНоменклатуры)
					ТОГДА ТоварыНаСкладахОбороты.КоличествоПриход
			КОНЕЦ,
			ВЫБОР
				КОГДА ТИПЗНАЧЕНИЯ(ТоварыНаСкладахОбороты.Регистратор) = ТИП(Документ.ОтчетПроизводстваЗаСмену)
					ТОГДА ТоварыНаСкладахОбороты.КоличествоПриход
			КОНЕЦ) КАК Приход
		ПО Остатки.Номенклатура = Приход.Номенклатура
ГДЕ
	Остатки.Склад = &Склад

СГРУППИРОВАТЬ ПО
	Остатки.Склад,
	Остатки.Артикул,
	Остатки.Номенклатура,
	Приход.КолВоПриход,
	Приход.Излишки,
	Приход.ПерекомплектацияПриход,
	Приход.КолВоПроизведено,
	РасходПроизводство.КолВоПоНорме,
	РасходПроизводство.КолВоПоФакту
Показать
dmu67; lap-den; +2 Ответить
Ответы
Подписаться на ответы Инфостарт бот Сортировка: Древо развёрнутое
Свернуть все
2. Xershi 1504 25.06.14 10:48 Сейчас в теме
(1) anterehin, в конструкторе заходи в запрос, там таблицы с твоим регистром и вот там есть кнопка с этим параметром!
3. anterehin 15 25.06.14 10:52 Сейчас в теме
(2) Xershi, Если выделить регистр Сведений РегистрСведений.ОсновныеСпецификацииНоменклатуры.СрезПоследних и нажать в конструкторе Параметры виртуальной таблицы , то там как и ожидалось стоит параметр КонецПериода
4. Xershi 1504 25.06.14 10:57 Сейчас в теме
(3) anterehin, так в запросе у вас так и написано, а текст ошибки с кодом не соотносится...
Пересохрани отчет, почисти кэш и проверь!
6. anterehin 15 25.06.14 11:12 Сейчас в теме
(4) Xershi, Очистка и пересохранение не помогло.
(5) spezc, что за автозаполнение?
7. Xershi 1504 25.06.14 11:30 Сейчас в теме
(6) anterehin, когда определяешь структуру вывода данных, там есть поле авто, попробуй указать только конкретные поля!
8. anterehin 15 25.06.14 11:33 Сейчас в теме
(7) Xershi, Авто убранно так как структура вывода нарисована с группами... но опять же какое отношение это имеет к параметрам?( Ушёл травиться никотином.. полтора часа сижу и не въеду
5. spezc 787 25.06.14 11:05 Сейчас в теме
убрать Автозаполнение в СКД?
9. anterehin 15 25.06.14 11:43 Сейчас в теме
Факт в том что в консоли запросов запрос отрабатывает на ура
10. Xershi 1504 25.06.14 11:47 Сейчас в теме
(9) anterehin, создай новый отчет с нуля с таким же запросом и проверь может глюк в настройках все-таки...
anterehin; +1 Ответить
11. anterehin 15 25.06.14 11:53 Сейчас в теме
(10) Xershi, хм... закинул. не стал делать стандартный период.. не страл делать структуру вывода с группами, просто накидал поля.. работает.. сейчас буду затачивать как нужно и смотреть... вылезит ли и если да то на каком месте
12. Xershi 1504 25.06.14 12:08 Сейчас в теме
(11) anterehin, СКД такая фишка, что кажется должно все пахать, а оно берет данные которые не учел. Поэтому если четко не знаешь что и откуда, метод тыка выручит))
46. user970589 11 22.06.21 04:50 Сейчас в теме
(11)
закинул. не стал делать стандартный период.. не страл делать структуру вывода с группами, просто накидал поля.. работает.. сейчас буду затачивать как нужно и смотреть... вылезит ли и если

аналогичное со стандартным периодом вылезло. До определенного момента причем работало, но после усложнения запроса стал вываливаться в ошибку представления. (добавил ЕЩЕ одну временную таблицу). Не знаю.. может в том, что в одних таблицах период начало и конец, а в новой - регистр остатки срез последних.
13. anterehin 15 25.06.14 14:05 Сейчас в теме
В общем други давайте думать вместе.... После того как создал новый отчет и вставил в него работающий запрос с вынесением в структуру данных полей всё заработало. Но... в СКД упорно появляется параметр "Период" и тянется он из регистра сведений

РегистрСведений.ОсновныеСпецификацииНоменклатуры.СрезПоследних. И начинается следующее..вешаю на "Период" стандартный период и параметры НачалоПериода и КонецПериода, после этого начинает появляться вышеописанная ошибка. В параметрах СКД создаю параметр "ПериодОтчета" делаю стандартным периодом и соответственно привязываю НачалоПериода и КонецПериода...Но возникает одно большое НО. Регистр сведений никак не хочет видить параметр КонецПериода который у него указан в виртуальной таблице и запрашивает свой. Если указываю стандартный период равный месяцу, а параметр "Период" = КонецПериода то всё работает. Но спрашивается зачем мне его указывать явно((. В чем трабла?

в параметрах СКД у параметра в выражение написал "&ПериодОтчета.ДатаОкончания" и поставил ограничение на параметр.

Но не понятно почему всё же не видит параметр из виртуальной таблицы
14. Dmitry_Shelchkov 25.06.14 14:24 Сейчас в теме
Переименуй НачалоПериода и КонецПериода и будет тебе счастье)
15. anterehin 15 25.06.14 14:32 Сейчас в теме
(14) Dmitry_Shelchkov, Переименовать в запросе?
Переименовал , теперь в СКД 3 параметра: НачалоОтчета,КонецОтчета, ПериодОтчета))
В общем как показал гуглёжь мои метод один из правильных.

НачалоПериода и КонецПериода появляются при использование оборотных регистров
Период при использование регистра остатков.

В параметрах Период ограничивается и в выражение приравнивается либо к НачалоПериода либо КонецПериода в зависимости от того какой срез нужен
Rusel; &rew; Helly_ti; serverstar; user712426; user1315860; LavinVladik; Mehozavr; +8 Ответить
16. Dmitry_Shelchkov 25.06.14 14:49 Сейчас в теме
Переименовать в запросе.
В оборотном регистре, если явно не указан параметр, то появляются скдэшные "НачалоПериода" и "КонецПериода", поэтому нежелательно использовать параметры с таким именем в запросах - могут конфликтовать. В итоге в параметрах должны появиться и наши параметры и эти, добавляем стандартный период, на все параметры вешаем Период.ДатаОкончания и Период.ДатаНачала и все работает))
&rew; serverstar; user712426; Xershi; +4 Ответить
17. IvanKh 1 06.04.16 12:04 Сейчас в теме
Долгая медитация и расследования привели к следующему результату.
Если коротко: Параметры для СКД устанавливать на вкладке "компоновка данных" в конструкторе запроса.
И длинно:
В конструкторе запроса на вкладке "таблицы и поля" параметру виртуальной таблицы *СрезПоследних "Период" задаем имя "&Период1". Имеются другие виртуальные таблицы с параметрами "НачалоПериода" и "КонецПериода". СКД создает параметры: "НачалоПериода" тип "дата", "КонецПериода" тип "дата" и "Период1" тип "дата" Параметр "Период" тип "СтандартныйПериод" создадим для удобства повесив Период.ДатаОкончания и Период.ДатаНачала на соответствующие параметры. При выполнении выдает ошибку примерно следующего толка: "Ошибка обработки представления "РегистрСведений.*.СрезПоследних:Несоответствие типов (Параметр номер ""1"")"ЛЕВОЕ СОЕДИНЕНИЕ <<?>>РегистрСведений.*.СрезПоследних(&П3, )"
Что за параметр П3 (пэ три)?! И именно в этот момент стоить обратить внимание вкладку "компоновка данных" в конструкторе запроса. И на ней мы обнаружим, что у параметров виртуальной таблицы нет установленных нами значений! Задаём имя параметру "период" - "&ПериодКД". Теперь на вкладке "Параметры" в СКД появится параметр ПериодКД (с типом "дата") и повесив на него Период.ДатаОкончания убедимся что все работает.
В тексте запроса это выглядит так: ... РегистрСведений.*.СрезПоследних(&Период1 {(&ПериодКД)}, ) КАК ...
sasha777666; user1730557; werd00; pavel_vrn; karg; denis83; MaximKulkov; taasha25; Климов; Rusel; saszj; fatman78; user1667741; Raskad; user988448; sdaf; goliath-itd; nelya1c; a22011973; Corbis; yaroslav.artem; begemot; Innuil; ipzotov; leralugovaya; Anatolia; Enot; user688921_moldpavel; MarMargo; EpiSH; DIOmisus; thornhiven; Veric; Iva_Irina_Iva; shevchen88; zaycevav1977; ejijoka; user_pdd; mnitsi; &rew; user1402183; Tutr; Julia7150; kulak1974; criptid; serverstar; link_l; maksimus753; user712426; sizeoff; _Dmitry_; Invodev; TManukovskaya; NittenRenegade; Maruska77; vikochkagridina; merabn; Den_D; user785234; Andrekaa; vtolstenev; salikoff; akalugin; user1040665; jimli; BurlakovIvan; Mahon83; blackjack666; Draconus; user659124_s.kostina; aupovy; Salavat; Pigzilla; user1058210; newborn; fixin; nixen88; MaxxiMiliSan; Xel'naga; WasiliyMay; Slypower; ivanek; Jackch; Mehozavr; Andy_NTG; alenka1c; Meson; V_Izzy; dvadva; simy4; Somaha; Sergey_Borisovi4; delsoft; SmArtist; smokevg; AleksKol; Vida; user1044069; lsnr; spenser123; user811769; YellowAndBlue; compaud; JinAir7460; k992007; ilya4; Inzoo; Georot; mlv84; cobern; SometimesItDoesWork; terran_1C; user1003854; tarassov; корум; Gadzhalik; VasilyErmak; MulderCelica; _Farsh_; Ctrl P; levante90; mkosirev; BladeWorld; AnyaIT; Amfick; Bovori; DarkUser; vist666; Dicc; scanner1980; oleg55555; GOshaSaveiko; pihy; АнатолийАндреевич; alalsl; bluntschi; Misanets; suepifanov; Elena_Q; Georgik; bobah_; Lunulariss; +142 Ответить
18. scanner1980 268 14.03.17 19:09 Сейчас в теме
(17)
компоновка данных" в конструкторе запроса.
да блин, охрененное, неее..ческое спасибо, это так неочевидно, на закладке "компоновка данных" вообще и не думал что можно устанавливать параметры.
mnitsi; user712426; _Dmitry_; Mahon83; Slypower; +5 Ответить
19. Bovori 2 03.07.17 11:19 Сейчас в теме
(18) Вот тоже присоединяюсь к Нее......скому спасибо в (17), пипец, долго мучился))
23. MulderCelica 02.03.18 04:28 Сейчас в теме
(17)
РегистрСведений.*.СрезПоследних(&Период1 {(&ПериодКД)}, )

Тоже долго мучился с этим, спасибо!
На самом деле можно просто РегистрСведений.*.СрезПоследних( {(&ПериодКД)}, ) то есть просто использовать параметр виртуальной таблицы компоновки данных. В "привычном" месте указывать параметры виртуальной таблицы вообще не нужно.
denis83; taasha25; xico; pas; Дмитрий74Чел; Anthon; Voyr; user712426; korzhishe; +9 Ответить
26. Timur.V 79 28.06.18 13:37 Сейчас в теме
(17) Спасибо, помог ваш комментарий.
user712426; +1 Ответить
29. k992007 28 19.12.18 21:05 Сейчас в теме
(17) огромная благодарность
39. fixin 4263 31.03.20 16:20 Сейчас в теме
(17) Спасибо, реально помогло. Перемудрили они там в своем 1Се.

Мой кейс выглядит так, вот так заработало:
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ТЦ.Номенклатура КАК Номенклатура,
	ТЦ.Характеристика КАК Характеристика,
	ТЦ.Цена КАК Цена
ПОМЕСТИТЬ ТЦеныРозничные
ИЗ
	РегистрСведений.ЦеныНоменклатуры.СрезПоследних(&ПериодСреза {(&ПериодСреза)}, ВидЦены = &ВидЦеныРозничная) КАК ТЦ
{ГДЕ
	ТЦ.Номенклатура.* КАК Номенклатура,
	ТЦ.Характеристика.* КАК Характеристика}
Показать
42. newborn 16.04.20 22:52 Сейчас в теме
(17) Ой, ребятушки, спасибо. Через четыре года пригодилось, а то бы башку совсем сломал. И так-то на самоизоляции она не шибко работает... ))))
44. sml 41 17.03.21 13:01 Сейчас в теме
(17) а не проще для стандартного периода выбрать нетиповое наименование, например, "ПериодОтч", а представление задать "Период", тогда для параметра НачалоПериода (КонецПериода) выражения поменяются с &Период.ДатаНачала (&Период.ДатаОкончания) на &ПериодОтч.ДатаНачала (&ПериодОтч.ДатаОкончания) и остальные танцы с бубном не нужны
user823999; +1 Ответить
45. Julia7150 05.05.21 17:59 Сейчас в теме
(17) Спасибо большое! Очень помогло! Сработало просто ...Остатки(&НачалоПериода{&НачалоПериода}) с параметрами, которые создаются по умолчанию.
51. user823999 21 29.04.22 14:41 Сейчас в теме
(45) Мне тоже так помогло! Спасибо!
49. user1026611 19.03.22 05:52 Сейчас в теме
(17)
&ПериодКД
Спасибо большое!!! Мне тоже помогло. А, то мучились с моим другом несколько часов.
52. Innuil 01.07.22 14:52 Сейчас в теме
(17)
{(&ПериодКД)}

Присоединяюсь ко всем Благодарностям.
53. yaroslav.artem 28.07.22 11:47 Сейчас в теме
(17) Где вы раньше были.. столько времени пропарился
54. VinokurovDY 09.02.23 13:32 Сейчас в теме
Называйте параметр не Период, а
ПериодОтчета - тип СтандартныйПериод
другие параметры:
НачалоПериода = &ПериодОтчета.ДатаНачала
КонецПериода = &ПериодОтчета.ДатаОкончания

выборку делайте СрезПоследних(&КонецПериода, )
это такая 8.3 фича
56. pavel_vrn 23 27.11.23 18:07 Сейчас в теме
(17)
&Период1

Спасибо большое. Помогает и в 2023.
20. Poyto_n_z@mail.ru 24.08.17 11:18 Сейчас в теме
Спасибо Огромное!!!... ну, как можно это раскопать???? если бы не этот форум никогда бы не решила эту задачку...
21. meclonec 18 08.10.17 21:48 Сейчас в теме
У меня на "компоновка данных" нет установки параметров, где вы их там нашли, не смог исправить такую же точно ситуацию на с регистром "УстановкаЦенНоменклатуры
22. IvanKh 1 19.10.17 04:11 Сейчас в теме
(21) Это параметры виртуальной таблицы регистра. Нужно выбрать таблицу на вкладке "Компоновка данных" и тогда кнопа станет активной.
Прикрепленные файлы:
scaramouche; air_mike; user712426; Den_D; GeterX; tarassov; +6 Ответить
24. dadel 19 15.05.18 15:38 Сейчас в теме
Аналогично тема помогла сегодня. Тоже добавил к уже несвежему отчету регистр сведений, периодический. Потребовалось прикрутить статус из среза последних к объекту. И сразу получил ошибку типа "Ошибка обработки представления "РегистрСведений......"
Но быстро в первых же постах этой темы наткнулся на мысль, у меня период отчета назывался "Период", сразу вспомнил, что при добавлении периодического регистра в параметрах появляется новый стандартный параметр Период.
Пришлось сначала удалить регистр сведений из запроса, изменить наименование моего Период на ПериодОтчета и затем назад Регистр сведений вернул.
Все взлетело.
user712426; LavinVladik; terran_1C; tarassov; +4 Ответить
25. alexlx 113 31.05.18 09:39 Сейчас в теме
Спасибо! Очень помогло. Совсем неочевидное решение
27. nik.averkin@mail.ru 02.08.18 16:44 Сейчас в теме
Спасибо - это самое малое, что можно сказать! Это просто невозможно понять, и требует кучу времени для самостоятельного разбирательства. Автор - ты нам часть жизни сэкономил! А я-то начал крутить-вертеть, вместо запроса с объединением сделал два отдельных и т.п. СПАСИБО!!
user712426; +1 Ответить
28. crosby 280 14.11.18 17:58 Сейчас в теме
Присоединяюсь и благодарю за статью. Одновременно хочу выразить негодование в адрес 1С за подобные скрытые камни, поддержка разработчиков "на местах" оставляет желать лучшего.
user712426; +1 Ответить
30. Walet 07.02.19 17:40 Сейчас в теме
Присоединяюсь ко всем спасибам! А то если не всю, то две трети башки уже сломал!
Я в эту компановку за 12 лет в 1С и не заглядывал ни разу. Не нуждался как-то.
user712426; +1 Ответить
31. valej 15.03.19 16:59 Сейчас в теме
Спасибо! Установил параметры виртуальной таблицы на вкладке "Компоновка данных" для 2-х таблиц и сработало.
user712426; +1 Ответить
32. user608978_dtih 08.04.19 18:42 Сейчас в теме
При добавлении в запрос СКД накопительных регистров появляются автоматические параметры НачалоПериода и КонецПериода тип Дата. При добавлении периодических регистров - параметр Период тоже тип Дата. Не надо менять типы этих параметров и ошибки не будет.
user712426; stas_r; +2 Ответить
33. ryzn 40 23.07.19 07:54 Сейчас в теме
34. OrcaMax 15 01.08.19 09:49 Сейчас в теме
Нашёл эту статью по тексту ошибки. Хочу вставить свои 5 копеек. В моем случае, я использовал параметр с именем «Параметр» тип Стандартный период и все работало тип-топ. Но вот пришлось создать соединение с виртуальной таблицей регистра сведений срез последних и отчёт перестал формироваться с формулировкой ошибки, которую мы обсуждаем. Причина оказалась в том, что после того как я добавил в таблицы виртуальную таблицу, СКД автоматически добавило параметр этой таблицы в параметры данных. А так как имена этих параметров совпали («Период»), то я и не заметил этого эффекта, и не вспомнил, что для СКД это норм. Назови я свой параметр «ПериодОтчета» то никаких проблем бы не было. Пришлось развести эти параметры на вкладке Параметры и все заработало, что в общем-то, логично. Добавляя виртуальные таблицы нужно обязательно проверять ошибки совпадения имён параметров.
user712426; user1021675; +2 Ответить
40. user1163207 01.04.20 16:24 Сейчас в теме
(34) Спасибо большое! Вы сэкономили моё время.
35. T_Guest 10.09.19 15:33 Сейчас в теме
Так же столкнулся с ошибкой при формировании отчета, но ситуация немного другая: мне нужен срез по параметру который никак не связан с периодом отчета. Если точнее то мне нужен был срез на конкретную дату не зависимую от параметров отчета. Вроде кто то писал про автозаполнение, но почему то никто не поддержал, по моему это решение самое простое.
Снимаем галку "автозаполнение" (тогда СКДшный период пропадет из закладки параметров СКД). Это в общем то все что мне было нужно, что бы срез заработал.
Если нужен стандартный период, то смело добавляем его и устанавливаем к нашим параметрам начало и конец стандартного периода.
Конечно выбранные поля нужно выбрать в компановщике, что бы появились поля в СКД .
Всем удачи, а разработчикам платформы огромный привет и "спасибо что сломали", а то жизнь медом показалась =)
begemot; user712426; +2 Ответить
36. Nowa 45 08.11.19 16:19 Сейчас в теме
37. VAVANSTR 19.12.19 10:53 Сейчас в теме
1C-ники извращенцы
Enziger; user712426; +2 Ответить
38. insurgut 207 28.02.20 13:02 Сейчас в теме
Самое простое - никогда не использовать параметр "Период". Лучше ограничивать его видимость, создавать свой параметр "ПериодОтчета" и использовать его.
Прикрепленные файлы:
COMPER; taasha25; pdsit; user1145086; sml; natal_tihom; +6 Ответить
57. user1183932 12.06.24 12:10 Сейчас в теме
(38)
Подскажите пожалуйста, почему нельзя удалить стандартный Период?
58. insurgut 207 12.06.24 13:48 Сейчас в теме
(57) он создается системой компоновки данных автоматически, что-то вроде служебного реквизита.
41. yasar92 6 07.04.20 23:09 Сейчас в теме
Просто убери параметр виртуальной таблицы и ты увидишь что в параметрах СКД нечего не поменялось и поймешь что дела в Периоде..))
43. igor_belyaev 07.10.20 18:42 Сейчас в теме
Похожая история, убрал срезпоследних (в моем случае он пофиг) и заработало! Допер когда здесь прочел
47. Altone1976 26.08.21 11:39 Сейчас в теме
у меня регистр в расширении
помогло убрать галочку "Автозаполнение" в СКД
55. taasha25 13 05.07.23 21:03 Сейчас в теме
(47)Прошу прощения, можно скрин., где эта галочка?
48. Sobol007 20 09.11.21 04:12 Сейчас в теме
50. vipetrov2 05.04.22 11:33 Сейчас в теме
В моем случаи помогло вместо:
СрезПоследних(&Дата, )

Написать:
СрезПоследних({&Дата}, )

т.е. , просто добавить фигурные скобки {}.
Оставьте свое сообщение

Для получения уведомлений об ответах подключите телеграм бот:
Инфостарт бот