Оптимизация скорости работы РМК в Розница 2.2

ВЫБРАТЬ
	Товары.НомерСтроки КАК НомерСтрокиЧека,
	Товары.ПродажаПодарка,
	Товары.Номенклатура,
	Товары.Характеристика,
	Товары.Количество,
	Товары.Цена,
	Товары.Сумма + Товары.СуммаРучнойСкидки КАК Сумма,
	Товары.СтавкаНДС,
	Товары.СуммаНДС,
	Товары.ПроцентАвтоматическойСкидки,
	Товары.ПроцентРучнойСкидки,
	Товары.ПродажаПодарка,
	Товары.Упаковка,
	Товары.КоличествоУпаковок,
	Товары.КлючСвязи,
	Товары.СуммаАвтоматическойСкидки,
	Товары.СуммаРучнойСкидки
ПОМЕСТИТЬ ТоварыДокументаВременная
ИЗ
	&Товары КАК Товары
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	Товары.НомерСтрокиЧека,
	Товары.Номенклатура,
	Товары.Номенклатура.ЦеноваяГруппа КАК ЦеноваяГруппа,
	Товары.Номенклатура.ТипНоменклатуры КАК ТипНоменклатуры,
	Товары.Номенклатура.ДоговорПлатежногоАгента КАК ДоговорПлатежногоАгента,
	Товары.Характеристика,
	Товары.Количество,
	Товары.Цена,
	Товары.Сумма,
	Товары.СтавкаНДС,
	Товары.СуммаНДС,
	Товары.ПроцентАвтоматическойСкидки,
	Товары.ПроцентРучнойСкидки,
	Товары.ПродажаПодарка,
	Товары.Упаковка,
	Товары.КоличествоУпаковок,
	Товары.КлючСвязи,
	Товары.СуммаАвтоматическойСкидки,
	Товары.СуммаРучнойСкидки,
	ВЫБОР
		КОГДА Сегменты.Номенклатура ЕСТЬ NULL 
			ТОГДА ЛОЖЬ
		ИНАЧЕ ИСТИНА
	КОНЕЦ КАК ИсключенаИзРасчета
ПОМЕСТИТЬ ТоварыДокумента
ИЗ
	ТоварыДокументаВременная КАК Товары
	ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.НоменклатураСегмента КАК Сегменты
		ПО	Товары.Номенклатура = Сегменты.Номенклатура
		И Товары.Характеристика = Сегменты.Характеристика
		И Сегменты.Сегмент = &СегментИсключаемойНоменклатуры
	ГДЕ НЕ Товары.ПродажаПодарка
;

////////////////////////////////////////////////////////////­////////////////////
УНИЧТОЖИТЬ ТоварыДокументаВременная
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
	СкидкиНаценки.Ссылка КАК СкидкаНаценка,
	СкидкиНаценки.СегментНоменклатурыПредоставления КАК СегментНоменклатурыПредоставления
ПОМЕСТИТЬ ТаблицаСкидок
ИЗ
	Справочник.СкидкиНаценки КАК СкидкиНаценки
ГДЕ
	СкидкиНаценки.Ссылка В (ВЫБРАТЬ ДействиеСкидок.СкидкаНаценка ИЗ РегистрСведений.ДействиеСкидокНаценок.СрезПоследних(
			&ТекущаяДата,
			(КОНЕЦПЕРИОДА(ДатаОкончания, ДЕНЬ) >= &ТекущаяДата
				ИЛИ ДатаОкончания = &ПустаяДата)
				И (Магазин = &Магазин
					ИЛИ Магазин = &ПустойМагазин)) КАК ДействиеСкидок)
	И СкидкиНаценки.СтатусДействия = &Действует
	И СкидкиНаценки.СпособПредоставления <> &ЗапретРозничнойПродажи
	И (&РасчетПодарков
			ИЛИ СкидкиНаценки.СпособПредоставления <> &Подарок)
	И (&РасчетСообщений
			ИЛИ СкидкиНаценки.СпособПредоставления <> &Сообщение)
	И ВЫБОР
			КОГДА СкидкиНаценки.СпособПредоставления = &Сообщение
					И СкидкиНаценки.МоментВыдачиСообщения = &ПослеОформленияЧека
				ТОГДА &ТолькоСообщенияПослеОформления = ИСТИНА
			ИНАЧЕ &ТолькоСообщенияПослеОформления = ЛОЖЬ
		КОНЕЦ
		И (СкидкиНаценки.Ссылка В (&МассивУправляемыхСкидок)
			ИЛИ НЕ СкидкиНаценки.Управляемая)
