Дополнительная кнопка в верхнем меню

&НаСервере
Функция ВосстановитьПуть()
	КлючКоманды = Метаданные.ОбщиеКоманды.ОткрытьВнешнююОбработку.ПолноеИмя();
	Возврат ХранилищеОбщихНастроек.Загрузить(КлючКоманды, "ФайлОбработки");
КонецФункции

&НаСервере
Процедура СохранитьПуть(ФайлОбработки)
	КлючКоманды = Метаданные.ОбщиеКоманды.ОткрытьВнешнююОбработку.ПолноеИмя();
	ХранилищеОбщихНастроек.Сохранить(КлючКоманды, "ФайлОбработки",ФайлОбработки);
КонецПроцедуры

&НаСервере
Функция ПодключитьОбработку(АдресОбработки,БезопасныйРежим,ЕррорИнфо)
	Попытка
		ИмяОбъекта = ВнешниеОбработки.Подключить(АдресОбработки,,(БезопасныйРежим=Истина)ИЛИ(БезопасныйРежим<>Ложь));
	Исключение
		ЕррорИнфо = 
		"Ошибка подключения данных внешней обработки:
		|" + ИнформацияОбОшибке().Описание;
		ИмяОбъекта = "";
	КонецПопытки;
	Возврат ИмяОбъекта;
КонецФункции

&НаКлиенте
Процедура ОбработкаКоманды(ПараметрКоманды, ПараметрыВыполненияКоманды)
	Перем ЕррорИнфо;
	Перем ПутьОбработки;
	Перем ФайлОбработки;
	Перем БезопасныйРежим;
	БезопасныйРежим = Истина;
	
	ФайлОбработки = ВосстановитьПуть();
	
	сзМеню = Новый СписокЗначений;
	Если ЗначениеЗаполнено(ФайлОбработки) Тогда
		Файло = Новый Файл(ФайлОбработки);
		Если Файло.Существует() Тогда
			сзМеню.Добавить(ФайлОбработки, ФайлОбработки);
		Иначе
			сзМеню.Добавить(ФайлОбработки, ФайлОбработки, , БиблиотекаКартинок.УдалитьЭлементСписка);
		КонецЕсли; 
	КонецЕсли; 
	сзМеню.Добавить("", "Выбрать файл обработки", , БиблиотекаКартинок.Выбрать);
	
	Выбор = сзМеню.ВыбратьЭлемент("Открытие внешней обработки");
	Если Выбор = Неопределено Тогда
		Возврат;
	КонецЕсли;
	
	Если ПустаяСтрока(Выбор.Значение) Тогда
		ДиалогФайла = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Открытие);
		ДиалогФайла.ПолноеИмяФайла = ФайлОбработки;
		ДиалогФайла.Каталог = ПутьОбработки;
		ДиалогФайла.Заголовок = "Выбор файла внешней обработки";
		ДиалогФайла.Фильтр = "Внешняя обработка 1С (*.epf)|*.epf";
		ДиалогФайла.Расширение = "epf";
		ДиалогФайла.ПроверятьСуществованиеФайла=Истина;
		Если ДиалогФайла.Выбрать() Тогда
			ФайлОбработки = ДиалогФайла.ПолноеИмяФайла;
			СохранитьПуть(ФайлОбработки);
		Иначе
			Возврат;
		КонецЕсли;
	Иначе
		ФайлОбработки = Выбор.Значение;
		БезопасныйРежим = Выбор.Пометка;
	КонецЕсли;
	
	Файло = Новый Файл(ФайлОбработки);
	Если Файло.Существует() = Ложь Тогда
		Предупреждение(
		"Выбранный файл обработки не существует
		|'" + ФайлОбработки + "'
		| !!!");
		Возврат;
	КонецЕсли;
	
	АдресОбработки = "";
	Если ПоместитьФайл(АдресОбработки, ФайлОбработки, ФайлОбработки, Ложь) = Ложь Тогда
		Предупреждение(
		"Файл внешней обработки не удалось
		|поместить во временное хранилище
		| !!!");
		Возврат;
	КонецЕсли; 
	
	ИмяОбработки = ПодключитьОбработку(АдресОбработки,БезопасныйРежим,ЕррорИнфо);
	Если ЗначениеЗаполнено(ЕррорИнфо) ИЛИ ПустаяСтрока(ИмяОбработки) Тогда
		Предупреждение(
		"Ошибка подключения внешней обработки:
		|'" + ФайлОбработки + "'
		| !!!");
		Возврат;
	КонецЕсли;
	
	Попытка
		ОткрытьФорму("ВнешняяОбработка." + ИмяОбработки + ".Форма");
	Исключение
		ВызватьИсключение(
		"Ошибка открытия формы внешней обработки:
		|'" + ОписаниеОшибки() + "'
		| !!!");
	КонецПопытки;
	
КонецПроцедуры