Форум Администрирование Общие вопросы администрирования (Admin)

Запуск консоли администрирования серверов 1C определенной платформы

1. shirei 27.09.23 17:23 Сейчас в теме

Такая проблема. Имеется несколько версий сервера 1С на одном сервере, на них разные порты. При запуске 1СV8 servers я попадаю на сервер определенной версии (8.3.22 допустим). Подскажите как я могу запустить консоль администрирования серверов 1C но с другой версией платформы?

По теме из базы знаний

Найденные решения

6. user620512 28.09.23 08:45 Сейчас в теме

regsvr32 "C:\Program Files\1cv8\8.3.??.????\bin\radmin.dll" /s
start mmc "C:\Program Files\1cv8\common\1CV8 Servers (x86-64).msc"

Ярлык на CMD файл лежит на столе, в свойствах ярлыка в дополнительно ставить галку запускать под администратором
Делаешь по одному файлу на каждую версию платформы

Остальные ответы

В избранное Подписаться на ответы

Свернуть все

3. vlad636 4 28.09.23 04:19 Сейчас в теме

(1) Напишите bat-файлы, в которых будет: регистрация утилиты администрирования серверов 1С Предприятия нужной платформы и запуск самого Администрирования серверов 1С Предприятия. Запускайте их от имени администратора.

4. shirei 28.09.23 08:29 Сейчас в теме

(3) Нашел на просторах интернета такие батники:

1) start /wait regsvr32 /s "C:\Program Files\1cv8\8.3.13.1513\bin\radmin.dll"
start "C:\Windows\System32\mmc.exe" "C:\Program Files\1cv8\common\1CV8 Servers (x86-64).msc"

2)regedit /s "C:\Program Files\1cv8\common\8.3.13.1513.reg"
mmc /s "C:\Program Files\1cv8\common\1CV8 Servers (x86-64).msc"

Какой из них может быть верным? Или они идентичны

5. vlad636 4 28.09.23 08:40 Сейчас в теме

(4) Вообще, если смотреть на свойства ярлыка из меню Пуск "Регистрация утилиты администрирования серверов 1С Предприятие", то там запускается "C:\Program Files\1cv8\Версия платформы\bin\RegMSC.cmd", в котором прописаны следующие команды:

@set CS=CScript //nologo %TMP%\%~n0.vbs /REALTIME^>nul^ & del /Q %TMP%\%~n0.vbs&CLS
@ECHO off
title %~n0
SET CX=CLS^&EXIT
SET BS=^>%TMP%\%~n0.vbs
SET G=GOTO 
SET H=shell&fsutil>NUL
IF %ERRORLEVEL% EQU 0 (
    GOTO 2
) ELSE (
    if not "%minimized%"=="" GOTO 1
)
SET minimized=true & start /min cmd /C "%~dpnx0"&%CX%
:1
ECHO SET %H%=CreateObject("%H%.Application"):%H%.%H%Execute "%~dpnx0",,"%CD%", "runas", 1 : SET %H%=nothing%BS%&%CS%&%CX%
:2
ECHO %~dpnx0 & regsvr32.exe /i:user "%~dp0radmin.dll"&%CX%

Показать

8. SAShikutkin 5 28.09.23 09:07 Сейчас в теме

(1)Нужно просто в командной строке выбрать нужную платформу. Батник:

@echo off
setlocal EnableDelayedExpansion

set Path83_x86=C:\Program Files (x86)\1cv8\
set Path83_x64=C:\Program Files\1cv8\

set PathMmc83_x86=%Path83_x86%common\1CV8 Servers.msc
set PathMmc83_x64=%Path83_x64%common\1CV8 Servers (x86-64).msc

set /a num=0
cd /d %Path83_x86%

rem Поиск консолей версий 8.3, 8.4 x86
for /d %%d in ("8.*") do (
    if exist %%d\bin\radmin.dll (
        echo !num!. x86 %%d
        set arrayRadmin[!num!]="!Path83_x86!%%d\bin\radmin.dll"
        set arrayMmc[!num!]="%PathMmc83_x86%"
        set /a num+=1
    )
)

cd /d %Path83_x64%
rem Поиск консолей версий 8.3, 8.4 x64
for /d %%d in ("8.*") do (
    if exist %%d\bin\radmin.dll (
        echo !num!. x64 %%d
        set arrayRadmin[!num!]="!Path83_x64!%%d\bin\radmin.dll"
        set arrayMmc[!num!]="%PathMmc83_x64%"
        set /a num+=1
    )
)

echo.
set /P num_curr="Select platform version (enter line number): "
set /a num-=1

rem Удалить прежнюю регистрацию
FOR /L %%i IN (0,1,%num%) DO ( 
    start /wait regsvr32 /u /s !arrayRadmin[%%i]!
)

rem Зарегистрировать новую версию
start /wait regsvr32 !arrayRadmin[%num_curr%]! /s

rem Запуск
start mmc !arrayMmc[%num_curr%]!

Показать

2. djrust 27.09.23 22:25 Сейчас в теме

Регистрацией утилиты администрирования нужной версии.

6. user620512 28.09.23 08:45 Сейчас в теме

7. djrust 28.09.23 09:04 Сейчас в теме

Зачем что то писать? Если это уже есть в меню пуск под каждую версию платформы?
Достаточно просто навести ,посмотреть платформу и ткнуть для регистрации

Оставьте свое сообщение

E-mail:

Вакансии

Программист 1С
Кемерово
зарплата от 200 000 руб.
Полный день

Программист 1С
Киров (Кировская обл.)
зарплата от 100 000 руб.
Полный день

Программист 1С
Санкт-Петербург
зарплата от 150 000 руб.
Полный день

Архитектор 1С
Москва
зарплата от 250 000 руб.
Полный день

1С-Программист (интегратор Битрикс24)
Санкт-Петербург
зарплата от 150 000 руб. до 250 000 руб.
Полный день