Как отправить отчет нескольким пользователям на Email

Question

Как отправить отчет нескольким пользователям на Email.
Как это сделать программно при его (отчета) формировании?
Что то я не нашел с наскока типового функционала.
Плюс еще хотят отчет видеть в формате *.PDF

Accepted Answer

Можно через внутренние объекты 1С
[CODE]
Процедура ОтправитьАдминам(Тема, ТабДок) Экспорт
	ИмяФайла = ПолучитьИмяВременногоФайла(".PDF");
	ТабДок.Вывод = ИспользованиеВывода.Разрешить;
	ТабДок.Записать(ИмяФайла, ТипФайлаТабличногоДокумента.PDF);

	Почта = Новый ИнтернетПочта;
	УчетнаяЗапись = Справочники.УчетныеЗаписиЭлектроннойПочты.НайтиПоНаименованию("Robot");
	Профиль = Новый ИнтернетПочтовыйПрофиль;
	Профиль.АдресСервераPOP3 = УчетнаяЗапись.POP3Сервер;
	Профиль.АдресСервераSMTP = УчетнаяЗапись.SMTPСервер;
	Если УчетнаяЗапись.ВремяОжиданияСервера > 0 Тогда
		Профиль.ВремяОжидания = УчетнаяЗапись.ВремяОжиданияСервера;
	КонецЕсли; 
	Профиль.Пароль           = УчетнаяЗапись.Пароль;
	Профиль.Пользователь     = УчетнаяЗапись.Логин;
	Профиль.ПортPOP3         = УчетнаяЗапись.ПортPOP3;
	Профиль.ПортSMTP         = УчетнаяЗапись.ПортSMTP;
	
	Если УчетнаяЗапись.ТребуетсяSMTPАутентификация Тогда
		Профиль.АутентификацияSMTP = СпособSMTPАутентификации.ПоУмолчанию;       
		Профиль.ПарольSMTP       = УчетнаяЗапись.ПарольSMTP;
		Профиль.ПользовательSMTP = УчетнаяЗапись.ЛогинSMTP;
	Иначе
		Профиль.АутентификацияSMTP = СпособSMTPАутентификации.БезАутентификации; 
		Профиль.ПарольSMTP       = УчетнаяЗапись.Пароль;
		Профиль.ПользовательSMTP = УчетнаяЗапись.Логин;
	КонецЕсли; 

	Если УчетнаяЗапись.IMAP Тогда
		Профиль.ПортIMAP = УчетнаяЗапись.ПортPOP3;
		Профиль.АдресСервераIMAP = УчетнаяЗапись.POP3Сервер;
		Профиль.ИспользоватьSSLIMAP = УчетнаяЗапись.IMAPTLS;
		Профиль.ПользовательIMAP = УчетнаяЗапись.Логин;
		Профиль.ПарольIMAP = УчетнаяЗапись.Пароль;
	КонецЕсли;	
	
	Почта.Подключиться(Профиль, ПротоколИнтернетПочты[?(УчетнаяЗапись.IMAP, "IMAP", "POP3")]);
	Сообщение = Новый ИнтернетПочтовоеСообщение;
	Сообщение.Тема = Тема;
	Сообщение.ИмяОтправителя = Метаданные.Синоним+": Ошибки";
	Сообщение.Отправитель = "xxxxxx@xxxxxx.ru";
	Сообщение.Кодировка = "windows-1251";
	Сообщение.Получатели.Добавить("xxxxxxxxxxx@xxxxxxx.ru");
	Сообщение.Тексты.Добавить(Тема, ТипТекстаПочтовогоСообщения.ПростойТекст);
	Сообщение.Вложения.Добавить(ИмяФайла);
	Почта.Послать(Сообщение);
	Почта.Отключиться();
КонецПроцедуры
[/CODE]