Розница 3.0. Продажа моторных масел на розлив

&ИзменениеИКонтроль("ПараметрыФискальныхСтрокЧека")
Функция МРРасш_ПараметрыФискальныхСтрокЧека(ПредметыРасчетов, ПараметрыФискальногоЧека)

	ОплатаЭлектроннымиСертификатамиФСС = Ложь;
	Если ОбщегоНазначенияУТКлиентСервер.ЕстьРеквизитОбъекта(ПараметрыФискальногоЧека, "ЭтоОплатаЭСФСС")
		И ПараметрыФискальногоЧека.ЭтоОплатаЭСФСС = Истина
		И ПолучитьФункциональнуюОпцию("ОплатаЭлектроннымиСертификатамиФСС") Тогда

		ОплатаЭлектроннымиСертификатамиФСС = Истина;
	КонецЕсли;

	ВерсияФФД = ПараметрыФискальногоЧека.ВерсияФФД;

	ИдентификаторУстройства = ПараметрыФискальногоЧека.ИдентификаторУстройства;
	ВалютаВрем              = ЗначениеНастроекПовтИсп.ВалютаРегламентированногоУчетаОрганизации(ПараметрыФискальногоЧека.Организация);

	ПозицииЧека = Новый Массив;

	Для Каждого СтрокаДляДобавленияВЧек Из ПредметыРасчетов Цикл

		НоменклатураВидУпаковки = Неопределено;
		Если ОбщегоНазначенияУТКлиентСервер.ЕстьРеквизитОбъекта(СтрокаДляДобавленияВЧек, "РезультатРаспределения")
			И СтрокаДляДобавленияВЧек.РезультатРаспределения <> Неопределено Тогда
			НоменклатураВидУпаковки = СтрокаДляДобавленияВЧек.РезультатРаспределения.ВидУпаковки;
		КонецЕсли;

		СтрокаПозицииЧека = ОборудованиеЧекопечатающиеУстройстваКлиентСервер.ПараметрыФискальнойСтрокиЧека();
		СтрокаПозицииЧека.Вставить("РезультатРаспределенияВрем");

		СтрокаПозицииЧека.НомерСтрокиТовара = СтрокаДляДобавленияВЧек.НомерСтроки;
		СтрокаПозицииЧека.НомерСекции = 1;

		СтрокаПозицииЧека.Наименование = НоменклатураКлиентСервер.ПредставлениеНоменклатурыДляПечати(
		СтрокаДляДобавленияВЧек.НоменклатураНаименование,
		СтрокаДляДобавленияВЧек.ХарактеристикаНаименование);

		Упаковка = СтрокаДляДобавленияВЧек.Упаковка;

		Если НЕ ЗначениеЗаполнено(Упаковка) Тогда
			Если ОбщегоНазначенияУТКлиентСервер.ЕстьРеквизитОбъекта(СтрокаДляДобавленияВЧек, "БазоваяУпаковка") Тогда
				Упаковка = СтрокаДляДобавленияВЧек.БазоваяУпаковка;
			Иначе
				Упаковка = "шт.";
			КонецЕсли;
		КонецЕсли;

		Если ВерсияФФД = "1.2" Тогда
			СтрокаПозицииЧека.КодЕдиницыИзмерения = РозничныеПродажи.КодЕдиницыИзмеренияПараметраЧека(Упаковка);
		Иначе
			СтрокаПозицииЧека.ЕдиницаИзмерения = СокрЛП(Упаковка);
		КонецЕсли;

		СтрокаПозицииЧека.Количество = ?(СтрокаДляДобавленияВЧек.КоличествоУпаковок = 0, 1, СтрокаДляДобавленияВЧек.КоличествоУпаковок);
		СтрокаПозицииЧека.Цена       = СтрокаДляДобавленияВЧек.Цена;
		СтрокаПозицииЧека.СтавкаНДС  = РозничныеПродажиКлиентСервер.СтавкаНДСФискальнойОперации(СтрокаДляДобавленияВЧек.СтавкаНДС);
		СтрокаПозицииЧека.Сумма      = СтрокаДляДобавленияВЧек.СуммаСНДС;

		Если ОбщегоНазначенияУТКлиентСервер.ЕстьРеквизитОбъекта(СтрокаДляДобавленияВЧек, "СуммаНДС")
			И (ТипЗнч(СтрокаДляДобавленияВЧек.СуммаНДС) = Тип("Число") И СтрокаДляДобавленияВЧек.СуммаНДС > 0) Тогда

			СтрокаПозицииЧека.СуммаНДС = СтрокаДляДобавленияВЧек.СуммаНДС;
		КонецЕсли;

		Если СтрокаПозицииЧека.Количество <> 0
			И СтрокаПозицииЧека.СуммаСкидок <> 0 Тогда
			СтрокаПозицииЧека.ЦенаСоСкидками = Окр(СтрокаПозицииЧека.Сумма / СтрокаПозицииЧека.Количество, 2);
		Иначе
			СтрокаПозицииЧека.ЦенаСоСкидками = СтрокаПозицииЧека.Цена;
		КонецЕсли;
		СтрокаПозицииЧека.СуммаСкидок = СтрокаДляДобавленияВЧек.СуммаСкидки;

		СтрокаПозицииЧека.ДанныеКодаТоварнойНоменклатуры.ТипМаркировки                          = Неопределено;
		СтрокаПозицииЧека.ДанныеКодаТоварнойНоменклатуры.КонтрольныйИдентификационныйЗнак       = Неопределено;
		СтрокаПозицииЧека.ДанныеКодаТоварнойНоменклатуры.ГлобальныйИдентификаторТорговойЕдиницы = Неопределено;
		СтрокаПозицииЧека.ДанныеКодаТоварнойНоменклатуры.СерийныйНомер                          = Неопределено;

		Если ОбщегоНазначенияУТКлиентСервер.ЕстьРеквизитОбъекта(СтрокаДляДобавленияВЧек, "Штрихкод")
			И ЗначениеЗаполнено(СтрокаДляДобавленияВЧек.Штрихкод) Тогда
			СтрокаПозицииЧека.Штрихкод = СтрокаДляДобавленияВЧек.Штрихкод;

			ЭтоВидПродукцииПиво = Ложь;
#Вставка
			ЭтоВидПродукцииМоторныеМасла = Ложь;
#КонецВставки
			Если ОбщегоНазначенияУТКлиентСервер.ЕстьРеквизитОбъекта(СтрокаДляДобавленияВЧек, "РезультатРаспределения")
				И ЗначениеЗаполнено(СтрокаДляДобавленияВЧек.РезультатРаспределения) Тогда

				ЭтоВидПродукцииПиво = СтрокаДляДобавленияВЧек.РезультатРаспределения.ВидПродукции = Перечисления.ВидыПродукцииИС.Пиво
				ИЛИ СтрокаДляДобавленияВЧек.РезультатРаспределения.ВидПродукции = Перечисления.ВидыПродукцииИС.БезалкогольноеПиво;
#Вставка
                ЭтоВидПродукцииМоторныеМасла = СтрокаДляДобавленияВЧек.РезультатРаспределения.ВидПродукции = 
				Перечисления.ВидыПродукцииИС.МоторныеМасла;
#КонецВставки				
			КонецЕсли;

			Если ОбщегоНазначенияУТКлиентСервер.ЕстьРеквизитОбъекта(СтрокаДляДобавленияВЧек, "РезультатРаспределения")
				И ЗначениеЗаполнено(СтрокаДляДобавленияВЧек.РезультатРаспределения) Тогда
				СтрокаПозицииЧека.РезультатРаспределенияВрем = СтрокаДляДобавленияВЧек.РезультатРаспределения;

				Если ТипЗнч(СтрокаПозицииЧека.РезультатРаспределенияВрем) = Тип("Структура")
					И НЕ СтрокаПозицииЧека.РезультатРаспределенияВрем.Свойство("ПредставлениеНоменклатуры") Тогда
					СтрокаПозицииЧека.РезультатРаспределенияВрем.Вставить(
					"ПредставлениеНоменклатуры",
					СтрокаПозицииЧека.Наименование);
				КонецЕсли;

				ПолныйКодМаркировки = СтрокаДляДобавленияВЧек.РезультатРаспределения.ПолныйКодМаркировки;
				Если ВерсияФФД = "1.2" И ЗначениеЗаполнено(ПолныйКодМаркировки) Тогда
					Если СтрокаДляДобавленияВЧек.РезультатРаспределения.ЧастичноеВыбытие
						И ЭтоВидПродукцииПиво Тогда
						СтрокаПозицииЧека.Штрихкод = Неопределено;
						СтрокаПозицииЧека.ШтрихкодBase64 = Неопределено;
					Иначе
						СтрокаПозицииЧека.ШтрихкодBase64 = СтрокаДляДобавленияВЧек.РезультатРаспределения.ПолныйКодМаркировки;
					КонецЕсли;
				КонецЕсли;

				Если ЗначениеЗаполнено(ИдентификаторУстройства)
					И МенеджерОборудованияВызовСервера.ФискальноеУстройствоПоддерживаетПроверкуКодовМаркировки(ИдентификаторУстройства) Тогда

					СтрокаПозицииЧека.КонтрольнаяМарка = ПолныйКодМаркировки;
#Удаление
					Если СтрокаДляДобавленияВЧек.РезультатРаспределения.ЧастичноеВыбытие
						И НЕ ЭтоВидПродукцииПиво Тогда
						СтрокаПозицииЧека.ДробноеКоличество.Числитель   = СтрокаДляДобавленияВЧек.РезультатРаспределения.ЧастичноеВыбытиеКоличество;
						СтрокаПозицииЧека.ДробноеКоличество.Знаменатель = СтрокаДляДобавленияВЧек.РезультатРаспределения.ЕмкостьПотребительскойУпаковки;
					КонецЕсли;
#КонецУдаления
#Вставка
// Здесь можно описать новое поведение.
					Если СтрокаДляДобавленияВЧек.РезультатРаспределения.ЧастичноеВыбытие
						И НЕ (ЭтоВидПродукцииПиво Или ЭтоВидПродукцииМоторныеМасла) Тогда
						СтрокаПозицииЧека.ДробноеКоличество.Числитель   = СтрокаДляДобавленияВЧек.РезультатРаспределения.ЧастичноеВыбытиеКоличество;
						СтрокаПозицииЧека.ДробноеКоличество.Знаменатель = СтрокаДляДобавленияВЧек.РезультатРаспределения.ЕмкостьПотребительскойУпаковки;
					КонецЕсли;
#КонецВставки

					Если НоменклатураВидУпаковки = Перечисления.ВидыУпаковокИС.ОбъемноСортовойУчет Тогда

						СтрокаПозицииЧека.ОбъемноСортовойУчет = Истина;

						GTIN = СтрокаДляДобавленияВЧек.РезультатРаспределения.СоставКодаМаркировки.GTIN;
						СтрокаПозицииЧека.КонтрольнаяМарка = МенеджерОборудованияКлиентСервер.ШтрихкодВBase64(GTIN);

						СтрокаПозицииЧека.Количество = СтрокаПозицииЧека.Количество;

						ТипИзмеряемойВеличины = СтрокаДляДобавленияВЧек.БазоваяУпаковка.ТипИзмеряемойВеличины;
						КоличествоВесовогоТовара = СтрокаДляДобавленияВЧек.РезультатРаспределения.КоличествоПотребительскихУпаковок;
						Если ТипИзмеряемойВеличины = Перечисления.ТипыИзмеряемыхВеличин.Вес
							И СтрокаДляДобавленияВЧек.РезультатРаспределения.КоличествоПотребительскихУпаковок > 0 Тогда

							СтрокаПозицииЧека.КоличествоВесовогоТовара = КоличествоВесовогоТовара;
						КонецЕсли;

						СтрокаПозицииЧека.Штрихкод = Неопределено;
						СтрокаПозицииЧека.ШтрихкодBase64 = Неопределено;

					КонецЕсли;

					Если ЗначениеЗаполнено(СтрокаДляДобавленияВЧек.РезультатРаспределения.РазрешительныйРежимИдентификаторЗапросаГИСМТ) Тогда
						СтрокаПозицииЧека.ЗапросПроверкиКода.ИдентификаторЗапроса
						= СтрокаДляДобавленияВЧек.РезультатРаспределения.РазрешительныйРежимИдентификаторЗапросаГИСМТ;
						СтрокаПозицииЧека.ЗапросПроверкиКода.ВременнаяМетка
						= СтрокаДляДобавленияВЧек.РезультатРаспределения.РазрешительныйРежимДатаЗапросаГИСМТ;
						СтрокаПозицииЧека.ЗапросПроверкиКода.ИдентификаторЭкземпляра
						= СтрокаДляДобавленияВЧек.РезультатРаспределения.РазрешительныйРежимИдентификаторЭкземпляраПО;
						СтрокаПозицииЧека.ЗапросПроверкиКода.ВерсияБазы
						= СтрокаДляДобавленияВЧек.РезультатРаспределения.РазрешительныйРежимВерсияБазы;
					КонецЕсли;

					СтрокаПозицииЧека.НормализованныйКодМаркировки = СтрокаДляДобавленияВЧек.РезультатРаспределения.КодИдентификации;

				КонецЕсли;
			КонецЕсли;

			Если ОбщегоНазначенияУТКлиентСервер.ЕстьРеквизитОбъекта(СтрокаДляДобавленияВЧек, "РезультатРаспределения")
				И ЗначениеЗаполнено(СтрокаДляДобавленияВЧек.РезультатРаспределения)
				И Не СтрокаДляДобавленияВЧек.РезультатРаспределения.ЧастичноеВыбытие
				И СтрокаДляДобавленияВЧек.РезультатРаспределения.ВидПродукции = Перечисления.ВидыПродукцииИС.ВетеринарныеПрепараты Тогда

				Если ОбщегоНазначенияУТКлиентСервер.ЕстьРеквизитОбъекта(СтрокаДляДобавленияВЧек, "РазрешениеТипДокумента")
					И ЗначениеЗаполнено(СтрокаДляДобавленияВЧек.РазрешениеТипДокумента) Тогда

					СтрокаПозицииЧека.ВетеринарныйПрепарат = Истина;
					СтрокаПозицииЧека.ВетеринарноеТребование =
					(СтрокаДляДобавленияВЧек.РазрешениеТипДокумента = Перечисления.ТипыРазрешенийНаПродажу);
					СтрокаПозицииЧека.РецептНомер = СтрокаДляДобавленияВЧек.РазрешениеНомерДокумента;
					СтрокаПозицииЧека.РецептДата = СтрокаДляДобавленияВЧек.РазрешениеДатаДокумента;

					СтрокаПозицииЧека.Штрихкод = Неопределено;
					СтрокаПозицииЧека.ШтрихкодBase64 = Неопределено;

				КонецЕсли;

			ИначеЕсли ОбщегоНазначенияУТКлиентСервер.ЕстьРеквизитОбъекта(СтрокаДляДобавленияВЧек, "РезультатРаспределения")
				И ЗначениеЗаполнено(СтрокаДляДобавленияВЧек.РезультатРаспределения)
				И СтрокаДляДобавленияВЧек.РезультатРаспределения.ЧастичноеВыбытие
				И ЭтоВидПродукцииПиво Тогда

				Если НЕ ЗначениеЗаполнено(Упаковка) Тогда
					Упаковка = "л.";
				КонецЕсли;

				Если ВерсияФФД = "1.2" Тогда
					СтрокаПозицииЧека.КодЕдиницыИзмерения = "112";
				Иначе
					СтрокаПозицииЧека.ЕдиницаИзмерения = Упаковка;
				КонецЕсли;

				СтрокаПозицииЧека.Количество = СтрокаДляДобавленияВЧек.Количество;

			ИначеЕсли ОбщегоНазначенияУТКлиентСервер.ЕстьРеквизитОбъекта(СтрокаДляДобавленияВЧек, "ДополнениеКНаименованиюТовара")
				И НоменклатураВидУпаковки <> Перечисления.ВидыУпаковокИС.ОбъемноСортовойУчет
				И ТипЗнч(СтрокаДляДобавленияВЧек.ДополнениеКНаименованиюТовара) = Тип("Структура") Тогда

				Если НЕ ЗначениеЗаполнено(Упаковка) Тогда
					Упаковка = "шт.";
				КонецЕсли;

				Если ВерсияФФД = "1.2" Тогда
					Если СтрокаПозицииЧека.РезультатРаспределенияВрем.ЧастичноеВыбытие
						ИЛИ ТипЗнч(Упаковка) = Тип("СправочникСсылка.УпаковкиЕдиницыИзмерения")
						И Справочники.УпаковкиЕдиницыИзмерения.ЭтоМернаяЕдиница(Упаковка, "") Тогда
						СтрокаПозицииЧека.КодЕдиницыИзмерения = РозничныеПродажи.КодЕдиницыИзмеренияПараметраЧека("шт.");
					Иначе
						СтрокаПозицииЧека.КодЕдиницыИзмерения = РозничныеПродажи.КодЕдиницыИзмеренияПараметраЧека(Упаковка);
					КонецЕсли;
				Иначе
					СтрокаПозицииЧека.ЕдиницаИзмерения = Упаковка;
				КонецЕсли;

				СтрокаПозицииЧека.Количество = 1;
				СтрокаПозицииЧека.Цена       = СтрокаПозицииЧека.Сумма;

#Вставка
// исправление для продажи масла на розлив.
                Если ЭтоВидПродукцииМоторныеМасла Тогда
					СтрокаПозицииЧека.КодЕдиницыИзмерения = РозничныеПродажи.КодЕдиницыИзмеренияПараметраЧека(Упаковка);
					//СтрокаПозицииЧека.КодЕдиницыИзмерения = "112";
					СтрокаПозицииЧека.Количество = СтрокаДляДобавленияВЧек.Количество;
					СтрокаПозицииЧека.Цена       = СтрокаПозицииЧека.Сумма / СтрокаДляДобавленияВЧек.Количество;
				КонецЕсли;
#КонецВставки
				
				Если ВерсияФФД = "1.2" 
					И (СтрокаПозицииЧека.РезультатРаспределенияВрем.ЧастичноеВыбытие
					ИЛИ ТипЗнч(Упаковка) = Тип("СправочникСсылка.УпаковкиЕдиницыИзмерения"))
					И Справочники.УпаковкиЕдиницыИзмерения.ЭтоМернаяЕдиница(Упаковка, "") Тогда

					УпаковкаНаименование = "ед";
					Если ЗначениеЗаполнено(Упаковка) Тогда
						УпаковкаНаименование = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(Упаковка, "Наименование");
					КонецЕсли;
					УпаковкаНаименование = УпаковкаНаименование + ".";

					КоличествоЕдиниц = СтрокаДляДобавленияВЧек.ДополнениеКНаименованиюТовара.Количество;
					Если ТипЗнч(СтрокаДляДобавленияВЧек.ДополнениеКНаименованиюТовара.КоличествоУпаковок) = Тип("Число")
						И СтрокаДляДобавленияВЧек.ДополнениеКНаименованиюТовара.КоличествоУпаковок > 0 Тогда
						КоличествоЕдиниц = СтрокаДляДобавленияВЧек.ДополнениеКНаименованиюТовара.КоличествоУпаковок;
					КонецЕсли;

					ЦенаЕдиницы = СтрокаДляДобавленияВЧек.ДополнениеКНаименованиюТовара.Цена;

					Если СтрокаДляДобавленияВЧек.РезультатРаспределения.ЧастичноеВыбытие Тогда
						ЧастичноеВыбытиеКоличество = СтрокаДляДобавленияВЧек.РезультатРаспределения.ЧастичноеВыбытиеКоличество;
						ЦенаЕдиницы = Окр(СтрокаПозицииЧека.Цена / ЧастичноеВыбытиеКоличество, 2);
					Иначе
						ЦенаЕдиницы = Окр(СтрокаПозицииЧека.Цена / КоличествоЕдиниц, 2);
					КонецЕсли;

#Вставка
					// исправление для продажи масла на розлив.
                    Если ЭтоВидПродукцииМоторныеМасла Тогда
						Если СтрокаДляДобавленияВЧек.РезультатРаспределения.ЧастичноеВыбытие Тогда
							ЧастичноеВыбытиеКоличество = СтрокаДляДобавленияВЧек.РезультатРаспределения.ЧастичноеВыбытиеКоличество;
							ЦенаЕдиницы = Окр(СтрокаПозицииЧека.Цена, 2);
						Иначе
							ЦенаЕдиницы = Окр(СтрокаПозицииЧека.Цена, 2);
						КонецЕсли;
					КонецЕсли;
#КонецВставки


					СтрокаПозицииЧека.Наименование = СтрокаПозицииЧека.Наименование
					+ " (" + КоличествоЕдиниц + " " + УпаковкаНаименование
					+ ", цена: " + ЦенаЕдиницы + " " + Строка(ВалютаВрем) + "/" + УпаковкаНаименование + ")";

				КонецЕсли;
			КонецЕсли;

		КонецЕсли;

		Если ОбщегоНазначенияУТКлиентСервер.ЕстьРеквизитОбъекта(СтрокаДляДобавленияВЧек, "КодВидаНоменклатурнойКлассификации") Тогда
			СтрокаПозицииЧека.КодВидаНоменклатурнойКлассификации = СтрокаДляДобавленияВЧек.КодВидаНоменклатурнойКлассификации;
		КонецЕсли;

		Если ОплатаЭлектроннымиСертификатамиФСС
			И ОбщегоНазначенияУТКлиентСервер.ЕстьРеквизитОбъекта(СтрокаДляДобавленияВЧек, "КодТРУ") Тогда
			СтрокаПозицииЧека.NTIN = СтрокаДляДобавленияВЧек.КодТРУ;
		КонецЕсли;

		ЗаполнитьСтрокуПоДаннымРазбораШтрихкода(СтрокаПозицииЧека, СтрокаДляДобавленияВЧек);

		Если ОбщегоНазначенияУТКлиентСервер.ЕстьРеквизитОбъекта(СтрокаДляДобавленияВЧек, "ТипЗапасов")
			И ОбщегоНазначенияУТКлиентСервер.ЕстьРеквизитОбъекта(СтрокаДляДобавленияВЧек, "Комитент")
			И СтрокаДляДобавленияВЧек.ТипЗапасов = Перечисления.ТипыЗапасов.КомиссионныйТовар Тогда

			РеквизитыКомитента = ФормированиеПечатныхФорм.СведенияОЮрФизЛице(СтрокаДляДобавленияВЧек.Комитент, ТекущаяДатаСеанса());

			СтрокаПозицииЧека.ПризнакАгентаПоПредметуРасчета = Перечисления.ПризнакиАгента.Комиссионер;

			ДанныеПоставщика = Новый Структура();
			ДанныеПоставщика.Вставить("Телефон"	 	, РеквизитыКомитента.Телефоны);
			ДанныеПоставщика.Вставить("Наименование", РеквизитыКомитента.ПолноеНаименование);
			ДанныеПоставщика.Вставить("ИНН"		 	, РеквизитыКомитента.ИНН);

			СтрокаПозицииЧека.ДанныеПоставщика = ДанныеПоставщика; 
		КонецЕсли;

		Если ОбщегоНазначенияУТКлиентСервер.ЕстьРеквизитОбъекта(СтрокаДляДобавленияВЧек, "ОсобенностьУчета")
			И ОбщегоНазначенияУТКлиентСервер.ЕстьРеквизитОбъекта(СтрокаДляДобавленияВЧек, "Агент")
			И (СтрокаДляДобавленияВЧек.ОсобенностьУчета = Перечисления.ОсобенностиУчетаНоменклатуры.Партнером
			ИЛИ СтрокаДляДобавленияВЧек.ОсобенностьУчета = Перечисления.ОсобенностиУчетаНоменклатуры.ОрганизациейПоАгентскойСхеме)
			И ЗначениеЗаполнено(СтрокаДляДобавленияВЧек.Агент) Тогда

			РеквизитыКомитента = ФормированиеПечатныхФорм.СведенияОЮрФизЛице(СтрокаДляДобавленияВЧек.Агент, ТекущаяДатаСеанса());

			СтрокаПозицииЧека.ПризнакАгентаПоПредметуРасчета = Перечисления.ПризнакиАгента.Агент;

			ДанныеПоставщика = Новый Структура();
			ДанныеПоставщика.Вставить("Телефон"	 	, РеквизитыКомитента.Телефоны);
			ДанныеПоставщика.Вставить("Наименование", РеквизитыКомитента.ПолноеНаименование);
			ДанныеПоставщика.Вставить("ИНН"		 	, РеквизитыКомитента.ИНН);

			СтрокаПозицииЧека.ДанныеПоставщика = ДанныеПоставщика; 
		КонецЕсли;

		Если ОбщегоНазначенияУТКлиентСервер.ЕстьРеквизитОбъекта(СтрокаДляДобавленияВЧек, "ПодакцизныйТовар")
			И ВерсияФФД = "1.2"
			И СтрокаДляДобавленияВЧек.ПодакцизныйТовар = Истина Тогда

			СтрокаПозицииЧека.СуммаАкциза = 0;
		КонецЕсли;

		СтрокаПозицииЧека.ПризнакСпособаРасчета = Неопределено; // Заполняется из РМК или ПредпросмотраЧека

		СтрокаПозицииЧека.ПризнакПредметаРасчета = РозничныеПродажиКлиентСервер.ПризнакПредметаРасчетаФискальнойОперации(
		СтрокаДляДобавленияВЧек.ТипНоменклатуры,
		СтрокаДляДобавленияВЧек.ПодакцизныйТовар,
		ЗначениеЗаполнено(СтрокаПозицииЧека.КонтрольнаяМарка), // УказанаКМ
		СтрокаДляДобавленияВЧек);

		ДанныеПоИмпортнойПоставке = Новый Структура("НомерТаможеннойДекларации, КодСтраныПроисхождения", Неопределено, Неопределено);
		ЗаполнитьЗначенияСвойств(ДанныеПоИмпортнойПоставке, СтрокаДляДобавленияВЧек);

		СтрокаПозицииЧека.НомерТаможеннойДекларации = ДанныеПоИмпортнойПоставке.НомерТаможеннойДекларации; 
		СтрокаПозицииЧека.КодСтраныПроисхожденияТовара = ДанныеПоИмпортнойПоставке.КодСтраныПроисхождения;

		Если ОплатаЭлектроннымиСертификатамиФСС И Не ПустаяСтрока(СтрокаПозицииЧека.NTIN) Тогда
			СтрокаТекста = СтрШаблон(НСтр("ru = 'ТРУ (КОД): %1'"), СтрокаПозицииЧека.NTIN);
			ТекстоваяСтрокаЧека =
			ОборудованиеЧекопечатающиеУстройстваКлиентСервер.ПараметрыТекстовойСтрокиЧека(СтрокаТекста);
			ПозицииЧека.Добавить(ТекстоваяСтрокаЧека);
		КонецЕсли;

		ПозицииЧека.Добавить(СтрокаПозицииЧека);

	КонецЦикла;

	Возврат ПозицииЧека;

КонецФункции