СГРУППИРОВАТЬ ПО
	СкидкиНаценки.Ссылка,
	СкидкиНаценки.СегментНоменклатурыПредоставления

ИНДЕКСИРОВАТЬ ПО
	СкидкаНаценка
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
	ТаблицаСкидок.СкидкаНаценка КАК СкидкаНаценка,
	Условия.УсловиеПредоставления КАК УсловиеПредоставления
ПОМЕСТИТЬ УсловияПредоставления
ИЗ	
	ТаблицаСкидок КАК ТаблицаСкидок
	ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.СкидкиНаценки.УсловияПредоставления КАК Условия
	ПО ТаблицаСкидок.СкидкаНаценка = Условия.Ссылка
				
СГРУППИРОВАТЬ ПО
	ТаблицаСкидок.СкидкаНаценка,
	Условия.УсловиеПредоставления

ИНДЕКСИРОВАТЬ ПО
	СкидкаНаценка,
	УсловиеПредоставления
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ
	Подзапрос.Сегмент КАК Сегмент
ПОМЕСТИТЬ ИспользуемыеСегменты
ИЗ
	(ВЫБРАТЬ
		Скидки.СегментНоменклатурыПредоставления КАК Сегмент
	ИЗ
		ТаблицаСкидок КАК Скидки
		
	
	ОБЪЕДИНИТЬ ВСЕ
	
	ВЫБРАТЬ
		Условия.УсловиеПредоставления.СегментНоменклатурыОграничения
	ИЗ
		УсловияПредоставления КАК Условия) КАК Подзапрос
ГДЕ
	НЕ Подзапрос.Сегмент = &ПустойСегмент
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	Сегменты.Сегмент КАК Сегмент,
	ТоварыДокумента.Номенклатура КАК Номенклатура,
	ТоварыДокумента.Характеристика КАК Характеристика
ПОМЕСТИТЬ ТоварыСегментов
ИЗ
	ТоварыДокумента КАК ТоварыДокумента
	ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.НоменклатураСегмента КАК Сегменты
	ПО Сегменты.Номенклатура = ТоварыДокумента.Номенклатура
	И Сегменты.Характеристика = ТоварыДокумента.Характеристика
	ВНУТРЕННЕЕ СОЕДИНЕНИЕ ИспользуемыеСегменты КАК ИспользуемыеСегменты
	ПО Сегменты.Сегмент = ИспользуемыеСегменты.Сегмент

СГРУППИРОВАТЬ ПО
	Сегменты.Сегмент,
	ТоварыДокумента.Номенклатура,
	ТоварыДокумента.Характеристика
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	&НаборПодарков КАК ИмяРаздела,
	НаборПодарков.Ссылка КАК СкидкаНаценка,
	НаборПодарков.НомерСтроки КАК НомерСтрокиПодарка,
	НаборПодарков.Номенклатура КАК Номенклатура,
	НаборПодарков.Характеристика КАК Характеристика,
	НаборПодарков.Упаковка КАК Упаковка,
	НаборПодарков.КоличествоУпаковок КАК КоличествоУпаковок,
	НаборПодарков.Количество КАК Количество,
	NULL КАК НомерСтрокиЦеновойГруппы,
	NULL КАК ЦеноваяГруппа,
	NULL КАК ЗначениеСкидкиНаценки
ПОМЕСТИТЬ ПараметрыСкидок
ИЗ	
	Справочник.СкидкиНаценки.НаборПодарков КАК НаборПодарков
	ВНУТРЕННЕЕ СОЕДИНЕНИЕ ТаблицаСкидок КАК ТаблицаСкидок
	ПО ТаблицаСкидок.СкидкаНаценка = НаборПодарков.Ссылка
ГДЕ
	НаборПодарков.Ссылка.СпособПредоставления = &Подарок

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	&ЦеновыеГруппы,
	ЦеновыеГруппы.Ссылка,
	NULL,
	NULL,
	NULL,
	NULL,
	NULL,
	NULL,
	ЦеновыеГруппы.НомерСтроки,
	ЦеновыеГруппы.ЦеноваяГруппа,
	ЦеновыеГруппы.ЗначениеСкидкиНаценки
