СКД: как определить в процедуре в модуле объекта "ПриКомпоновкеРезультата", какой вариант отчета компануется?

Форум Программирование Общие вопросы программирования (Dev)

Платформа 1С v8.3 Система компоновки данных

1. kvovka 32 05.03.14 17:02 Сейчас в теме

Собвственно сабж

Ответы

Свернуть все

2. starjevschik 05.03.14 17:32 Сейчас в теме

(1) kvovka, мне так сдается, что никак. Из варианта берутся настройки и загружаются в компоновщик, он знает только свои настройки, а откуда они взялись, ему все равно.
ЗЫ компонуется, он же компоновщик.

3. Kom-off 05.03.14 18:39 Сейчас в теме

(1) Сталкивался. Сначала было кинулся специальный реквизит отчета для этого дела создавать, типа, при загрузке варианта отчета, который должен заполнятся, ну и далее... Но потом подумав, решил, что проще создать параметр, который будет иметь собственное значение для каждого варианта (значение по умолчанию), сам параметр, при этом, в пользовательский интерфейс не выводить. Таким образом, при компоновке варианта отчета, анализируя значение этого параметра можно сделать вывод о том, какой вариант отчета загружен и используется. Этот способ имеет один недостаток: если используется настройка отображения параметров в сформированном отчете, то этот параметр будет выводиться вместе со всеми и, безусловно, путать пользователя. С этим делом пришлось бороться при помощи костылей - дорабатывать готовый сформированный табличный документ (в том же обработчике "При компоновке результата") "ручками" удалением из табличного документа строки, в которой этот параметр отображается.

17. fixin 4273 10.12.23 10:31 Сейчас в теме

(1) Можно, в КомпоновщикНастроек.Настройки.ДополнительныеСвойства можно посмотреть

	ДопПараметр = НайтиПользовательскийПараметр(КомпоновщикНастроек, Новый ПараметрКомпоновкиДанных("ВыводитьОстатки"));
	//Исключение
	//	Контекст.Вставить("ВыводитьОстатки", Ложь);
	//КонецПопытки;
	ДС = КомпоновщикНастроек.Настройки.ДополнительныеСвойства;
	Если ДС.Свойство("ВариантНаименование")
		И Найти(ВРЕГ(ДС.ВариантНаименование), "ОБОРОТЫ") <> 0 Тогда
		ДопПараметр.Значение = ложь;
	КонецЕсли;
	//Сообщить(ДС.ВариантНаименование);
	Контекст.Вставить("ВыводитьОстатки", ДопПараметр.Значение);

Функция НайтиПользовательскийПараметр(КомпоновщикНастроек, ПараметрКомпоновкиДанных)
	Для Каждого ТекЭлемент ИЗ КомпоновщикНастроек.ПользовательскиеНастройки.Элементы Цикл
		Если Тип(ТекЭлемент) = Тип("ЗначениеПараметраНастроекКомпоновкиДанных") И  ТекЭлемент.Параметр = ПараметрКомпоновкиДанных Тогда
			Возврат ТекЭлемент;
		КонецЕсли;
	КонецЦикла;
КонецФункции

Показать

Проверял на: УТ 11.4.13.46

Прикрепленные файлы:

4. kvovka 32 05.03.14 19:05 Сейчас в теме

Понятно. У меня пока такой способ - буду определять по имени первой группировки.

5. KrivosheevEV 06.03.14 10:48 Сейчас в теме

Коллеги, блин, будьте настойчивее при поиске хороших встроенных функций. Их много и они удобны.

Кусок кода:

ДокументОбъект = РеквизитФормыВЗначение("Отчет");
//...
Если НЕ ЗначениеЗаполнено(ЭтаФорма.НаименованиеТекущегоВарианта) И ДокументОбъект.СхемаКомпоновкиДанных.ВариантыНастроек.Количество()>0 Тогда
  Вариант = ДокументОбъект.СхемаКомпоновкиДанных.ВариантыНастроек[0];
  ЭтаФорма.УстановитьТекущийВариант(Вариант.Имя); 
КонецЕсли;

6. kvovka 32 06.03.14 11:05 Сейчас в теме

(5) KrivosheevEV, СКД: как определить в процедуре в модуле объекта "ПриКомпоновкеРезультата" (объект - отчет)

7. imispb 5 20.05.15 20:33 Сейчас в теме

Если форма отчета не создана, тогда можно так:

КлючВарианта = НеОпределено;
КомпоновщикНастроек.ПользовательскиеНастройки.ДополнительныеСвойства.Свойство("КлючВарианта", КлючВарианта);

Кто может подсказать, как можно узнать вариант, если отчет формируется из созданной формы отчета?

Ответить

22. eda76 12.08.24 11:51 Сейчас в теме

(7) по "КлючВарианта" можно найти в справочнике "ВариантыОтчетов" сам вариант

ВЫБРАТЬ
	ВариантыОтчетов.Ссылка КАК Ссылка,
	ВариантыОтчетов.КлючВарианта КАК КлючВарианта
ИЗ
	Справочник.ВариантыОтчетов КАК ВариантыОтчетов
ГДЕ
	ВариантыОтчетов.КлючВарианта = &КлючВарианта

