ЭДО через СБИС по маркируемой обуви в УТ 10.3

///////////////////++Вставить этот кусок кода
Если ТипЗнч(ДобавленныеСтроки) = Тип("Массив") Тогда
		ДобавленныеСтроки.Добавить(НайденнаяСтрока);
КонецЕсли;
////////////////////Вставить этот кусок кода++

Процедура ДополнитьТаблицуДанныеКодовМаркировкиПоСтрокамДереваУпаковок­(ДанныеКодовМаркировки, ДеревоУпаковок, ДобавленныеСтроки = Неопределено, ПараметрыСканирования = Неопределено, ИменаКолонокДляКопированияСвойств = Неопределено, ЭтоЗагрузкаИзТСД = Ложь) Экспорт
	
	Если ИменаКолонокДляКопированияСвойств = Неопределено Тогда
		
		ИменаКолонокДляКопированияСвойств = Новый Массив;
		Для Каждого КолонкаДерева Из ДеревоУпаковок.Колонки Цикл
			
			ИмяКолонки = КолонкаДерева.Имя;
			Если ДанныеКодовМаркировки.Колонки.Найти(ИмяКолонки) = Неопределено Тогда
				Продолжить;
			КонецЕсли;
			
			ИменаКолонокДляКопированияСвойств.Добавить(ИмяКолонки);
			
		КонецЦикла;
		
	КонецЕсли;
	
	ПараметрыОтбора = Новый Структура("НормализованныйШтрихкод");
	
	Для Каждого СтрокаДерева Из ДеревоУпаковок.Строки Цикл
		
		ДополнитьТаблицуДанныеКодовМаркировкиПоСтрокамДереваУпаковок­(
			ДанныеКодовМаркировки, СтрокаДерева, ДобавленныеСтроки, ПараметрыСканирования, ИменаКолонокДляКопированияСвойств, ЭтоЗагрузкаИзТСД);
		
		Если Не ЭтоЗагрузкаИзТСД Тогда
			ПараметрыОтбора.НормализованныйШтрихкод = СтрокаДерева.НормализованныйШтрихкод;
			НайденныеСтроки = ДанныеКодовМаркировки.НайтиСтроки(ПараметрыОтбора);
		КонецЕсли;
		
		Если Не ЭтоЗагрузкаИзТСД И НайденныеСтроки.Количество() Тогда
			
			Для Каждого НайденнаяСтрока Из НайденныеСтроки Цикл
				
				ПоляСкопированы = Ложь;
				Для Каждого ИмяКолонки Из ИменаКолонокДляКопированияСвойств Цикл
					
					Значение = СтрокаДерева[ИмяКолонки];
					Если ЗначениеЗаполнено(Значение)
						И НайденнаяСтрока[ИмяКолонки] <> Значение Тогда
						НайденнаяСтрока[ИмяКолонки] = Значение;
						ПоляСкопированы = Истина;
					КонецЕсли;
					
				КонецЦикла;
				
				Если Не ПоляСкопированы Тогда
					Продолжить;
				КонецЕсли;
				
				НайденнаяСтрока.СтрокаДерева               = СтрокаДерева;
				НайденнаяСтрока.Идентифицирован            = Истина;
				НайденнаяСтрока.НайденВоВложенныхУпаковках = Истина;
				
				Если Не ЗначениеЗаполнено(НайденнаяСтрока.Номенклатура)
					И НайденнаяСтрока.СписокНоменклатуры.Количество() = 0
					И Не НайденнаяСтрока.ЭтоКодВводаОстатков
					И ЗначениеЗаполнено(НайденнаяСтрока.GTIN) Тогда
					НайденнаяСтрока.ТребуетсяСопоставление = Истина;
				КонецЕсли;
				///////////////////++Вставить этот кусок кода
                               Если ТипЗнч(ДобавленныеСтроки) = Тип("Массив") Тогда
		                      ДобавленныеСтроки.Добавить(НайденнаяСтрока);
                               КонецЕсли;
                               ////////////////////Вставить этот кусок кода++
			КонецЦикла;
			
		Иначе
			
			ЭтоСтрокаВерхнегоУровня = (СтрокаДерева.Родитель = Неопределено);
			
			НоваяСтрока = ДанныеКодовМаркировки.Добавить();
			ЗаполнитьЗначенияСвойств(НоваяСтрока, СтрокаДерева);
			
			Если ЗначениеЗаполнено(СтрокаДерева.ВидПродукции) Тогда
				НоваяСтрока.ВидыПродукцииКодаМаркировки.Добавить(СтрокаДерева.ВидПродукции);
			ИначеЕсли СтрокаДерева.ТипУпаковки <> Перечисления.ТипыУпаковок.МаркированныйТовар Тогда
				
				ВидыПродукции = ВидПродукцииУпаковкиПоСоставу(СтрокаДерева);
				Если ВидыПродукции.Количество() = 1 И ЗначениеЗаполнено(ВидыПродукции[0]) Тогда
					НоваяСтрока.ВидПродукции = ВидыПродукции[0];
				КонецЕсли;
			Иначе
				ЭлементДляРазбора = Новый Массив;
				ЭлементДляРазбора.Добавить(НоваяСтрока);
				НормализоватьИРазобратьНаСоставляющиеКодыМаркировки(ЭлементДляРазбора, ПараметрыСканирования);
			КонецЕсли;
			
			НоваяСтрока.Входящий            = ЭтоСтрокаВерхнегоУровня;
			НоваяСтрока.Идентифицирован     = Не ЭтоЗагрузкаИзТСД;
			НоваяСтрока.ЭтоКодВводаОстатков = ШтрихкодированиеИСКлиентСервер.ЭтоШтрихкодВводаОстатков(НоваяСтрока.Штрихкод);
			НоваяСтрока.СтрокаДерева        = СтрокаДерева;
			
			// При загрузке из ТСД первоначально заполняются вложенные упаковки
			НоваяСтрока.НайденВоВложенныхУпаковках = ЭтоЗагрузкаИзТСД;
			
			Если Не ЗначениеЗаполнено(НоваяСтрока.Номенклатура)
				И НоваяСтрока.СписокНоменклатуры.Количество() = 0
				И Не НоваяСтрока.ЭтоКодВводаОстатков
				И ЗначениеЗаполнено(НоваяСтрока.GTIN) Тогда
				НоваяСтрока.ТребуетсяСопоставление = Истина;
			КонецЕсли;
			
			Если ТипЗнч(ДобавленныеСтроки) = Тип("Массив") Тогда
				ДобавленныеСтроки.Добавить(НоваяСтрока);
			КонецЕсли;
			
		КонецЕсли;
		
	КонецЦикла;
	
КонецПроцедуры