ИЗ	
	Справочник.СкидкиНаценки.ЦеновыеГруппы КАК ЦеновыеГруппы
	ВНУТРЕННЕЕ СОЕДИНЕНИЕ ТаблицаСкидок КАК ТаблицаСкидок
	ПО ТаблицаСкидок.СкидкаНаценка = ЦеновыеГруппы.Ссылка

ИНДЕКСИРОВАТЬ ПО
	СкидкаНаценка
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	&ВремяДействия КАК ИмяРаздела,
	ВремяДействия.Ссылка КАК Условие,
	ВремяДействия.НомерСтроки КАК НомерСтрокиВремени,
	ВремяДействия.ДеньНедели КАК ДеньНедели,
	ВремяДействия.ВремяНачала КАК ВремяНачала,
	ВремяДействия.ВремяОкончания КАК ВремяОкончания,
	NULL КАК НомерСтрокиПолучателя,
	NULL КАК Получатель,
	NULL КАК НомерСтрокиКомплекта,
	NULL КАК Номенклатура,
	NULL КАК Характеристика,
	NULL КАК Упаковка,
	NULL КАК КоличествоУпаковок,
	NULL КАК Количество
ПОМЕСТИТЬ ПараметрыУсловий
ИЗ
	Справочник.УсловияПредоставленияСкидокНаценок.ВремяДействия КАК ВремяДействия
	ВНУТРЕННЕЕ СОЕДИНЕНИЕ УсловияПредоставления КАК Т
	ПО ВремяДействия.Ссылка = Т.УсловиеПредоставления
ГДЕ
	ВремяДействия.Ссылка.УсловиеПредоставления = &ЗаВремяПродажи
	И ВремяДействия.ДеньНедели = &ТекущийДеньНедели

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	&Получатели,
	Получатели.Ссылка,
	NULL,
	NULL,
	NULL,
	NULL,
	Получатели.НомерСтроки,
	Получатели.Получатель,
	NULL,
	NULL,
	NULL,
	NULL,
	NULL,
	NULL
ИЗ
	Справочник.УсловияПредоставленияСкидокНаценок.Получатели КАК Получатели
	ВНУТРЕННЕЕ СОЕДИНЕНИЕ УсловияПредоставления КАК Т
	ПО Получатели.Ссылка = Т.УсловиеПредоставления
ГДЕ
	Получатели.Ссылка.УсловиеПредоставления = &ПоТипуПолучателя
	И Получатели.Получатель В(&ПолучателиСкидок)

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	&КомплектПокупки,
	КомплектПокупки.Ссылка,
	NULL,
	NULL,
	NULL,
	NULL,
	NULL,
	NULL,
	КомплектПокупки.НомерСтроки,
	КомплектПокупки.Номенклатура,
	КомплектПокупки.Характеристика,
	КомплектПокупки.Упаковка,
	КомплектПокупки.КоличествоУпаковок,
	КомплектПокупки.Количество
ИЗ
	Справочник.УсловияПредоставленияСкидокНаценок.КомплектПокупки КАК КомплектПокупки
	ВНУТРЕННЕЕ СОЕДИНЕНИЕ УсловияПредоставления КАК Т
	ПО КомплектПокупки.Ссылка = Т.УсловиеПредоставления
ГДЕ
	КомплектПокупки.Ссылка.УсловиеПредоставления = &ЗаКомплектПокупки

ИНДЕКСИРОВАТЬ ПО
	Условие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ТоварыДокумента.НомерСтрокиЧека КАК НомерСтрокиЧека,
	ТоварыСегментов.Сегмент КАК Сегмент,
	ТоварыДокумента.Номенклатура КАК Номенклатура,
	ТоварыДокумента.ЦеноваяГруппа КАК ЦеноваяГруппа,
	ТоварыДокумента.ТипНоменклатуры КАК ТипНоменклатуры,
	ТоварыДокумента.ДоговорПлатежногоАгента КАК ДоговорПлатежногоАгента,
	ТоварыДокумента.Характеристика КАК Характеристика,
	ТоварыДокумента.Количество КАК Количество,
	ТоварыДокумента.Цена КАК Цена,
	ТоварыДокумента.Сумма КАК Сумма,
	ТоварыДокумента.Сумма КАК СуммаДляРасчета,
	ТоварыДокумента.Сумма КАК СуммаВГруппе,
	ТоварыДокумента.Сумма КАК СуммаБезСкидки,
	ТоварыДокумента.СтавкаНДС КАК СтавкаНДС,
	ТоварыДокумента.СуммаНДС КАК СуммаНДС,
	ТоварыДокумента.ПроцентАвтоматическойСкидки КАК ПроцентАвтоматическойСкидки,
	ТоварыДокумента.ПроцентРучнойСкидки КАК ПроцентРучнойСкидки,
	ТоварыДокумента.Упаковка КАК Упаковка,
	ТоварыДокумента.КоличествоУпаковок КАК КоличествоУпаковок,
	ТоварыДокумента.КлючСвязи КАК КлючСвязи,
	ТоварыДокумента.СуммаАвтоматическойСкидки КАК СуммаАвтоматическойСкидки,
	ТоварыДокумента.СуммаРучнойСкидки КАК СуммаРучнойСкидки,
	ТоварыДокумента.ИсключенаИзРасчета КАК ИсключенаИзРасчета,
	ЛОЖЬ КАК УсловиеПоСтрокеВыполнено,
	0 КАК КоличествоВыполненийУсловия