8. imispb 5 21.05.15 14:48 Сейчас в теме

В модуле формы, в процедуре ПриОбновленииСоставаПользовательскихНастроекНаСервере, пишем следующий код

Отчет.КомпоновщикНастроек.ПользовательскиеНастройки.ДополнительныеСвойства.Вставить("КлючВарианта",ЭтаФорма.КлючТекущегоВарианта);

После этого в Модуле Объекта в процедуре ПриКомпоновкеРезультата станет доступный реквизит КлючВарианта, как и при не созданной форме.

Ответить

9. kvovka 32 21.05.15 18:36 Сейчас в теме

(8) imispb, без формы, но уже не актуально

10. Поручик 4692 21.05.15 22:43 Сейчас в теме

В конфигурациях на БСП передача дополнительных свойств для СКД реализована.

11. IvanKh 1 29.11.17 10:37 Сейчас в теме

Добавляем параметр. Устанавливаем значение (например название варианта, просто строкой, для каждого варианта настроек свое), но не устанавливаем галочку использование.

В процедуре ПриКомпоновкеРезультата :

Настройки = КомпоновщикНастроек.ПолучитьНастройки();
НазваниеВарианта = Настройки.ПараметрыДанных.Элементы.Найти("ИмяПараметра").Значение; // получаем строковое значение

т.к. Настройки.ПараметрыДанных.Элементы.Найти("ИмяПараметра").Использование = ложь - в табличный документ параметр отчета выводиться не будет.

Ответить

13. Auser777 23.06.19 16:26 Сейчас в теме

(11)
По-моему, самый ясный и оптимальный способ, так как не зависит от того, есть ли форма у отчета и т.п.

12. Mart 106 21.12.18 16:17 Сейчас в теме

+ еще 1 вариант:
На форму вывести элемент Отчет.КомпоновщикНастроек.ПользовательскиеНастройки (таблицу без колонок), если его там нет, обычно он там присутствует. Также на форме обычно присутствует стандартная кнопка выбора варианта отчета. После ее нажатия и выбора варианта, срабатывает событие ПриАктивизацииСтроки() у элемента таблицы ПользовательскиеНастройки, срабатывает оно также и при открытии формы, нужно в это событие написать такой код:

Отчет.КлючТекущегоВарианта = КлючТекущегоВарианта;

Обязательно в реквизиты отчета добавить реквизит КлючТекущегоВарианта, тип строка без ограничения длины.
Затем при нажатии кнопки Сформировать, срабатывает событие ПриКомпоновкеРезультата() в модуле объекта,
и вот здесь уже можно прочитать выбранный пользователем вариант:

Если КлючТекущегоВарианта = "Мой вариант" Тогда
// выбран нужный вариант

14. info1i 236 06.04.20 10:49 Сейчас в теме

(12)

Отчет.КлючТекущегоВарианта = КлючТекущегоВарианта;

А как получить переменную КлючТекущегоВарианта?

15. info1i 236 06.04.20 11:26 Сейчас в теме

(14) Оказывается, это встроенная платформенная переменная.

16. user726666 16.10.20 01:12 Сейчас в теме

(8)
(12) а как быть, если форма обычная ?

18. dusha0020 1116 13.02.24 13:04 Сейчас в теме

В итоге ничего из ветки не подошло. Получил наименование исполняемого варианта в модуле отчета СКД так:

СхемаКомпоновки = СхемаКомпоновкиДанных;
НастройкиКомпоновки = ЭтотОбъект.КомпоновщикНастроек.ПолучитьНастройки();

Функция ФормируемыйВариантОтчета(СхемаКомпоновки, НастройкиКомпоновки)

	Рез = "";
	ИдТекущегоВарианта = НастройкиКомпоновки.Структура.ИдентификаторПользовательскойНастройки;
	
	Для Каждого ВариантНастроек Из СхемаКомпоновки.ВариантыНастроек Цикл
		Если ВариантНастроек.Настройки.Структура.ИдентификаторПользовательскойНастройки = ИдТекущегоВарианта Тогда
			Рез = ВариантНастроек.Имя;
			Прервать;
		КонецЕсли;
	КонецЦикла;
	
	Возврат Рез;
	
КонецФункции

Показать

19. German_Tagil 43 19.06.24 13:26 Сейчас в теме

(18) Вариант отчета и вариант настроек разные понятия

20. VZyryanov 19.06.24 13:58 Сейчас в теме

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)

	Вариант=ЭтотОбъект.КомпоновщикНастроек.Настройки.ДополнительныеСвойства.ВариантНаименование;
	ДокументРезультат.ФиксацияСлева=2;

КонецПроцедуры

21. eda76 12.08.24 11:24 Сейчас в теме

(20) это работает при формировании отчета в пользовательском режиме, а например если формирует через рассылку отчетов то нет

23. VZyryanov 12.08.24 16:53 Сейчас в теме

(21) Возможно надо смотреть другие настройки:

КомпоновщикНастроек.Настройки
КомпоновщикНастроек.ПользовательскиеНастройки
КомпоновщикНастроек.ФиксированныеНастройки

Оставьте свое сообщение

E-mail: