Распределение расходов на партии производства

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	Если Параметры.Свойство("ПриобретениеУслугПрочихАктивов") Тогда
		ПУиПА = Параметры.ПриобретениеУслугПрочихАктивов;
		Элементы.ПУиПА.ТолькоПросмотр = Истина;
		//Элементы.ПУиПА.Видимость = Ложь;	
	КонецЕсли; 
	
КонецПроцедуры

&НаКлиенте
Процедура Расчитать(Команда)
	
	Если НЕ ЗначениеЗаполнено(Подразделение) Тогда
		
		Сообщение = Новый СообщениеПользователю;
		Сообщение.Текст = "Не указано подразделение!";
		Сообщение.Сообщить();  
		Возврат;
	
	КонецЕсли; 
	
	Если НЕ ЗначениеЗаполнено(ДатаНачала) Тогда
		
		Сообщение = Новый СообщениеПользователю;
		Сообщение.Текст = "Не указано Дата начала!";
		Сообщение.Сообщить();                      		
		Возврат;

	КонецЕсли;
	
	Если НЕ ЗначениеЗаполнено(ДатаОкончания) Тогда
		
		Сообщение = Новый СообщениеПользователю;
		Сообщение.Текст = "Не указано Дата окончания!";
		Сообщение.Сообщить();                      		
		Возврат;

	КонецЕсли;
	
	РасчитатьНаСервере();
	
КонецПроцедуры

&НаСервере
Процедура РасчитатьНаСервере()
	
	ТЗ_Расчета.Очистить();
	
	Запрос = Новый Запрос;
	Запрос.Текст = 
		"ВЫБРАТЬ
		|	ВыпускПродукцииОбороты.Регистратор КАК Регистратор,
		|	ВыпускПродукцииОбороты.Подразделение КАК Подразделение,
		|	ВыпускПродукцииОбороты.АналитикаУчетаНоменклатуры.Номенклатура КАК Номенклатура,
		|	СУММА(ВыпускПродукцииОбороты.КоличествоОборот) КАК Количество
		|ПОМЕСТИТЬ ВТ_ВыпускПродукции
		|ИЗ
		|	РегистрНакопления.ВыпускПродукции.Обороты(
		|			&ДатаНачала,
		|			&ДатаОкончания,
		|			Регистратор,
		|			Подразделение = &Подразделение
		|				И НЕ АналитикаУчетаНоменклатуры.Номенклатура В (&ИсключитьНоменклатуру)) КАК ВыпускПродукцииОбороты
		|
		|СГРУППИРОВАТЬ ПО
		|	ВыпускПродукцииОбороты.Регистратор,
		|	ВыпускПродукцииОбороты.Подразделение,
		|	ВыпускПродукцииОбороты.АналитикаУчетаНоменклатуры.Номенклатура
		|;
		|
		|////////////////////////////////////////////////////////////­////////////////////
		|ВЫБРАТЬ
		|	ВТ_ВыпускПродукции.Регистратор КАК Этап,
		|	ВТ_ВыпускПродукции.Подразделение КАК Подразделение,
		|	ВТ_ВыпускПродукции.Номенклатура КАК Номенклатура,
		|	ВТ_ВыпускПродукции.Количество КАК Количество,
		|	ЕСТЬNULL(рс_ПоказателиДляРасчетаСебестоимостиСрезПоследних.Показатель, 0) КАК Показатель,
		|	ВТ_ВыпускПродукции.Количество * ЕСТЬNULL(рс_ПоказателиДляРасчетаСебестоимостиСрезПоследних.Показатель, 0) КАК Сумма
		|ИЗ
		|	ВТ_ВыпускПродукции КАК ВТ_ВыпускПродукции
		|		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.рс_ПоказателиДляРасчетаСебестоимости.СрезПоследних(&ДатаОкончания, ) КАК рс_ПоказателиДляРасчетаСебестоимостиСрезПоследних
		|		ПО ВТ_ВыпускПродукции.Номенклатура = рс_ПоказателиДляРасчетаСебестоимостиСрезПоследних.Номенклатура";
	
	Запрос.УстановитьПараметр("ДатаНачала", 	ДатаНачала);
	Запрос.УстановитьПараметр("ДатаОкончания", 	ДатаОкончания);
	Запрос.УстановитьПараметр("ИсключитьНоменклатуру", ИсключитьНоменклатуру.ВыгрузитьЗначения());
	Запрос.УстановитьПараметр("Подразделение", 	Подразделение);
	
	РезультатЗапроса = Запрос.Выполнить();
	
	ВыборкаДЗ = РезультатЗапроса.Выбрать();
	
	НомерСтроки = 1;
	
	Пока ВыборкаДЗ.Следующий() Цикл
		НоваяСтрока 			= ТЗ_Расчета.Добавить();
		НоваяСтрока.НомерСтроки = НомерСтроки;
		ЗаполнитьЗначенияСвойств(НоваяСтрока, ВыборкаДЗ);
		НомерСтроки 			= НомерСтроки + 1;
	КонецЦикла;
	
КонецПроцедуры

&НаКлиенте
Процедура ПеренестиВПУиПА(Команда)
	
	Если НЕ ЗначениеЗаполнено(ПУиПА) Тогда
		Закрыть();
	КонецЕсли; 
	
	Если Элементы.ПУиПА.ТолькоПросмотр Тогда
		Закрыть(ПоместитьРезультатВоВременноеХранилище());
	Иначе
		ПеренестиВПУиПАНаСервере();
	КонецЕсли; 
	
КонецПроцедуры

&НаСервере
Процедура ПеренестиВПУиПАНаСервере()
	
	СтатьяМотивация = ПланыВидовХарактеристик.СтатьиРасходов.НайтиПоНаименованию("Мотивация");
	СуммаРасходов = ТЗ_Расчета.Итог("Сумма");
	
	ОбъектДокумент = ПУиПА.ПолучитьОбъект();
	
	НоваяСтрока 				= ОбъектДокумент.Расходы.Добавить();     	
	НоваяСтрока.Содержание 		= СтатьяМотивация; 
	НоваяСтрока.Количество 		= 1; 
	НоваяСтрока.Цена 			= СуммаРасходов; 
	НоваяСтрока.Сумма 			= СуммаРасходов; 
	НоваяСтрока.СтавкаНДС 		= Перечисления.СтавкиНДС.БезНДС;
	НоваяСтрока.СуммаНДС  		= 0;
	НоваяСтрока.СуммаСНДС  		= СуммаРасходов;
	НоваяСтрока.СуммаСНДС  		= СуммаРасходов;
	НоваяСтрока.Подразделение  	= Подразделение;
	НоваяСтрока.СтатьяРасходов	= СтатьяМотивация; 
	
	Попытка
	
		ОбъектДокумент.Записать(РежимЗаписиДокумента.Проведение);
	
	Исключение
		
		Сообщение = Новый СообщениеПользователю;
		Сообщение.Текст = ПодробноеПредставлениеОшибки(ИнформацияОбОшибке());
		Сообщение.Сообщить(); 
	
	КонецПопытки;    
	
КонецПроцедуры

&НаСервере
Функция ПоместитьРезультатВоВременноеХранилище()
	
	ТЗ_ТМП = ТЗ_Расчета.Выгрузить();
	ТЗ_ТМП.Свернуть("Подразделение", "Сумма");
	
	ПараметрыЗакрытия = Новый Структура("АдресВоВременномХранилище", ПоместитьВоВременноеХранилище(ТЗ_ТМП));

	Возврат ПараметрыЗакрытия; 

КонецФункции

&НаКлиенте
Процедура СоздатьРаспределение(Команда)
	
	Если НЕ ЗначениеЗаполнено(ПУиПА) Тогда
		Возврат;
	КонецЕсли; 
	
	СоздатьРаспределениеНаСервере();
	
КонецПроцедуры

&НаСервере
Процедура СоздатьРаспределениеНаСервере()
	
	Значения_ПУиПА 	= ОбщегоНазначения.ЗначенияРеквизитовОбъекта(ПУиПА, "Организация, Подразделение");
	СтатьяМотивация = ПланыВидовХарактеристик.СтатьиРасходов.НайтиПоНаименованию("Мотивация");
	СтатьяМатериал 	= Справочники.СтатьиКалькуляции.НайтиПоНаименованию("Материал для производства");
	
	НовыйДокумент 									= Документы.РаспределениеПрочихЗатрат.СоздатьДокумент();
	НовыйДокумент.Дата								= ТекущаяДата();	
	НовыйДокумент.Организация 						= Значения_ПУиПА.Организация;	
	НовыйДокумент.Подразделение						= Подразделение;
	НовыйДокумент.СтатьяРасходов 					= СтатьяМотивация;
	НовыйДокумент.Ответственный						= Пользователи.ТекущийПользователь();
	НовыйДокумент.РаспределятьПоПартиям 			= Истина;	
	НовыйДокумент.РаспределятьПоПодразделениям		= Ложь;
	НовыйДокумент.РаспределятьНаСтатьи				= Ложь;
	НовыйДокумент.ОставитьВНЗП						= Ложь;
	НовыйДокумент.ПартииУказаныВручную				= Истина;
	НовыйДокумент.ПодразделенияУказаныВручную		= Ложь;
	НовыйДокумент.НаВыпускТекущегоМесяца			= Ложь;
	НовыйДокумент.РегламентированныйУчет			= Ложь;
	НовыйДокумент.УправленческийУчет				= Истина;
	НовыйДокумент.НазначениеНастройкиРаспределения	= Перечисления.НазначениеПравилРаспределенияРасходов.РаспределениеСтатейРасходовПоЭтапамПроизводства;
	
	СуммаДолей = 0;
	
	ПоляПартии = Новый Структура("Документ, Организация, Номенклатура, ГруппировкаЗатрат, ГруппаЗатрат, ВидДеятельностиНДС, ОсновноеИзделиеНоменклатура");
	ПоляПартии.Организация = Значения_ПУиПА.Организация;
	ПоляПартии.ГруппировкаЗатрат = Перечисления.ГруппировкиЗатратВЗаказеПереработчику.ПоПродукции;
	ПоляПартии.ВидДеятельностиНДС	= Перечисления.ТипыНалогообложенияНДС.ПродажаОблагаетсяНДС;
	
	Для каждого Строка Из ТЗ_Расчета Цикл
		
		НоваяСтрока = НовыйДокумент.ПартииПроизводства.Добавить();
		
		ПоляПартии.Документ 			= Строка.Этап;
		ПоляПартии.Номенклатура 		= Строка.Номенклатура; 	
		ПоляПартии.ГруппаЗатрат 		= Строка.Номенклатура; 
		ПоляПартии.ОсновноеИзделиеНоменклатура = Строка.Номенклатура; 
		
		НоваяСтрока.ПартияПроизводства  = Справочники.ПартииПроизводства.ПолучитьПартиюПроизводства(ПоляПартии, Истина, Истина);
		НоваяСтрока.Подразделение		= Строка.Подразделение;	
		НоваяСтрока.Этап				= Строка.Этап;	
		НоваяСтрока.СтатьяКалькуляции	= СтатьяМатериал;
		НоваяСтрока.ДоляСтоимости		= Строка.Сумма; 	
		
		СуммаДолей = СуммаДолей + Строка.Сумма;
		
	КонецЦикла; 
	
	НовыйДокумент.ДоляСтоимостиНаПроизводство 	= СуммаДолей;
	НовыйДокумент.ВсегоДолейСтоимости 			= СуммаДолей;
	
	Попытка 
		НовыйДокумент.Записать(РежимЗаписиДокумента.Запись);
		Сообщение = Новый СообщениеПользователю;
		Сообщение.Текст = НовыйДокумент;
		Сообщение.Сообщить();
	Исключение
		
		Сообщение = Новый СообщениеПользователю;
		Сообщение.Текст = ПодробноеПредставлениеОшибки(ИнформацияОбОшибке());
		Сообщение.Сообщить(); 
	
	КонецПопытки;    
	
КонецПроцедуры

НоваяСтрока.ПартияПроизводства  = Справочники.ПартииПроизводства.ПолучитьПартиюПроизводства(ПоляПартии, Истина, Истина);