ИЗ
	ТоварыДокумента КАК ТоварыДокумента
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ТоварыСегментов КАК ТоварыСегментов
		ПО ТоварыДокумента.Номенклатура = ТоварыСегментов.Номенклатура
		И ТоварыДокумента.Характеристика = ТоварыСегментов.Характеристика

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	ТоварыДокумента.НомерСтрокиЧека,
	&ПустойСегмент,
	ТоварыДокумента.Номенклатура,
	ТоварыДокумента.ЦеноваяГруппа,
	ТоварыДокумента.ТипНоменклатуры,
	ТоварыДокумента.ДоговорПлатежногоАгента,
	ТоварыДокумента.Характеристика,
	ТоварыДокумента.Количество,
	ТоварыДокумента.Цена,
	ТоварыДокумента.Сумма,
	ТоварыДокумента.Сумма,
	ТоварыДокумента.Сумма,
	ТоварыДокумента.Сумма,
	ТоварыДокумента.СтавкаНДС,
	ТоварыДокумента.СуммаНДС,
	ТоварыДокумента.ПроцентАвтоматическойСкидки,
	ТоварыДокумента.ПроцентРучнойСкидки,
	ТоварыДокумента.Упаковка,
	ТоварыДокумента.КоличествоУпаковок,
	ТоварыДокумента.КлючСвязи,
	ТоварыДокумента.СуммаАвтоматическойСкидки,
	ТоварыДокумента.СуммаРучнойСкидки,
	ТоварыДокумента.ИсключенаИзРасчета,
	ЛОЖЬ,
	0
ИЗ
	ТоварыДокумента КАК ТоварыДокумента
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
	Условия.СкидкаНаценка КАК СкидкаНаценка,
	Условия.УсловиеПредоставления КАК Условие,
	Условия.УсловиеПредоставления.УсловиеПредоставления КАК ТипУсловия,
	Условия.УсловиеПредоставления.ВариантОпределенияПериодаНакопительнойСкидки КАК ВариантОпределенияПериодаНакопительнойСкидки,
	Условия.УсловиеПредоставления.ВариантНакопления КАК ВариантНакопления,
	Условия.УсловиеПредоставления.ТипСравнения КАК ТипСравнения,
	Условия.УсловиеПредоставления.УчитыватьПримененныеСкидки КАК УчитыватьПримененныеСкидки,
	Условия.УсловиеПредоставления.КритерийОграниченияПримененияЗаОбъемПродаж КАК КритерийОграниченияПримененияЗаОбъемПродаж,
	Условия.УсловиеПредоставления.ОбластьОграничения КАК ОбластьОграничения,
	Условия.УсловиеПредоставления.ГрафикОплаты КАК ГрафикОплаты,
	Условия.УсловиеПредоставления.ФормаОплаты КАК ФормаОплаты,
	Условия.УсловиеПредоставления.СегментНоменклатурыОграничения КАК СегментНоменклатурыОграничения,
	Условия.УсловиеПредоставления.ПериодНакопления КАК ПериодНакопления,
	Условия.УсловиеПредоставления.ГруппаПользователей КАК ГруппаПользователей,
	Условия.УсловиеПредоставления.ДнейДоДняРождения КАК ДнейДоДняРождения,
	Условия.УсловиеПредоставления.ДнейПослеДняРождения КАК ДнейПослеДняРождения,
	Условия.УсловиеПредоставления.ПорядковыйНомерПродажиКратен КАК ПорядковыйНомерПродажиКратен,
	Условия.УсловиеПредоставления.УчитыватьТекущийЧекВНакоплениях КАК УчитыватьТекущийЧекВНакоплениях,
	Условия.УсловиеПредоставления.ЗначениеУсловияОграничения КАК ЗначениеУсловияОграничения,
	Условия.УсловиеПредоставления.ВнешняяОбработка КАК ВнешняяОбработка,
	Условия.УсловиеПредоставления.ПараметрыВнешнейОбработки КАК ПараметрыВнешнейОбработки,
	Условия.УсловиеПредоставления.ВнешняяОбработка.Публикация КАК Публикация,
	ЛОЖЬ КАК Выполнено,
	ПараметрыУсловий.ИмяРаздела КАК ИмяРаздела,
	ПараметрыУсловий.НомерСтрокиВремени КАК НомерСтрокиВремени,
	ПараметрыУсловий.ДеньНедели КАК ДеньНедели,
	ПараметрыУсловий.ВремяНачала КАК ВремяНачала,
	ПараметрыУсловий.ВремяОкончания КАК ВремяОкончания,
	ПараметрыУсловий.НомерСтрокиПолучателя КАК НомерСтрокиПолучателя,
	ПараметрыУсловий.Получатель КАК Получатель,
	ПараметрыУсловий.НомерСтрокиКомплекта КАК НомерСтрокиКомплекта,
	ПараметрыУсловий.Номенклатура КАК Номенклатура,
	ПараметрыУсловий.Характеристика КАК Характеристика,
	ПараметрыУсловий.Упаковка КАК Упаковка,
	ПараметрыУсловий.КоличествоУпаковок КАК КоличествоУпаковок,
	ПараметрыУсловий.Количество КАК Количество
ИЗ
	УсловияПредоставления КАК Условия
		ЛЕВОЕ СОЕДИНЕНИЕ ПараметрыУсловий КАК ПараметрыУсловий
		ПО (ПараметрыУсловий.Условие = Условия.УсловиеПредоставления)
ГДЕ
	Условия.СкидкаНаценка В
			(ВЫБРАТЬ РАЗЛИЧНЫЕ
				Т.СкидкаНаценка
			ИЗ
				ТаблицаСкидок КАК Т)
ИТОГИ ПО
	СкидкаНаценка,
	Условие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
	ТаблицаСкидок.СкидкаНаценка КАК СкидкаНаценка,
	ТаблицаСкидок.СкидкаНаценка.РеквизитДопУпорядочивания КАК РеквизитДопУпорядочивания,
	ТаблицаСкидок.СкидкаНаценка.ЭтоГруппа КАК ЭтоГруппа,
	ТаблицаСкидок.СкидкаНаценка.ПометкаУдаления КАК ПометкаУдаления,
	ТаблицаСкидок.СкидкаНаценка.Родитель.ВариантСовместногоПрименения КАК ВариантСовместногоПримененияРодителя,
	ТаблицаСкидок.СкидкаНаценка.ВариантСовместногоПрименения КАК ВариантСовместногоПрименения,
	ЛОЖЬ КАК Безусловная,
	ТаблицаСкидок.СкидкаНаценка.СпособПредоставления КАК СпособПредоставления,
	ТаблицаСкидок.СкидкаНаценка.ОбластьПредоставления КАК ОбластьПредоставления,
	ТаблицаСкидок.СкидкаНаценка.ВидЦены КАК ВидЦены,
	ТаблицаСкидок.СкидкаНаценка.ЗначениеСкидкиНаценки КАК ЗначениеСкидкиНаценки,
	ТаблицаСкидок.СкидкаНаценка.СегментНоменклатурыПредоставления КАК СегментНоменклатурыПредоставления,
	ТаблицаСкидок.СкидкаНаценка.ПодарокИзСписка КАК ПодарокИзСписка,
	ТаблицаСкидок.СкидкаНаценка.ПодарокИзКорзиныПокупателя КАК ПодарокИзКорзиныПокупателя,
	ТаблицаСкидок.СкидкаНаценка.КоличествоПодарковИзКорзиныПокупателя КАК КоличествоПодарковИзКорзиныПокупателя,
	ТаблицаСкидок.СкидкаНаценка.УчитыватьПодарокКакПродажу КАК УчитыватьПодарокКакПродажу,
	ТаблицаСкидок.СкидкаНаценка.ТекстСообщения КАК ТекстСообщения,
	ТаблицаСкидок.СкидкаНаценка.МоментВыдачиСообщения КАК МоментВыдачиСообщения,
	ТаблицаСкидок.СкидкаНаценка.КратноКоличествуУсловий КАК КратноКоличествуУсловий,
	ТаблицаСкидок.СкидкаНаценка.ОграничениеРазмераПодчиненныхСкидок КАК ОграничениеРазмераПодчиненныхСкидок,
	ТаблицаСкидок.СкидкаНаценка.СпособПредоставления КАК СпособОграничения,
	ТаблицаСкидок.СкидкаНаценка.ЗначениеСкидкиНаценки КАК ЗначениеОграничения,
	ТаблицаСкидок.СкидкаНаценка.ВнешняяОбработка КАК ВнешняяОбработка,
	ТаблицаСкидок.СкидкаНаценка.ПараметрыВнешнейОбработки КАК ПараметрыВнешнейОбработки,
	ТаблицаСкидок.СкидкаНаценка.ВнешняяОбработка.Публикация КАК Публикация,
	ТаблицаСкидок.СкидкаНаценка.Управляемая КАК Управляемая,
	0 КАК КоличествоВыполненийУсловия,
	ПараметрыСкидок.ИмяРаздела КАК ИмяРаздела,
	ПараметрыСкидок.НомерСтрокиПодарка КАК НомерСтрокиПодарка,
	ПараметрыСкидок.Номенклатура КАК Номенклатура,
	ПараметрыСкидок.Характеристика КАК Характеристика,
	ПараметрыСкидок.Упаковка КАК Упаковка,
	ПараметрыСкидок.КоличествоУпаковок КАК КоличествоУпаковок,
	ПараметрыСкидок.Количество КАК Количество,
	ПараметрыСкидок.НомерСтрокиЦеновойГруппы КАК НомерСтрокиЦеновойГруппы,
	ПараметрыСкидок.ЦеноваяГруппа КАК ЦеноваяГруппа,
	ПараметрыСкидок.ЗначениеСкидкиНаценки КАК ЗначениеПоЦеновойГруппе
ИЗ
	ТаблицаСкидок КАК ТаблицаСкидок
		ЛЕВОЕ СОЕДИНЕНИЕ ПараметрыСкидок КАК ПараметрыСкидок
		ПО (ПараметрыСкидок.СкидкаНаценка = ТаблицаСкидок.СкидкаНаценка)

УПОРЯДОЧИТЬ ПО
	РеквизитДопУпорядочивания,
	СкидкаНаценка
ИТОГИ
	ЛОЖЬ КАК Безусловная,
	МАКСИМУМ(СпособПредоставления) КАК СпособПредоставления,
	МАКСИМУМ(ОбластьПредоставления) КАК ОбластьПредоставления,
	МАКСИМУМ(ВидЦены) КАК ВидЦены,
	МАКСИМУМ(ЗначениеСкидкиНаценки) КАК ЗначениеСкидкиНаценки,
	МАКСИМУМ(СегментНоменклатурыПредоставления) КАК СегментНоменклатурыПредоставления,
	МАКСИМУМ(ПодарокИзСписка) КАК ПодарокИзСписка,
	МАКСИМУМ(ПодарокИзКорзиныПокупателя) КАК ПодарокИзКорзиныПокупателя,
	МАКСИМУМ(КоличествоПодарковИзКорзиныПокупателя) КАК КоличествоПодарковИзКорзиныПокупателя,
	МАКСИМУМ(УчитыватьПодарокКакПродажу) КАК УчитыватьПодарокКакПродажу,
	МАКСИМУМ(ТекстСообщения) КАК ТекстСообщения,
	МАКСИМУМ(МоментВыдачиСообщения) КАК МоментВыдачиСообщения,
	МАКСИМУМ(КратноКоличествуУсловий) КАК КратноКоличествуУсловий,
	ОграничениеРазмераПодчиненныхСкидок КАК ОграничениеРазмераПодчиненныхСкидок,
	СпособОграничения КАК СпособОграничения,
	ЗначениеОграничения КАК ЗначениеОграничения,
	Управляемая КАК Управляемая,
	0 КАК КоличествоВыполненийУсловия
ПО
	ОБЩИЕ,
	СкидкаНаценка ИЕРАРХИЯ