Начисление родительской платы

Процедура ЗаполнитьЗадолженностьОстаткамиНаНачалоМесяца() Экспорт
	
	Если Квитанции.Количество()=0 Тогда
		Возврат;
	КонецЕсли;
	
	СчетУчетаКод = Лев(СчетУчетаРП.Код,6);
	СчетУчета = ПолучениеНСИ.ПолучитьСчетПоКоду(СчетУчетаКод);
	Если Не СчетУчета.ЭлементГруппа Тогда
		СчетУчета = СчетУчета.Родитель;
	КонецЕсли;
	
	Запрос = Новый Запрос;
	Запрос.УстановитьПараметр("ДатаКон",        НачалоМесяца(Дата));
	Запрос.УстановитьПараметр("ТабЧасть",       Квитанции);
	Запрос.УстановитьПараметр("Учреждение",     Учреждение);
	Запрос.УстановитьПараметр("СчетУчета",      СчетУчета);
	Запрос.УстановитьПараметр("КБК",            КБКСчетУчетаРП);
	Запрос.УстановитьПараметр("Баланс",         Баланс);
	Запрос.УстановитьПараметр("КВД",            КВД);
	Запрос.Текст =
	"ВЫБРАТЬ
	|	ТабЧасть.Ребенок КАК Ребенок,
	|	ТабЧасть.Контрагент КАК Контрагент,
	|	ТабЧасть.Договор КАК Договор,
	|	ТабЧасть.НомерЛицевогоСчета КАК НомерЛицевогоСчета,
	|	ТабЧасть.СтавкаОплаты,
	|	ТабЧасть.ФиксированнаяСтавка,
	|	ТабЧасть.ПеременнаяСтавка,
	|	ТабЧасть.СтавкаЗаДень,
	|	ТабЧасть.ПроцентЛьготы,
	|	ТабЧасть.Сумма
	|ПОМЕСТИТЬ ВремТабЧасть
	|ИЗ
	|	&ТабЧасть КАК ТабЧасть
	|;
	|
	|////////////////////////////////////////////////////////////­////////////////////
	|ВЫБРАТЬ
	|	ВремТабЧасть.Ребенок КАК Ребенок,
	|	ВремТабЧасть.Контрагент КАК Контрагент,
	|	ВремТабЧасть.Договор КАК Договор,
	|	ВремТабЧасть.НомерЛицевогоСчета,
	|	ВремТабЧасть.СтавкаОплаты,
	|	ВремТабЧасть.ФиксированнаяСтавка,
	|	ВремТабЧасть.ПеременнаяСтавка,
	|	ВремТабЧасть.СтавкаЗаДень,
	|	ВремТабЧасть.ПроцентЛьготы,
	|	ВремТабЧасть.Сумма,
	|	ЕПСБУОстатки.СуммаОстаток КАК Задолженность
	|ИЗ
        |	ВремТабЧасть КАК ВремТабЧасть
	|		ЛЕВОЕ СОЕДИНЕНИЕ РегистрБухгалтерии.ЕПСБУ.Остатки(
	|				&ДатаКон,
	|				Счет В ИЕРАРХИИ (&СчетУчета),
	|				,
	|				Учреждение = &Учреждение
	|					И Баланс = &Баланс
	|					И КВД = &КВД
	|					И КБК = &КБК) КАК ЕПСБУОстатки
	|		ПО ВремТабЧасть.Контрагент = ЕПСБУОстатки.Субконто2
	|			И ВремТабЧасть.Договор = ЕПСБУОстатки.Субконто3";
	
	
	ТаблицаРезультатов = Запрос.Выполнить().Выгрузить(ОбходРезультатаЗапроса.Прямой);
	Если ТаблицаРезультатов.Количество()=0 Тогда
		Квитанции.Очистить();
	Иначе
		Квитанции.Загрузить(ТаблицаРезультатов);
	КонецЕсли;
	
	Для Каждого Строка Из Квитанции Цикл
		Если НЕ ЗначениеЗаполнено(Строка.Договор) Тогда
			Строка.Задолженность = 0;
			ОбщегоНазначения.СообщитьОбОшибке("В строке "+Строка.НомерСтроки+" не заполнен договор контрагента! Задолженность не рассчитана.",,, СтатусСообщения.Внимание);
		КонецЕсли;
		
		РассчитатьСуммуКвитанцииВСтрокеТабЧасти(Строка);
	КонецЦикла;
	
КонецПроцедуры